CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0068)
   6   cmake_policy(SET CMP0068 NEW)
   7   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
   8 endif()
   9
  10 if(POLICY CMP0075)
  11   cmake_policy(SET CMP0075 NEW)
  12 endif()
  13
  14 if(POLICY CMP0077)
  15   cmake_policy(SET CMP0077 NEW)
  16 endif()
  17
  18 if(NOT DEFINED LLVM_VERSION_MAJOR)
  19   set(LLVM_VERSION_MAJOR 10)
  20 endif()
  21 if(NOT DEFINED LLVM_VERSION_MINOR)
  22   set(LLVM_VERSION_MINOR 0)
  23 endif()
  24 if(NOT DEFINED LLVM_VERSION_PATCH)
  25   set(LLVM_VERSION_PATCH 0)
  26 endif()
  27 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  28   set(LLVM_VERSION_SUFFIX svn)
  29 endif()
  30
  31 if (NOT PACKAGE_VERSION)
  32   set(PACKAGE_VERSION
  33     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  34 endif()
  35
  36 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  37   message(WARNING "Visual Studio generators use the x86 host compiler by "
  38                   "default, even for 64-bit targets. This can result in linker "
  39                   "instability and out of memory errors. To use the 64-bit "
  40                   "host compiler, pass -Thost=x64 on the CMake command line.")
  41 endif()
  42
  43 if (CMAKE_GENERATOR STREQUAL "Xcode" AND NOT CMAKE_OSX_ARCHITECTURES)
  44   # Some CMake features like object libraries get confused if you don't
  45   # explicitly specify an architecture setting with the Xcode generator.
  46   set(CMAKE_OSX_ARCHITECTURES "x86_64")
  47 endif()
  48
  49 project(LLVM
  50   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  51   LANGUAGES C CXX ASM)
  52
  53 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  54   message(STATUS "No build type selected, default to Debug")
  55   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  56 endif()
  57
  58 # Side-by-side subprojects layout: automatically set the
  59 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
  60 # This allows an easy way of setting up a build directory for llvm and another
  61 # one for llvm+clang+... using the same sources.
  62 set(LLVM_ALL_PROJECTS "clang;clang-tools-extra;compiler-rt;debuginfo-tests;libclc;libcxx;libcxxabi;libunwind;lld;lldb;llgo;openmp;parallel-libs;polly;pstl")
  63 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
  64         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
  65 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
  66   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
  67 endif()
  68
  69 # LLVM_ENABLE_PROJECTS_USED is `ON` if the user has ever used the
  70 # `LLVM_ENABLE_PROJECTS` CMake cache variable.  This exists for
  71 # several reasons:
  72 #
  73 # * As an indicator that the `LLVM_ENABLE_PROJECTS` list is now the single
  74 # source of truth for which projects to build. This means we will ignore user
  75 # supplied `LLVM_TOOL_<project>_BUILD` CMake cache variables and overwrite
  76 # them.
  77 #
  78 # * The case where the user previously had `LLVM_ENABLE_PROJECTS` set to a
  79 # non-empty list but now the user wishes to disable building all other projects
  80 # by setting `LLVM_ENABLE_PROJECTS` to an empty string. In that case we still
  81 # need to set the `LLVM_TOOL_${upper_proj}_BUILD` variables so that we disable
  82 # building all the projects that were previously enabled.
  83 set(LLVM_ENABLE_PROJECTS_USED OFF CACHE BOOL "")
  84 mark_as_advanced(LLVM_ENABLE_PROJECTS_USED)
  85
  86 if (LLVM_ENABLE_PROJECTS_USED OR NOT LLVM_ENABLE_PROJECTS STREQUAL "")
  87   set(LLVM_ENABLE_PROJECTS_USED ON CACHE BOOL "" FORCE)
  88   foreach(proj ${LLVM_ALL_PROJECTS} ${LLVM_EXTERNAL_PROJECTS})
  89     string(TOUPPER "${proj}" upper_proj)
  90     string(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
  91     if ("${proj}" IN_LIST LLVM_ENABLE_PROJECTS)
  92       message(STATUS "${proj} project is enabled")
  93       set(SHOULD_ENABLE_PROJECT TRUE)
  94       set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
  95       if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
  96         message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
  97       endif()
  98       if( LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR STREQUAL "" )
  99         set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE PATH "" FORCE)
 100       else()
 101         set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE PATH "")
 102       endif()
 103     elseif ("${proj}" IN_LIST LLVM_EXTERNAL_PROJECTS)
 104       message(STATUS "${proj} project is enabled")
 105       set(SHOULD_ENABLE_PROJECT TRUE)
 106     else()
 107       message(STATUS "${proj} project is disabled")
 108       set(SHOULD_ENABLE_PROJECT FALSE)
 109     endif()
 110     # Force `LLVM_TOOL_${upper_proj}_BUILD` variables to have values that
 111     # corresponds with `LLVM_ENABLE_PROJECTS`. This prevents the user setting
 112     # `LLVM_TOOL_${upper_proj}_BUILD` variables externally. At some point
 113     # we should deprecate allowing users to set these variables by turning them
 114     # into normal CMake variables rather than cache variables.
 115     set(LLVM_TOOL_${upper_proj}_BUILD
 116       ${SHOULD_ENABLE_PROJECT}
 117       CACHE
 118       BOOL "Whether to build ${upper_proj} as part of LLVM" FORCE
 119     )
 120   endforeach()
 121 endif()
 122 unset(SHOULD_ENABLE_PROJECT)
 123
 124 # Build llvm with ccache if the package is present
 125 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 126 if(LLVM_CCACHE_BUILD)
 127   find_program(CCACHE_PROGRAM ccache)
 128   if(CCACHE_PROGRAM)
 129       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 130       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 131       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 132           CACHE STRING "Parameters to pass through to ccache")
 133
 134       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 135       if (LLVM_CCACHE_MAXSIZE)
 136         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 137       endif()
 138       if (LLVM_CCACHE_DIR)
 139         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 140       endif()
 141       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 142   else()
 143     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 144   endif()
 145 endif()
 146
 147 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 148
 149 # Some features of the LLVM build may be disallowed when dependency debugging is
 150 # enabled. In particular you cannot use ccache because we want to force compile
 151 # operations to always happen.
 152 if(LLVM_DEPENDENCY_DEBUGGING)
 153   if(NOT CMAKE_HOST_APPLE)
 154     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 155   endif()
 156   if(LLVM_CCACHE_BUILD)
 157     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 158   endif()
 159 endif()
 160
 161 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 162 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 163 if(LLVM_ENABLE_GISEL_COV)
 164   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 165 endif()
 166
 167 # Add path for custom modules
 168 set(CMAKE_MODULE_PATH
 169   ${CMAKE_MODULE_PATH}
 170   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 171   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 172   )
 173
 174 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 175 # for use by clang_complete, YouCompleteMe, etc.
 176 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 177
 178 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 179   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 180
 181 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 182
 183 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 184
 185 # Unfortunatly Clang is too eager to search directories for module maps, which can cause the
 186 # installed version of the maps to be found when building LLVM from source. Therefore we turn off
 187 # the installation by default. See llvm.org/PR31905.
 188 option(LLVM_INSTALL_MODULEMAPS "Install the modulemap files in the 'install' target." OFF)
 189
 190 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 191 if ( LLVM_USE_FOLDERS )
 192   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 193 endif()
 194
 195 include(VersionFromVCS)
 196
 197 option(LLVM_APPEND_VC_REV
 198   "Embed the version control system revision in LLVM" ON)
 199
 200 set(PACKAGE_NAME LLVM)
 201 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 202 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
 203
 204 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 205   "Default URL where bug reports are to be submitted.")
 206
 207 # Configure CPack.
 208 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 209 set(CPACK_PACKAGE_VENDOR "LLVM")
 210 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 211 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 212 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 213 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 214 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 215 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 216 if(WIN32 AND NOT UNIX)
 217   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 218   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 219   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 220   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 221   set(CPACK_NSIS_MODIFY_PATH "ON")
 222   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 223   if( CMAKE_CL_64 )
 224     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 225   endif()
 226 endif()
 227 include(CPack)
 228
 229 # Sanity check our source directory to make sure that we are not trying to
 230 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 231 # sure that we don't have any stray generated files lying around in the tree
 232 # (which would end up getting picked up by header search, instead of the correct
 233 # versions).
 234 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 235   message(FATAL_ERROR "In-source builds are not allowed.
 236 Please create a directory and run cmake from there, passing the path
 237 to this source directory as the last argument.
 238 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 239 Please delete them.")
 240 endif()
 241
 242 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 243
 244 if (CMAKE_BUILD_TYPE AND
 245     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 246   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 247 endif()
 248
 249 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 250
 251 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 252 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 253
 254 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 255     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 256 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 257
 258 # They are used as destination of target generators.
 259 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 260 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 261 if(WIN32 OR CYGWIN)
 262   # DLL platform -- put DLLs into bin.
 263   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 264 else()
 265   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 266 endif()
 267
 268 # Each of them corresponds to llvm-config's.
 269 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 270 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 271 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 272 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 273 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 274
 275 # Note: LLVM_CMAKE_PATH does not include generated files
 276 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 277 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 278 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 279
 280 # List of all targets to be built by default:
 281 set(LLVM_ALL_TARGETS
 282   AArch64
 283   AMDGPU
 284   ARM
 285   BPF
 286   Hexagon
 287   Lanai
 288   Mips
 289   MSP430
 290   NVPTX
 291   PowerPC
 292   RISCV
 293   Sparc
 294   SystemZ
 295   WebAssembly
 296   X86
 297   XCore
 298   )
 299
 300 # List of targets with JIT support:
 301 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 302
 303 set(LLVM_TARGETS_TO_BUILD "all"
 304     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 305
 306 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 307   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 308
 309 option(BUILD_SHARED_LIBS
 310   "Build all libraries as shared libraries instead of static" OFF)
 311
 312 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 313 if(LLVM_ENABLE_BACKTRACES)
 314   set(ENABLE_BACKTRACES 1)
 315 endif()
 316
 317 option(LLVM_ENABLE_UNWIND_TABLES "Emit unwind tables for the libraries" ON)
 318
 319 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 320 if(LLVM_ENABLE_CRASH_OVERRIDES)
 321   set(ENABLE_CRASH_OVERRIDES 1)
 322 endif()
 323
 324 option(LLVM_ENABLE_CRASH_DUMPS "Turn on memory dumps on crashes. Currently only implemented on Windows." OFF)
 325
 326 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 327 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 328 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 329
 330 set(LLVM_TARGET_ARCH "host"
 331   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 332
 333 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 334
 335 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 336
 337 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 338
 339 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 340
 341 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 342
 343 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 344
 345 set(LLVM_Z3_INSTALL_DIR "" CACHE STRING "Install directory of the Z3 solver.")
 346
 347 find_package(Z3 4.7.1)
 348
 349 if (LLVM_Z3_INSTALL_DIR)
 350   if (NOT Z3_FOUND)
 351     message(FATAL_ERROR "Z3 >= 4.7.1 has not been found in LLVM_Z3_INSTALL_DIR: ${LLVM_Z3_INSTALL_DIR}.")
 352   endif()
 353 endif()
 354
 355 set(LLVM_ENABLE_Z3_SOLVER_DEFAULT "${Z3_FOUND}")
 356
 357 option(LLVM_ENABLE_Z3_SOLVER
 358   "Enable Support for the Z3 constraint solver in LLVM."
 359   ${LLVM_ENABLE_Z3_SOLVER_DEFAULT}
 360 )
 361
 362 if (LLVM_ENABLE_Z3_SOLVER)
 363   if (NOT Z3_FOUND)
 364     message(FATAL_ERROR "LLVM_ENABLE_Z3_SOLVER cannot be enabled when Z3 is not available.")
 365   endif()
 366
 367   set(LLVM_WITH_Z3 1)
 368 endif()
 369
 370 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 371   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 372 endif()
 373
 374 set(LLVM_TARGETS_TO_BUILD
 375    ${LLVM_TARGETS_TO_BUILD}
 376    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 377 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 378
 379 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 380 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 381 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 382 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 383   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 384   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 385 else()
 386   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 387   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 388 endif()
 389 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 390 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 391 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 392 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 393
 394 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 395
 396 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 397   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 398 else()
 399   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 400 endif()
 401
 402 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 403
 404 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 405   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 406
 407 option(LLVM_FORCE_USE_OLD_TOOLCHAIN
 408        "Set to ON to force using an old, unsupported host toolchain." OFF)
 409
 410 option(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN
 411        "Set to ON to only warn when using a toolchain which is about to be deprecated, instead of emitting an error." OFF)
 412
 413 option(LLVM_USE_INTEL_JITEVENTS
 414   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 415   OFF)
 416
 417 if( LLVM_USE_INTEL_JITEVENTS )
 418   # Verify we are on a supported platform
 419   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 420     message(FATAL_ERROR
 421       "Intel JIT API support is available on Linux and Windows only.")
 422   endif()
 423 endif( LLVM_USE_INTEL_JITEVENTS )
 424
 425 option(LLVM_USE_OPROFILE
 426   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 427
 428 option(LLVM_EXTERNALIZE_DEBUGINFO
 429   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 430
 431 set(LLVM_CODESIGNING_IDENTITY "" CACHE STRING
 432   "Sign executables and dylibs with the given identity or skip if empty (Darwin Only)")
 433
 434 # If enabled, verify we are on a platform that supports oprofile.
 435 if( LLVM_USE_OPROFILE )
 436   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 437     message(FATAL_ERROR "OProfile support is available on Linux only.")
 438   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 439 endif( LLVM_USE_OPROFILE )
 440
 441 option(LLVM_USE_PERF
 442   "Use perf JIT interface to inform perf about JIT code" OFF)
 443
 444 # If enabled, verify we are on a platform that supports perf.
 445 if( LLVM_USE_PERF )
 446   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 447     message(FATAL_ERROR "perf support is available on Linux only.")
 448   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 449 endif( LLVM_USE_PERF )
 450
 451 set(LLVM_USE_SANITIZER "" CACHE STRING
 452   "Define the sanitizer used to build binaries and tests.")
 453 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 454 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 455   "Path to fuzzing library for linking with fuzz targets")
 456
 457 option(LLVM_USE_SPLIT_DWARF
 458   "Use -gsplit-dwarf when compiling llvm." OFF)
 459
 460 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 461 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 462
 463 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 464   set(POLLY_IN_TREE TRUE)
 465 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 466   set(POLLY_IN_TREE TRUE)
 467 else()
 468   set(POLLY_IN_TREE FALSE)
 469 endif()
 470
 471 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 472   set(WITH_POLLY ON)
 473 else()
 474   set(WITH_POLLY OFF)
 475 endif()
 476
 477 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 478   set(LINK_POLLY_INTO_TOOLS ON)
 479 else()
 480   set(LINK_POLLY_INTO_TOOLS OFF)
 481 endif()
 482
 483 # Define an option controlling whether we should build for 32-bit on 64-bit
 484 # platforms, where supported.
 485 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 486   # TODO: support other platforms and toolchains.
 487   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 488 endif()
 489
 490 # Define the default arguments to use with 'lit', and an option for the user to
 491 # override.
 492 set(LIT_ARGS_DEFAULT "-sv")
 493 if (MSVC_IDE OR XCODE)
 494   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 495 endif()
 496 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 497
 498 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 499 if( WIN32 AND NOT CYGWIN )
 500   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 501 endif()
 502
 503 # Define options to control the inclusion and default build behavior for
 504 # components which may not strictly be necessary (tools, examples, and tests).
 505 #
 506 # This is primarily to support building smaller or faster project files.
 507 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 508 option(LLVM_BUILD_TOOLS
 509   "Build the LLVM tools. If OFF, just generate build targets." ON)
 510
 511 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 512 option(LLVM_BUILD_UTILS
 513   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 514
 515 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 516 option(LLVM_BUILD_RUNTIMES
 517   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 518
 519 option(LLVM_BUILD_RUNTIME
 520   "Build the LLVM runtime libraries." ON)
 521 option(LLVM_BUILD_EXAMPLES
 522   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 523 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 524
 525 option(LLVM_BUILD_TESTS
 526   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 527 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 528 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 529
 530 option(LLVM_BUILD_BENCHMARKS "Add LLVM benchmark targets to the list of default
 531 targets. If OFF, benchmarks still could be built using Benchmarks target." OFF)
 532 option(LLVM_INCLUDE_BENCHMARKS "Generate benchmark targets. If OFF, benchmarks can't be built." ON)
 533
 534 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 535 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 536 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 537 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 538 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 539 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 540
 541 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 542     CACHE STRING "Doxygen-generated HTML documentation install directory")
 543 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 544     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 545
 546 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 547   "Build compiler-rt as an external project." OFF)
 548
 549 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 550   "Show target and host info when tools are invoked with --version." ON)
 551
 552 # You can configure which libraries from LLVM you want to include in the
 553 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 554 # list of LLVM components. All component names handled by llvm-config are valid.
 555 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 556   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 557     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 558 endif()
 559 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 560 if(MSVC)
 561   option(LLVM_BUILD_LLVM_C_DYLIB "Build LLVM-C.dll (Windows only)" ON)
 562 else()
 563   option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin only)" OFF)
 564 endif()
 565 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 566 if(LLVM_LINK_LLVM_DYLIB OR (LLVM_BUILD_LLVM_C_DYLIB AND NOT MSVC))
 567   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 568 endif()
 569 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 570
 571 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 572 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 573   set(LLVM_USE_HOST_TOOLS ON)
 574 endif()
 575
 576 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 577   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 578 else()
 579   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 580 endif()
 581
 582 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 583     LLVM_ENABLE_IR_PGO)
 584   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 585     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 586     # for spining disks. Anything higher may only help on slower mediums.
 587     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 588   endif()
 589   if(NOT LLVM_PROFILE_FILE_PATTERN)
 590     if(NOT LLVM_PROFILE_DATA_DIR)
 591       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 592     endif()
 593                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 594   endif()
 595   if(NOT LLVM_CSPROFILE_FILE_PATTERN)
 596     if(NOT LLVM_CSPROFILE_DATA_DIR)
 597       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/csprofiles" LLVM_CSPROFILE_DATA_DIR)
 598     endif()
 599     file(TO_NATIVE_PATH "${LLVM_CSPROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_CSPROFILE_FILE_PATTERN)
 600   endif()
 601 endif()
 602
 603 if (LLVM_BUILD_STATIC)
 604   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 605 endif()
 606
 607 # Use libtool instead of ar if you are both on an Apple host, and targeting Apple.
 608 if(CMAKE_HOST_APPLE AND APPLE)
 609   include(UseLibtool)
 610 endif()
 611
 612 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 613 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 614 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 615
 616 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR OFF CACHE BOOL
 617   "Enable per-target runtimes directory")
 618
 619 # All options referred to from HandleLLVMOptions have to be specified
 620 # BEFORE this include, otherwise options will not be correctly set on
 621 # first cmake run
 622 include(config-ix)
 623
 624 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 625   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 626 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 627
 628 # By default, we target the host, but this can be overridden at CMake
 629 # invocation time.
 630 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 631   "Default target for which LLVM will generate code." )
 632 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 633 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 634 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 635
 636 if(WIN32 OR CYGWIN)
 637   if(BUILD_SHARED_LIBS OR LLVM_BUILD_LLVM_DYLIB)
 638     set(LLVM_ENABLE_PLUGINS_default ON)
 639   else()
 640     set(LLVM_ENABLE_PLUGINS_default OFF)
 641   endif()
 642 else()
 643   set(LLVM_ENABLE_PLUGINS_default ${LLVM_ENABLE_PIC})
 644 endif()
 645 option(LLVM_ENABLE_PLUGINS "Enable plugin support" ${LLVM_ENABLE_PLUGINS_default})
 646
 647 include(HandleLLVMOptions)
 648
 649 include(FindPythonInterp)
 650 if( NOT PYTHONINTERP_FOUND )
 651   message(FATAL_ERROR
 652 "Unable to find Python interpreter, required for builds and testing.
 653
 654 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 655 endif()
 656
 657 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 658   message(FATAL_ERROR "Python 2.7 or newer is required")
 659 endif()
 660
 661 ######
 662 # LLVMBuild Integration
 663 #
 664 # We use llvm-build to generate all the data required by the CMake based
 665 # build system in one swoop:
 666 #
 667 #  - We generate a file (a CMake fragment) in the object root which contains
 668 #    all the definitions that are required by CMake.
 669 #
 670 #  - We generate the library table used by llvm-config.
 671 #
 672 #  - We generate the dependencies for the CMake fragment, so that we will
 673 #    automatically reconfigure ourselves.
 674
 675 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 676 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 677   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 678 set(LLVMBUILDCMAKEFRAG
 679   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 680
 681 # Create the list of optional components that are enabled
 682 if (LLVM_USE_INTEL_JITEVENTS)
 683   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 684 endif (LLVM_USE_INTEL_JITEVENTS)
 685 if (LLVM_USE_OPROFILE)
 686   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 687 endif (LLVM_USE_OPROFILE)
 688 if (LLVM_USE_PERF)
 689   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} PerfJITEvents)
 690 endif (LLVM_USE_PERF)
 691
 692 message(STATUS "Constructing LLVMBuild project information")
 693 execute_process(
 694   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 695             --native-target "${LLVM_NATIVE_ARCH}"
 696             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 697             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 698             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 699             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 700             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 701             ERROR_VARIABLE LLVMBUILDERRORS
 702             OUTPUT_STRIP_TRAILING_WHITESPACE
 703             ERROR_STRIP_TRAILING_WHITESPACE
 704   RESULT_VARIABLE LLVMBUILDRESULT)
 705
 706 # On Win32, CMake doesn't properly handle piping the default output/error
 707 # streams into the GUI console. So, we explicitly catch and report them.
 708 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 709   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 710 endif()
 711 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 712   message(FATAL_ERROR
 713     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 714 endif()
 715
 716 # Include the generated CMake fragment. This will define properties from the
 717 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 718 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 719 # files change.
 720 include(${LLVMBUILDCMAKEFRAG})
 721
 722 ######
 723
 724 # Configure all of the various header file fragments LLVM uses which depend on
 725 # configuration variables.
 726 set(LLVM_ENUM_TARGETS "")
 727 set(LLVM_ENUM_ASM_PRINTERS "")
 728 set(LLVM_ENUM_ASM_PARSERS "")
 729 set(LLVM_ENUM_DISASSEMBLERS "")
 730 foreach(t ${LLVM_TARGETS_TO_BUILD})
 731   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 732
 733   list(FIND LLVM_ALL_TARGETS ${t} idx)
 734   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 735   # At this point, LLVMBUILDTOOL already checked all the targets passed in
 736   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
 737   # this test just makes sure that any experimental targets were passed via
 738   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 739   if( idx LESS 0 AND idy LESS 0 )
 740     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 741       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 742   else()
 743     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 744   endif()
 745
 746   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 747   if( asmp_file )
 748     set(LLVM_ENUM_ASM_PRINTERS
 749       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 750   endif()
 751   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 752     set(LLVM_ENUM_ASM_PARSERS
 753       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 754   endif()
 755   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 756     set(LLVM_ENUM_DISASSEMBLERS
 757       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 758   endif()
 759 endforeach(t)
 760
 761 # Produce the target definition files, which provide a way for clients to easily
 762 # include various classes of targets.
 763 configure_file(
 764   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 765   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 766   )
 767 configure_file(
 768   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 769   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 770   )
 771 configure_file(
 772   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 773   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 774   )
 775 configure_file(
 776   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 777   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 778   )
 779
 780 # Configure the three LLVM configuration header files.
 781 configure_file(
 782   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 783   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 784 configure_file(
 785   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 786   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 787 configure_file(
 788   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 789   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 790
 791 # Add target for generating source rpm package.
 792 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 793     CACHE FILEPATH ".spec file to use for srpm generation")
 794 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 795 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 796
 797 get_source_info(${CMAKE_CURRENT_SOURCE_DIR} revision repository)
 798 string(LENGTH "${revision}" revision_length)
 799 if(revision MATCHES "^[0-9]+$" AND revision_length LESS 40)
 800   set(LLVM_RPM_SPEC_REVISION "r${revision}")
 801 else()
 802   set(LLVM_RPM_SPEC_REVISION "${revision}")
 803 endif()
 804
 805 configure_file(
 806   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 807   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 808
 809 add_custom_target(srpm
 810   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 811   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 812 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 813
 814
 815 # They are not referenced. See set_output_directory().
 816 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 817 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 818 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 819
 820 if(APPLE AND DARWIN_LTO_LIBRARY)
 821   set(CMAKE_EXE_LINKER_FLAGS
 822     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 823   set(CMAKE_SHARED_LINKER_FLAGS
 824     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 825   set(CMAKE_MODULE_LINKER_FLAGS
 826     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 827 endif()
 828
 829 # Build with _XOPEN_SOURCE on AIX, as stray macros in _ALL_SOURCE mode tend to
 830 # break things. In this case we need to enable the large-file API as well.
 831 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 832           add_definitions("-D_XOPEN_SOURCE=700")
 833           add_definitions("-D_LARGE_FILE_API")
 834 endif()
 835
 836 # Work around a broken bfd ld behavior. When linking a binary with a
 837 # foo.so library, it will try to find any library that foo.so uses and
 838 # check its symbols. This is wasteful (the check was done when foo.so
 839 # was created) and can fail since it is not the dynamic linker and
 840 # doesn't know how to handle search paths correctly.
 841 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 842   set(CMAKE_EXE_LINKER_FLAGS
 843       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 844 endif()
 845
 846 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 847
 848 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 849
 850 # when crosscompiling import the executable targets from a file
 851 if(LLVM_USE_HOST_TOOLS)
 852   include(CrossCompile)
 853   llvm_create_cross_target(LLVM NATIVE "" Release)
 854 endif(LLVM_USE_HOST_TOOLS)
 855 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 856 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 857 # (this is a variable that CrossCompile sets on recursive invocations)
 858 endif()
 859
 860 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 861   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 862   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 863   include_directories(SYSTEM "/usr/local/include")
 864   link_directories("/usr/local/lib")
 865 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 866
 867 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 868    # special hack for Solaris to handle crazy system sys/regset.h
 869    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 870 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 871
 872 # Make sure we don't get -rdynamic in every binary. For those that need it,
 873 # use export_executable_symbols(target).
 874 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 875
 876 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 877   "Profiling data file to use when compiling in order to improve runtime performance.")
 878
 879 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 880   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 881     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 882   else()
 883     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 884   endif()
 885 endif()
 886
 887 include(AddLLVM)
 888 include(TableGen)
 889
 890 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 891   # People report that -O3 is unreliable on MinGW. The traditional
 892   # build also uses -O2 for that reason:
 893   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 894 endif()
 895
 896 # Put this before tblgen. Else we have a circular dependence.
 897 add_subdirectory(lib/Demangle)
 898 add_subdirectory(lib/Support)
 899 add_subdirectory(lib/TableGen)
 900
 901 add_subdirectory(utils/TableGen)
 902
 903 add_subdirectory(include/llvm)
 904
 905 add_subdirectory(lib)
 906
 907 if( LLVM_INCLUDE_UTILS )
 908   add_subdirectory(utils/FileCheck)
 909   add_subdirectory(utils/PerfectShuffle)
 910   add_subdirectory(utils/count)
 911   add_subdirectory(utils/not)
 912   add_subdirectory(utils/yaml-bench)
 913 else()
 914   if ( LLVM_INCLUDE_TESTS )
 915     message(FATAL_ERROR "Including tests when not building utils will not work.
 916     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLUDE_TESTS to Off.")
 917   endif()
 918 endif()
 919
 920 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 921 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 922   add_subdirectory(utils/LLVMVisualizers)
 923 endif()
 924
 925 foreach( binding ${LLVM_BINDINGS_LIST} )
 926   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 927     add_subdirectory(bindings/${binding})
 928   endif()
 929 endforeach()
 930
 931 add_subdirectory(projects)
 932
 933 if( LLVM_INCLUDE_TOOLS )
 934   add_subdirectory(tools)
 935 endif()
 936
 937 if( LLVM_INCLUDE_RUNTIMES )
 938   add_subdirectory(runtimes)
 939 endif()
 940
 941 if( LLVM_INCLUDE_EXAMPLES )
 942   add_subdirectory(examples)
 943 endif()
 944
 945 if( LLVM_INCLUDE_TESTS )
 946   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 947     include(LLVMExternalProjectUtils)
 948     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 949       USE_TOOLCHAIN
 950       EXCLUDE_FROM_ALL
 951       NO_INSTALL
 952       ALWAYS_CLEAN)
 953   endif()
 954   add_subdirectory(utils/lit)
 955   add_subdirectory(test)
 956   add_subdirectory(unittests)
 957   if( LLVM_INCLUDE_UTILS )
 958     add_subdirectory(utils/unittest)
 959   endif()
 960
 961   if (WIN32)
 962     # This utility is used to prevent crashing tests from calling Dr. Watson on
 963     # Windows.
 964     add_subdirectory(utils/KillTheDoctor)
 965   endif()
 966
 967   # Add a global check rule now that all subdirectories have been traversed
 968   # and we know the total set of lit testsuites.
 969   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 970   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 971   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 972   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 973   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 974                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 975   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 976                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 977   add_lit_target(check-all
 978     "Running all regression tests"
 979     ${LLVM_LIT_TESTSUITES}
 980     PARAMS ${LLVM_LIT_PARAMS}
 981     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 982     ARGS ${LLVM_LIT_EXTRA_ARGS}
 983     )
 984   if(TARGET check-runtimes)
 985     add_dependencies(check-all check-runtimes)
 986   endif()
 987   add_custom_target(test-depends
 988                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 989   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 990 endif()
 991
 992 if (LLVM_INCLUDE_DOCS)
 993   add_subdirectory(docs)
 994 endif()
 995
 996 add_subdirectory(cmake/modules)
 997
 998 # Do this last so that all lit targets have already been created.
 999 if (LLVM_INCLUDE_UTILS)
1000   add_subdirectory(utils/llvm-lit)
1001 endif()
1002
1003 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1004   install(DIRECTORY include/llvm include/llvm-c
1005     DESTINATION include
1006     COMPONENT llvm-headers
1007     FILES_MATCHING
1008     PATTERN "*.def"
1009     PATTERN "*.h"
1010     PATTERN "*.td"
1011     PATTERN "*.inc"
1012     PATTERN "LICENSE.TXT"
1013     PATTERN ".svn" EXCLUDE
1014     )
1015
1016   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
1017     DESTINATION include
1018     COMPONENT llvm-headers
1019     FILES_MATCHING
1020     PATTERN "*.def"
1021     PATTERN "*.h"
1022     PATTERN "*.gen"
1023     PATTERN "*.inc"
1024     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
1025     PATTERN "CMakeFiles" EXCLUDE
1026     PATTERN "config.h" EXCLUDE
1027     PATTERN ".svn" EXCLUDE
1028     )
1029
1030   if (LLVM_INSTALL_MODULEMAPS)
1031     install(DIRECTORY include/llvm include/llvm-c
1032             DESTINATION include
1033             COMPONENT llvm-headers
1034             FILES_MATCHING
1035             PATTERN "module.modulemap"
1036             )
1037     install(FILES include/llvm/module.install.modulemap
1038             DESTINATION include/llvm
1039             COMPONENT llvm-headers
1040             RENAME "module.extern.modulemap"
1041             )
1042   endif(LLVM_INSTALL_MODULEMAPS)
1043
1044   # Installing the headers needs to depend on generating any public
1045   # tablegen'd headers.
1046   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
1047   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
1048
1049   if (NOT LLVM_ENABLE_IDE)
1050     add_llvm_install_targets(install-llvm-headers
1051                              DEPENDS llvm-headers
1052                              COMPONENT llvm-headers)
1053   endif()
1054
1055   # Custom target to install all libraries.
1056   add_custom_target(llvm-libraries)
1057   set_target_properties(llvm-libraries PROPERTIES FOLDER "Misc")
1058
1059   if (NOT LLVM_ENABLE_IDE)
1060     add_llvm_install_targets(install-llvm-libraries
1061                              DEPENDS llvm-libraries
1062                              COMPONENT llvm-libraries)
1063   endif()
1064
1065   get_property(LLVM_LIBS GLOBAL PROPERTY LLVM_LIBS)
1066   if(LLVM_LIBS)
1067     list(REMOVE_DUPLICATES LLVM_LIBS)
1068     foreach(lib ${LLVM_LIBS})
1069       add_dependencies(llvm-libraries ${lib})
1070       if (NOT LLVM_ENABLE_IDE)
1071         add_dependencies(install-llvm-libraries install-${lib})
1072       endif()
1073     endforeach()
1074   endif()
1075 endif()
1076
1077 # This must be at the end of the LLVM root CMakeLists file because it must run
1078 # after all targets are created.
1079 include(LLVMDistributionSupport)
1080 llvm_distribution_add_targets()
1081
1082 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1083 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" AND CMAKE_INSTALL_UCRT_LIBRARIES)
1084   include(InstallRequiredSystemLibraries)
1085 endif()
1086
1087 if (LLVM_INCLUDE_BENCHMARKS)
1088   # Override benchmark defaults so that when the library itself is updated these
1089   # modifications are not lost.
1090   set(BENCHMARK_ENABLE_TESTING OFF CACHE BOOL "Disable benchmark testing" FORCE)
1091   set(BENCHMARK_ENABLE_EXCEPTIONS OFF CACHE BOOL "Disable benchmark exceptions" FORCE)
1092   set(BENCHMARK_ENABLE_INSTALL OFF CACHE BOOL "Don't install benchmark" FORCE)
1093   set(BENCHMARK_DOWNLOAD_DEPENDENCIES OFF CACHE BOOL "Don't download dependencies" FORCE)
1094   set(BENCHMARK_ENABLE_GTEST_TESTS OFF CACHE BOOL "Disable Google Test in benchmark" FORCE)
1095   # Since LLVM requires C++11 it is safe to assume that std::regex is available.
1096   set(HAVE_STD_REGEX ON CACHE BOOL "OK" FORCE)
1097
1098   add_subdirectory(utils/benchmark)
1099   add_subdirectory(benchmarks)
1100 endif()