scripts/checkstack.pl

   1 #!/usr/bin/perl
   2
   3 #       Check the stack usage of functions
   4 #
   5 #       Copyright Joern Engel <joern@lazybastard.org>
   6 #       Inspired by Linus Torvalds
   7 #       Original idea maybe from Keith Owens
   8 #       s390 port and big speedup by Arnd Bergmann <arnd@bergmann-dalldorf.de>
   9 #       Mips port by Juan Quintela <quintela@mandrakesoft.com>
  10 #       IA64 port via Andreas Dilger
  11 #       Arm port by Holger Schurig
  12 #       sh64 port by Paul Mundt
  13 #       Random bits by Matt Mackall <mpm@selenic.com>
  14 #       M68k port by Geert Uytterhoeven and Andreas Schwab
  15 #       AVR32 port by Haavard Skinnemoen (Atmel)
  16 #       AArch64, PARISC ports by Kyle McMartin
  17 #       sparc port by Martin Habets <errandir_news@mph.eclipse.co.uk>
  18 #
  19 #       Usage:
  20 #       objdump -d vmlinux | scripts/checkstack.pl [arch]
  21 #
  22 #       TODO :  Port to all architectures (one regex per arch)
  23
  24 use strict;
  25
  26 # check for arch
  27 #
  28 # $re is used for two matches:
  29 # $& (whole re) matches the complete objdump line with the stack growth
  30 # $1 (first bracket) matches the size of the stack growth
  31 #
  32 # $dre is similar, but for dynamic stack redutions:
  33 # $& (whole re) matches the complete objdump line with the stack growth
  34 # $1 (first bracket) matches the dynamic amount of the stack growth
  35 #
  36 # use anything else and feel the pain ;)
  37 my (@stack, $re, $dre, $x, $xs, $funcre);
  38 {
  39         my $arch = shift;
  40         if ($arch eq "") {
  41                 $arch = `uname -m`;
  42                 chomp($arch);
  43         }
  44
  45         $x      = "[0-9a-f]";   # hex character
  46         $xs     = "[0-9a-f ]";  # hex character or space
  47         $funcre = qr/^$x* <(.*)>:$/;
  48         if ($arch eq 'aarch64') {
  49                 #ffffffc0006325cc:       a9bb7bfd        stp     x29, x30, [sp,#-80]!
  50                 $re = qr/^.*stp.*sp,\#-([0-9]{1,8})\]\!/o;
  51         } elsif ($arch eq 'arm') {
  52                 #c0008ffc:      e24dd064        sub     sp, sp, #100    ; 0x64
  53                 $re = qr/.*sub.*sp, sp, #(([0-9]{2}|[3-9])[0-9]{2})/o;
  54         } elsif ($arch eq 'avr32') {
  55                 #8000008a:       20 1d           sub sp,4
  56                 #80000ca8:       fa cd 05 b0     sub sp,sp,1456
  57                 $re = qr/^.*sub.*sp.*,([0-9]{1,8})/o;
  58         } elsif ($arch =~ /^x86(_64)?$/ || $arch =~ /^i[3456]86$/) {
  59                 #c0105234:       81 ec ac 05 00 00       sub    $0x5ac,%esp
  60                 # or
  61                 #    2f60:    48 81 ec e8 05 00 00       sub    $0x5e8,%rsp
  62                 $re = qr/^.*[as][du][db]    \$(0x$x{1,8}),\%(e|r)sp$/o;
  63                 $dre = qr/^.*[as][du][db]    (%.*),\%(e|r)sp$/o;
  64         } elsif ($arch eq 'ia64') {
  65                 #e0000000044011fc:       01 0f fc 8c     adds r12=-384,r12
  66                 $re = qr/.*adds.*r12=-(([0-9]{2}|[3-9])[0-9]{2}),r12/o;
  67         } elsif ($arch eq 'm68k') {
  68                 #    2b6c:       4e56 fb70       linkw %fp,#-1168
  69                 #  1df770:       defc ffe4       addaw #-28,%sp
  70                 $re = qr/.*(?:linkw %fp,|addaw )#-([0-9]{1,4})(?:,%sp)?$/o;
  71         } elsif ($arch eq 'metag') {
  72                 #400026fc:       40 00 00 82     ADD       A0StP,A0StP,#0x8
  73                 $re = qr/.*ADD.*A0StP,A0StP,\#(0x$x{1,8})/o;
  74                 $funcre = qr/^$x* <[^\$](.*)>:$/;
  75         } elsif ($arch eq 'mips64') {
  76                 #8800402c:       67bdfff0        daddiu  sp,sp,-16
  77                 $re = qr/.*daddiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  78         } elsif ($arch eq 'mips') {
  79                 #88003254:       27bdffe0        addiu   sp,sp,-32
  80                 $re = qr/.*addiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  81         } elsif ($arch eq 'nios2') {
  82                 #25a8:  defffb04        addi    sp,sp,-20
  83                 $re = qr/.*addi.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  84         } elsif ($arch eq 'openrisc') {
  85                 # c000043c:       9c 21 fe f0     l.addi r1,r1,-272
  86                 $re = qr/.*l\.addi.*r1,r1,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  87         } elsif ($arch eq 'parisc' || $arch eq 'parisc64') {
  88                 $re = qr/.*ldo ($x{1,8})\(sp\),sp/o;
  89         } elsif ($arch eq 'ppc') {
  90                 #c00029f4:       94 21 ff 30     stwu    r1,-208(r1)
  91                 $re = qr/.*stwu.*r1,-($x{1,8})\(r1\)/o;
  92         } elsif ($arch eq 'ppc64') {
  93                 #XXX
  94                 $re = qr/.*stdu.*r1,-($x{1,8})\(r1\)/o;
  95         } elsif ($arch eq 'powerpc') {
  96                 $re = qr/.*st[dw]u.*r1,-($x{1,8})\(r1\)/o;
  97         } elsif ($arch =~ /^s390x?$/) {
  98                 #   11160:       a7 fb ff 60             aghi   %r15,-160
  99                 # or
 100                 #  100092:       e3 f0 ff c8 ff 71       lay     %r15,-56(%r15)
 101                 $re = qr/.*(?:lay|ag?hi).*\%r15,-(([0-9]{2}|[3-9])[0-9]{2})
 102                       (?:\(\%r15\))?$/ox;
 103         } elsif ($arch =~ /^sh64$/) {
 104                 #XXX: we only check for the immediate case presently,
 105                 #     though we will want to check for the movi/sub
 106                 #     pair for larger users. -- PFM.
 107                 #a00048e0:       d4fc40f0        addi.l  r15,-240,r15
 108                 $re = qr/.*addi\.l.*r15,-(([0-9]{2}|[3-9])[0-9]{2}),r15/o;
 109         } elsif ($arch =~ /^blackfin$/) {
 110                 #   0:   00 e8 38 01     LINK 0x4e0;
 111                 $re = qr/.*[[:space:]]LINK[[:space:]]*(0x$x{1,8})/o;
 112         } elsif ($arch eq 'sparc' || $arch eq 'sparc64') {
 113                 # f0019d10:       9d e3 bf 90     save  %sp, -112, %sp
 114                 $re = qr/.*save.*%sp, -(([0-9]{2}|[3-9])[0-9]{2}), %sp/o;
 115         } else {
 116                 print("wrong or unknown architecture \"$arch\"\n");
 117                 exit
 118         }
 119 }
 120
 121 #
 122 # main()
 123 #
 124 my ($func, $file, $lastslash);
 125
 126 while (my $line = <STDIN>) {
 127         if ($line =~ m/$funcre/) {
 128                 $func = $1;
 129         }
 130         elsif ($line =~ m/(.*):\s*file format/) {
 131                 $file = $1;
 132                 $file =~ s/\.ko//;
 133                 $lastslash = rindex($file, "/");
 134                 if ($lastslash != -1) {
 135                         $file = substr($file, $lastslash + 1);
 136                 }
 137         }
 138         elsif ($line =~ m/$re/) {
 139                 my $size = $1;
 140                 $size = hex($size) if ($size =~ /^0x/);
 141
 142                 if ($size > 0xf0000000) {
 143                         $size = - $size;
 144                         $size += 0x80000000;
 145                         $size += 0x80000000;
 146                 }
 147                 next if ($size > 0x10000000);
 148
 149                 next if $line !~ m/^($xs*)/;
 150                 my $addr = $1;
 151                 $addr =~ s/ /0/g;
 152                 $addr = "0x$addr";
 153
 154                 my $intro = "$addr $func [$file]:";
 155                 my $padlen = 56 - length($intro);
 156                 while ($padlen > 0) {
 157                         $intro .= '     ';
 158                         $padlen -= 8;
 159                 }
 160                 next if ($size < 100);
 161                 push @stack, "$intro$size\n";
 162         }
 163         elsif (defined $dre && $line =~ m/$dre/) {
 164                 my $size = "Dynamic ($1)";
 165
 166                 next if $line !~ m/^($xs*)/;
 167                 my $addr = $1;
 168                 $addr =~ s/ /0/g;
 169                 $addr = "0x$addr";
 170
 171                 my $intro = "$addr $func [$file]:";
 172                 my $padlen = 56 - length($intro);
 173                 while ($padlen > 0) {
 174                         $intro .= '     ';
 175                         $padlen -= 8;
 176                 }
 177                 push @stack, "$intro$size\n";
 178         }
 179 }
 180
 181 # Sort output by size (last field)
 182 print sort { ($b =~ /:\t*(\d+)$/)[0] <=> ($a =~ /:\t*(\d+)$/)[0] } @stack;