arch/score/kernel/vmlinux.lds.S

   1 /*
   2  * arch/score/kernel/vmlinux.lds.S
   3  *
   4  * Score Processor version.
   5  *
   6  * Copyright (C) 2009 Sunplus Core Technology Co., Ltd.
   7  *  Chen Liqin <liqin.chen@sunplusct.com>
   8  *  Lennox Wu <lennox.wu@sunplusct.com>
   9  *
  10  * This program is free software; you can redistribute it and/or modify
  11  * it under the terms of the GNU General Public License as published by
  12  * the Free Software Foundation; either version 2 of the License, or
  13  * (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, see the file COPYING, or write
  22  * to the Free Software Foundation, Inc.,
  23  * 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
  24  */
  25
  26 #include <asm-generic/vmlinux.lds.h>
  27 #include <asm/thread_info.h>
  28 #include <asm/page.h>
  29
  30 OUTPUT_ARCH(score)
  31 ENTRY(_stext)
  32
  33 jiffies = jiffies_64;
  34
  35 SECTIONS
  36 {
  37         . = CONFIG_MEMORY_START + 0x2000;
  38         /* read-only */
  39         .text : {
  40                 _text = .;      /* Text and read-only data */
  41                 TEXT_TEXT
  42                 SCHED_TEXT
  43                 CPUIDLE_TEXT
  44                 LOCK_TEXT
  45                 KPROBES_TEXT
  46                 *(.text.*)
  47                 *(.fixup)
  48                 . = ALIGN (4) ;
  49                 _etext = .;     /* End of text section */
  50         }
  51
  52         . = ALIGN(16);
  53         _sdata =  .;                    /* Start of data section */
  54         RODATA
  55
  56         EXCEPTION_TABLE(16)
  57
  58         RW_DATA_SECTION(32, PAGE_SIZE, THREAD_SIZE)
  59
  60         /* We want the small data sections together, so single-instruction offsets
  61            can access them all, and initialized data all before uninitialized, so
  62            we can shorten the on-disk segment size.  */
  63         . = ALIGN(8);
  64         .sdata : {
  65                 *(.sdata)
  66         }
  67         _edata =  .;                    /* End of data section */
  68
  69         /* will be freed after init */
  70         . = ALIGN(PAGE_SIZE);           /* Init code and data */
  71         __init_begin = .;
  72
  73         INIT_TEXT_SECTION(PAGE_SIZE)
  74         INIT_DATA_SECTION(16)
  75
  76         /* .exit.text is discarded at runtime, not link time, to deal with
  77          * references from .rodata
  78          */
  79         .exit.text : {
  80                 EXIT_TEXT
  81         }
  82         .exit.data : {
  83                 EXIT_DATA
  84         }
  85         . = ALIGN(PAGE_SIZE);
  86         __init_end = .;
  87         /* freed after init ends here */
  88
  89         BSS_SECTION(0, 0, 0)
  90         _end = .;
  91 }