scripts/coccinelle/misc/irqf_oneshot.cocci

   1 /// Since commit 1c6c69525b40 ("genirq: Reject bogus threaded irq requests")
   2 /// threaded IRQs without a primary handler need to be requested with
   3 /// IRQF_ONESHOT, otherwise the request will fail.
   4 ///
   5 /// So pass the IRQF_ONESHOT flag in this case.
   6 ///
   7 //
   8 // Confidence: Moderate
   9 // Comments:
  10 // Options: --no-includes
  11
  12 virtual patch
  13 virtual context
  14 virtual org
  15 virtual report
  16
  17 @r1@
  18 expression dev, irq, thread_fn;
  19 position p;
  20 @@
  21 (
  22 request_threaded_irq@p(irq, NULL, thread_fn,
  23 (
  24 IRQF_ONESHOT | ...
  25 |
  26 IRQF_ONESHOT
  27 )
  28 , ...)
  29 |
  30 devm_request_threaded_irq@p(dev, irq, NULL, thread_fn,
  31 (
  32 IRQF_ONESHOT | ...
  33 |
  34 IRQF_ONESHOT
  35 )
  36 , ...)
  37 )
  38
  39 @r2@
  40 expression dev, irq, thread_fn, flags, e;
  41 position p != r1.p;
  42 @@
  43 (
  44 flags = IRQF_ONESHOT | ...
  45 |
  46 flags |= IRQF_ONESHOT | ...
  47 )
  48 ... when != flags = e
  49 (
  50 request_threaded_irq@p(irq, NULL, thread_fn, flags, ...);
  51 |
  52 devm_request_threaded_irq@p(dev, irq, NULL, thread_fn, flags, ...);
  53 )
  54
  55 @depends on patch@
  56 expression dev, irq, thread_fn, flags;
  57 position p != {r1.p,r2.p};
  58 @@
  59 (
  60 request_threaded_irq@p(irq, NULL, thread_fn,
  61 (
  62 -0
  63 +IRQF_ONESHOT
  64 |
  65 -flags
  66 +flags | IRQF_ONESHOT
  67 )
  68 , ...)
  69 |
  70 devm_request_threaded_irq@p(dev, irq, NULL, thread_fn,
  71 (
  72 -0
  73 +IRQF_ONESHOT
  74 |
  75 -flags
  76 +flags | IRQF_ONESHOT
  77 )
  78 , ...)
  79 )
  80
  81 @depends on context@
  82 expression dev, irq;
  83 position p != {r1.p,r2.p};
  84 @@
  85 (
  86 *request_threaded_irq@p(irq, NULL, ...)
  87 |
  88 *devm_request_threaded_irq@p(dev, irq, NULL, ...)
  89 )
  90
  91
  92 @match depends on report || org@
  93 expression dev, irq;
  94 position p != {r1.p,r2.p};
  95 @@
  96 (
  97 request_threaded_irq@p(irq, NULL, ...)
  98 |
  99 devm_request_threaded_irq@p(dev, irq, NULL, ...)
 100 )
 101
 102 @script:python depends on org@
 103 p << match.p;
 104 @@
 105 msg = "ERROR: Threaded IRQ with no primary handler requested without IRQF_ONESHOT"
 106 coccilib.org.print_todo(p[0],msg)
 107
 108 @script:python depends on report@
 109 p << match.p;
 110 @@
 111 msg = "ERROR: Threaded IRQ with no primary handler requested without IRQF_ONESHOT"
 112 coccilib.report.print_report(p[0],msg)