arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/assembler.h>
  12 #include <asm/unistd.h>
  13 #include <asm/ftrace.h>
  14 #include <asm/unwind.h>
  15 #include <asm/memory.h>
  16 #ifdef CONFIG_AEABI
  17 #include <asm/unistd-oabi.h>
  18 #endif
  19
  20         .equ    NR_syscalls, __NR_syscalls
  21
  22 #ifdef CONFIG_NEED_RET_TO_USER
  23 #include <mach/entry-macro.S>
  24 #else
  25         .macro  arch_ret_to_user, tmp1, tmp2
  26         .endm
  27 #endif
  28
  29 #include "entry-header.S"
  30
  31 saved_psr       .req    r8
  32 #if defined(CONFIG_TRACE_IRQFLAGS) || defined(CONFIG_CONTEXT_TRACKING)
  33 saved_pc        .req    r9
  34 #define TRACE(x...) x
  35 #else
  36 saved_pc        .req    lr
  37 #define TRACE(x...)
  38 #endif
  39
  40         .align  5
  41 #if !(IS_ENABLED(CONFIG_TRACE_IRQFLAGS) || IS_ENABLED(CONFIG_CONTEXT_TRACKING))
  42 /*
  43  * This is the fast syscall return path.  We do as little as possible here,
  44  * such as avoiding writing r0 to the stack.  We only use this path if we
  45  * have tracing and context tracking disabled - the overheads from those
  46  * features make this path too inefficient.
  47  */
  48 ret_fast_syscall:
  49 __ret_fast_syscall:
  50  UNWIND(.fnstart        )
  51  UNWIND(.cantunwind     )
  52         disable_irq_notrace                     @ disable interrupts
  53         ldr     r2, [tsk, #TI_ADDR_LIMIT]
  54         cmp     r2, #TASK_SIZE
  55         blne    addr_limit_check_failed
  56         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  57         tst     r1, #_TIF_SYSCALL_WORK | _TIF_WORK_MASK
  58         bne     fast_work_pending
  59
  60
  61         /* perform architecture specific actions before user return */
  62         arch_ret_to_user r1, lr
  63
  64         restore_user_regs fast = 1, offset = S_OFF
  65  UNWIND(.fnend          )
  66 ENDPROC(ret_fast_syscall)
  67
  68         /* Ok, we need to do extra processing, enter the slow path. */
  69 fast_work_pending:
  70         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  71         /* fall through to work_pending */
  72 #else
  73 /*
  74  * The "replacement" ret_fast_syscall for when tracing or context tracking
  75  * is enabled.  As we will need to call out to some C functions, we save
  76  * r0 first to avoid needing to save registers around each C function call.
  77  */
  78 ret_fast_syscall:
  79 __ret_fast_syscall:
  80  UNWIND(.fnstart        )
  81  UNWIND(.cantunwind     )
  82         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
  83         disable_irq_notrace                     @ disable interrupts
  84         ldr     r2, [tsk, #TI_ADDR_LIMIT]
  85         cmp     r2, #TASK_SIZE
  86         blne    addr_limit_check_failed
  87         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  88         tst     r1, #_TIF_SYSCALL_WORK | _TIF_WORK_MASK
  89         beq     no_work_pending
  90  UNWIND(.fnend          )
  91 ENDPROC(ret_fast_syscall)
  92
  93         /* Slower path - fall through to work_pending */
  94 #endif
  95
  96         tst     r1, #_TIF_SYSCALL_WORK
  97         bne     __sys_trace_return_nosave
  98 slow_work_pending:
  99         mov     r0, sp                          @ 'regs'
 100         mov     r2, why                         @ 'syscall'
 101         bl      do_work_pending
 102         cmp     r0, #0
 103         beq     no_work_pending
 104         movlt   scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
 105         ldmia   sp, {r0 - r6}                   @ have to reload r0 - r6
 106         b       local_restart                   @ ... and off we go
 107 ENDPROC(ret_fast_syscall)
 108
 109 /*
 110  * "slow" syscall return path.  "why" tells us if this was a real syscall.
 111  * IRQs may be enabled here, so always disable them.  Note that we use the
 112  * "notrace" version to avoid calling into the tracing code unnecessarily.
 113  * do_work_pending() will update this state if necessary.
 114  */
 115 ENTRY(ret_to_user)
 116 ret_slow_syscall:
 117         disable_irq_notrace                     @ disable interrupts
 118 ENTRY(ret_to_user_from_irq)
 119         ldr     r2, [tsk, #TI_ADDR_LIMIT]
 120         cmp     r2, #TASK_SIZE
 121         blne    addr_limit_check_failed
 122         ldr     r1, [tsk, #TI_FLAGS]
 123         tst     r1, #_TIF_WORK_MASK
 124         bne     slow_work_pending
 125 no_work_pending:
 126         asm_trace_hardirqs_on save = 0
 127
 128         /* perform architecture specific actions before user return */
 129         arch_ret_to_user r1, lr
 130         ct_user_enter save = 0
 131
 132         restore_user_regs fast = 0, offset = 0
 133 ENDPROC(ret_to_user_from_irq)
 134 ENDPROC(ret_to_user)
 135
 136 /*
 137  * This is how we return from a fork.
 138  */
 139 ENTRY(ret_from_fork)
 140         bl      schedule_tail
 141         cmp     r5, #0
 142         movne   r0, r4
 143         badrne  lr, 1f
 144         retne   r5
 145 1:      get_thread_info tsk
 146         b       ret_slow_syscall
 147 ENDPROC(ret_from_fork)
 148
 149 /*=============================================================================
 150  * SWI handler
 151  *-----------------------------------------------------------------------------
 152  */
 153
 154         .align  5
 155 ENTRY(vector_swi)
 156 #ifdef CONFIG_CPU_V7M
 157         v7m_exception_entry
 158 #else
 159         sub     sp, sp, #PT_REGS_SIZE
 160         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 161  ARM(   add     r8, sp, #S_PC           )
 162  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 163  THUMB( mov     r8, sp                  )
 164  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 165         mrs     saved_psr, spsr                 @ called from non-FIQ mode, so ok.
 166  TRACE( mov     saved_pc, lr            )
 167         str     saved_pc, [sp, #S_PC]           @ Save calling PC
 168         str     saved_psr, [sp, #S_PSR]         @ Save CPSR
 169         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 170 #endif
 171         zero_fp
 172         alignment_trap r10, ip, __cr_alignment
 173         asm_trace_hardirqs_on save=0
 174         enable_irq_notrace
 175         ct_user_exit save=0
 176
 177         /*
 178          * Get the system call number.
 179          */
 180
 181 #if defined(CONFIG_OABI_COMPAT)
 182
 183         /*
 184          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 185          * value to determine if it is an EABI or an old ABI call.
 186          */
 187 #ifdef CONFIG_ARM_THUMB
 188         tst     saved_psr, #PSR_T_BIT
 189         movne   r10, #0                         @ no thumb OABI emulation
 190  USER(  ldreq   r10, [saved_pc, #-4]    )       @ get SWI instruction
 191 #else
 192  USER(  ldr     r10, [saved_pc, #-4]    )       @ get SWI instruction
 193 #endif
 194  ARM_BE8(rev    r10, r10)                       @ little endian instruction
 195
 196 #elif defined(CONFIG_AEABI)
 197
 198         /*
 199          * Pure EABI user space always put syscall number into scno (r7).
 200          */
 201 #elif defined(CONFIG_ARM_THUMB)
 202         /* Legacy ABI only, possibly thumb mode. */
 203         tst     saved_psr, #PSR_T_BIT           @ this is SPSR from save_user_regs
 204         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 205  USER(  ldreq   scno, [saved_pc, #-4]   )
 206
 207 #else
 208         /* Legacy ABI only. */
 209  USER(  ldr     scno, [saved_pc, #-4]   )       @ get SWI instruction
 210 #endif
 211
 212         /* saved_psr and saved_pc are now dead */
 213
 214         uaccess_disable tbl
 215
 216         adr     tbl, sys_call_table             @ load syscall table pointer
 217
 218 #if defined(CONFIG_OABI_COMPAT)
 219         /*
 220          * If the swi argument is zero, this is an EABI call and we do nothing.
 221          *
 222          * If this is an old ABI call, get the syscall number into scno and
 223          * get the old ABI syscall table address.
 224          */
 225         bics    r10, r10, #0xff000000
 226         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 227         ldrne   tbl, =sys_oabi_call_table
 228 #elif !defined(CONFIG_AEABI)
 229         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 230         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 231 #endif
 232         get_thread_info tsk
 233         /*
 234          * Reload the registers that may have been corrupted on entry to
 235          * the syscall assembly (by tracing or context tracking.)
 236          */
 237  TRACE( ldmia   sp, {r0 - r3}           )
 238
 239 local_restart:
 240         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 241         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 242
 243         tst     r10, #_TIF_SYSCALL_WORK         @ are we tracing syscalls?
 244         bne     __sys_trace
 245
 246         invoke_syscall tbl, scno, r10, __ret_fast_syscall
 247
 248         add     r1, sp, #S_OFF
 249 2:      cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 250         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 251         bcs     arm_syscall
 252         mov     why, #0                         @ no longer a real syscall
 253         b       sys_ni_syscall                  @ not private func
 254
 255 #if defined(CONFIG_OABI_COMPAT) || !defined(CONFIG_AEABI)
 256         /*
 257          * We failed to handle a fault trying to access the page
 258          * containing the swi instruction, but we're not really in a
 259          * position to return -EFAULT. Instead, return back to the
 260          * instruction and re-enter the user fault handling path trying
 261          * to page it in. This will likely result in sending SEGV to the
 262          * current task.
 263          */
 264 9001:
 265         sub     lr, saved_pc, #4
 266         str     lr, [sp, #S_PC]
 267         get_thread_info tsk
 268         b       ret_fast_syscall
 269 #endif
 270 ENDPROC(vector_swi)
 271
 272         /*
 273          * This is the really slow path.  We're going to be doing
 274          * context switches, and waiting for our parent to respond.
 275          */
 276 __sys_trace:
 277         mov     r1, scno
 278         add     r0, sp, #S_OFF
 279         bl      syscall_trace_enter
 280         mov     scno, r0
 281         invoke_syscall tbl, scno, r10, __sys_trace_return, reload=1
 282         cmp     scno, #-1                       @ skip the syscall?
 283         bne     2b
 284         add     sp, sp, #S_OFF                  @ restore stack
 285
 286 __sys_trace_return_nosave:
 287         enable_irq_notrace
 288         mov     r0, sp
 289         bl      syscall_trace_exit
 290         b       ret_slow_syscall
 291
 292 __sys_trace_return:
 293         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 294         mov     r0, sp
 295         bl      syscall_trace_exit
 296         b       ret_slow_syscall
 297
 298         .align  5
 299 #ifdef CONFIG_ALIGNMENT_TRAP
 300         .type   __cr_alignment, #object
 301 __cr_alignment:
 302         .word   cr_alignment
 303 #endif
 304         .ltorg
 305
 306         .macro  syscall_table_start, sym
 307         .equ    __sys_nr, 0
 308         .type   \sym, #object
 309 ENTRY(\sym)
 310         .endm
 311
 312         .macro  syscall, nr, func
 313         .ifgt   __sys_nr - \nr
 314         .error  "Duplicated/unorded system call entry"
 315         .endif
 316         .rept   \nr - __sys_nr
 317         .long   sys_ni_syscall
 318         .endr
 319         .long   \func
 320         .equ    __sys_nr, \nr + 1
 321         .endm
 322
 323         .macro  syscall_table_end, sym
 324         .ifgt   __sys_nr - __NR_syscalls
 325         .error  "System call table too big"
 326         .endif
 327         .rept   __NR_syscalls - __sys_nr
 328         .long   sys_ni_syscall
 329         .endr
 330         .size   \sym, . - \sym
 331         .endm
 332
 333 #define NATIVE(nr, func) syscall nr, func
 334
 335 /*
 336  * This is the syscall table declaration for native ABI syscalls.
 337  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 338  */
 339         syscall_table_start sys_call_table
 340 #define COMPAT(nr, native, compat) syscall nr, native
 341 #ifdef CONFIG_AEABI
 342 #include <calls-eabi.S>
 343 #else
 344 #include <calls-oabi.S>
 345 #endif
 346 #undef COMPAT
 347         syscall_table_end sys_call_table
 348
 349 /*============================================================================
 350  * Special system call wrappers
 351  */
 352 @ r0 = syscall number
 353 @ r8 = syscall table
 354 sys_syscall:
 355                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 356                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 357                 cmpne   scno, #NR_syscalls      @ check range
 358 #ifdef CONFIG_CPU_SPECTRE
 359                 movhs   scno, #0
 360                 csdb
 361 #endif
 362                 stmloia sp, {r5, r6}            @ shuffle args
 363                 movlo   r0, r1
 364                 movlo   r1, r2
 365                 movlo   r2, r3
 366                 movlo   r3, r4
 367                 ldrlo   pc, [tbl, scno, lsl #2]
 368                 b       sys_ni_syscall
 369 ENDPROC(sys_syscall)
 370
 371 sys_sigreturn_wrapper:
 372                 add     r0, sp, #S_OFF
 373                 mov     why, #0         @ prevent syscall restart handling
 374                 b       sys_sigreturn
 375 ENDPROC(sys_sigreturn_wrapper)
 376
 377 sys_rt_sigreturn_wrapper:
 378                 add     r0, sp, #S_OFF
 379                 mov     why, #0         @ prevent syscall restart handling
 380                 b       sys_rt_sigreturn
 381 ENDPROC(sys_rt_sigreturn_wrapper)
 382
 383 sys_statfs64_wrapper:
 384                 teq     r1, #88
 385                 moveq   r1, #84
 386                 b       sys_statfs64
 387 ENDPROC(sys_statfs64_wrapper)
 388
 389 sys_fstatfs64_wrapper:
 390                 teq     r1, #88
 391                 moveq   r1, #84
 392                 b       sys_fstatfs64
 393 ENDPROC(sys_fstatfs64_wrapper)
 394
 395 /*
 396  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 397  * offset, we return EINVAL.
 398  */
 399 sys_mmap2:
 400 #if PAGE_SHIFT > 12
 401                 tst     r5, #PGOFF_MASK
 402                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 403                 streq   r5, [sp, #4]
 404                 beq     sys_mmap_pgoff
 405                 mov     r0, #-EINVAL
 406                 ret     lr
 407 #else
 408                 str     r5, [sp, #4]
 409                 b       sys_mmap_pgoff
 410 #endif
 411 ENDPROC(sys_mmap2)
 412
 413 #ifdef CONFIG_OABI_COMPAT
 414
 415 /*
 416  * These are syscalls with argument register differences
 417  */
 418
 419 sys_oabi_pread64:
 420                 stmia   sp, {r3, r4}
 421                 b       sys_pread64
 422 ENDPROC(sys_oabi_pread64)
 423
 424 sys_oabi_pwrite64:
 425                 stmia   sp, {r3, r4}
 426                 b       sys_pwrite64
 427 ENDPROC(sys_oabi_pwrite64)
 428
 429 sys_oabi_truncate64:
 430                 mov     r3, r2
 431                 mov     r2, r1
 432                 b       sys_truncate64
 433 ENDPROC(sys_oabi_truncate64)
 434
 435 sys_oabi_ftruncate64:
 436                 mov     r3, r2
 437                 mov     r2, r1
 438                 b       sys_ftruncate64
 439 ENDPROC(sys_oabi_ftruncate64)
 440
 441 sys_oabi_readahead:
 442                 str     r3, [sp]
 443                 mov     r3, r2
 444                 mov     r2, r1
 445                 b       sys_readahead
 446 ENDPROC(sys_oabi_readahead)
 447
 448 /*
 449  * Let's declare a second syscall table for old ABI binaries
 450  * using the compatibility syscall entries.
 451  */
 452         syscall_table_start sys_oabi_call_table
 453 #define COMPAT(nr, native, compat) syscall nr, compat
 454 #include <calls-oabi.S>
 455         syscall_table_end sys_oabi_call_table
 456
 457 #endif
 458