arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/assembler.h>
  12 #include <asm/unistd.h>
  13 #include <asm/ftrace.h>
  14 #include <asm/unwind.h>
  15 #include <asm/memory.h>
  16 #ifdef CONFIG_AEABI
  17 #include <asm/unistd-oabi.h>
  18 #endif
  19
  20         .equ    NR_syscalls, __NR_syscalls
  21
  22 #ifdef CONFIG_NEED_RET_TO_USER
  23 #include <mach/entry-macro.S>
  24 #else
  25         .macro  arch_ret_to_user, tmp1, tmp2
  26         .endm
  27 #endif
  28
  29 #include "entry-header.S"
  30
  31 saved_psr       .req    r8
  32 #if defined(CONFIG_TRACE_IRQFLAGS) || defined(CONFIG_CONTEXT_TRACKING)
  33 saved_pc        .req    r9
  34 #define TRACE(x...) x
  35 #else
  36 saved_pc        .req    lr
  37 #define TRACE(x...)
  38 #endif
  39
  40         .section .entry.text,"ax",%progbits
  41         .align  5
  42 #if !(IS_ENABLED(CONFIG_TRACE_IRQFLAGS) || IS_ENABLED(CONFIG_CONTEXT_TRACKING))
  43 /*
  44  * This is the fast syscall return path.  We do as little as possible here,
  45  * such as avoiding writing r0 to the stack.  We only use this path if we
  46  * have tracing and context tracking disabled - the overheads from those
  47  * features make this path too inefficient.
  48  */
  49 ret_fast_syscall:
  50  UNWIND(.fnstart        )
  51  UNWIND(.cantunwind     )
  52         disable_irq_notrace                     @ disable interrupts
  53         ldr     r2, [tsk, #TI_ADDR_LIMIT]
  54         cmp     r2, #TASK_SIZE
  55         blne    addr_limit_check_failed
  56         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  57         tst     r1, #_TIF_SYSCALL_WORK | _TIF_WORK_MASK
  58         bne     fast_work_pending
  59
  60
  61         /* perform architecture specific actions before user return */
  62         arch_ret_to_user r1, lr
  63
  64         restore_user_regs fast = 1, offset = S_OFF
  65  UNWIND(.fnend          )
  66 ENDPROC(ret_fast_syscall)
  67
  68         /* Ok, we need to do extra processing, enter the slow path. */
  69 fast_work_pending:
  70         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  71         /* fall through to work_pending */
  72 #else
  73 /*
  74  * The "replacement" ret_fast_syscall for when tracing or context tracking
  75  * is enabled.  As we will need to call out to some C functions, we save
  76  * r0 first to avoid needing to save registers around each C function call.
  77  */
  78 ret_fast_syscall:
  79  UNWIND(.fnstart        )
  80  UNWIND(.cantunwind     )
  81         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
  82         disable_irq_notrace                     @ disable interrupts
  83         ldr     r2, [tsk, #TI_ADDR_LIMIT]
  84         cmp     r2, #TASK_SIZE
  85         blne    addr_limit_check_failed
  86         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  87         tst     r1, #_TIF_SYSCALL_WORK | _TIF_WORK_MASK
  88         beq     no_work_pending
  89  UNWIND(.fnend          )
  90 ENDPROC(ret_fast_syscall)
  91
  92         /* Slower path - fall through to work_pending */
  93 #endif
  94
  95         tst     r1, #_TIF_SYSCALL_WORK
  96         bne     __sys_trace_return_nosave
  97 slow_work_pending:
  98         mov     r0, sp                          @ 'regs'
  99         mov     r2, why                         @ 'syscall'
 100         bl      do_work_pending
 101         cmp     r0, #0
 102         beq     no_work_pending
 103         movlt   scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
 104         ldmia   sp, {r0 - r6}                   @ have to reload r0 - r6
 105         b       local_restart                   @ ... and off we go
 106 ENDPROC(ret_fast_syscall)
 107
 108 /*
 109  * "slow" syscall return path.  "why" tells us if this was a real syscall.
 110  * IRQs may be enabled here, so always disable them.  Note that we use the
 111  * "notrace" version to avoid calling into the tracing code unnecessarily.
 112  * do_work_pending() will update this state if necessary.
 113  */
 114 ENTRY(ret_to_user)
 115 ret_slow_syscall:
 116         disable_irq_notrace                     @ disable interrupts
 117 ENTRY(ret_to_user_from_irq)
 118         ldr     r2, [tsk, #TI_ADDR_LIMIT]
 119         cmp     r2, #TASK_SIZE
 120         blne    addr_limit_check_failed
 121         ldr     r1, [tsk, #TI_FLAGS]
 122         tst     r1, #_TIF_WORK_MASK
 123         bne     slow_work_pending
 124 no_work_pending:
 125         asm_trace_hardirqs_on save = 0
 126
 127         /* perform architecture specific actions before user return */
 128         arch_ret_to_user r1, lr
 129         ct_user_enter save = 0
 130
 131         restore_user_regs fast = 0, offset = 0
 132 ENDPROC(ret_to_user_from_irq)
 133 ENDPROC(ret_to_user)
 134
 135 /*
 136  * This is how we return from a fork.
 137  */
 138 ENTRY(ret_from_fork)
 139         bl      schedule_tail
 140         cmp     r5, #0
 141         movne   r0, r4
 142         badrne  lr, 1f
 143         retne   r5
 144 1:      get_thread_info tsk
 145         b       ret_slow_syscall
 146 ENDPROC(ret_from_fork)
 147
 148 /*=============================================================================
 149  * SWI handler
 150  *-----------------------------------------------------------------------------
 151  */
 152
 153         .align  5
 154 ENTRY(vector_swi)
 155 #ifdef CONFIG_CPU_V7M
 156         v7m_exception_entry
 157 #else
 158         sub     sp, sp, #PT_REGS_SIZE
 159         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 160  ARM(   add     r8, sp, #S_PC           )
 161  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 162  THUMB( mov     r8, sp                  )
 163  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 164         mrs     saved_psr, spsr                 @ called from non-FIQ mode, so ok.
 165  TRACE( mov     saved_pc, lr            )
 166         str     saved_pc, [sp, #S_PC]           @ Save calling PC
 167         str     saved_psr, [sp, #S_PSR]         @ Save CPSR
 168         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 169 #endif
 170         zero_fp
 171         alignment_trap r10, ip, __cr_alignment
 172         asm_trace_hardirqs_on save=0
 173         enable_irq_notrace
 174         ct_user_exit save=0
 175
 176         /*
 177          * Get the system call number.
 178          */
 179
 180 #if defined(CONFIG_OABI_COMPAT)
 181
 182         /*
 183          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 184          * value to determine if it is an EABI or an old ABI call.
 185          */
 186 #ifdef CONFIG_ARM_THUMB
 187         tst     saved_psr, #PSR_T_BIT
 188         movne   r10, #0                         @ no thumb OABI emulation
 189  USER(  ldreq   r10, [saved_pc, #-4]    )       @ get SWI instruction
 190 #else
 191  USER(  ldr     r10, [saved_pc, #-4]    )       @ get SWI instruction
 192 #endif
 193  ARM_BE8(rev    r10, r10)                       @ little endian instruction
 194
 195 #elif defined(CONFIG_AEABI)
 196
 197         /*
 198          * Pure EABI user space always put syscall number into scno (r7).
 199          */
 200 #elif defined(CONFIG_ARM_THUMB)
 201         /* Legacy ABI only, possibly thumb mode. */
 202         tst     saved_psr, #PSR_T_BIT           @ this is SPSR from save_user_regs
 203         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 204  USER(  ldreq   scno, [saved_pc, #-4]   )
 205
 206 #else
 207         /* Legacy ABI only. */
 208  USER(  ldr     scno, [saved_pc, #-4]   )       @ get SWI instruction
 209 #endif
 210
 211         /* saved_psr and saved_pc are now dead */
 212
 213         uaccess_disable tbl
 214
 215         adr     tbl, sys_call_table             @ load syscall table pointer
 216
 217 #if defined(CONFIG_OABI_COMPAT)
 218         /*
 219          * If the swi argument is zero, this is an EABI call and we do nothing.
 220          *
 221          * If this is an old ABI call, get the syscall number into scno and
 222          * get the old ABI syscall table address.
 223          */
 224         bics    r10, r10, #0xff000000
 225         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 226         ldrne   tbl, =sys_oabi_call_table
 227 #elif !defined(CONFIG_AEABI)
 228         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 229         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 230 #endif
 231         get_thread_info tsk
 232         /*
 233          * Reload the registers that may have been corrupted on entry to
 234          * the syscall assembly (by tracing or context tracking.)
 235          */
 236  TRACE( ldmia   sp, {r0 - r3}           )
 237
 238 local_restart:
 239         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 240         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 241
 242         tst     r10, #_TIF_SYSCALL_WORK         @ are we tracing syscalls?
 243         bne     __sys_trace
 244
 245         cmp     scno, #NR_syscalls              @ check upper syscall limit
 246         badr    lr, ret_fast_syscall            @ return address
 247         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 248
 249         add     r1, sp, #S_OFF
 250 2:      cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 251         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 252         bcs     arm_syscall
 253         mov     why, #0                         @ no longer a real syscall
 254         b       sys_ni_syscall                  @ not private func
 255
 256 #if defined(CONFIG_OABI_COMPAT) || !defined(CONFIG_AEABI)
 257         /*
 258          * We failed to handle a fault trying to access the page
 259          * containing the swi instruction, but we're not really in a
 260          * position to return -EFAULT. Instead, return back to the
 261          * instruction and re-enter the user fault handling path trying
 262          * to page it in. This will likely result in sending SEGV to the
 263          * current task.
 264          */
 265 9001:
 266         sub     lr, saved_pc, #4
 267         str     lr, [sp, #S_PC]
 268         get_thread_info tsk
 269         b       ret_fast_syscall
 270 #endif
 271 ENDPROC(vector_swi)
 272
 273         /*
 274          * This is the really slow path.  We're going to be doing
 275          * context switches, and waiting for our parent to respond.
 276          */
 277 __sys_trace:
 278         mov     r1, scno
 279         add     r0, sp, #S_OFF
 280         bl      syscall_trace_enter
 281
 282         badr    lr, __sys_trace_return          @ return address
 283         mov     scno, r0                        @ syscall number (possibly new)
 284         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 285         cmp     scno, #NR_syscalls              @ check upper syscall limit
 286         ldmccia r1, {r0 - r6}                   @ have to reload r0 - r6
 287         stmccia sp, {r4, r5}                    @ and update the stack args
 288         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 289         cmp     scno, #-1                       @ skip the syscall?
 290         bne     2b
 291         add     sp, sp, #S_OFF                  @ restore stack
 292         b       ret_slow_syscall
 293
 294 __sys_trace_return:
 295         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 296         mov     r0, sp
 297         bl      syscall_trace_exit
 298         b       ret_slow_syscall
 299
 300 __sys_trace_return_nosave:
 301         enable_irq_notrace
 302         mov     r0, sp
 303         bl      syscall_trace_exit
 304         b       ret_slow_syscall
 305
 306         .align  5
 307 #ifdef CONFIG_ALIGNMENT_TRAP
 308         .type   __cr_alignment, #object
 309 __cr_alignment:
 310         .word   cr_alignment
 311 #endif
 312         .ltorg
 313
 314         .macro  syscall_table_start, sym
 315         .equ    __sys_nr, 0
 316         .type   \sym, #object
 317 ENTRY(\sym)
 318         .endm
 319
 320         .macro  syscall, nr, func
 321         .ifgt   __sys_nr - \nr
 322         .error  "Duplicated/unorded system call entry"
 323         .endif
 324         .rept   \nr - __sys_nr
 325         .long   sys_ni_syscall
 326         .endr
 327         .long   \func
 328         .equ    __sys_nr, \nr + 1
 329         .endm
 330
 331         .macro  syscall_table_end, sym
 332         .ifgt   __sys_nr - __NR_syscalls
 333         .error  "System call table too big"
 334         .endif
 335         .rept   __NR_syscalls - __sys_nr
 336         .long   sys_ni_syscall
 337         .endr
 338         .size   \sym, . - \sym
 339         .endm
 340
 341 #define NATIVE(nr, func) syscall nr, func
 342
 343 /*
 344  * This is the syscall table declaration for native ABI syscalls.
 345  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 346  */
 347         syscall_table_start sys_call_table
 348 #define COMPAT(nr, native, compat) syscall nr, native
 349 #ifdef CONFIG_AEABI
 350 #include <calls-eabi.S>
 351 #else
 352 #include <calls-oabi.S>
 353 #endif
 354 #undef COMPAT
 355         syscall_table_end sys_call_table
 356
 357 /*============================================================================
 358  * Special system call wrappers
 359  */
 360 @ r0 = syscall number
 361 @ r8 = syscall table
 362 sys_syscall:
 363                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 364                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 365                 cmpne   scno, #NR_syscalls      @ check range
 366                 stmloia sp, {r5, r6}            @ shuffle args
 367                 movlo   r0, r1
 368                 movlo   r1, r2
 369                 movlo   r2, r3
 370                 movlo   r3, r4
 371                 ldrlo   pc, [tbl, scno, lsl #2]
 372                 b       sys_ni_syscall
 373 ENDPROC(sys_syscall)
 374
 375 sys_sigreturn_wrapper:
 376                 add     r0, sp, #S_OFF
 377                 mov     why, #0         @ prevent syscall restart handling
 378                 b       sys_sigreturn
 379 ENDPROC(sys_sigreturn_wrapper)
 380
 381 sys_rt_sigreturn_wrapper:
 382                 add     r0, sp, #S_OFF
 383                 mov     why, #0         @ prevent syscall restart handling
 384                 b       sys_rt_sigreturn
 385 ENDPROC(sys_rt_sigreturn_wrapper)
 386
 387 sys_statfs64_wrapper:
 388                 teq     r1, #88
 389                 moveq   r1, #84
 390                 b       sys_statfs64
 391 ENDPROC(sys_statfs64_wrapper)
 392
 393 sys_fstatfs64_wrapper:
 394                 teq     r1, #88
 395                 moveq   r1, #84
 396                 b       sys_fstatfs64
 397 ENDPROC(sys_fstatfs64_wrapper)
 398
 399 /*
 400  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 401  * offset, we return EINVAL.
 402  */
 403 sys_mmap2:
 404                 str     r5, [sp, #4]
 405                 b       sys_mmap_pgoff
 406 ENDPROC(sys_mmap2)
 407
 408 #ifdef CONFIG_OABI_COMPAT
 409
 410 /*
 411  * These are syscalls with argument register differences
 412  */
 413
 414 sys_oabi_pread64:
 415                 stmia   sp, {r3, r4}
 416                 b       sys_pread64
 417 ENDPROC(sys_oabi_pread64)
 418
 419 sys_oabi_pwrite64:
 420                 stmia   sp, {r3, r4}
 421                 b       sys_pwrite64
 422 ENDPROC(sys_oabi_pwrite64)
 423
 424 sys_oabi_truncate64:
 425                 mov     r3, r2
 426                 mov     r2, r1
 427                 b       sys_truncate64
 428 ENDPROC(sys_oabi_truncate64)
 429
 430 sys_oabi_ftruncate64:
 431                 mov     r3, r2
 432                 mov     r2, r1
 433                 b       sys_ftruncate64
 434 ENDPROC(sys_oabi_ftruncate64)
 435
 436 sys_oabi_readahead:
 437                 str     r3, [sp]
 438                 mov     r3, r2
 439                 mov     r2, r1
 440                 b       sys_readahead
 441 ENDPROC(sys_oabi_readahead)
 442
 443 /*
 444  * Let's declare a second syscall table for old ABI binaries
 445  * using the compatibility syscall entries.
 446  */
 447         syscall_table_start sys_oabi_call_table
 448 #define COMPAT(nr, native, compat) syscall nr, compat
 449 #include <calls-oabi.S>
 450         syscall_table_end sys_oabi_call_table
 451
 452 #endif
 453