arch/arm/mm/abort-ev5tj.S

   1 #include <linux/linkage.h>
   2 #include <asm/assembler.h>
   3 #include "abort-macro.S"
   4 /*
   5  * Function: v5tj_early_abort
   6  *
   7  * Params  : r2 = pt_regs
   8  *         : r4 = aborted context pc
   9  *         : r5 = aborted context psr
  10  *
  11  * Returns : r4 - r11, r13 preserved
  12  *
  13  * Purpose : obtain information about current aborted instruction.
  14  * Note: we read user space.  This means we might cause a data
  15  * abort here if the I-TLB and D-TLB aren't seeing the same
  16  * picture.  Unfortunately, this does happen.  We live with it.
  17  */
  18         .align  5
  19 ENTRY(v5tj_early_abort)
  20         mrc     p15, 0, r1, c5, c0, 0           @ get FSR
  21         mrc     p15, 0, r0, c6, c0, 0           @ get FAR
  22         bic     r1, r1, #1 << 11 | 1 << 10      @ clear bits 11 and 10 of FSR
  23         tst     r5, #PSR_J_BIT                  @ Java?
  24         bne     do_DataAbort
  25         do_thumb_abort fsr=r1, pc=r4, psr=r5, tmp=r3
  26         ldreq   r3, [r4]                        @ read aborted ARM instruction
  27         uaccess_disable ip                      @ disable userspace access
  28         teq_ldrd tmp=ip, insn=r3                @ insn was LDRD?
  29         beq     do_DataAbort                    @ yes
  30         tst     r3, #1 << 20                    @ L = 0 -> write
  31         orreq   r1, r1, #1 << 11                @ yes.
  32         b       do_DataAbort