arch/mips/kernel/mcount.S

   1 /*
   2  * MIPS specific _mcount support
   3  *
   4  * This file is subject to the terms and conditions of the GNU General Public
   5  * License.  See the file "COPYING" in the main directory of this archive for
   6  * more details.
   7  *
   8  * Copyright (C) 2009 Lemote Inc. & DSLab, Lanzhou University, China
   9  * Copyright (C) 2010 DSLab, Lanzhou University, China
  10  * Author: Wu Zhangjin <wuzhangjin@gmail.com>
  11  */
  12
  13 #include <asm/regdef.h>
  14 #include <asm/stackframe.h>
  15 #include <asm/ftrace.h>
  16
  17         .text
  18         .set noreorder
  19         .set noat
  20
  21         .macro MCOUNT_SAVE_REGS
  22         PTR_SUBU        sp, PT_SIZE
  23         PTR_S   ra, PT_R31(sp)
  24         PTR_S   AT, PT_R1(sp)
  25         PTR_S   a0, PT_R4(sp)
  26         PTR_S   a1, PT_R5(sp)
  27         PTR_S   a2, PT_R6(sp)
  28         PTR_S   a3, PT_R7(sp)
  29 #ifdef CONFIG_64BIT
  30         PTR_S   a4, PT_R8(sp)
  31         PTR_S   a5, PT_R9(sp)
  32         PTR_S   a6, PT_R10(sp)
  33         PTR_S   a7, PT_R11(sp)
  34 #endif
  35         .endm
  36
  37         .macro MCOUNT_RESTORE_REGS
  38         PTR_L   ra, PT_R31(sp)
  39         PTR_L   AT, PT_R1(sp)
  40         PTR_L   a0, PT_R4(sp)
  41         PTR_L   a1, PT_R5(sp)
  42         PTR_L   a2, PT_R6(sp)
  43         PTR_L   a3, PT_R7(sp)
  44 #ifdef CONFIG_64BIT
  45         PTR_L   a4, PT_R8(sp)
  46         PTR_L   a5, PT_R9(sp)
  47         PTR_L   a6, PT_R10(sp)
  48         PTR_L   a7, PT_R11(sp)
  49 #endif
  50         PTR_ADDIU       sp, PT_SIZE
  51         .endm
  52
  53         .macro RETURN_BACK
  54         jr ra
  55          move ra, AT
  56         .endm
  57
  58 /*
  59  * The -mmcount-ra-address option of gcc 4.5 uses register $12 to pass
  60  * the location of the parent's return address.
  61  */
  62 #define MCOUNT_RA_ADDRESS_REG   $12
  63
  64 #ifdef CONFIG_DYNAMIC_FTRACE
  65
  66 NESTED(ftrace_caller, PT_SIZE, ra)
  67         .globl _mcount
  68 _mcount:
  69         b       ftrace_stub
  70 #ifdef CONFIG_32BIT
  71          addiu sp,sp,8
  72 #else
  73          nop
  74 #endif
  75
  76         /* When tracing is activated, it calls ftrace_caller+8 (aka here) */
  77         lw      t1, function_trace_stop
  78         bnez    t1, ftrace_stub
  79          nop
  80
  81         MCOUNT_SAVE_REGS
  82 #ifdef KBUILD_MCOUNT_RA_ADDRESS
  83         PTR_S   MCOUNT_RA_ADDRESS_REG, PT_R12(sp)
  84 #endif
  85
  86         move    a0, ra          /* arg1: self return address */
  87         .globl ftrace_call
  88 ftrace_call:
  89         nop     /* a placeholder for the call to a real tracing function */
  90          move   a1, AT          /* arg2: parent's return address */
  91
  92 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  93         .globl ftrace_graph_call
  94 ftrace_graph_call:
  95         nop
  96          nop
  97 #endif
  98
  99         MCOUNT_RESTORE_REGS
 100         .globl ftrace_stub
 101 ftrace_stub:
 102         RETURN_BACK
 103         END(ftrace_caller)
 104
 105 #else   /* ! CONFIG_DYNAMIC_FTRACE */
 106
 107 NESTED(_mcount, PT_SIZE, ra)
 108         lw      t1, function_trace_stop
 109         bnez    t1, ftrace_stub
 110          nop
 111         PTR_LA  t1, ftrace_stub
 112         PTR_L   t2, ftrace_trace_function /* Prepare t2 for (1) */
 113         bne     t1, t2, static_trace
 114          nop
 115
 116 #ifdef  CONFIG_FUNCTION_GRAPH_TRACER
 117         PTR_L   t3, ftrace_graph_return
 118         bne     t1, t3, ftrace_graph_caller
 119          nop
 120         PTR_LA  t1, ftrace_graph_entry_stub
 121         PTR_L   t3, ftrace_graph_entry
 122         bne     t1, t3, ftrace_graph_caller
 123          nop
 124 #endif
 125         b       ftrace_stub
 126          nop
 127
 128 static_trace:
 129         MCOUNT_SAVE_REGS
 130
 131         move    a0, ra          /* arg1: self return address */
 132         jalr    t2              /* (1) call *ftrace_trace_function */
 133          move   a1, AT          /* arg2: parent's return address */
 134
 135         MCOUNT_RESTORE_REGS
 136         .globl ftrace_stub
 137 ftrace_stub:
 138         RETURN_BACK
 139         END(_mcount)
 140
 141 #endif  /* ! CONFIG_DYNAMIC_FTRACE */
 142
 143 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 144
 145 NESTED(ftrace_graph_caller, PT_SIZE, ra)
 146 #ifndef CONFIG_DYNAMIC_FTRACE
 147         MCOUNT_SAVE_REGS
 148 #endif
 149
 150         /* arg1: Get the location of the parent's return address */
 151 #ifdef KBUILD_MCOUNT_RA_ADDRESS
 152 #ifdef CONFIG_DYNAMIC_FTRACE
 153         PTR_L   a0, PT_R12(sp)
 154 #else
 155         move    a0, MCOUNT_RA_ADDRESS_REG
 156 #endif
 157         bnez    a0, 1f  /* non-leaf func: stored in MCOUNT_RA_ADDRESS_REG */
 158          nop
 159 #endif
 160         PTR_LA  a0, PT_R1(sp)   /* leaf func: the location in current stack */
 161 1:
 162
 163         /* arg2: Get self return address */
 164 #ifdef CONFIG_DYNAMIC_FTRACE
 165         PTR_L   a1, PT_R31(sp)
 166 #else
 167         move    a1, ra
 168 #endif
 169
 170         /* arg3: Get frame pointer of current stack */
 171 #ifdef CONFIG_FRAME_POINTER
 172         move    a2, fp
 173 #else /* ! CONFIG_FRAME_POINTER */
 174 #ifdef CONFIG_64BIT
 175         PTR_LA  a2, PT_SIZE(sp)
 176 #else
 177         PTR_LA  a2, (PT_SIZE+8)(sp)
 178 #endif
 179 #endif
 180
 181         jal     prepare_ftrace_return
 182          nop
 183         MCOUNT_RESTORE_REGS
 184         RETURN_BACK
 185         END(ftrace_graph_caller)
 186
 187         .align  2
 188         .globl  return_to_handler
 189 return_to_handler:
 190         PTR_SUBU        sp, PT_SIZE
 191         PTR_S   v0, PT_R2(sp)
 192
 193         jal     ftrace_return_to_handler
 194          PTR_S  v1, PT_R3(sp)
 195
 196         /* restore the real parent address: v0 -> ra */
 197         move    ra, v0
 198
 199         PTR_L   v0, PT_R2(sp)
 200         PTR_L   v1, PT_R3(sp)
 201         jr      ra
 202          PTR_ADDIU      sp, PT_SIZE
 203 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */
 204
 205         .set at
 206         .set reorder