arch/sparc64/kernel/syscalls.S

   1         /* SunOS's execv() call only specifies the argv argument, the
   2          * environment settings are the same as the calling processes.
   3          */
   4 sys_execve:
   5         sethi   %hi(sparc_execve), %g1
   6         ba,pt   %xcc, execve_merge
   7          or     %g1, %lo(sparc_execve), %g1
   8
   9 #ifdef CONFIG_COMPAT
  10 sunos_execv:
  11         stx     %g0, [%sp + PTREGS_OFF + PT_V9_I2]
  12 sys32_execve:
  13         sethi   %hi(sparc32_execve), %g1
  14         or      %g1, %lo(sparc32_execve), %g1
  15 #endif
  16
  17 execve_merge:
  18         flushw
  19         jmpl    %g1, %g0
  20          add    %sp, PTREGS_OFF, %o0
  21
  22         .align  32
  23 sys_sparc_pipe:
  24         ba,pt   %xcc, sys_sparc_pipe_real
  25          add    %sp, PTREGS_OFF, %o0
  26 sys_nis_syscall:
  27         ba,pt   %xcc, c_sys_nis_syscall
  28          add    %sp, PTREGS_OFF, %o0
  29 sys_memory_ordering:
  30         ba,pt   %xcc, sparc_memory_ordering
  31          add    %sp, PTREGS_OFF, %o1
  32 sys_sigaltstack:
  33         ba,pt   %xcc, do_sigaltstack
  34          add    %i6, STACK_BIAS, %o2
  35 #ifdef CONFIG_COMPAT
  36 sys32_sigstack:
  37         ba,pt   %xcc, do_sys32_sigstack
  38          mov    %i6, %o2
  39 sys32_sigaltstack:
  40         ba,pt   %xcc, do_sys32_sigaltstack
  41          mov    %i6, %o2
  42 #endif
  43         .align  32
  44 #ifdef CONFIG_COMPAT
  45 sys32_sigreturn:
  46         add     %sp, PTREGS_OFF, %o0
  47         call    do_sigreturn32
  48          add    %o7, 1f-.-4, %o7
  49         nop
  50 #endif
  51 sys_rt_sigreturn:
  52         add     %sp, PTREGS_OFF, %o0
  53         call    do_rt_sigreturn
  54          add    %o7, 1f-.-4, %o7
  55         nop
  56 #ifdef CONFIG_COMPAT
  57 sys32_rt_sigreturn:
  58         add     %sp, PTREGS_OFF, %o0
  59         call    do_rt_sigreturn32
  60          add    %o7, 1f-.-4, %o7
  61         nop
  62 #endif
  63         .align  32
  64 1:      ldx     [%g6 + TI_FLAGS], %l5
  65         andcc   %l5, (_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT), %g0
  66         be,pt   %icc, rtrap
  67          nop
  68         add     %sp, PTREGS_OFF, %o0
  69         call    syscall_trace
  70          mov    1, %o1
  71         ba,pt   %xcc, rtrap
  72          nop
  73
  74         /* This is how fork() was meant to be done, 8 instruction entry.
  75          *
  76          * I questioned the following code briefly, let me clear things
  77          * up so you must not reason on it like I did.
  78          *
  79          * Know the fork_kpsr etc. we use in the sparc32 port?  We don't
  80          * need it here because the only piece of window state we copy to
  81          * the child is the CWP register.  Even if the parent sleeps,
  82          * we are safe because we stuck it into pt_regs of the parent
  83          * so it will not change.
  84          *
  85          * XXX This raises the question, whether we can do the same on
  86          * XXX sparc32 to get rid of fork_kpsr _and_ fork_kwim.  The
  87          * XXX answer is yes.  We stick fork_kpsr in UREG_G0 and
  88          * XXX fork_kwim in UREG_G1 (global registers are considered
  89          * XXX volatile across a system call in the sparc ABI I think
  90          * XXX if it isn't we can use regs->y instead, anyone who depends
  91          * XXX upon the Y register being preserved across a fork deserves
  92          * XXX to lose).
  93          *
  94          * In fact we should take advantage of that fact for other things
  95          * during system calls...
  96          */
  97         .align  32
  98 sys_vfork: /* Under Linux, vfork and fork are just special cases of clone. */
  99         sethi   %hi(0x4000 | 0x0100 | SIGCHLD), %o0
 100         or      %o0, %lo(0x4000 | 0x0100 | SIGCHLD), %o0
 101         ba,pt   %xcc, sys_clone
 102 sys_fork:
 103          clr    %o1
 104         mov     SIGCHLD, %o0
 105 sys_clone:
 106         flushw
 107         movrz   %o1, %fp, %o1
 108         mov     0, %o3
 109         ba,pt   %xcc, sparc_do_fork
 110          add    %sp, PTREGS_OFF, %o2
 111
 112         .globl  ret_from_syscall
 113 ret_from_syscall:
 114         /* Clear current_thread_info()->new_child, and
 115          * check performance counter stuff too.
 116          */
 117         stb     %g0, [%g6 + TI_NEW_CHILD]
 118         ldx     [%g6 + TI_FLAGS], %l0
 119         call    schedule_tail
 120          mov    %g7, %o0
 121         andcc   %l0, _TIF_PERFCTR, %g0
 122         be,pt   %icc, 1f
 123          nop
 124         ldx     [%g6 + TI_PCR], %o7
 125         wr      %g0, %o7, %pcr
 126
 127         /* Blackbird errata workaround.  See commentary in
 128          * smp.c:smp_percpu_timer_interrupt() for more
 129          * information.
 130          */
 131         ba,pt   %xcc, 99f
 132          nop
 133
 134         .align  64
 135 99:     wr      %g0, %g0, %pic
 136         rd      %pic, %g0
 137
 138 1:      ba,pt   %xcc, ret_sys_call
 139          ldx    [%sp + PTREGS_OFF + PT_V9_I0], %o0
 140
 141         .globl  sparc_exit
 142         .type   sparc_exit,#function
 143 sparc_exit:
 144         rdpr    %pstate, %g2
 145         wrpr    %g2, PSTATE_IE, %pstate
 146         rdpr    %otherwin, %g1
 147         rdpr    %cansave, %g3
 148         add     %g3, %g1, %g3
 149         wrpr    %g3, 0x0, %cansave
 150         wrpr    %g0, 0x0, %otherwin
 151         wrpr    %g2, 0x0, %pstate
 152         ba,pt   %xcc, sys_exit
 153          stb    %g0, [%g6 + TI_WSAVED]
 154         .size   sparc_exit,.-sparc_exit
 155
 156 linux_sparc_ni_syscall:
 157         sethi   %hi(sys_ni_syscall), %l7
 158         ba,pt   %xcc, 4f
 159          or     %l7, %lo(sys_ni_syscall), %l7
 160
 161 linux_syscall_trace32:
 162         add     %sp, PTREGS_OFF, %o0
 163         call    syscall_trace
 164          clr    %o1
 165         brnz,pn %o0, 3f
 166          mov    -ENOSYS, %o0
 167         srl     %i0, 0, %o0
 168         srl     %i4, 0, %o4
 169         srl     %i1, 0, %o1
 170         srl     %i2, 0, %o2
 171         ba,pt   %xcc, 2f
 172          srl    %i3, 0, %o3
 173
 174 linux_syscall_trace:
 175         add     %sp, PTREGS_OFF, %o0
 176         call    syscall_trace
 177          clr    %o1
 178         brnz,pn %o0, 3f
 179          mov    -ENOSYS, %o0
 180         mov     %i0, %o0
 181         mov     %i1, %o1
 182         mov     %i2, %o2
 183         mov     %i3, %o3
 184         b,pt    %xcc, 2f
 185          mov    %i4, %o4
 186
 187
 188         /* Linux 32-bit system calls enter here... */
 189         .align  32
 190         .globl  linux_sparc_syscall32
 191 linux_sparc_syscall32:
 192         /* Direct access to user regs, much faster. */
 193         cmp     %g1, NR_SYSCALLS                        ! IEU1  Group
 194         bgeu,pn %xcc, linux_sparc_ni_syscall            ! CTI
 195          srl    %i0, 0, %o0                             ! IEU0
 196         sll     %g1, 2, %l4                             ! IEU0  Group
 197         srl     %i4, 0, %o4                             ! IEU1
 198         lduw    [%l7 + %l4], %l7                        ! Load
 199         srl     %i1, 0, %o1                             ! IEU0  Group
 200         ldx     [%g6 + TI_FLAGS], %l0           ! Load
 201
 202         srl     %i5, 0, %o5                             ! IEU1
 203         srl     %i2, 0, %o2                             ! IEU0  Group
 204         andcc   %l0, (_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT), %g0
 205         bne,pn  %icc, linux_syscall_trace32             ! CTI
 206          mov    %i0, %l5                                ! IEU1
 207         call    %l7                                     ! CTI   Group brk forced
 208          srl    %i3, 0, %o3                             ! IEU0
 209         ba,a,pt %xcc, 3f
 210
 211         /* Linux native system calls enter here... */
 212         .align  32
 213         .globl  linux_sparc_syscall
 214 linux_sparc_syscall:
 215         /* Direct access to user regs, much faster. */
 216         cmp     %g1, NR_SYSCALLS                        ! IEU1  Group
 217         bgeu,pn %xcc, linux_sparc_ni_syscall            ! CTI
 218          mov    %i0, %o0                                ! IEU0
 219         sll     %g1, 2, %l4                             ! IEU0  Group
 220         mov     %i1, %o1                                ! IEU1
 221         lduw    [%l7 + %l4], %l7                        ! Load
 222 4:      mov     %i2, %o2                                ! IEU0  Group
 223         ldx     [%g6 + TI_FLAGS], %l0           ! Load
 224
 225         mov     %i3, %o3                                ! IEU1
 226         mov     %i4, %o4                                ! IEU0  Group
 227         andcc   %l0, (_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT), %g0
 228         bne,pn  %icc, linux_syscall_trace               ! CTI   Group
 229          mov    %i0, %l5                                ! IEU0
 230 2:      call    %l7                                     ! CTI   Group brk forced
 231          mov    %i5, %o5                                ! IEU0
 232         nop
 233
 234 3:      stx     %o0, [%sp + PTREGS_OFF + PT_V9_I0]
 235 ret_sys_call:
 236         ldx     [%sp + PTREGS_OFF + PT_V9_TSTATE], %g3
 237         ldx     [%sp + PTREGS_OFF + PT_V9_TNPC], %l1 ! pc = npc
 238         sra     %o0, 0, %o0
 239         mov     %ulo(TSTATE_XCARRY | TSTATE_ICARRY), %g2
 240         sllx    %g2, 32, %g2
 241
 242         /* Check if force_successful_syscall_return()
 243          * was invoked.
 244          */
 245         ldub    [%g6 + TI_SYS_NOERROR], %l2
 246         brnz,a,pn %l2, 80f
 247          stb    %g0, [%g6 + TI_SYS_NOERROR]
 248
 249         cmp     %o0, -ERESTART_RESTARTBLOCK
 250         bgeu,pn %xcc, 1f
 251          andcc  %l0, (_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT), %l6
 252 80:
 253         /* System call success, clear Carry condition code. */
 254         andn    %g3, %g2, %g3
 255         stx     %g3, [%sp + PTREGS_OFF + PT_V9_TSTATE]
 256         bne,pn  %icc, linux_syscall_trace2
 257          add    %l1, 0x4, %l2                   ! npc = npc+4
 258         stx     %l1, [%sp + PTREGS_OFF + PT_V9_TPC]
 259         ba,pt   %xcc, rtrap
 260          stx    %l2, [%sp + PTREGS_OFF + PT_V9_TNPC]
 261
 262 1:
 263         /* System call failure, set Carry condition code.
 264          * Also, get abs(errno) to return to the process.
 265          */
 266         andcc   %l0, (_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT), %l6
 267         sub     %g0, %o0, %o0
 268         or      %g3, %g2, %g3
 269         stx     %o0, [%sp + PTREGS_OFF + PT_V9_I0]
 270         stx     %g3, [%sp + PTREGS_OFF + PT_V9_TSTATE]
 271         bne,pn  %icc, linux_syscall_trace2
 272          add    %l1, 0x4, %l2                   ! npc = npc+4
 273         stx     %l1, [%sp + PTREGS_OFF + PT_V9_TPC]
 274
 275         b,pt    %xcc, rtrap
 276          stx    %l2, [%sp + PTREGS_OFF + PT_V9_TNPC]
 277 linux_syscall_trace2:
 278         add     %sp, PTREGS_OFF, %o0
 279         call    syscall_trace
 280          mov    1, %o1
 281         stx     %l1, [%sp + PTREGS_OFF + PT_V9_TPC]
 282         ba,pt   %xcc, rtrap
 283          stx    %l2, [%sp + PTREGS_OFF + PT_V9_TNPC]