cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 # This is commonly needed so make sure it's defined before we include anything
   6 # else.
   7 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
   8
   9 include(CheckCompilerVersion)
  10 include(HandleLLVMStdlib)
  11 include(CheckCCompilerFlag)
  12 include(CheckCXXCompilerFlag)
  13 include(CheckSymbolExists)
  14
  15 if(CMAKE_LINKER MATCHES "lld-link" OR (WIN32 AND LLVM_USE_LINKER STREQUAL "lld") OR LLVM_ENABLE_LLD)
  16   set(LINKER_IS_LLD_LINK TRUE)
  17 else()
  18   set(LINKER_IS_LLD_LINK FALSE)
  19 endif()
  20
  21 set(LLVM_CXX_STD_default "c++14")
  22 # Preserve behaviour of legacy cache variables
  23 if (LLVM_ENABLE_CXX1Z)
  24   set(LLVM_CXX_STD_default "c++1z")
  25 endif()
  26 if (LLVM_CXX_STD STREQUAL "c++11")
  27   set(LLVM_CXX_STD_force FORCE)
  28 endif()
  29 set(LLVM_CXX_STD ${LLVM_CXX_STD_default}
  30     CACHE STRING "C++ standard to use for compilation." ${LLVM_CXX_STD_force})
  31
  32 set(LLVM_ENABLE_LTO OFF CACHE STRING "Build LLVM with LTO. May be specified as Thin or Full to use a particular kind of LTO")
  33 string(TOUPPER "${LLVM_ENABLE_LTO}" uppercase_LLVM_ENABLE_LTO)
  34
  35 # Ninja Job Pool support
  36 # The following only works with the Ninja generator in CMake >= 3.0.
  37 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  38   "Define the maximum number of concurrent compilation jobs (Ninja only).")
  39 if(LLVM_PARALLEL_COMPILE_JOBS)
  40   if(NOT CMAKE_MAKE_PROGRAM MATCHES "ninja")
  41     message(WARNING "Job pooling is only available with Ninja generators.")
  42   else()
  43     set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  44     set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  45   endif()
  46 endif()
  47
  48 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  49   "Define the maximum number of concurrent link jobs (Ninja only).")
  50 if(CMAKE_MAKE_PROGRAM MATCHES "ninja")
  51   if(NOT LLVM_PARALLEL_LINK_JOBS AND uppercase_LLVM_ENABLE_LTO STREQUAL "THIN")
  52     message(STATUS "ThinLTO provides its own parallel linking - limiting parallel link jobs to 2.")
  53     set(LLVM_PARALLEL_LINK_JOBS "2")
  54   endif()
  55   if(LLVM_PARALLEL_LINK_JOBS)
  56     set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  57     set(CMAKE_JOB_POOL_LINK link_job_pool)
  58   endif()
  59 elseif(LLVM_PARALLEL_LINK_JOBS)
  60   message(WARNING "Job pooling is only available with Ninja generators.")
  61 endif()
  62
  63 if( LLVM_ENABLE_ASSERTIONS )
  64   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  65   if( NOT MSVC )
  66     add_definitions( -D_DEBUG )
  67   endif()
  68   # On non-Debug builds cmake automatically defines NDEBUG, so we
  69   # explicitly undefine it:
  70   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  71     add_definitions( -UNDEBUG )
  72     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  73     foreach (flags_var_to_scrub
  74         CMAKE_CXX_FLAGS_RELEASE
  75         CMAKE_CXX_FLAGS_RELWITHDEBINFO
  76         CMAKE_CXX_FLAGS_MINSIZEREL
  77         CMAKE_C_FLAGS_RELEASE
  78         CMAKE_C_FLAGS_RELWITHDEBINFO
  79         CMAKE_C_FLAGS_MINSIZEREL)
  80       string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
  81         "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
  82     endforeach()
  83   endif()
  84 endif()
  85
  86 if(LLVM_ENABLE_EXPENSIVE_CHECKS)
  87   add_definitions(-DEXPENSIVE_CHECKS)
  88   add_definitions(-D_GLIBCXX_DEBUG)
  89 endif()
  90
  91 string(TOUPPER "${LLVM_ABI_BREAKING_CHECKS}" uppercase_LLVM_ABI_BREAKING_CHECKS)
  92
  93 if( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "WITH_ASSERTS" )
  94   if( LLVM_ENABLE_ASSERTIONS )
  95     set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  96   endif()
  97 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_ON" )
  98   set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  99 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_OFF" )
 100   # We don't need to do anything special to turn off ABI breaking checks.
 101 elseif( NOT DEFINED LLVM_ABI_BREAKING_CHECKS )
 102   # Treat LLVM_ABI_BREAKING_CHECKS like "FORCE_OFF" when it has not been
 103   # defined.
 104 else()
 105   message(FATAL_ERROR "Unknown value for LLVM_ABI_BREAKING_CHECKS: \"${LLVM_ABI_BREAKING_CHECKS}\"!")
 106 endif()
 107
 108 if( LLVM_REVERSE_ITERATION )
 109   set( LLVM_ENABLE_REVERSE_ITERATION 1 )
 110 endif()
 111
 112 if(WIN32)
 113   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
 114   if(CYGWIN)
 115     set(LLVM_ON_WIN32 0)
 116     set(LLVM_ON_UNIX 1)
 117   else(CYGWIN)
 118     set(LLVM_ON_WIN32 1)
 119     set(LLVM_ON_UNIX 0)
 120   endif(CYGWIN)
 121 else(WIN32)
 122   if(FUCHSIA OR UNIX)
 123     set(LLVM_ON_WIN32 0)
 124     set(LLVM_ON_UNIX 1)
 125     if(APPLE OR ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 126       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
 127     else()
 128       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
 129     endif()
 130   else(FUCHSIA OR UNIX)
 131     MESSAGE(SEND_ERROR "Unable to determine platform")
 132   endif(FUCHSIA OR UNIX)
 133 endif(WIN32)
 134
 135 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
 136 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 137
 138 # We use *.dylib rather than *.so on darwin.
 139 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 140
 141 if(APPLE)
 142   if(LLVM_ENABLE_LLD AND LLVM_ENABLE_LTO)
 143     message(FATAL_ERROR "lld does not support LTO on Darwin")
 144   endif()
 145   # Darwin-specific linker flags for loadable modules.
 146   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 147 endif()
 148
 149 if(${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 150   if(NOT LLVM_BUILD_32_BITS)
 151     if (CMAKE_CXX_COMPILER_ID MATCHES "XL")
 152       append("-q64" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 153     else()
 154       append("-maix64" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 155     endif()
 156     set(CMAKE_CXX_ARCHIVE_CREATE "<CMAKE_AR> -X64 qc <TARGET> <LINK_FLAGS> <OBJECTS>")
 157     set(CMAKE_CXX_ARCHIVE_APPEND "<CMAKE_AR> -X64 q  <TARGET> <LINK_FLAGS> <OBJECTS>")
 158     set(CMAKE_C_ARCHIVE_FINISH "<CMAKE_RANLIB> -X64 <TARGET>")
 159     set(CMAKE_CXX_ARCHIVE_FINISH "<CMAKE_RANLIB> -X64 <TARGET>")
 160   endif()
 161   # -fPIC does not enable the large code model for GCC on AIX but does for XL.
 162   if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 163     append("-mcmodel=large" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 164   elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 165     # XL generates a small number of relocations not of the large model, -bbigtoc is needed.
 166     append("-Wl,-bbigtoc"
 167            CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 168   endif()
 169 endif()
 170
 171 # Pass -Wl,-z,defs. This makes sure all symbols are defined. Otherwise a DSO
 172 # build might work on ELF but fail on MachO/COFF.
 173 if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin|FreeBSD|OpenBSD|DragonFly|AIX|SunOS" OR
 174         WIN32 OR CYGWIN) AND
 175    NOT LLVM_USE_SANITIZER)
 176   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,defs")
 177 endif()
 178
 179 # Pass -Wl,-z,nodelete. This makes sure our shared libraries are not unloaded
 180 # by dlclose(). We need that since the CLI API relies on cross-references
 181 # between global objects which became horribly broken when one of the libraries
 182 # is unloaded.
 183 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 184   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,nodelete")
 185   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-z,nodelete")
 186 endif()
 187
 188
 189 function(append value)
 190   foreach(variable ${ARGN})
 191     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 192   endforeach(variable)
 193 endfunction()
 194
 195 function(append_if condition value)
 196   if (${condition})
 197     foreach(variable ${ARGN})
 198       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 199     endforeach(variable)
 200   endif()
 201 endfunction()
 202
 203 macro(add_flag_if_supported flag name)
 204   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 205   append_if("C_SUPPORTS_${name}" "${flag}" CMAKE_C_FLAGS)
 206   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 207   append_if("CXX_SUPPORTS_${name}" "${flag}" CMAKE_CXX_FLAGS)
 208 endmacro()
 209
 210 function(add_flag_or_print_warning flag name)
 211   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 212   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 213   if (C_SUPPORTS_${name} AND CXX_SUPPORTS_${name})
 214     message(STATUS "Building with ${flag}")
 215     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
 216     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
 217     set(CMAKE_ASM_FLAGS "${CMAKE_ASM_FLAGS} ${flag}" PARENT_SCOPE)
 218   else()
 219     message(WARNING "${flag} is not supported.")
 220   endif()
 221 endfunction()
 222
 223 if( LLVM_ENABLE_LLD )
 224   if ( LLVM_USE_LINKER )
 225     message(FATAL_ERROR "LLVM_ENABLE_LLD and LLVM_USE_LINKER can't be set at the same time")
 226   endif()
 227   set(LLVM_USE_LINKER "lld")
 228 endif()
 229
 230 if( LLVM_USE_LINKER )
 231   set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 232   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fuse-ld=${LLVM_USE_LINKER}")
 233   check_cxx_source_compiles("int main() { return 0; }" CXX_SUPPORTS_CUSTOM_LINKER)
 234   if ( NOT CXX_SUPPORTS_CUSTOM_LINKER )
 235     message(FATAL_ERROR "Host compiler does not support '-fuse-ld=${LLVM_USE_LINKER}'")
 236   endif()
 237   set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 238   append("-fuse-ld=${LLVM_USE_LINKER}"
 239     CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 240 endif()
 241
 242 if( LLVM_ENABLE_PIC )
 243   if( XCODE )
 244     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
 245     # know how to disable this, so just force ENABLE_PIC off for now.
 246     message(WARNING "-fPIC not supported with Xcode.")
 247   elseif( WIN32 OR CYGWIN)
 248     # On Windows all code is PIC. MinGW warns if -fPIC is used.
 249   else()
 250     add_flag_or_print_warning("-fPIC" FPIC)
 251   endif()
 252   # GCC for MIPS can miscompile LLVM due to PR37701.
 253   if(CMAKE_COMPILER_IS_GNUCXX AND LLVM_NATIVE_ARCH STREQUAL "Mips" AND
 254          NOT Uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 255     add_flag_or_print_warning("-fno-shrink-wrap" FNO_SHRINK_WRAP)
 256   endif()
 257 endif()
 258
 259 if(NOT WIN32 AND NOT CYGWIN AND NOT (${CMAKE_SYSTEM_NAME} MATCHES "AIX" AND CMAKE_CXX_COMPILER_ID STREQUAL "GNU"))
 260   # MinGW warns if -fvisibility-inlines-hidden is used.
 261   # GCC on AIX warns if -fvisibility-inlines-hidden is used.
 262   check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 263   append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 264 endif()
 265
 266 if(CMAKE_SIZEOF_VOID_P EQUAL 8 AND MINGW)
 267   add_definitions( -D_FILE_OFFSET_BITS=64 )
 268 endif()
 269
 270 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 271   # TODO: support other platforms and toolchains.
 272   if( LLVM_BUILD_32_BITS )
 273     message(STATUS "Building 32 bits executables and libraries.")
 274     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m32")
 275     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -m32")
 276     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 277     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 278     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 279
 280     # FIXME: CMAKE_SIZEOF_VOID_P is still 8
 281     add_definitions(-D_LARGEFILE_SOURCE)
 282     add_definitions(-D_FILE_OFFSET_BITS=64)
 283   endif( LLVM_BUILD_32_BITS )
 284 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 285
 286 # If building on a GNU specific 32-bit system, make sure off_t is 64 bits
 287 # so that off_t can stored offset > 2GB.
 288 # Android until version N (API 24) doesn't support it.
 289 if (ANDROID AND (ANDROID_NATIVE_API_LEVEL LESS 24))
 290   set(LLVM_FORCE_SMALLFILE_FOR_ANDROID TRUE)
 291 endif()
 292 if( CMAKE_SIZEOF_VOID_P EQUAL 4 AND NOT LLVM_FORCE_SMALLFILE_FOR_ANDROID)
 293   # FIXME: It isn't handled in LLVM_BUILD_32_BITS.
 294   add_definitions( -D_LARGEFILE_SOURCE )
 295   add_definitions( -D_FILE_OFFSET_BITS=64 )
 296 endif()
 297
 298 if( XCODE )
 299   # For Xcode enable several build settings that correspond to
 300   # many warnings that are on by default in Clang but are
 301   # not enabled for historical reasons.  For versions of Xcode
 302   # that do not support these options they will simply
 303   # be ignored.
 304   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_RETURN_TYPE "YES")
 305   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_MISSING_NEWLINE "YES")
 306   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VALUE "YES")
 307   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VARIABLE "YES")
 308   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_SIGN_COMPARE "YES")
 309   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_FUNCTION "YES")
 310   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_INITIALIZER_NOT_FULLY_BRACKETED "YES")
 311   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_HIDDEN_VIRTUAL_FUNCTIONS "YES")
 312   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNINITIALIZED_AUTOS "YES")
 313   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_BOOL_CONVERSION "YES")
 314   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_EMPTY_BODY "YES")
 315   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_ENUM_CONVERSION "YES")
 316   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_INT_CONVERSION "YES")
 317   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_CONSTANT_CONVERSION "YES")
 318   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_NON_VIRTUAL_DESTRUCTOR "YES")
 319 endif()
 320
 321 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 322 # to use.
 323 if( MSVC_IDE )
 324   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 325     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 326   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 327     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 328       add_definitions( /MP )
 329     else()
 330       message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 331       add_definitions( /MP${LLVM_COMPILER_JOBS} )
 332     endif()
 333   else()
 334     message(STATUS "Parallel compilation disabled")
 335   endif()
 336 endif()
 337
 338 # set stack reserved size to ~10MB
 339 if(MSVC)
 340   # CMake previously automatically set this value for MSVC builds, but the
 341   # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
 342   # value (1 MB) which is not enough for us in tasks such as parsing recursive
 343   # C++ templates in Clang.
 344   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
 345 elseif(MINGW) # FIXME: Also cygwin?
 346   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--stack,16777216")
 347
 348   # Pass -mbig-obj to mingw gas on Win64. COFF has a 2**16 section limit, and
 349   # on Win64, every COMDAT function creates at least 3 sections: .text, .pdata,
 350   # and .xdata.
 351   if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 352     append("-Wa,-mbig-obj" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 353   endif()
 354 endif()
 355
 356 if( MSVC )
 357   include(ChooseMSVCCRT)
 358
 359   # Add definitions that make MSVC much less annoying.
 360   add_definitions(
 361     # For some reason MS wants to deprecate a bunch of standard functions...
 362     -D_CRT_SECURE_NO_DEPRECATE
 363     -D_CRT_SECURE_NO_WARNINGS
 364     -D_CRT_NONSTDC_NO_DEPRECATE
 365     -D_CRT_NONSTDC_NO_WARNINGS
 366     -D_SCL_SECURE_NO_DEPRECATE
 367     -D_SCL_SECURE_NO_WARNINGS
 368     )
 369
 370   # Tell MSVC to use the Unicode version of the Win32 APIs instead of ANSI.
 371   add_definitions(
 372     -DUNICODE
 373     -D_UNICODE
 374   )
 375
 376   if (LLVM_ENABLE_WERROR)
 377     append("/WX" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 378   endif (LLVM_ENABLE_WERROR)
 379
 380   append("/Zc:inline" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 381
 382   # Allow users to request PDBs in release mode. CMake offeres the
 383   # RelWithDebInfo configuration, but it uses different optimization settings
 384   # (/Ob1 vs /Ob2 or -O2 vs -O3). LLVM provides this flag so that users can get
 385   # PDBs without changing codegen.
 386   option(LLVM_ENABLE_PDB OFF)
 387   if (LLVM_ENABLE_PDB AND uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE")
 388     append("/Zi" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 389     # /DEBUG disables linker GC and ICF, but we want those in Release mode.
 390     append("/DEBUG /OPT:REF /OPT:ICF"
 391           CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS
 392           CMAKE_SHARED_LINKER_FLAGS)
 393   endif()
 394
 395   # Disable string literal const->non-const type conversion.
 396   # "When specified, the compiler requires strict const-qualification
 397   # conformance for pointers initialized by using string literals."
 398   append("/Zc:strictStrings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 399
 400   # "Generate Intrinsic Functions".
 401   append("/Oi" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 402
 403   # "Enforce type conversion rules".
 404   append("/Zc:rvalueCast" CMAKE_CXX_FLAGS)
 405
 406   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND NOT LLVM_ENABLE_LTO)
 407     # clang-cl and cl by default produce non-deterministic binaries because
 408     # link.exe /incremental requires a timestamp in the .obj file.  clang-cl
 409     # has the flag /Brepro to force deterministic binaries. We want to pass that
 410     # whenever you're building with clang unless you're passing /incremental
 411     # or using LTO (/Brepro with LTO would result in a warning about the flag
 412     # being unused, because we're not generating object files).
 413     # This checks CMAKE_CXX_COMPILER_ID in addition to check_cxx_compiler_flag()
 414     # because cl.exe does not emit an error on flags it doesn't understand,
 415     # letting check_cxx_compiler_flag() claim it understands all flags.
 416     check_cxx_compiler_flag("/Brepro" SUPPORTS_BREPRO)
 417     if (SUPPORTS_BREPRO)
 418       # Check if /INCREMENTAL is passed to the linker and complain that it
 419       # won't work with /Brepro.
 420       string(TOUPPER "${CMAKE_EXE_LINKER_FLAGS}" upper_exe_flags)
 421       string(TOUPPER "${CMAKE_MODULE_LINKER_FLAGS}" upper_module_flags)
 422       string(TOUPPER "${CMAKE_SHARED_LINKER_FLAGS}" upper_shared_flags)
 423
 424       string(FIND "${upper_exe_flags} ${upper_module_flags} ${upper_shared_flags}"
 425         "/INCREMENTAL" linker_flag_idx)
 426
 427       if (${linker_flag_idx} GREATER -1)
 428         message(WARNING "/Brepro not compatible with /INCREMENTAL linking - builds will be non-deterministic")
 429       else()
 430         append("/Brepro" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 431       endif()
 432     endif()
 433   endif()
 434 endif( MSVC )
 435
 436 # Warnings-as-errors handling for GCC-compatible compilers:
 437 if ( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 438   append_if(LLVM_ENABLE_WERROR "-Werror" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 439   append_if(LLVM_ENABLE_WERROR "-Wno-error" CMAKE_REQUIRED_FLAGS)
 440 endif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 441
 442 # Specific default warnings-as-errors for compilers accepting GCC-compatible warning flags:
 443 if ( LLVM_COMPILER_IS_GCC_COMPATIBLE OR CMAKE_CXX_COMPILER_ID MATCHES "XL" )
 444   add_flag_if_supported("-Werror=date-time" WERROR_DATE_TIME)
 445   add_flag_if_supported("-Werror=unguarded-availability-new" WERROR_UNGUARDED_AVAILABILITY_NEW)
 446 endif( LLVM_COMPILER_IS_GCC_COMPATIBLE OR CMAKE_CXX_COMPILER_ID MATCHES "XL" )
 447
 448 # C++ language standard selection for compilers accepting the GCC-style option:
 449 if ( LLVM_COMPILER_IS_GCC_COMPATIBLE OR CMAKE_CXX_COMPILER_ID MATCHES "XL" )
 450   check_cxx_compiler_flag("-std=${LLVM_CXX_STD}" CXX_SUPPORTS_CXX_STD)
 451   if (CXX_SUPPORTS_CXX_STD)
 452    if (CYGWIN OR MINGW)
 453       # MinGW and Cygwin are a bit stricter and lack things like
 454       # 'strdup', 'stricmp', etc in c++11 mode.
 455       string(REPLACE "c++" "gnu++" gnu_LLVM_CXX_STD "${LLVM_CXX_STD}")
 456       append("-std=${gnu_LLVM_CXX_STD}" CMAKE_CXX_FLAGS)
 457     else()
 458       append("-std=${LLVM_CXX_STD}" CMAKE_CXX_FLAGS)
 459     endif()
 460   else()
 461     message(FATAL_ERROR "The host compiler does not support '-std=${LLVM_CXX_STD}'.")
 462   endif()
 463 endif( LLVM_COMPILER_IS_GCC_COMPATIBLE OR CMAKE_CXX_COMPILER_ID MATCHES "XL" )
 464
 465 # Modules enablement for GCC-compatible compilers:
 466 if ( LLVM_COMPILER_IS_GCC_COMPATIBLE AND LLVM_ENABLE_MODULES )
 467   set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 468   set(module_flags "-fmodules -fmodules-cache-path=${PROJECT_BINARY_DIR}/module.cache")
 469   if (${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 470     # On Darwin -fmodules does not imply -fcxx-modules.
 471     set(module_flags "${module_flags} -fcxx-modules")
 472   endif()
 473   if (LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY)
 474     set(module_flags "${module_flags} -Xclang -fmodules-local-submodule-visibility")
 475   endif()
 476   if (LLVM_ENABLE_MODULE_DEBUGGING AND
 477       ((uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG") OR
 478        (uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")))
 479     set(module_flags "${module_flags} -gmodules")
 480   endif()
 481   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${module_flags}")
 482
 483   # Check that we can build code with modules enabled, and that repeatedly
 484   # including <cassert> still manages to respect NDEBUG properly.
 485   CHECK_CXX_SOURCE_COMPILES("#undef NDEBUG
 486                              #include <cassert>
 487                              #define NDEBUG
 488                              #include <cassert>
 489                              int main() { assert(this code is not compiled); }"
 490                              CXX_SUPPORTS_MODULES)
 491   set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 492   if (CXX_SUPPORTS_MODULES)
 493     append("${module_flags}" CMAKE_CXX_FLAGS)
 494   else()
 495     message(FATAL_ERROR "LLVM_ENABLE_MODULES is not supported by this compiler")
 496   endif()
 497 endif( LLVM_COMPILER_IS_GCC_COMPATIBLE AND LLVM_ENABLE_MODULES )
 498
 499 if (MSVC)
 500   if (NOT CLANG_CL)
 501     set(msvc_warning_flags
 502       # Disabled warnings.
 503       -wd4141 # Suppress ''modifier' : used more than once' (because of __forceinline combined with inline)
 504       -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 505       -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 506       -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 507       -wd4258 # Suppress ''var' : definition from the for loop is ignored; the definition from the enclosing scope is used'
 508       -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 509       -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 510       -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 511       -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 512       -wd4456 # Suppress 'declaration of 'var' hides local variable'
 513       -wd4457 # Suppress 'declaration of 'var' hides function parameter'
 514       -wd4458 # Suppress 'declaration of 'var' hides class member'
 515       -wd4459 # Suppress 'declaration of 'var' hides global declaration'
 516       -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 517       -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 518       -wd4722 # Suppress 'function' : destructor never returns, potential memory leak
 519       -wd4100 # Suppress 'unreferenced formal parameter'
 520       -wd4127 # Suppress 'conditional expression is constant'
 521       -wd4512 # Suppress 'assignment operator could not be generated'
 522       -wd4505 # Suppress 'unreferenced local function has been removed'
 523       -wd4610 # Suppress '<class> can never be instantiated'
 524       -wd4510 # Suppress 'default constructor could not be generated'
 525       -wd4702 # Suppress 'unreachable code'
 526       -wd4245 # Suppress 'signed/unsigned mismatch'
 527       -wd4706 # Suppress 'assignment within conditional expression'
 528       -wd4310 # Suppress 'cast truncates constant value'
 529       -wd4701 # Suppress 'potentially uninitialized local variable'
 530       -wd4703 # Suppress 'potentially uninitialized local pointer variable'
 531       -wd4389 # Suppress 'signed/unsigned mismatch'
 532       -wd4611 # Suppress 'interaction between '_setjmp' and C++ object destruction is non-portable'
 533       -wd4805 # Suppress 'unsafe mix of type <type> and type <type> in operation'
 534       -wd4204 # Suppress 'nonstandard extension used : non-constant aggregate initializer'
 535       -wd4577 # Suppress 'noexcept used with no exception handling mode specified; termination on exception is not guaranteed'
 536       -wd4091 # Suppress 'typedef: ignored on left of '' when no variable is declared'
 537           # C4592 is disabled because of false positives in Visual Studio 2015
 538           # Update 1. Re-evaluate the usefulness of this diagnostic with Update 2.
 539       -wd4592 # Suppress ''var': symbol will be dynamically initialized (implementation limitation)
 540       -wd4319 # Suppress ''operator' : zero extending 'type' to 'type' of greater size'
 541           # C4709 is disabled because of a bug with Visual Studio 2017 as of
 542           # v15.8.8. Re-evaluate the usefulness of this diagnostic when the bug
 543           # is fixed.
 544       -wd4709 # Suppress comma operator within array index expression
 545
 546       # Ideally, we'd like this warning to be enabled, but MSVC 2013 doesn't
 547       # support the 'aligned' attribute in the way that clang sources requires (for
 548       # any code that uses the LLVM_ALIGNAS macro), so this is must be disabled to
 549       # avoid unwanted alignment warnings.
 550       # When we switch to requiring a version of MSVC that supports the 'alignas'
 551       # specifier (MSVC 2015?) this warning can be re-enabled.
 552       -wd4324 # Suppress 'structure was padded due to __declspec(align())'
 553
 554       # Promoted warnings.
 555       -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 556
 557       # Promoted warnings to errors.
 558       -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 559       )
 560   endif(NOT CLANG_CL)
 561
 562   # Enable warnings
 563   if (LLVM_ENABLE_WARNINGS)
 564     # Put /W4 in front of all the -we flags. cl.exe doesn't care, but for
 565     # clang-cl having /W4 after the -we flags will re-enable the warnings
 566     # disabled by -we.
 567     set(msvc_warning_flags "/W4 ${msvc_warning_flags}")
 568     # CMake appends /W3 by default, and having /W3 followed by /W4 will result in
 569     # cl : Command line warning D9025 : overriding '/W3' with '/W4'.  Since this is
 570     # a command line warning and not a compiler warning, it cannot be suppressed except
 571     # by fixing the command line.
 572     string(REGEX REPLACE " /W[0-4]" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 573     string(REGEX REPLACE " /W[0-4]" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 574
 575     if (LLVM_ENABLE_PEDANTIC)
 576       # No MSVC equivalent available
 577     endif (LLVM_ENABLE_PEDANTIC)
 578   endif (LLVM_ENABLE_WARNINGS)
 579
 580   foreach(flag ${msvc_warning_flags})
 581     append("${flag}" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 582   endforeach(flag)
 583 endif (MSVC)
 584
 585 if (LLVM_ENABLE_WARNINGS AND (LLVM_COMPILER_IS_GCC_COMPATIBLE OR CLANG_CL))
 586
 587   # Don't add -Wall for clang-cl, because it maps -Wall to -Weverything for
 588   # MSVC compatibility.  /W4 is added above instead.
 589   if (NOT CLANG_CL)
 590     append("-Wall" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 591   endif()
 592
 593   append("-Wextra -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 594   append("-Wcast-qual" CMAKE_CXX_FLAGS)
 595
 596   # Turn off missing field initializer warnings for gcc to avoid noise from
 597   # false positives with empty {}. Turn them on otherwise (they're off by
 598   # default for clang).
 599   check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 600   if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 601     if (CMAKE_COMPILER_IS_GNUCXX)
 602       append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 603     else()
 604       append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 605     endif()
 606   endif()
 607
 608   if (LLVM_ENABLE_PEDANTIC AND LLVM_COMPILER_IS_GCC_COMPATIBLE)
 609     append("-pedantic" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 610     append("-Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 611   endif()
 612
 613   add_flag_if_supported("-Wimplicit-fallthrough" IMPLICIT_FALLTHROUGH_FLAG)
 614   add_flag_if_supported("-Wcovered-switch-default" COVERED_SWITCH_DEFAULT_FLAG)
 615   append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 616   append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 617
 618   # Disable -Wclass-memaccess, a C++-only warning from GCC 8 that fires on
 619   # LLVM's ADT classes.
 620   check_cxx_compiler_flag("-Wclass-memaccess" CXX_SUPPORTS_CLASS_MEMACCESS_FLAG)
 621   append_if(CXX_SUPPORTS_CLASS_MEMACCESS_FLAG "-Wno-class-memaccess" CMAKE_CXX_FLAGS)
 622
 623   # The LLVM libraries have no stable C++ API, so -Wnoexcept-type is not useful.
 624   check_cxx_compiler_flag("-Wnoexcept-type" CXX_SUPPORTS_NOEXCEPT_TYPE_FLAG)
 625   append_if(CXX_SUPPORTS_NOEXCEPT_TYPE_FLAG "-Wno-noexcept-type" CMAKE_CXX_FLAGS)
 626
 627   # Check if -Wnon-virtual-dtor warns even though the class is marked final.
 628   # If it does, don't add it. So it won't be added on clang 3.4 and older.
 629   # This also catches cases when -Wnon-virtual-dtor isn't supported by
 630   # the compiler at all.  This flag is not activated for gcc since it will
 631   # incorrectly identify a protected non-virtual base when there is a friend
 632   # declaration. Don't activate this in general on Windows as this warning has
 633   # too many false positives on COM-style classes, which are destroyed with
 634   # Release() (PR32286).
 635   if (NOT CMAKE_COMPILER_IS_GNUCXX AND NOT WIN32)
 636     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 637     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++11 -Werror=non-virtual-dtor")
 638     CHECK_CXX_SOURCE_COMPILES("class base {public: virtual void anchor();protected: ~base();};
 639                                class derived final : public base { public: ~derived();};
 640                                int main() { return 0; }"
 641                               CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR)
 642     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 643     append_if(CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR
 644               "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 645   endif()
 646
 647   # Enable -Wdelete-non-virtual-dtor if available.
 648   add_flag_if_supported("-Wdelete-non-virtual-dtor" DELETE_NON_VIRTUAL_DTOR_FLAG)
 649
 650   # Check if -Wcomment is OK with an // comment ending with '\' if the next
 651   # line is also a // comment.
 652   set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 653   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror -Wcomment")
 654   CHECK_C_SOURCE_COMPILES("// \\\\\\n//\\nint main() {return 0;}"
 655                           C_WCOMMENT_ALLOWS_LINE_WRAP)
 656   set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 657   if (NOT C_WCOMMENT_ALLOWS_LINE_WRAP)
 658     append("-Wno-comment" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 659   endif()
 660
 661   # Enable -Wstring-conversion to catch misuse of string literals.
 662   add_flag_if_supported("-Wstring-conversion" STRING_CONVERSION_FLAG)
 663 endif (LLVM_ENABLE_WARNINGS AND (LLVM_COMPILER_IS_GCC_COMPATIBLE OR CLANG_CL))
 664
 665 if (LLVM_COMPILER_IS_GCC_COMPATIBLE AND NOT LLVM_ENABLE_WARNINGS)
 666   append("-w" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 667 endif()
 668
 669 macro(append_common_sanitizer_flags)
 670   if (NOT MSVC)
 671     # Append -fno-omit-frame-pointer and turn on debug info to get better
 672     # stack traces.
 673     add_flag_if_supported("-fno-omit-frame-pointer" FNO_OMIT_FRAME_POINTER)
 674     if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 675         NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 676       add_flag_if_supported("-gline-tables-only" GLINE_TABLES_ONLY)
 677     endif()
 678     # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
 679     if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND LLVM_OPTIMIZE_SANITIZED_BUILDS)
 680       add_flag_if_supported("-O1" O1)
 681     endif()
 682   elseif (CLANG_CL)
 683     # Keep frame pointers around.
 684     append("/Oy-" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 685     # Always ask the linker to produce symbols with asan.
 686     append("/Z7" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 687     append("-debug" CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 688   endif()
 689 endmacro()
 690
 691 # Turn on sanitizers if necessary.
 692 if(LLVM_USE_SANITIZER)
 693   if (LLVM_ON_UNIX)
 694     if (LLVM_USE_SANITIZER STREQUAL "Address")
 695       append_common_sanitizer_flags()
 696       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 697     elseif (LLVM_USE_SANITIZER STREQUAL "HWAddress")
 698       append_common_sanitizer_flags()
 699       append("-fsanitize=hwaddress" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 700     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 701       append_common_sanitizer_flags()
 702       append("-fsanitize=memory" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 703       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 704         append("-fsanitize-memory-track-origins" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 705       endif()
 706     elseif (LLVM_USE_SANITIZER STREQUAL "Undefined")
 707       append_common_sanitizer_flags()
 708       append("-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 709               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 710     elseif (LLVM_USE_SANITIZER STREQUAL "Thread")
 711       append_common_sanitizer_flags()
 712       append("-fsanitize=thread" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 713     elseif (LLVM_USE_SANITIZER STREQUAL "Address;Undefined" OR
 714             LLVM_USE_SANITIZER STREQUAL "Undefined;Address")
 715       append_common_sanitizer_flags()
 716       append("-fsanitize=address,undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 717               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 718     elseif (LLVM_USE_SANITIZER STREQUAL "Leaks")
 719       append_common_sanitizer_flags()
 720       append("-fsanitize=leak" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 721     else()
 722       message(FATAL_ERROR "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 723     endif()
 724   elseif(MSVC)
 725     if (LLVM_USE_SANITIZER STREQUAL "Address")
 726       append_common_sanitizer_flags()
 727       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 728     else()
 729       message(FATAL_ERROR "This sanitizer not yet supported in the MSVC environment: ${LLVM_USE_SANITIZER}")
 730     endif()
 731   else()
 732     message(FATAL_ERROR "LLVM_USE_SANITIZER is not supported on this platform.")
 733   endif()
 734   if (LLVM_USE_SANITIZER MATCHES "(Undefined;)?Address(;Undefined)?")
 735     add_flag_if_supported("-fsanitize-address-use-after-scope"
 736                           FSANITIZE_USE_AFTER_SCOPE_FLAG)
 737   endif()
 738   if (LLVM_USE_SANITIZE_COVERAGE)
 739     append("-fsanitize=fuzzer-no-link" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 740   endif()
 741   if (LLVM_USE_SANITIZER MATCHES ".*Undefined.*")
 742     set(BLACKLIST_FILE "${CMAKE_SOURCE_DIR}/utils/sanitizers/ubsan_blacklist.txt")
 743     if (EXISTS "${BLACKLIST_FILE}")
 744       append("-fsanitize-blacklist=${BLACKLIST_FILE}"
 745              CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 746     endif()
 747   endif()
 748 endif()
 749
 750 # Turn on -gsplit-dwarf if requested
 751 if(LLVM_USE_SPLIT_DWARF)
 752   add_definitions("-gsplit-dwarf")
 753 endif()
 754
 755 add_definitions( -D__STDC_CONSTANT_MACROS )
 756 add_definitions( -D__STDC_FORMAT_MACROS )
 757 add_definitions( -D__STDC_LIMIT_MACROS )
 758
 759 # clang and gcc don't default-print colored diagnostics when invoked from Ninja.
 760 if (UNIX AND
 761     CMAKE_GENERATOR STREQUAL "Ninja" AND
 762     (CMAKE_CXX_COMPILER_ID MATCHES "Clang" OR
 763      (CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND
 764       NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.9))))
 765   append("-fdiagnostics-color" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 766 endif()
 767
 768 # lld doesn't print colored diagnostics when invoked from Ninja
 769 if (UNIX AND CMAKE_GENERATOR STREQUAL "Ninja")
 770   include(CheckLinkerFlag)
 771   check_linker_flag("-Wl,--color-diagnostics" LINKER_SUPPORTS_COLOR_DIAGNOSTICS)
 772   append_if(LINKER_SUPPORTS_COLOR_DIAGNOSTICS "-Wl,--color-diagnostics"
 773     CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 774 endif()
 775
 776 # Add flags for add_dead_strip().
 777 # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
 778 # But MinSizeRel seems to add that automatically, so maybe disable these
 779 # flags instead if LLVM_NO_DEAD_STRIP is set.
 780 if(NOT CYGWIN AND NOT WIN32)
 781   if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin" AND
 782      NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 783     check_c_compiler_flag("-Werror -fno-function-sections" C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 784     if (C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 785       # Don't add -ffunction-section if it can be disabled with -fno-function-sections.
 786       # Doing so will break sanitizers.
 787       add_flag_if_supported("-ffunction-sections" FFUNCTION_SECTIONS)
 788     endif()
 789     add_flag_if_supported("-fdata-sections" FDATA_SECTIONS)
 790   endif()
 791 endif()
 792
 793 if(MSVC)
 794   # Remove flags here, for exceptions and RTTI.
 795   # Each target property or source property should be responsible to control
 796   # them.
 797   # CL.EXE complains to override flags like "/GR /GR-".
 798   string(REGEX REPLACE "(^| ) */EH[-cs]+ *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 799   string(REGEX REPLACE "(^| ) */GR-? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 800 endif()
 801
 802 # Provide public options to globally control RTTI and EH
 803 option(LLVM_ENABLE_EH "Enable Exception handling" OFF)
 804 option(LLVM_ENABLE_RTTI "Enable run time type information" OFF)
 805 if(LLVM_ENABLE_EH AND NOT LLVM_ENABLE_RTTI)
 806   message(FATAL_ERROR "Exception handling requires RTTI. You must set LLVM_ENABLE_RTTI to ON")
 807 endif()
 808
 809 option(LLVM_USE_NEWPM "Build LLVM using the experimental new pass manager" Off)
 810 mark_as_advanced(LLVM_USE_NEWPM)
 811 if (LLVM_USE_NEWPM)
 812   append("-fexperimental-new-pass-manager"
 813     CMAKE_CXX_FLAGS
 814     CMAKE_C_FLAGS
 815     CMAKE_EXE_LINKER_FLAGS
 816     CMAKE_SHARED_LINKER_FLAGS)
 817 endif()
 818
 819 option(LLVM_ENABLE_IR_PGO "Build LLVM and tools with IR PGO instrumentation (deprecated)" Off)
 820 mark_as_advanced(LLVM_ENABLE_IR_PGO)
 821
 822 set(LLVM_BUILD_INSTRUMENTED OFF CACHE STRING "Build LLVM and tools with PGO instrumentation. May be specified as IR or Frontend")
 823 mark_as_advanced(LLVM_BUILD_INSTRUMENTED)
 824 string(TOUPPER "${LLVM_BUILD_INSTRUMENTED}" uppercase_LLVM_BUILD_INSTRUMENTED)
 825
 826 if (LLVM_BUILD_INSTRUMENTED)
 827   if (LLVM_ENABLE_IR_PGO OR uppercase_LLVM_BUILD_INSTRUMENTED STREQUAL "IR")
 828     append("-fprofile-generate='${LLVM_PROFILE_DATA_DIR}'"
 829       CMAKE_CXX_FLAGS
 830       CMAKE_C_FLAGS
 831       CMAKE_EXE_LINKER_FLAGS
 832       CMAKE_SHARED_LINKER_FLAGS)
 833   elseif(uppercase_LLVM_BUILD_INSTRUMENTED STREQUAL "CSIR")
 834     append("-fcs-profile-generate='${LLVM_CSPROFILE_DATA_DIR}'"
 835       CMAKE_CXX_FLAGS
 836       CMAKE_C_FLAGS
 837       CMAKE_EXE_LINKER_FLAGS
 838       CMAKE_SHARED_LINKER_FLAGS)
 839   else()
 840     append("-fprofile-instr-generate='${LLVM_PROFILE_FILE_PATTERN}'"
 841       CMAKE_CXX_FLAGS
 842       CMAKE_C_FLAGS
 843       CMAKE_EXE_LINKER_FLAGS
 844       CMAKE_SHARED_LINKER_FLAGS)
 845   endif()
 846 endif()
 847
 848 # Need to pass -fprofile-instr-use to linker for context-sensitive PGO
 849 # compilation.
 850 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 851     append("-fprofile-instr-use='${LLVM_PROFDATA_FILE}'"
 852       CMAKE_EXE_LINKER_FLAGS
 853       CMAKE_SHARED_LINKER_FLAGS)
 854 endif()
 855
 856 option(LLVM_BUILD_INSTRUMENTED_COVERAGE "Build LLVM and tools with Code Coverage instrumentation" Off)
 857 mark_as_advanced(LLVM_BUILD_INSTRUMENTED_COVERAGE)
 858 append_if(LLVM_BUILD_INSTRUMENTED_COVERAGE "-fprofile-instr-generate='${LLVM_PROFILE_FILE_PATTERN}' -fcoverage-mapping"
 859   CMAKE_CXX_FLAGS
 860   CMAKE_C_FLAGS
 861   CMAKE_EXE_LINKER_FLAGS
 862   CMAKE_SHARED_LINKER_FLAGS)
 863
 864 if (LLVM_BUILD_INSTRUMENTED AND LLVM_BUILD_INSTRUMENTED_COVERAGE)
 865   message(FATAL_ERROR "LLVM_BUILD_INSTRUMENTED and LLVM_BUILD_INSTRUMENTED_COVERAGE cannot both be specified")
 866 endif()
 867
 868 if(LLVM_ENABLE_LTO AND LLVM_ON_WIN32 AND NOT LINKER_IS_LLD_LINK)
 869   message(FATAL_ERROR "When compiling for Windows, LLVM_ENABLE_LTO requires using lld as the linker (point CMAKE_LINKER at lld-link.exe)")
 870 endif()
 871 if(uppercase_LLVM_ENABLE_LTO STREQUAL "THIN")
 872   append("-flto=thin" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 873   if(NOT LINKER_IS_LLD_LINK)
 874     append("-flto=thin" CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 875   endif()
 876   # If the linker supports it, enable the lto cache. This improves initial build
 877   # time a little since we re-link a lot of the same objects, and significantly
 878   # improves incremental build time.
 879   # FIXME: We should move all this logic into the clang driver.
 880   if(APPLE)
 881     append("-Wl,-cache_path_lto,${PROJECT_BINARY_DIR}/lto.cache"
 882            CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 883   elseif(UNIX AND LLVM_USE_LINKER STREQUAL "lld")
 884     append("-Wl,--thinlto-cache-dir=${PROJECT_BINARY_DIR}/lto.cache"
 885            CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 886   elseif(LLVM_USE_LINKER STREQUAL "gold")
 887     append("-Wl,--plugin-opt,cache-dir=${PROJECT_BINARY_DIR}/lto.cache"
 888            CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 889   endif()
 890 elseif(uppercase_LLVM_ENABLE_LTO STREQUAL "FULL")
 891   append("-flto=full" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 892   if(NOT LINKER_IS_LLD_LINK)
 893     append("-flto=full" CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 894   endif()
 895 elseif(LLVM_ENABLE_LTO)
 896   append("-flto" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 897   if(NOT LINKER_IS_LLD_LINK)
 898     append("-flto" CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 899   endif()
 900 endif()
 901
 902 # This option makes utils/extract_symbols.py be used to determine the list of
 903 # symbols to export from LLVM tools. This is necessary when using MSVC if you
 904 # want to allow plugins, though note that the plugin has to explicitly link
 905 # against (exactly one) tool so we can't unilaterally turn on
 906 # LLVM_ENABLE_PLUGINS when it's enabled.
 907 option(LLVM_EXPORT_SYMBOLS_FOR_PLUGINS "Export symbols from LLVM tools so that plugins can import them" OFF)
 908 if(BUILD_SHARED_LIBS AND LLVM_EXPORT_SYMBOLS_FOR_PLUGINS)
 909   message(FATAL_ERROR "BUILD_SHARED_LIBS not compatible with LLVM_EXPORT_SYMBOLS_FOR_PLUGINS")
 910 endif()
 911 if(LLVM_LINK_LLVM_DYLIB AND LLVM_EXPORT_SYMBOLS_FOR_PLUGINS)
 912   message(FATAL_ERROR "LLVM_LINK_LLVM_DYLIB not compatible with LLVM_EXPORT_SYMBOLS_FOR_PLUGINS")
 913 endif()
 914
 915 # By default we should enable LLVM_ENABLE_IDE only for multi-configuration
 916 # generators. This option disables optional build system features that make IDEs
 917 # less usable.
 918 set(LLVM_ENABLE_IDE_default OFF)
 919 if (CMAKE_CONFIGURATION_TYPES)
 920   set(LLVM_ENABLE_IDE_default ON)
 921 endif()
 922 option(LLVM_ENABLE_IDE
 923        "Disable optional build system features that cause problems for IDE generators"
 924        ${LLVM_ENABLE_IDE_default})
 925 if (CMAKE_CONFIGURATION_TYPES AND NOT LLVM_ENABLE_IDE)
 926   message(WARNING "Disabling LLVM_ENABLE_IDE on multi-configuration generators is not recommended.")
 927 endif()
 928
 929 function(get_compile_definitions)
 930   get_directory_property(top_dir_definitions DIRECTORY ${CMAKE_SOURCE_DIR} COMPILE_DEFINITIONS)
 931   foreach(definition ${top_dir_definitions})
 932     if(DEFINED result)
 933       string(APPEND result " -D${definition}")
 934     else()
 935       set(result "-D${definition}")
 936     endif()
 937   endforeach()
 938   set(LLVM_DEFINITIONS "${result}" PARENT_SCOPE)
 939 endfunction()
 940 get_compile_definitions()
 941
 942 option(LLVM_FORCE_ENABLE_STATS "Enable statistics collection for builds that wouldn't normally enable it" OFF)
 943
 944 check_symbol_exists(os_signpost_interval_begin "os/signpost.h" macos_signposts_available)
 945 if(macos_signposts_available)
 946   check_cxx_source_compiles(
 947     "#include <os/signpost.h>
 948     int main() { os_signpost_interval_begin(nullptr, 0, \"\", \"\"); return 0; }"
 949     macos_signposts_usable)
 950   if(macos_signposts_usable)
 951     set(LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS "WITH_ASSERTS" CACHE STRING
 952         "Enable support for Xcode signposts. Can be WITH_ASSERTS, FORCE_ON, FORCE_OFF")
 953     string(TOUPPER "${LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS}"
 954                    uppercase_LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS)
 955     if( uppercase_LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS STREQUAL "WITH_ASSERTS" )
 956       if( LLVM_ENABLE_ASSERTIONS )
 957         set( LLVM_SUPPORT_XCODE_SIGNPOSTS 1 )
 958       endif()
 959     elseif( uppercase_LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS STREQUAL "FORCE_ON" )
 960       set( LLVM_SUPPORT_XCODE_SIGNPOSTS 1 )
 961     elseif( uppercase_LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS STREQUAL "FORCE_OFF" )
 962       # We don't need to do anything special to turn off signposts.
 963     elseif( NOT DEFINED LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS )
 964       # Treat LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS like "FORCE_OFF" when it has not been
 965       # defined.
 966     else()
 967       message(FATAL_ERROR "Unknown value for LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS:"
 968                           " \"${LLVM_ENABLE_SUPPORT_XCODE_SIGNPOSTS}\"!")
 969     endif()
 970   endif()
 971 endif()
 972
 973 option(LLVM_USE_RELATIVE_PATHS_IN_DEBUG_INFO "Use relative paths in debug info" OFF)
 974 set(LLVM_SOURCE_PREFIX "" CACHE STRING "Use prefix for sources in debug info")
 975
 976 if(LLVM_USE_RELATIVE_PATHS_IN_DEBUG_INFO)
 977   check_c_compiler_flag("-fdebug-prefix-map=foo=bar" SUPPORTS_FDEBUG_PREFIX_MAP)
 978   if(LLVM_ENABLE_PROJECTS_USED)
 979     get_filename_component(source_root "${LLVM_MAIN_SRC_DIR}/.." ABSOLUTE)
 980   else()
 981     set(source_root "${LLVM_MAIN_SRC_DIR}")
 982   endif()
 983   file(RELATIVE_PATH relative_root "${source_root}" "${CMAKE_BINARY_DIR}")
 984   append_if(SUPPORTS_FDEBUG_PREFIX_MAP "-fdebug-prefix-map=${CMAKE_BINARY_DIR}=${relative_root}" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 985   append_if(SUPPORTS_FDEBUG_PREFIX_MAP "-fdebug-prefix-map=${source_root}/=${LLVM_SOURCE_PREFIX}" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 986   add_flag_if_supported("-no-canonical-prefixes" NO_CANONICAL_PREFIXES)
 987 endif()