arch/cris/kernel/vmlinux.lds.S

   1 /* ld script to make the Linux/CRIS kernel
   2  * Authors: Bjorn Wesen (bjornw@axis.com)
   3  *
   4  * It is VERY DANGEROUS to fiddle around with the symbols in this
   5  * script. It is for example quite vital that all generated sections
   6  * that are used are actually named here, otherwise the linker will
   7  * put them at the end, where the init stuff is which is FREED after
   8  * the kernel has booted.
   9  */
  10
  11 #include <asm-generic/vmlinux.lds.h>
  12 #include <asm/page.h>
  13
  14 #ifdef CONFIG_ETRAX_VMEM_SIZE
  15 #define __CONFIG_ETRAX_VMEM_SIZE CONFIG_ETRAX_VMEM_SIZE
  16 #else
  17 #define __CONFIG_ETRAX_VMEM_SIZE 0
  18 #endif
  19
  20
  21 jiffies = jiffies_64;
  22 SECTIONS
  23 {
  24         . = DRAM_VIRTUAL_BASE;
  25         dram_start = .;
  26 #ifdef CONFIG_ETRAX_ARCH_V10
  27         ibr_start = .;
  28 #else
  29         ebp_start = .;
  30         /* The boot section is only necessary until the VCS top */
  31         /* level testbench includes both flash and DRAM. */
  32         .boot : { *(.boot) }
  33 #endif
  34
  35         /* see head.S and pages reserved at the start */
  36         . = DRAM_VIRTUAL_BASE + 0x4000;
  37
  38         _text = .;                      /* Text and read-only data. */
  39         text_start = .;                 /* Lots of aliases. */
  40         _stext = .;
  41         __stext = .;
  42         .text : {
  43                 HEAD_TEXT
  44                 TEXT_TEXT
  45                 SCHED_TEXT
  46                 CPUIDLE_TEXT
  47                 LOCK_TEXT
  48                 *(.fixup)
  49                 *(.text.__*)
  50         }
  51
  52         _etext = . ;                    /* End of text section. */
  53         __etext = .;
  54
  55         EXCEPTION_TABLE(4)
  56
  57         _sdata = .;
  58         RODATA
  59
  60         . = ALIGN (4);
  61         ___data_start = . ;
  62         __Sdata = . ;
  63         .data : {                       /* Data */
  64                 CACHELINE_ALIGNED_DATA(32)
  65                 READ_MOSTLY_DATA(32)
  66                 DATA_DATA
  67         }
  68         __edata = . ;                   /* End of data section. */
  69         _edata = . ;
  70
  71         INIT_TASK_DATA_SECTION(PAGE_SIZE)
  72
  73         . = ALIGN(PAGE_SIZE);           /* Init code and data. */
  74         __init_begin = .;
  75         INIT_TEXT_SECTION(PAGE_SIZE)
  76         .init.data : { INIT_DATA }
  77         .init.setup : { INIT_SETUP(16) }
  78         .initcall.init : {
  79                 INIT_CALLS
  80         }
  81
  82         .con_initcall.init : {
  83                 CON_INITCALL
  84         }
  85         SECURITY_INIT
  86
  87         /* .exit.text is discarded at runtime, not link time,
  88          * to deal with references from __bug_table
  89          */
  90         .exit.text : {
  91                 EXIT_TEXT
  92         }
  93         .exit.data : {
  94                 EXIT_DATA
  95         }
  96
  97 #ifdef CONFIG_ETRAX_ARCH_V10
  98 #ifdef CONFIG_BLK_DEV_INITRD
  99         .init.ramfs : {
 100                 __initramfs_start = .;
 101                 *(.init.ramfs)
 102                 __initramfs_end = .;
 103         }
 104 #endif
 105 #endif
 106         __vmlinux_end = .;              /* Last address of the physical file. */
 107 #ifdef CONFIG_ETRAX_ARCH_V32
 108         PERCPU_SECTION(32)
 109
 110         .init.ramfs : {
 111                 INIT_RAM_FS
 112         }
 113 #endif
 114
 115         /*
 116          * We fill to the next page, so we can discard all init
 117          * pages without needing to consider what payload might be
 118          * appended to the kernel image.
 119          */
 120         . = ALIGN(PAGE_SIZE);
 121
 122         __init_end = .;
 123
 124         __data_end = . ;                /* Move to _edata ? */
 125         BSS_SECTION(1, 1, 1)
 126
 127         . =  ALIGN (0x20);
 128         _end = .;
 129         __end = .;
 130
 131         dram_end = dram_start + (CONFIG_ETRAX_DRAM_SIZE - __CONFIG_ETRAX_VMEM_SIZE)*1024*1024;
 132
 133         DISCARDS
 134 }