scripts/namespace.pl

   1 #!/usr/bin/perl -w
   2 #
   3 #       namespace.pl.  Mon Aug 30 2004
   4 #
   5 #       Perform a name space analysis on the linux kernel.
   6 #
   7 #       Copyright Keith Owens <kaos@ocs.com.au>.  GPL.
   8 #
   9 #       Invoke by changing directory to the top of the kernel object
  10 #       tree then namespace.pl, no parameters.
  11 #
  12 #       Tuned for 2.1.x kernels with the new module handling, it will
  13 #       work with 2.0 kernels as well.
  14 #
  15 #       Last change 2.6.9-rc1, adding support for separate source and object
  16 #       trees.
  17 #
  18 #       The source must be compiled/assembled first, the object files
  19 #       are the primary input to this script.  Incomplete or missing
  20 #       objects will result in a flawed analysis.  Compile both vmlinux
  21 #       and modules.
  22 #
  23 #       Even with complete objects, treat the result of the analysis
  24 #       with caution.  Some external references are only used by
  25 #       certain architectures, others with certain combinations of
  26 #       configuration parameters.  Ideally the source should include
  27 #       something like
  28 #
  29 #       #ifndef CONFIG_...
  30 #       static
  31 #       #endif
  32 #       symbol_definition;
  33 #
  34 #       so the symbols are defined as static unless a particular
  35 #       CONFIG_... requires it to be external.
  36 #
  37 #       A symbol that is suffixed with '(export only)' has these properties
  38 #
  39 #       * It is global.
  40 #       * It is marked EXPORT_SYMBOL or EXPORT_SYMBOL_GPL, either in the same
  41 #         source file or a different source file.
  42 #       * Given the current .config, nothing uses the symbol.
  43 #
  44 #       The symbol is a candidate for conversion to static, plus removal of the
  45 #       export.  But be careful that a different .config might use the symbol.
  46 #
  47 #
  48 #       Name space analysis and cleanup is an iterative process.  You cannot
  49 #       expect to find all the problems in a single pass.
  50 #
  51 #       * Identify possibly unnecessary global declarations, verify that they
  52 #         really are unnecessary and change them to static.
  53 #       * Compile and fix up gcc warnings about static, removing dead symbols
  54 #         as necessary.
  55 #       * make clean and rebuild with different configs (especially
  56 #         CONFIG_MODULES=n) to see which symbols are being defined when the
  57 #         config does not require them.  These symbols bloat the kernel object
  58 #         for no good reason, which is frustrating for embedded systems.
  59 #       * Wrap config sensitive symbols in #ifdef CONFIG_foo, as long as the
  60 #         code does not get too ugly.
  61 #       * Repeat the name space analysis until you can live with with the
  62 #         result.
  63 #
  64
  65 require 5;      # at least perl 5
  66 use strict;
  67 use File::Find;
  68 use File::Spec;
  69
  70 my $nm = ($ENV{'NM'} || "nm") . " -p";
  71 my $objdump = ($ENV{'OBJDUMP'} || "objdump") . " -s -j .comment";
  72 my $srctree = File::Spec->curdir();
  73 my $objtree = File::Spec->curdir();
  74 $srctree = File::Spec->rel2abs($ENV{'srctree'}) if (exists($ENV{'srctree'}));
  75 $objtree = File::Spec->rel2abs($ENV{'objtree'}) if (exists($ENV{'objtree'}));
  76
  77 if ($#ARGV != -1) {
  78         print STDERR "usage: $0 takes no parameters\n";
  79         die("giving up\n");
  80 }
  81
  82 my %nmdata = ();        # nm data for each object
  83 my %def = ();           # all definitions for each name
  84 my %ksymtab = ();       # names that appear in __ksymtab_
  85 my %ref = ();           # $ref{$name} exists if there is a true external reference to $name
  86 my %export = ();        # $export{$name} exists if there is an EXPORT_... of $name
  87
  88 my %nmexception = (
  89     'fs/ext3/bitmap'                    => 1,
  90     'fs/ext4/bitmap'                    => 1,
  91     'arch/x86/lib/thunk_32'             => 1,
  92     'arch/x86/lib/cmpxchg'              => 1,
  93     'arch/x86/vdso/vdso32/note'         => 1,
  94     'lib/irq_regs'                      => 1,
  95     'usr/initramfs_data'                => 1,
  96     'drivers/scsi/aic94xx/aic94xx_dump' => 1,
  97     'drivers/scsi/libsas/sas_dump'      => 1,
  98     'lib/dec_and_lock'                  => 1,
  99     'drivers/ide/ide-probe-mini'        => 1,
 100     'usr/initramfs_data'                => 1,
 101     'drivers/acpi/acpia/exdump'         => 1,
 102     'drivers/acpi/acpia/rsdump'         => 1,
 103     'drivers/acpi/acpia/nsdumpdv'       => 1,
 104     'drivers/acpi/acpia/nsdump'         => 1,
 105     'arch/ia64/sn/kernel/sn2/io'        => 1,
 106     'arch/ia64/kernel/gate-data'        => 1,
 107     'security/capability'               => 1,
 108     'fs/ntfs/sysctl'                    => 1,
 109     'fs/jfs/jfs_debug'                  => 1,
 110 );
 111
 112 my %nameexception = (
 113     'mod_use_count_'     => 1,
 114     '__initramfs_end'   => 1,
 115     '__initramfs_start' => 1,
 116     '_einittext'        => 1,
 117     '_sinittext'        => 1,
 118     'kallsyms_names'    => 1,
 119     'kallsyms_num_syms' => 1,
 120     'kallsyms_addresses'=> 1,
 121     '__this_module'     => 1,
 122     '_etext'            => 1,
 123     '_edata'            => 1,
 124     '_end'              => 1,
 125     '__bss_start'       => 1,
 126     '_text'             => 1,
 127     '_stext'            => 1,
 128     '__gp'              => 1,
 129     'ia64_unw_start'    => 1,
 130     'ia64_unw_end'      => 1,
 131     '__init_begin'      => 1,
 132     '__init_end'        => 1,
 133     '__bss_stop'        => 1,
 134     '__nosave_begin'    => 1,
 135     '__nosave_end'      => 1,
 136     'pg0'               => 1,
 137     'vdso_enabled'      => 1,
 138     '__stack_chk_fail'  => 1,
 139     'VDSO32_PRELINK'    => 1,
 140     'VDSO32_vsyscall'   => 1,
 141     'VDSO32_rt_sigreturn'=>1,
 142     'VDSO32_sigreturn'  => 1,
 143 );
 144
 145
 146 &find(\&linux_objects, '.');    # find the objects and do_nm on them
 147 &list_multiply_defined();
 148 &resolve_external_references();
 149 &list_extra_externals();
 150
 151 exit(0);
 152
 153 sub linux_objects
 154 {
 155         # Select objects, ignoring objects which are only created by
 156         # merging other objects.  Also ignore all of modules, scripts
 157         # and compressed.  Most conglomerate objects are handled by do_nm,
 158         # this list only contains the special cases.  These include objects
 159         # that are linked from just one other object and objects for which
 160         # there is really no permanent source file.
 161         my $basename = $_;
 162         $_ = $File::Find::name;
 163         s:^\./::;
 164         if (/.*\.o$/ &&
 165                 ! (
 166                 m:/built-in.o$:
 167                 || m:arch/x86/vdso/:
 168                 || m:arch/x86/boot/:
 169                 || m:arch/ia64/ia32/ia32.o$:
 170                 || m:arch/ia64/kernel/gate-syms.o$:
 171                 || m:arch/ia64/lib/__divdi3.o$:
 172                 || m:arch/ia64/lib/__divsi3.o$:
 173                 || m:arch/ia64/lib/__moddi3.o$:
 174                 || m:arch/ia64/lib/__modsi3.o$:
 175                 || m:arch/ia64/lib/__udivdi3.o$:
 176                 || m:arch/ia64/lib/__udivsi3.o$:
 177                 || m:arch/ia64/lib/__umoddi3.o$:
 178                 || m:arch/ia64/lib/__umodsi3.o$:
 179                 || m:arch/ia64/scripts/check_gas_for_hint.o$:
 180                 || m:arch/ia64/sn/kernel/xp.o$:
 181                 || m:boot/bbootsect.o$:
 182                 || m:boot/bsetup.o$:
 183                 || m:/bootsect.o$:
 184                 || m:/boot/setup.o$:
 185                 || m:/compressed/:
 186                 || m:drivers/cdrom/driver.o$:
 187                 || m:drivers/char/drm/tdfx_drv.o$:
 188                 || m:drivers/ide/ide-detect.o$:
 189                 || m:drivers/ide/pci/idedriver-pci.o$:
 190                 || m:drivers/media/media.o$:
 191                 || m:drivers/scsi/sd_mod.o$:
 192                 || m:drivers/video/video.o$:
 193                 || m:fs/devpts/devpts.o$:
 194                 || m:fs/exportfs/exportfs.o$:
 195                 || m:fs/hugetlbfs/hugetlbfs.o$:
 196                 || m:fs/msdos/msdos.o$:
 197                 || m:fs/nls/nls.o$:
 198                 || m:fs/ramfs/ramfs.o$:
 199                 || m:fs/romfs/romfs.o$:
 200                 || m:fs/vfat/vfat.o$:
 201                 || m:init/mounts.o$:
 202                 || m:^modules/:
 203                 || m:net/netlink/netlink.o$:
 204                 || m:net/sched/sched.o$:
 205                 || m:/piggy.o$:
 206                 || m:^scripts/:
 207                 || m:sound/.*/snd-:
 208                 || m:^.*/\.tmp_:
 209                 || m:^\.tmp_:
 210                 || m:/vmlinux-obj.o$:
 211                 || m:^tools/:
 212                 )
 213         ) {
 214                 do_nm($basename, $_);
 215         }
 216         $_ = $basename;         # File::Find expects $_ untouched (undocumented)
 217 }
 218
 219 sub do_nm
 220 {
 221         my ($basename, $fullname) = @_;
 222         my ($source, $type, $name);
 223         if (! -e $basename) {
 224                 printf STDERR "$basename does not exist\n";
 225                 return;
 226         }
 227         if ($fullname !~ /\.o$/) {
 228                 printf STDERR "$fullname is not an object file\n";
 229                 return;
 230         }
 231         ($source = $basename) =~ s/\.o$//;
 232         if (-e "$source.c" || -e "$source.S") {
 233                 $source = File::Spec->catfile($objtree, $File::Find::dir, $source)
 234         } else {
 235                 $source = File::Spec->catfile($srctree, $File::Find::dir, $source)
 236         }
 237         if (! -e "$source.c" && ! -e "$source.S") {
 238                 # No obvious source, exclude the object if it is conglomerate
 239                 open(my $objdumpdata, "$objdump $basename|")
 240                     or die "$objdump $fullname failed $!\n";
 241
 242                 my $comment;
 243                 while (<$objdumpdata>) {
 244                         chomp();
 245                         if (/^In archive/) {
 246                                 # Archives are always conglomerate
 247                                 $comment = "GCC:GCC:";
 248                                 last;
 249                         }
 250                         next if (! /^[ 0-9a-f]{5,} /);
 251                         $comment .= substr($_, 43);
 252                 }
 253                 close($objdumpdata);
 254
 255                 if (!defined($comment) || $comment !~ /GCC\:.*GCC\:/m) {
 256                         printf STDERR "No source file found for $fullname\n";
 257                 }
 258                 return;
 259         }
 260         open (my $nmdata, "$nm $basename|")
 261             or die "$nm $fullname failed $!\n";
 262
 263         my @nmdata;
 264         while (<$nmdata>) {
 265                 chop;
 266                 ($type, $name) = (split(/ +/, $_, 3))[1..2];
 267                 # Expected types
 268                 # A absolute symbol
 269                 # B weak external reference to data that has been resolved
 270                 # C global variable, uninitialised
 271                 # D global variable, initialised
 272                 # G global variable, initialised, small data section
 273                 # R global array, initialised
 274                 # S global variable, uninitialised, small bss
 275                 # T global label/procedure
 276                 # U external reference
 277                 # W weak external reference to text that has been resolved
 278                 # V similar to W, but the value of the weak symbol becomes zero with no error.
 279                 # a assembler equate
 280                 # b static variable, uninitialised
 281                 # d static variable, initialised
 282                 # g static variable, initialised, small data section
 283                 # r static array, initialised
 284                 # s static variable, uninitialised, small bss
 285                 # t static label/procedures
 286                 # w weak external reference to text that has not been resolved
 287                 # v similar to w
 288                 # ? undefined type, used a lot by modules
 289                 if ($type !~ /^[ABCDGRSTUWVabdgrstwv?]$/) {
 290                         printf STDERR "nm output for $fullname contains unknown type '$_'\n";
 291                 }
 292                 elsif ($name =~ /\./) {
 293                         # name with '.' is local static
 294                 }
 295                 else {
 296                         $type = 'R' if ($type eq '?');  # binutils replaced ? with R at one point
 297                         # binutils keeps changing the type for exported symbols, force it to R
 298                         $type = 'R' if ($name =~ /^__ksymtab/ || $name =~ /^__kstrtab/);
 299                         $name =~ s/_R[a-f0-9]{8}$//;    # module versions adds this
 300                         if ($type =~ /[ABCDGRSTWV]/ &&
 301                                 $name ne 'init_module' &&
 302                                 $name ne 'cleanup_module' &&
 303                                 $name ne 'Using_Versions' &&
 304                                 $name !~ /^Version_[0-9]+$/ &&
 305                                 $name !~ /^__parm_/ &&
 306                                 $name !~ /^__kstrtab/ &&
 307                                 $name !~ /^__ksymtab/ &&
 308                                 $name !~ /^__kcrctab_/ &&
 309                                 $name !~ /^__exitcall_/ &&
 310                                 $name !~ /^__initcall_/ &&
 311                                 $name !~ /^__kdb_initcall_/ &&
 312                                 $name !~ /^__kdb_exitcall_/ &&
 313                                 $name !~ /^__module_/ &&
 314                                 $name !~ /^__mod_/ &&
 315                                 $name !~ /^__crc_/ &&
 316                                 $name ne '__this_module' &&
 317                                 $name ne 'kernel_version') {
 318                                 if (!exists($def{$name})) {
 319                                         $def{$name} = [];
 320                                 }
 321                                 push(@{$def{$name}}, $fullname);
 322                         }
 323                         push(@nmdata, "$type $name");
 324                         if ($name =~ /^__ksymtab_/) {
 325                                 $name = substr($name, 10);
 326                                 if (!exists($ksymtab{$name})) {
 327                                         $ksymtab{$name} = [];
 328                                 }
 329                                 push(@{$ksymtab{$name}}, $fullname);
 330                         }
 331                 }
 332         }
 333         close($nmdata);
 334
 335         if ($#nmdata < 0) {
 336             printf "No nm data for $fullname\n"
 337                 unless $nmexception{$fullname};
 338             return;
 339         }
 340         $nmdata{$fullname} = \@nmdata;
 341 }
 342
 343 sub drop_def
 344 {
 345         my ($object, $name) = @_;
 346         my $nmdata = $nmdata{$object};
 347         my ($i, $j);
 348         for ($i = 0; $i <= $#{$nmdata}; ++$i) {
 349                 if ($name eq (split(' ', $nmdata->[$i], 2))[1]) {
 350                         splice(@{$nmdata{$object}}, $i, 1);
 351                         my $def = $def{$name};
 352                         for ($j = 0; $j < $#{$def{$name}}; ++$j) {
 353                                 if ($def{$name}[$j] eq $object) {
 354                                         splice(@{$def{$name}}, $j, 1);
 355                                 }
 356                         }
 357                         last;
 358                 }
 359         }
 360 }
 361
 362 sub list_multiply_defined
 363 {
 364         foreach my $name (keys(%def)) {
 365                 if ($#{$def{$name}} > 0) {
 366                         # Special case for cond_syscall
 367                         if ($#{$def{$name}} == 1 &&
 368                            ($name =~ /^sys_/ || $name =~ /^compat_sys_/ ||
 369                             $name =~ /^sys32_/)) {
 370                                 if($def{$name}[0] eq "kernel/sys_ni.o" ||
 371                                    $def{$name}[1] eq "kernel/sys_ni.o") {
 372                                         &drop_def("kernel/sys_ni.o", $name);
 373                                         next;
 374                                 }
 375                         }
 376
 377                         printf "$name is multiply defined in :-\n";
 378                         foreach my $module (@{$def{$name}}) {
 379                                 printf "\t$module\n";
 380                         }
 381                 }
 382         }
 383 }
 384
 385 sub resolve_external_references
 386 {
 387         my ($kstrtab, $ksymtab, $export);
 388
 389         printf "\n";
 390         foreach my $object (keys(%nmdata)) {
 391                 my $nmdata = $nmdata{$object};
 392                 for (my $i = 0; $i <= $#{$nmdata}; ++$i) {
 393                         my ($type, $name) = split(' ', $nmdata->[$i], 2);
 394                         if ($type eq "U" || $type eq "w") {
 395                                 if (exists($def{$name}) || exists($ksymtab{$name})) {
 396                                         # add the owning object to the nmdata
 397                                         $nmdata->[$i] = "$type $name $object";
 398                                         # only count as a reference if it is not EXPORT_...
 399                                         $kstrtab = "R __kstrtab_$name";
 400                                         $ksymtab = "R __ksymtab_$name";
 401                                         $export = 0;
 402                                         for (my $j = 0; $j <= $#{$nmdata}; ++$j) {
 403                                                 if ($nmdata->[$j] eq $kstrtab ||
 404                                                     $nmdata->[$j] eq $ksymtab) {
 405                                                         $export = 1;
 406                                                         last;
 407                                                 }
 408                                         }
 409                                         if ($export) {
 410                                                 $export{$name} = "";
 411                                         }
 412                                         else {
 413                                                 $ref{$name} = ""
 414                                         }
 415                                 }
 416                                 elsif ( ! $nameexception{$name}
 417                                         && $name !~ /^__sched_text_/
 418                                         && $name !~ /^__start_/
 419                                         && $name !~ /^__end_/
 420                                         && $name !~ /^__stop_/
 421                                         && $name !~ /^__scheduling_functions_.*_here/
 422                                         && $name !~ /^__.*initcall_/
 423                                         && $name !~ /^__.*per_cpu_start/
 424                                         && $name !~ /^__.*per_cpu_end/
 425                                         && $name !~ /^__alt_instructions/
 426                                         && $name !~ /^__setup_/
 427                                         && $name !~ /^__mod_timer/
 428                                         && $name !~ /^__mod_page_state/
 429                                         && $name !~ /^init_module/
 430                                         && $name !~ /^cleanup_module/
 431                                 ) {
 432                                         printf "Cannot resolve ";
 433                                         printf "weak " if ($type eq "w");
 434                                         printf "reference to $name from $object\n";
 435                                 }
 436                         }
 437                 }
 438         }
 439 }
 440
 441 sub list_extra_externals
 442 {
 443         my %noref = ();
 444
 445         foreach my $name (keys(%def)) {
 446                 if (! exists($ref{$name})) {
 447                         my @module = @{$def{$name}};
 448                         foreach my $module (@module) {
 449                                 if (! exists($noref{$module})) {
 450                                         $noref{$module} = [];
 451                                 }
 452                                 push(@{$noref{$module}}, $name);
 453                         }
 454                 }
 455         }
 456         if (%noref) {
 457                 printf "\nExternally defined symbols with no external references\n";
 458                 foreach my $module (sort(keys(%noref))) {
 459                         printf "  $module\n";
 460                         foreach (sort(@{$noref{$module}})) {
 461                             my $export;
 462                             if (exists($export{$_})) {
 463                                 $export = " (export only)";
 464                             } else {
 465                                 $export = "";
 466                             }
 467                             printf "    $_$export\n";
 468                         }
 469                 }
 470         }
 471 }