| blob | e5b43c97a8340a807671ace329a4fa87a573709a |
1 /*
2 * S390 low-level entry points.
3 *
4 * Copyright IBM Corp. 1999, 2012
5 * Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
6 * Hartmut Penner (hp@de.ibm.com),
7 * Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
8 * Heiko Carstens <heiko.carstens@de.ibm.com>
9 */
11 #include <linux/init.h>
12 #include <linux/linkage.h>
13 #include <asm/processor.h>
14 #include <asm/cache.h>
15 #include <asm/errno.h>
16 #include <asm/ptrace.h>
17 #include <asm/thread_info.h>
18 #include <asm/asm-offsets.h>
19 #include <asm/unistd.h>
20 #include <asm/page.h>
21 #include <asm/sigp.h>
22 #include <asm/irq.h>
24 __PT_R0 = __PT_GPRS
25 __PT_R1 = __PT_GPRS + 8
26 __PT_R2 = __PT_GPRS + 16
27 __PT_R3 = __PT_GPRS + 24
28 __PT_R4 = __PT_GPRS + 32
29 __PT_R5 = __PT_GPRS + 40
30 __PT_R6 = __PT_GPRS + 48
31 __PT_R7 = __PT_GPRS + 56
32 __PT_R8 = __PT_GPRS + 64
33 __PT_R9 = __PT_GPRS + 72
34 __PT_R10 = __PT_GPRS + 80
35 __PT_R11 = __PT_GPRS + 88
36 __PT_R12 = __PT_GPRS + 96
37 __PT_R13 = __PT_GPRS + 104
38 __PT_R14 = __PT_GPRS + 112
39 __PT_R15 = __PT_GPRS + 120
41 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
42 STACK_SIZE = 1 << STACK_SHIFT
43 STACK_INIT = STACK_SIZE - STACK_FRAME_OVERHEAD - __PT_SIZE
45 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
46 _TIF_MCCK_PENDING | _TIF_PER_TRAP )
47 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
48 _TIF_MCCK_PENDING)
49 _TIF_TRACE = (_TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT | _TIF_SECCOMP | \
50 _TIF_SYSCALL_TRACEPOINT)
52 #define BASED(name) name-system_call(%r13)
54 .macro TRACE_IRQS_ON
55 #ifdef CONFIG_TRACE_IRQFLAGS
56 basr %r2,%r0
57 brasl %r14,trace_hardirqs_on_caller
58 #endif
59 .endm
61 .macro TRACE_IRQS_OFF
62 #ifdef CONFIG_TRACE_IRQFLAGS
63 basr %r2,%r0
64 brasl %r14,trace_hardirqs_off_caller
65 #endif
66 .endm
68 .macro LOCKDEP_SYS_EXIT
69 #ifdef CONFIG_LOCKDEP
70 tm __PT_PSW+1(%r11),0x01 # returning to user ?
71 jz .+10
72 brasl %r14,lockdep_sys_exit
73 #endif
74 .endm
76 .macro LPP newpp
77 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
78 tm __LC_MACHINE_FLAGS+6,0x20 # MACHINE_FLAG_LPP
79 jz .+8
80 .insn s,0xb2800000,\newpp
81 #endif
82 .endm
84 .macro HANDLE_SIE_INTERCEPT scratch,reason
85 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
86 tmhh %r8,0x0001 # interrupting from user ?
87 jnz .+62
88 lgr \scratch,%r9
89 slg \scratch,BASED(.Lsie_critical)
90 clg \scratch,BASED(.Lsie_critical_length)
91 .if \reason==1
92 # Some program interrupts are suppressing (e.g. protection).
93 # We must also check the instruction after SIE in that case.
94 # do_protection_exception will rewind to rewind_pad
95 jh .+42
96 .else
97 jhe .+42
98 .endif
99 lg %r14,__SF_EMPTY(%r15) # get control block pointer
100 LPP __SF_EMPTY+16(%r15) # set host id
101 ni __SIE_PROG0C+3(%r14),0xfe # no longer in SIE
102 lctlg %c1,%c1,__LC_USER_ASCE # load primary asce
103 larl %r9,sie_exit # skip forward to sie_exit
104 mvi __SF_EMPTY+31(%r15),\reason # set exit reason
105 #endif
106 .endm
108 .macro CHECK_STACK stacksize,savearea
109 #ifdef CONFIG_CHECK_STACK
110 tml %r15,\stacksize - CONFIG_STACK_GUARD
111 lghi %r14,\savearea
112 jz stack_overflow
113 #endif
114 .endm
116 .macro SWITCH_ASYNC savearea,stack,shift
117 tmhh %r8,0x0001 # interrupting from user ?
118 jnz 1f
119 lgr %r14,%r9
120 slg %r14,BASED(.Lcritical_start)
121 clg %r14,BASED(.Lcritical_length)
122 jhe 0f
123 lghi %r11,\savearea # inside critical section, do cleanup
124 brasl %r14,cleanup_critical
125 tmhh %r8,0x0001 # retest problem state after cleanup
126 jnz 1f
127 0: lg %r14,\stack # are we already on the target stack?
128 slgr %r14,%r15
129 srag %r14,%r14,\shift
130 jnz 1f
131 CHECK_STACK 1<<\shift,\savearea
132 aghi %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
133 j 2f
134 1: lg %r15,\stack # load target stack
135 2: la %r11,STACK_FRAME_OVERHEAD(%r15)
136 .endm
138 .macro UPDATE_VTIME scratch,enter_timer
139 lg \scratch,__LC_EXIT_TIMER
140 slg \scratch,\enter_timer
141 alg \scratch,__LC_USER_TIMER
142 stg \scratch,__LC_USER_TIMER
143 lg \scratch,__LC_LAST_UPDATE_TIMER
144 slg \scratch,__LC_EXIT_TIMER
145 alg \scratch,__LC_SYSTEM_TIMER
146 stg \scratch,__LC_SYSTEM_TIMER
147 mvc __LC_LAST_UPDATE_TIMER(8),\enter_timer
148 .endm
150 .macro LAST_BREAK scratch
151 srag \scratch,%r10,23
152 jz .+10
153 stg %r10,__TI_last_break(%r12)
154 .endm
156 .macro REENABLE_IRQS
157 stg %r8,__LC_RETURN_PSW
158 ni __LC_RETURN_PSW,0xbf
159 ssm __LC_RETURN_PSW
160 .endm
162 .macro STCK savearea
163 #ifdef CONFIG_HAVE_MARCH_Z9_109_FEATURES
164 .insn s,0xb27c0000,\savearea # store clock fast
165 #else
166 .insn s,0xb2050000,\savearea # store clock
167 #endif
168 .endm
170 .section .kprobes.text, "ax"
172 /*
173 * Scheduler resume function, called by switch_to
174 * gpr2 = (task_struct *) prev
175 * gpr3 = (task_struct *) next
176 * Returns:
177 * gpr2 = prev
178 */
179 ENTRY(__switch_to)
180 stmg %r6,%r15,__SF_GPRS(%r15) # store gprs of prev task
181 stg %r15,__THREAD_ksp(%r2) # store kernel stack of prev
182 lg %r4,__THREAD_info(%r2) # get thread_info of prev
183 lg %r5,__THREAD_info(%r3) # get thread_info of next
184 lgr %r15,%r5
185 aghi %r15,STACK_INIT # end of kernel stack of next
186 stg %r3,__LC_CURRENT # store task struct of next
187 stg %r5,__LC_THREAD_INFO # store thread info of next
188 stg %r15,__LC_KERNEL_STACK # store end of kernel stack
189 lctl %c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
190 mvc __LC_CURRENT_PID+4(4,%r0),__TASK_pid(%r3) # store pid of next
191 lg %r15,__THREAD_ksp(%r3) # load kernel stack of next
192 tm __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
193 jz 0f
194 ni __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
195 oi __TI_flags+7(%r5),_TIF_MCCK_PENDING # set it in next
196 0: lmg %r6,%r15,__SF_GPRS(%r15) # load gprs of next task
197 br %r14
199 __critical_start:
200 /*
201 * SVC interrupt handler routine. System calls are synchronous events and
202 * are executed with interrupts enabled.
203 */
205 ENTRY(system_call)
206 stpt __LC_SYNC_ENTER_TIMER
207 sysc_stmg:
208 stmg %r8,%r15,__LC_SAVE_AREA_SYNC
209 lg %r10,__LC_LAST_BREAK
210 lg %r12,__LC_THREAD_INFO
211 sysc_per:
212 lg %r15,__LC_KERNEL_STACK
213 la %r11,STACK_FRAME_OVERHEAD(%r15) # pointer to pt_regs
214 sysc_vtime:
215 UPDATE_VTIME %r13,__LC_SYNC_ENTER_TIMER
216 LAST_BREAK %r13
217 stmg %r0,%r7,__PT_R0(%r11)
218 mvc __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
219 mvc __PT_PSW(16,%r11),__LC_SVC_OLD_PSW
220 mvc __PT_INT_CODE(4,%r11),__LC_SVC_ILC
221 sysc_do_svc:
222 oi __TI_flags+7(%r12),_TIF_SYSCALL
223 lg %r10,__TI_sysc_table(%r12) # address of system call table
224 llgh %r8,__PT_INT_CODE+2(%r11)
225 slag %r8,%r8,2 # shift and test for svc 0
226 jnz sysc_nr_ok
227 # svc 0: system call number in %r1
228 llgfr %r1,%r1 # clear high word in r1
229 cghi %r1,NR_syscalls
230 jnl sysc_nr_ok
231 sth %r1,__PT_INT_CODE+2(%r11)
232 slag %r8,%r1,2
233 sysc_nr_ok:
234 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
235 stg %r2,__PT_ORIG_GPR2(%r11)
236 stg %r7,STACK_FRAME_OVERHEAD(%r15)
237 lgf %r9,0(%r8,%r10) # get system call add.
238 tm __TI_flags+6(%r12),_TIF_TRACE >> 8
239 jnz sysc_tracesys
240 basr %r14,%r9 # call sys_xxxx
241 stg %r2,__PT_R2(%r11) # store return value
243 sysc_return:
244 LOCKDEP_SYS_EXIT
245 sysc_tif:
246 tm __PT_PSW+1(%r11),0x01 # returning to user ?
247 jno sysc_restore
248 tm __TI_flags+7(%r12),_TIF_WORK_SVC
249 jnz sysc_work # check for work
250 ni __TI_flags+7(%r12),255-_TIF_SYSCALL
251 sysc_restore:
252 lg %r14,__LC_VDSO_PER_CPU
253 lmg %r0,%r10,__PT_R0(%r11)
254 mvc __LC_RETURN_PSW(16),__PT_PSW(%r11)
255 stpt __LC_EXIT_TIMER
256 mvc __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
257 lmg %r11,%r15,__PT_R11(%r11)
258 lpswe __LC_RETURN_PSW
259 sysc_done:
261 #
262 # One of the work bits is on. Find out which one.
263 #
264 sysc_work:
265 tm __TI_flags+7(%r12),_TIF_MCCK_PENDING
266 jo sysc_mcck_pending
267 tm __TI_flags+7(%r12),_TIF_NEED_RESCHED
268 jo sysc_reschedule
269 tm __TI_flags+7(%r12),_TIF_PER_TRAP
270 jo sysc_singlestep
271 tm __TI_flags+7(%r12),_TIF_SIGPENDING
272 jo sysc_sigpending
273 tm __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
274 jo sysc_notify_resume
275 j sysc_return # beware of critical section cleanup
277 #
278 # _TIF_NEED_RESCHED is set, call schedule
279 #
280 sysc_reschedule:
281 larl %r14,sysc_return
282 jg schedule
284 #
285 # _TIF_MCCK_PENDING is set, call handler
286 #
287 sysc_mcck_pending:
288 larl %r14,sysc_return
289 jg s390_handle_mcck # TIF bit will be cleared by handler
291 #
292 # _TIF_SIGPENDING is set, call do_signal
293 #
294 sysc_sigpending:
295 lgr %r2,%r11 # pass pointer to pt_regs
296 brasl %r14,do_signal
297 tm __TI_flags+7(%r12),_TIF_SYSCALL
298 jno sysc_return
299 lmg %r2,%r7,__PT_R2(%r11) # load svc arguments
300 lg %r10,__TI_sysc_table(%r12) # address of system call table
301 lghi %r8,0 # svc 0 returns -ENOSYS
302 llgh %r1,__PT_INT_CODE+2(%r11) # load new svc number
303 cghi %r1,NR_syscalls
304 jnl sysc_nr_ok # invalid svc number -> do svc 0
305 slag %r8,%r1,2
306 j sysc_nr_ok # restart svc
308 #
309 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
310 #
311 sysc_notify_resume:
312 lgr %r2,%r11 # pass pointer to pt_regs
313 larl %r14,sysc_return
314 jg do_notify_resume
316 #
317 # _TIF_PER_TRAP is set, call do_per_trap
318 #
319 sysc_singlestep:
320 ni __TI_flags+7(%r12),255-_TIF_PER_TRAP
321 lgr %r2,%r11 # pass pointer to pt_regs
322 larl %r14,sysc_return
323 jg do_per_trap
325 #
326 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
327 # and after the system call
328 #
329 sysc_tracesys:
330 lgr %r2,%r11 # pass pointer to pt_regs
331 la %r3,0
332 llgh %r0,__PT_INT_CODE+2(%r11)
333 stg %r0,__PT_R2(%r11)
334 brasl %r14,do_syscall_trace_enter
335 lghi %r0,NR_syscalls
336 clgr %r0,%r2
337 jnh sysc_tracenogo
338 sllg %r8,%r2,2
339 lgf %r9,0(%r8,%r10)
340 sysc_tracego:
341 lmg %r3,%r7,__PT_R3(%r11)
342 stg %r7,STACK_FRAME_OVERHEAD(%r15)
343 lg %r2,__PT_ORIG_GPR2(%r11)
344 basr %r14,%r9 # call sys_xxx
345 stg %r2,__PT_R2(%r11) # store return value
346 sysc_tracenogo:
347 tm __TI_flags+6(%r12),_TIF_TRACE >> 8
348 jz sysc_return
349 lgr %r2,%r11 # pass pointer to pt_regs
350 larl %r14,sysc_return
351 jg do_syscall_trace_exit
353 #
354 # a new process exits the kernel with ret_from_fork
355 #
356 ENTRY(ret_from_fork)
357 la %r11,STACK_FRAME_OVERHEAD(%r15)
358 lg %r12,__LC_THREAD_INFO
359 brasl %r14,schedule_tail
360 TRACE_IRQS_ON
361 ssm __LC_SVC_NEW_PSW # reenable interrupts
362 tm __PT_PSW+1(%r11),0x01 # forking a kernel thread ?
363 jne sysc_tracenogo
364 # it's a kernel thread
365 lmg %r9,%r10,__PT_R9(%r11) # load gprs
366 ENTRY(kernel_thread_starter)
367 la %r2,0(%r10)
368 basr %r14,%r9
369 j sysc_tracenogo
371 /*
372 * Program check handler routine
373 */
375 ENTRY(pgm_check_handler)
376 stpt __LC_SYNC_ENTER_TIMER
377 stmg %r8,%r15,__LC_SAVE_AREA_SYNC
378 lg %r10,__LC_LAST_BREAK
379 lg %r12,__LC_THREAD_INFO
380 larl %r13,system_call
381 lmg %r8,%r9,__LC_PGM_OLD_PSW
382 HANDLE_SIE_INTERCEPT %r14,1
383 tmhh %r8,0x0001 # test problem state bit
384 jnz 1f # -> fault in user space
385 tmhh %r8,0x4000 # PER bit set in old PSW ?
386 jnz 0f # -> enabled, can't be a double fault
387 tm __LC_PGM_ILC+3,0x80 # check for per exception
388 jnz pgm_svcper # -> single stepped svc
389 0: CHECK_STACK STACK_SIZE,__LC_SAVE_AREA_SYNC
390 aghi %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
391 j 2f
392 1: UPDATE_VTIME %r14,__LC_SYNC_ENTER_TIMER
393 LAST_BREAK %r14
394 lg %r15,__LC_KERNEL_STACK
395 lg %r14,__TI_task(%r12)
396 lghi %r13,__LC_PGM_TDB
397 tm __LC_PGM_ILC+2,0x02 # check for transaction abort
398 jz 2f
399 mvc __THREAD_trap_tdb(256,%r14),0(%r13)
400 2: la %r11,STACK_FRAME_OVERHEAD(%r15)
401 stmg %r0,%r7,__PT_R0(%r11)
402 mvc __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
403 stmg %r8,%r9,__PT_PSW(%r11)
404 mvc __PT_INT_CODE(4,%r11),__LC_PGM_ILC
405 mvc __PT_INT_PARM_LONG(8,%r11),__LC_TRANS_EXC_CODE
406 stg %r10,__PT_ARGS(%r11)
407 tm __LC_PGM_ILC+3,0x80 # check for per exception
408 jz 0f
409 tmhh %r8,0x0001 # kernel per event ?
410 jz pgm_kprobe
411 oi __TI_flags+7(%r12),_TIF_PER_TRAP
412 mvc __THREAD_per_address(8,%r14),__LC_PER_ADDRESS
413 mvc __THREAD_per_cause(2,%r14),__LC_PER_CAUSE
414 mvc __THREAD_per_paid(1,%r14),__LC_PER_PAID
415 0: REENABLE_IRQS
416 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
417 larl %r1,pgm_check_table
418 llgh %r10,__PT_INT_CODE+2(%r11)
419 nill %r10,0x007f
420 sll %r10,2
421 je sysc_return
422 lgf %r1,0(%r10,%r1) # load address of handler routine
423 lgr %r2,%r11 # pass pointer to pt_regs
424 basr %r14,%r1 # branch to interrupt-handler
425 j sysc_return
427 #
428 # PER event in supervisor state, must be kprobes
429 #
430 pgm_kprobe:
431 REENABLE_IRQS
432 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
433 lgr %r2,%r11 # pass pointer to pt_regs
434 brasl %r14,do_per_trap
435 j sysc_return
437 #
438 # single stepped system call
439 #
440 pgm_svcper:
441 oi __TI_flags+7(%r12),_TIF_PER_TRAP
442 mvc __LC_RETURN_PSW(8),__LC_SVC_NEW_PSW
443 larl %r14,sysc_per
444 stg %r14,__LC_RETURN_PSW+8
445 lpswe __LC_RETURN_PSW # branch to sysc_per and enable irqs
447 /*
448 * IO interrupt handler routine
449 */
450 ENTRY(io_int_handler)
451 STCK __LC_INT_CLOCK
452 stpt __LC_ASYNC_ENTER_TIMER
453 stmg %r8,%r15,__LC_SAVE_AREA_ASYNC
454 lg %r10,__LC_LAST_BREAK
455 lg %r12,__LC_THREAD_INFO
456 larl %r13,system_call
457 lmg %r8,%r9,__LC_IO_OLD_PSW
458 HANDLE_SIE_INTERCEPT %r14,2
459 SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
460 tmhh %r8,0x0001 # interrupting from user?
461 jz io_skip
462 UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
463 LAST_BREAK %r14
464 io_skip:
465 stmg %r0,%r7,__PT_R0(%r11)
466 mvc __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
467 stmg %r8,%r9,__PT_PSW(%r11)
468 mvc __PT_INT_CODE(12,%r11),__LC_SUBCHANNEL_ID
469 TRACE_IRQS_OFF
470 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
471 io_loop:
472 lgr %r2,%r11 # pass pointer to pt_regs
473 lghi %r3,IO_INTERRUPT
474 tm __PT_INT_CODE+8(%r11),0x80 # adapter interrupt ?
475 jz io_call
476 lghi %r3,THIN_INTERRUPT
477 io_call:
478 brasl %r14,do_IRQ
479 tm __LC_MACHINE_FLAGS+6,0x10 # MACHINE_FLAG_LPAR
480 jz io_return
481 tpi 0
482 jz io_return
483 mvc __PT_INT_CODE(12,%r11),__LC_SUBCHANNEL_ID
484 j io_loop
485 io_return:
486 LOCKDEP_SYS_EXIT
487 TRACE_IRQS_ON
488 io_tif:
489 tm __TI_flags+7(%r12),_TIF_WORK_INT
490 jnz io_work # there is work to do (signals etc.)
491 io_restore:
492 lg %r14,__LC_VDSO_PER_CPU
493 lmg %r0,%r10,__PT_R0(%r11)
494 mvc __LC_RETURN_PSW(16),__PT_PSW(%r11)
495 stpt __LC_EXIT_TIMER
496 mvc __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
497 lmg %r11,%r15,__PT_R11(%r11)
498 lpswe __LC_RETURN_PSW
499 io_done:
501 #
502 # There is work todo, find out in which context we have been interrupted:
503 # 1) if we return to user space we can do all _TIF_WORK_INT work
504 # 2) if we return to kernel code and kvm is enabled check if we need to
505 # modify the psw to leave SIE
506 # 3) if we return to kernel code and preemptive scheduling is enabled check
507 # the preemption counter and if it is zero call preempt_schedule_irq
508 # Before any work can be done, a switch to the kernel stack is required.
509 #
510 io_work:
511 tm __PT_PSW+1(%r11),0x01 # returning to user ?
512 jo io_work_user # yes -> do resched & signal
513 #ifdef CONFIG_PREEMPT
514 # check for preemptive scheduling
515 icm %r0,15,__TI_precount(%r12)
516 jnz io_restore # preemption is disabled
517 tm __TI_flags+7(%r12),_TIF_NEED_RESCHED
518 jno io_restore
519 # switch to kernel stack
520 lg %r1,__PT_R15(%r11)
521 aghi %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
522 mvc STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
523 xc __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
524 la %r11,STACK_FRAME_OVERHEAD(%r1)
525 lgr %r15,%r1
526 # TRACE_IRQS_ON already done at io_return, call
527 # TRACE_IRQS_OFF to keep things symmetrical
528 TRACE_IRQS_OFF
529 brasl %r14,preempt_schedule_irq
530 j io_return
531 #else
532 j io_restore
533 #endif
535 #
536 # Need to do work before returning to userspace, switch to kernel stack
537 #
538 io_work_user:
539 lg %r1,__LC_KERNEL_STACK
540 mvc STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
541 xc __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
542 la %r11,STACK_FRAME_OVERHEAD(%r1)
543 lgr %r15,%r1
545 #
546 # One of the work bits is on. Find out which one.
547 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
548 # and _TIF_MCCK_PENDING
549 #
550 io_work_tif:
551 tm __TI_flags+7(%r12),_TIF_MCCK_PENDING
552 jo io_mcck_pending
553 tm __TI_flags+7(%r12),_TIF_NEED_RESCHED
554 jo io_reschedule
555 tm __TI_flags+7(%r12),_TIF_SIGPENDING
556 jo io_sigpending
557 tm __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
558 jo io_notify_resume
559 j io_return # beware of critical section cleanup
561 #
562 # _TIF_MCCK_PENDING is set, call handler
563 #
564 io_mcck_pending:
565 # TRACE_IRQS_ON already done at io_return
566 brasl %r14,s390_handle_mcck # TIF bit will be cleared by handler
567 TRACE_IRQS_OFF
568 j io_return
570 #
571 # _TIF_NEED_RESCHED is set, call schedule
572 #
573 io_reschedule:
574 # TRACE_IRQS_ON already done at io_return
575 ssm __LC_SVC_NEW_PSW # reenable interrupts
576 brasl %r14,schedule # call scheduler
577 ssm __LC_PGM_NEW_PSW # disable I/O and ext. interrupts
578 TRACE_IRQS_OFF
579 j io_return
581 #
582 # _TIF_SIGPENDING or is set, call do_signal
583 #
584 io_sigpending:
585 # TRACE_IRQS_ON already done at io_return
586 ssm __LC_SVC_NEW_PSW # reenable interrupts
587 lgr %r2,%r11 # pass pointer to pt_regs
588 brasl %r14,do_signal
589 ssm __LC_PGM_NEW_PSW # disable I/O and ext. interrupts
590 TRACE_IRQS_OFF
591 j io_return
593 #
594 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
595 #
596 io_notify_resume:
597 # TRACE_IRQS_ON already done at io_return
598 ssm __LC_SVC_NEW_PSW # reenable interrupts
599 lgr %r2,%r11 # pass pointer to pt_regs
600 brasl %r14,do_notify_resume
601 ssm __LC_PGM_NEW_PSW # disable I/O and ext. interrupts
602 TRACE_IRQS_OFF
603 j io_return
605 /*
606 * External interrupt handler routine
607 */
608 ENTRY(ext_int_handler)
609 STCK __LC_INT_CLOCK
610 stpt __LC_ASYNC_ENTER_TIMER
611 stmg %r8,%r15,__LC_SAVE_AREA_ASYNC
612 lg %r10,__LC_LAST_BREAK
613 lg %r12,__LC_THREAD_INFO
614 larl %r13,system_call
615 lmg %r8,%r9,__LC_EXT_OLD_PSW
616 HANDLE_SIE_INTERCEPT %r14,3
617 SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
618 tmhh %r8,0x0001 # interrupting from user ?
619 jz ext_skip
620 UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
621 LAST_BREAK %r14
622 ext_skip:
623 stmg %r0,%r7,__PT_R0(%r11)
624 mvc __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
625 stmg %r8,%r9,__PT_PSW(%r11)
626 lghi %r1,__LC_EXT_PARAMS2
627 mvc __PT_INT_CODE(4,%r11),__LC_EXT_CPU_ADDR
628 mvc __PT_INT_PARM(4,%r11),__LC_EXT_PARAMS
629 mvc __PT_INT_PARM_LONG(8,%r11),0(%r1)
630 TRACE_IRQS_OFF
631 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
632 lgr %r2,%r11 # pass pointer to pt_regs
633 lghi %r3,EXT_INTERRUPT
634 brasl %r14,do_IRQ
635 j io_return
637 /*
638 * Load idle PSW. The second "half" of this function is in cleanup_idle.
639 */
640 ENTRY(psw_idle)
641 stg %r3,__SF_EMPTY(%r15)
642 larl %r1,psw_idle_lpsw+4
643 stg %r1,__SF_EMPTY+8(%r15)
644 STCK __CLOCK_IDLE_ENTER(%r2)
645 stpt __TIMER_IDLE_ENTER(%r2)
646 psw_idle_lpsw:
647 lpswe __SF_EMPTY(%r15)
648 br %r14
649 psw_idle_end:
651 __critical_end:
653 /*
654 * Machine check handler routines
655 */
656 ENTRY(mcck_int_handler)
657 STCK __LC_MCCK_CLOCK
658 la %r1,4095 # revalidate r1
659 spt __LC_CPU_TIMER_SAVE_AREA-4095(%r1) # revalidate cpu timer
660 lmg %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
661 lg %r10,__LC_LAST_BREAK
662 lg %r12,__LC_THREAD_INFO
663 larl %r13,system_call
664 lmg %r8,%r9,__LC_MCK_OLD_PSW
665 HANDLE_SIE_INTERCEPT %r14,4
666 tm __LC_MCCK_CODE,0x80 # system damage?
667 jo mcck_panic # yes -> rest of mcck code invalid
668 lghi %r14,__LC_CPU_TIMER_SAVE_AREA
669 mvc __LC_MCCK_ENTER_TIMER(8),0(%r14)
670 tm __LC_MCCK_CODE+5,0x02 # stored cpu timer value valid?
671 jo 3f
672 la %r14,__LC_SYNC_ENTER_TIMER
673 clc 0(8,%r14),__LC_ASYNC_ENTER_TIMER
674 jl 0f
675 la %r14,__LC_ASYNC_ENTER_TIMER
676 0: clc 0(8,%r14),__LC_EXIT_TIMER
677 jl 1f
678 la %r14,__LC_EXIT_TIMER
679 1: clc 0(8,%r14),__LC_LAST_UPDATE_TIMER
680 jl 2f
681 la %r14,__LC_LAST_UPDATE_TIMER
682 2: spt 0(%r14)
683 mvc __LC_MCCK_ENTER_TIMER(8),0(%r14)
684 3: tm __LC_MCCK_CODE+2,0x09 # mwp + ia of old psw valid?
685 jno mcck_panic # no -> skip cleanup critical
686 SWITCH_ASYNC __LC_GPREGS_SAVE_AREA+64,__LC_PANIC_STACK,PAGE_SHIFT
687 tm %r8,0x0001 # interrupting from user ?
688 jz mcck_skip
689 UPDATE_VTIME %r14,__LC_MCCK_ENTER_TIMER
690 LAST_BREAK %r14
691 mcck_skip:
692 lghi %r14,__LC_GPREGS_SAVE_AREA+64
693 stmg %r0,%r7,__PT_R0(%r11)
694 mvc __PT_R8(64,%r11),0(%r14)
695 stmg %r8,%r9,__PT_PSW(%r11)
696 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
697 lgr %r2,%r11 # pass pointer to pt_regs
698 brasl %r14,s390_do_machine_check
699 tm __PT_PSW+1(%r11),0x01 # returning to user ?
700 jno mcck_return
701 lg %r1,__LC_KERNEL_STACK # switch to kernel stack
702 mvc STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
703 xc __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
704 la %r11,STACK_FRAME_OVERHEAD(%r1)
705 lgr %r15,%r1
706 ssm __LC_PGM_NEW_PSW # turn dat on, keep irqs off
707 tm __TI_flags+7(%r12),_TIF_MCCK_PENDING
708 jno mcck_return
709 TRACE_IRQS_OFF
710 brasl %r14,s390_handle_mcck
711 TRACE_IRQS_ON
712 mcck_return:
713 lg %r14,__LC_VDSO_PER_CPU
714 lmg %r0,%r10,__PT_R0(%r11)
715 mvc __LC_RETURN_MCCK_PSW(16),__PT_PSW(%r11) # move return PSW
716 tm __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
717 jno 0f
718 stpt __LC_EXIT_TIMER
719 mvc __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
720 0: lmg %r11,%r15,__PT_R11(%r11)
721 lpswe __LC_RETURN_MCCK_PSW
723 mcck_panic:
724 lg %r14,__LC_PANIC_STACK
725 slgr %r14,%r15
726 srag %r14,%r14,PAGE_SHIFT
727 jz 0f
728 lg %r15,__LC_PANIC_STACK
729 0: aghi %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
730 j mcck_skip
732 #
733 # PSW restart interrupt handler
734 #
735 ENTRY(restart_int_handler)
736 stg %r15,__LC_SAVE_AREA_RESTART
737 lg %r15,__LC_RESTART_STACK
738 aghi %r15,-__PT_SIZE # create pt_regs on stack
739 xc 0(__PT_SIZE,%r15),0(%r15)
740 stmg %r0,%r14,__PT_R0(%r15)
741 mvc __PT_R15(8,%r15),__LC_SAVE_AREA_RESTART
742 mvc __PT_PSW(16,%r15),__LC_RST_OLD_PSW # store restart old psw
743 aghi %r15,-STACK_FRAME_OVERHEAD # create stack frame on stack
744 xc 0(STACK_FRAME_OVERHEAD,%r15),0(%r15)
745 lg %r1,__LC_RESTART_FN # load fn, parm & source cpu
746 lg %r2,__LC_RESTART_DATA
747 lg %r3,__LC_RESTART_SOURCE
748 ltgr %r3,%r3 # test source cpu address
749 jm 1f # negative -> skip source stop
750 0: sigp %r4,%r3,SIGP_SENSE # sigp sense to source cpu
751 brc 10,0b # wait for status stored
752 1: basr %r14,%r1 # call function
753 stap __SF_EMPTY(%r15) # store cpu address
754 llgh %r3,__SF_EMPTY(%r15)
755 2: sigp %r4,%r3,SIGP_STOP # sigp stop to current cpu
756 brc 2,2b
757 3: j 3b
759 .section .kprobes.text, "ax"
761 #ifdef CONFIG_CHECK_STACK
762 /*
763 * The synchronous or the asynchronous stack overflowed. We are dead.
764 * No need to properly save the registers, we are going to panic anyway.
765 * Setup a pt_regs so that show_trace can provide a good call trace.
766 */
767 stack_overflow:
768 lg %r15,__LC_PANIC_STACK # change to panic stack
769 la %r11,STACK_FRAME_OVERHEAD(%r15)
770 stmg %r0,%r7,__PT_R0(%r11)
771 stmg %r8,%r9,__PT_PSW(%r11)
772 mvc __PT_R8(64,%r11),0(%r14)
773 stg %r10,__PT_ORIG_GPR2(%r11) # store last break to orig_gpr2
774 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
775 lgr %r2,%r11 # pass pointer to pt_regs
776 jg kernel_stack_overflow
777 #endif
779 .align 8
780 cleanup_table:
781 .quad system_call
782 .quad sysc_do_svc
783 .quad sysc_tif
784 .quad sysc_restore
785 .quad sysc_done
786 .quad io_tif
787 .quad io_restore
788 .quad io_done
789 .quad psw_idle
790 .quad psw_idle_end
792 cleanup_critical:
793 clg %r9,BASED(cleanup_table) # system_call
794 jl 0f
795 clg %r9,BASED(cleanup_table+8) # sysc_do_svc
796 jl cleanup_system_call
797 clg %r9,BASED(cleanup_table+16) # sysc_tif
798 jl 0f
799 clg %r9,BASED(cleanup_table+24) # sysc_restore
800 jl cleanup_sysc_tif
801 clg %r9,BASED(cleanup_table+32) # sysc_done
802 jl cleanup_sysc_restore
803 clg %r9,BASED(cleanup_table+40) # io_tif
804 jl 0f
805 clg %r9,BASED(cleanup_table+48) # io_restore
806 jl cleanup_io_tif
807 clg %r9,BASED(cleanup_table+56) # io_done
808 jl cleanup_io_restore
809 clg %r9,BASED(cleanup_table+64) # psw_idle
810 jl 0f
811 clg %r9,BASED(cleanup_table+72) # psw_idle_end
812 jl cleanup_idle
813 0: br %r14
816 cleanup_system_call:
817 # check if stpt has been executed
818 clg %r9,BASED(cleanup_system_call_insn)
819 jh 0f
820 mvc __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
821 cghi %r11,__LC_SAVE_AREA_ASYNC
822 je 0f
823 mvc __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
824 0: # check if stmg has been executed
825 clg %r9,BASED(cleanup_system_call_insn+8)
826 jh 0f
827 mvc __LC_SAVE_AREA_SYNC(64),0(%r11)
828 0: # check if base register setup + TIF bit load has been done
829 clg %r9,BASED(cleanup_system_call_insn+16)
830 jhe 0f
831 # set up saved registers r10 and r12
832 stg %r10,16(%r11) # r10 last break
833 stg %r12,32(%r11) # r12 thread-info pointer
834 0: # check if the user time update has been done
835 clg %r9,BASED(cleanup_system_call_insn+24)
836 jh 0f
837 lg %r15,__LC_EXIT_TIMER
838 slg %r15,__LC_SYNC_ENTER_TIMER
839 alg %r15,__LC_USER_TIMER
840 stg %r15,__LC_USER_TIMER
841 0: # check if the system time update has been done
842 clg %r9,BASED(cleanup_system_call_insn+32)
843 jh 0f
844 lg %r15,__LC_LAST_UPDATE_TIMER
845 slg %r15,__LC_EXIT_TIMER
846 alg %r15,__LC_SYSTEM_TIMER
847 stg %r15,__LC_SYSTEM_TIMER
848 0: # update accounting time stamp
849 mvc __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
850 # do LAST_BREAK
851 lg %r9,16(%r11)
852 srag %r9,%r9,23
853 jz 0f
854 mvc __TI_last_break(8,%r12),16(%r11)
855 0: # set up saved register r11
856 lg %r15,__LC_KERNEL_STACK
857 la %r9,STACK_FRAME_OVERHEAD(%r15)
858 stg %r9,24(%r11) # r11 pt_regs pointer
859 # fill pt_regs
860 mvc __PT_R8(64,%r9),__LC_SAVE_AREA_SYNC
861 stmg %r0,%r7,__PT_R0(%r9)
862 mvc __PT_PSW(16,%r9),__LC_SVC_OLD_PSW
863 mvc __PT_INT_CODE(4,%r9),__LC_SVC_ILC
864 # setup saved register r15
865 stg %r15,56(%r11) # r15 stack pointer
866 # set new psw address and exit
867 larl %r9,sysc_do_svc
868 br %r14
869 cleanup_system_call_insn:
870 .quad system_call
871 .quad sysc_stmg
872 .quad sysc_per
873 .quad sysc_vtime+18
874 .quad sysc_vtime+42
876 cleanup_sysc_tif:
877 larl %r9,sysc_tif
878 br %r14
880 cleanup_sysc_restore:
881 clg %r9,BASED(cleanup_sysc_restore_insn)
882 je 0f
883 lg %r9,24(%r11) # get saved pointer to pt_regs
884 mvc __LC_RETURN_PSW(16),__PT_PSW(%r9)
885 mvc 0(64,%r11),__PT_R8(%r9)
886 lmg %r0,%r7,__PT_R0(%r9)
887 0: lmg %r8,%r9,__LC_RETURN_PSW
888 br %r14
889 cleanup_sysc_restore_insn:
890 .quad sysc_done - 4
892 cleanup_io_tif:
893 larl %r9,io_tif
894 br %r14
896 cleanup_io_restore:
897 clg %r9,BASED(cleanup_io_restore_insn)
898 je 0f
899 lg %r9,24(%r11) # get saved r11 pointer to pt_regs
900 mvc __LC_RETURN_PSW(16),__PT_PSW(%r9)
901 mvc 0(64,%r11),__PT_R8(%r9)
902 lmg %r0,%r7,__PT_R0(%r9)
903 0: lmg %r8,%r9,__LC_RETURN_PSW
904 br %r14
905 cleanup_io_restore_insn:
906 .quad io_done - 4
908 cleanup_idle:
909 # copy interrupt clock & cpu timer
910 mvc __CLOCK_IDLE_EXIT(8,%r2),__LC_INT_CLOCK
911 mvc __TIMER_IDLE_EXIT(8,%r2),__LC_ASYNC_ENTER_TIMER
912 cghi %r11,__LC_SAVE_AREA_ASYNC
913 je 0f
914 mvc __CLOCK_IDLE_EXIT(8,%r2),__LC_MCCK_CLOCK
915 mvc __TIMER_IDLE_EXIT(8,%r2),__LC_MCCK_ENTER_TIMER
916 0: # check if stck & stpt have been executed
917 clg %r9,BASED(cleanup_idle_insn)
918 jhe 1f
919 mvc __CLOCK_IDLE_ENTER(8,%r2),__CLOCK_IDLE_EXIT(%r2)
920 mvc __TIMER_IDLE_ENTER(8,%r2),__TIMER_IDLE_EXIT(%r2)
921 1: # account system time going idle
922 lg %r9,__LC_STEAL_TIMER
923 alg %r9,__CLOCK_IDLE_ENTER(%r2)
924 slg %r9,__LC_LAST_UPDATE_CLOCK
925 stg %r9,__LC_STEAL_TIMER
926 mvc __LC_LAST_UPDATE_CLOCK(8),__CLOCK_IDLE_EXIT(%r2)
927 lg %r9,__LC_SYSTEM_TIMER
928 alg %r9,__LC_LAST_UPDATE_TIMER
929 slg %r9,__TIMER_IDLE_ENTER(%r2)
930 stg %r9,__LC_SYSTEM_TIMER
931 mvc __LC_LAST_UPDATE_TIMER(8),__TIMER_IDLE_EXIT(%r2)
932 # prepare return psw
933 nihh %r8,0xfcfd # clear irq & wait state bits
934 lg %r9,48(%r11) # return from psw_idle
935 br %r14
936 cleanup_idle_insn:
937 .quad psw_idle_lpsw
939 /*
940 * Integer constants
941 */
942 .align 8
943 .Lcritical_start:
944 .quad __critical_start
945 .Lcritical_length:
946 .quad __critical_end - __critical_start
949 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
950 /*
951 * sie64a calling convention:
952 * %r2 pointer to sie control block
953 * %r3 guest register save area
954 */
955 ENTRY(sie64a)
956 stmg %r6,%r14,__SF_GPRS(%r15) # save kernel registers
957 stg %r2,__SF_EMPTY(%r15) # save control block pointer
958 stg %r3,__SF_EMPTY+8(%r15) # save guest register save area
959 xc __SF_EMPTY+16(16,%r15),__SF_EMPTY+16(%r15) # host id & reason
960 lmg %r0,%r13,0(%r3) # load guest gprs 0-13
961 lg %r14,__LC_GMAP # get gmap pointer
962 ltgr %r14,%r14
963 jz sie_gmap
964 lctlg %c1,%c1,__GMAP_ASCE(%r14) # load primary asce
965 sie_gmap:
966 lg %r14,__SF_EMPTY(%r15) # get control block pointer
967 oi __SIE_PROG0C+3(%r14),1 # we are going into SIE now
968 tm __SIE_PROG20+3(%r14),1 # last exit...
969 jnz sie_done
970 LPP __SF_EMPTY(%r15) # set guest id
971 sie 0(%r14)
972 sie_done:
973 LPP __SF_EMPTY+16(%r15) # set host id
974 ni __SIE_PROG0C+3(%r14),0xfe # no longer in SIE
975 lctlg %c1,%c1,__LC_USER_ASCE # load primary asce
976 # some program checks are suppressing. C code (e.g. do_protection_exception)
977 # will rewind the PSW by the ILC, which is 4 bytes in case of SIE. Other
978 # instructions beween sie64a and sie_done should not cause program
979 # interrupts. So lets use a nop (47 00 00 00) as a landing pad.
980 # See also HANDLE_SIE_INTERCEPT
981 rewind_pad:
982 nop 0
983 .globl sie_exit
984 sie_exit:
985 lg %r14,__SF_EMPTY+8(%r15) # load guest register save area
986 stmg %r0,%r13,0(%r14) # save guest gprs 0-13
987 lmg %r6,%r14,__SF_GPRS(%r15) # restore kernel registers
988 lg %r2,__SF_EMPTY+24(%r15) # return exit reason code
989 br %r14
990 sie_fault:
991 lghi %r14,-EFAULT
992 stg %r14,__SF_EMPTY+24(%r15) # set exit reason code
993 j sie_exit
995 .align 8
996 .Lsie_critical:
997 .quad sie_gmap
998 .Lsie_critical_length:
999 .quad sie_done - sie_gmap
1001 EX_TABLE(rewind_pad,sie_fault)
1002 EX_TABLE(sie_exit,sie_fault)
1003 #endif
1005 .section .rodata, "a"
1006 #define SYSCALL(esa,esame,emu) .long esame
1007 .globl sys_call_table
1008 sys_call_table:
1009 #include "syscalls.S"
1010 #undef SYSCALL
1012 #ifdef CONFIG_COMPAT
1014 #define SYSCALL(esa,esame,emu) .long emu
1015 .globl sys_call_table_emu
1016 sys_call_table_emu:
1017 #include "syscalls.S"
1018 #undef SYSCALL
1019 #endif