scripts/coccinelle/misc/irqf_oneshot.cocci

   1 // SPDX-License-Identifier: GPL-2.0
   2 /// Since commit 1c6c69525b40 ("genirq: Reject bogus threaded irq requests")
   3 /// threaded IRQs without a primary handler need to be requested with
   4 /// IRQF_ONESHOT, otherwise the request will fail.
   5 ///
   6 /// So pass the IRQF_ONESHOT flag in this case.
   7 ///
   8 //
   9 // Confidence: Moderate
  10 // Comments:
  11 // Options: --no-includes
  12
  13 virtual patch
  14 virtual context
  15 virtual org
  16 virtual report
  17
  18 @r1@
  19 expression dev, irq, thread_fn;
  20 position p;
  21 @@
  22 (
  23 request_threaded_irq@p(irq, NULL, thread_fn,
  24 (
  25 IRQF_ONESHOT | ...
  26 |
  27 IRQF_ONESHOT
  28 )
  29 , ...)
  30 |
  31 devm_request_threaded_irq@p(dev, irq, NULL, thread_fn,
  32 (
  33 IRQF_ONESHOT | ...
  34 |
  35 IRQF_ONESHOT
  36 )
  37 , ...)
  38 )
  39
  40 @r2@
  41 expression dev, irq, thread_fn, flags, e;
  42 position p != r1.p;
  43 @@
  44 (
  45 flags = IRQF_ONESHOT | ...
  46 |
  47 flags |= IRQF_ONESHOT | ...
  48 )
  49 ... when != flags = e
  50 (
  51 request_threaded_irq@p(irq, NULL, thread_fn, flags, ...);
  52 |
  53 devm_request_threaded_irq@p(dev, irq, NULL, thread_fn, flags, ...);
  54 )
  55
  56 @depends on patch@
  57 expression dev, irq, thread_fn, flags;
  58 position p != {r1.p,r2.p};
  59 @@
  60 (
  61 request_threaded_irq@p(irq, NULL, thread_fn,
  62 (
  63 -0
  64 +IRQF_ONESHOT
  65 |
  66 -flags
  67 +flags | IRQF_ONESHOT
  68 )
  69 , ...)
  70 |
  71 devm_request_threaded_irq@p(dev, irq, NULL, thread_fn,
  72 (
  73 -0
  74 +IRQF_ONESHOT
  75 |
  76 -flags
  77 +flags | IRQF_ONESHOT
  78 )
  79 , ...)
  80 )
  81
  82 @depends on context@
  83 expression dev, irq;
  84 position p != {r1.p,r2.p};
  85 @@
  86 (
  87 *request_threaded_irq@p(irq, NULL, ...)
  88 |
  89 *devm_request_threaded_irq@p(dev, irq, NULL, ...)
  90 )
  91
  92
  93 @match depends on report || org@
  94 expression dev, irq;
  95 position p != {r1.p,r2.p};
  96 @@
  97 (
  98 request_threaded_irq@p(irq, NULL, ...)
  99 |
 100 devm_request_threaded_irq@p(dev, irq, NULL, ...)
 101 )
 102
 103 @script:python depends on org@
 104 p << match.p;
 105 @@
 106 msg = "ERROR: Threaded IRQ with no primary handler requested without IRQF_ONESHOT"
 107 coccilib.org.print_todo(p[0],msg)
 108
 109 @script:python depends on report@
 110 p << match.p;
 111 @@
 112 msg = "ERROR: Threaded IRQ with no primary handler requested without IRQF_ONESHOT"
 113 coccilib.report.print_report(p[0],msg)