arch/arm/lib/putuser.S

   1 /*
   2  *  linux/arch/arm/lib/putuser.S
   3  *
   4  *  Copyright (C) 2001 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  Idea from x86 version, (C) Copyright 1998 Linus Torvalds
  11  *
  12  * These functions have a non-standard call interface to make
  13  * them more efficient, especially as they return an error
  14  * value in addition to the "real" return value.
  15  *
  16  * __put_user_X
  17  *
  18  * Inputs:      r0 contains the address
  19  *              r1 contains the address limit, which must be preserved
  20  *              r2, r3 contains the value
  21  * Outputs:     r0 is the error code
  22  *              lr corrupted
  23  *
  24  * No other registers must be altered.  (see <asm/uaccess.h>
  25  * for specific ASM register usage).
  26  *
  27  * Note that ADDR_LIMIT is either 0 or 0xc0000000
  28  * Note also that it is intended that __put_user_bad is not global.
  29  */
  30 #include <linux/linkage.h>
  31 #include <asm/assembler.h>
  32 #include <asm/errno.h>
  33 #include <asm/domain.h>
  34
  35 ENTRY(__put_user_1)
  36         check_uaccess r0, 1, r1, ip, __put_user_bad
  37 1: TUSER(strb)  r2, [r0]
  38         mov     r0, #0
  39         ret     lr
  40 ENDPROC(__put_user_1)
  41
  42 ENTRY(__put_user_2)
  43         check_uaccess r0, 2, r1, ip, __put_user_bad
  44 #if __LINUX_ARM_ARCH__ >= 6
  45
  46 2: TUSER(strh)  r2, [r0]
  47
  48 #else
  49
  50         mov     ip, r2, lsr #8
  51 #ifndef __ARMEB__
  52 2: TUSER(strb)  r2, [r0], #1
  53 3: TUSER(strb)  ip, [r0]
  54 #else
  55 2: TUSER(strb)  ip, [r0], #1
  56 3: TUSER(strb)  r2, [r0]
  57 #endif
  58
  59 #endif /* __LINUX_ARM_ARCH__ >= 6 */
  60         mov     r0, #0
  61         ret     lr
  62 ENDPROC(__put_user_2)
  63
  64 ENTRY(__put_user_4)
  65         check_uaccess r0, 4, r1, ip, __put_user_bad
  66 4: TUSER(str)   r2, [r0]
  67         mov     r0, #0
  68         ret     lr
  69 ENDPROC(__put_user_4)
  70
  71 ENTRY(__put_user_8)
  72         check_uaccess r0, 8, r1, ip, __put_user_bad
  73 #ifdef CONFIG_THUMB2_KERNEL
  74 5: TUSER(str)   r2, [r0]
  75 6: TUSER(str)   r3, [r0, #4]
  76 #else
  77 5: TUSER(str)   r2, [r0], #4
  78 6: TUSER(str)   r3, [r0]
  79 #endif
  80         mov     r0, #0
  81         ret     lr
  82 ENDPROC(__put_user_8)
  83
  84 __put_user_bad:
  85         mov     r0, #-EFAULT
  86         ret     lr
  87 ENDPROC(__put_user_bad)
  88
  89 .pushsection __ex_table, "a"
  90         .long   1b, __put_user_bad
  91         .long   2b, __put_user_bad
  92 #if __LINUX_ARM_ARCH__ < 6
  93         .long   3b, __put_user_bad
  94 #endif
  95         .long   4b, __put_user_bad
  96         .long   5b, __put_user_bad
  97         .long   6b, __put_user_bad
  98 .popsection