arch/s390/kernel/base.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  *  arch/s390/kernel/base.S
   4  *
   5  *    Copyright IBM Corp. 2006, 2007
   6  *    Author(s): Heiko Carstens <heiko.carstens@de.ibm.com>
   7  *               Michael Holzheu <holzheu@de.ibm.com>
   8  */
   9
  10 #include <linux/linkage.h>
  11 #include <asm/asm-offsets.h>
  12 #include <asm/nospec-insn.h>
  13 #include <asm/ptrace.h>
  14 #include <asm/sigp.h>
  15
  16         GEN_BR_THUNK %r9
  17         GEN_BR_THUNK %r14
  18
  19 ENTRY(s390_base_mcck_handler)
  20         basr    %r13,0
  21 0:      lg      %r15,__LC_NODAT_STACK   # load panic stack
  22         aghi    %r15,-STACK_FRAME_OVERHEAD
  23         larl    %r1,s390_base_mcck_handler_fn
  24         lg      %r9,0(%r1)
  25         ltgr    %r9,%r9
  26         jz      1f
  27         BASR_EX %r14,%r9
  28 1:      la      %r1,4095
  29         lmg     %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)
  30         lpswe   __LC_MCK_OLD_PSW
  31 ENDPROC(s390_base_mcck_handler)
  32
  33         .section .bss
  34         .align 8
  35         .globl  s390_base_mcck_handler_fn
  36 s390_base_mcck_handler_fn:
  37         .quad   0
  38         .previous
  39
  40 ENTRY(s390_base_ext_handler)
  41         stmg    %r0,%r15,__LC_SAVE_AREA_ASYNC
  42         basr    %r13,0
  43 0:      aghi    %r15,-STACK_FRAME_OVERHEAD
  44         larl    %r1,s390_base_ext_handler_fn
  45         lg      %r9,0(%r1)
  46         ltgr    %r9,%r9
  47         jz      1f
  48         BASR_EX %r14,%r9
  49 1:      lmg     %r0,%r15,__LC_SAVE_AREA_ASYNC
  50         ni      __LC_EXT_OLD_PSW+1,0xfd # clear wait state bit
  51         lpswe   __LC_EXT_OLD_PSW
  52 ENDPROC(s390_base_ext_handler)
  53
  54         .section .bss
  55         .align 8
  56         .globl s390_base_ext_handler_fn
  57 s390_base_ext_handler_fn:
  58         .quad   0
  59         .previous
  60
  61 ENTRY(s390_base_pgm_handler)
  62         stmg    %r0,%r15,__LC_SAVE_AREA_SYNC
  63         basr    %r13,0
  64 0:      aghi    %r15,-STACK_FRAME_OVERHEAD
  65         larl    %r1,s390_base_pgm_handler_fn
  66         lg      %r9,0(%r1)
  67         ltgr    %r9,%r9
  68         jz      1f
  69         BASR_EX %r14,%r9
  70         lmg     %r0,%r15,__LC_SAVE_AREA_SYNC
  71         lpswe   __LC_PGM_OLD_PSW
  72 1:      lpswe   disabled_wait_psw-0b(%r13)
  73 ENDPROC(s390_base_pgm_handler)
  74
  75         .align  8
  76 disabled_wait_psw:
  77         .quad   0x0002000180000000,0x0000000000000000 + s390_base_pgm_handler
  78
  79         .section .bss
  80         .align 8
  81         .globl s390_base_pgm_handler_fn
  82 s390_base_pgm_handler_fn:
  83         .quad   0
  84         .previous