liteman.pro

   1 #
   2 # The top-level QMAKE project file for LiteMan
   3 #
   4
   5 #
   6 # Settings
   7 #
   8 VERSION = 0.2
   9 TEMPLATE = app
  10 CONFIG += qt thread release
  11 QT += sql
  12
  13 DEPENDPATH += src
  14
  15 MOC_DIR = build
  16 OBJECTS_DIR = build
  17
  18 #
  19 # Output Files
  20 #
  21 TARGET = liteman
  22
  23 #
  24 # Input Files
  25 #
  26 HEADERS += database.h dataviewer.h \
  27            litemanwindow.h tableeditordialog.h \
  28            tabletree.h queryeditordialog.h termeditor.h
  29 SOURCES += database.cpp dataviewer.cpp \
  30            litemanwindow.cpp main.cpp \
  31            tableeditordialog.cpp tabletree.cpp \
  32            queryeditordialog.cpp
  33
  34 #
  35 # Distrobution Files
  36 #
  37 PREFIX = /usr/local
  38 DISTFILES = Doxyfile README INSTALL COPYING NEWS AUTHORS
  39
  40 binary.path = $${PREFIX}/bin/
  41 binary.files = $$TARGET
  42
  43 docs.path = $${PREFIX}/share/doc/liteman
  44 docs.files = README COPYING NEWS AUTHORS
  45
  46 INSTALLS += binary docs
  47
  48 #
  49 # My dist target
  50 #
  51 unix {
  52         TEMPPLACE = build/liteman-$${VERSION}
  53
  54         mdist.target = mdist
  55         mdist.commands = mkdir $${TEMPPLACE}/ && mkdir $${TEMPPLACE}/{doc,src} && \
  56                         cp -f  $${DISTFILES} liteman.pro $${TEMPPLACE}/ && \
  57                         cp -f  src/* $${TEMPPLACE}/src/ && cd $${TEMPPLACE}/../ &&\
  58                         tar -czf ../liteman-$${VERSION}.tar.gz liteman-$${VERSION}/ && \
  59                         cd .. && rm -rf $${TEMPPLACE}/
  60
  61         QMAKE_EXTRA_TARGETS += mdist
  62 }