utils/gn/secondary/llvm/lib/Target/AArch64/MCTargetDesc/BUILD.gn

   1 import("//llvm/utils/TableGen/tablegen.gni")
   2
   3 tablegen("AArch64GenAsmWriter") {
   4   visibility = [ ":MCTargetDesc" ]
   5   args = [ "-gen-asm-writer" ]
   6   td_file = "../AArch64.td"
   7 }
   8
   9 tablegen("AArch64GenAsmWriter1") {
  10   visibility = [ ":MCTargetDesc" ]
  11   args = [
  12     "-gen-asm-writer",
  13     "-asmwriternum=1",
  14   ]
  15   td_file = "../AArch64.td"
  16 }
  17
  18 tablegen("AArch64GenInstrInfo") {
  19   visibility = [ ":tablegen" ]
  20   args = [ "-gen-instr-info" ]
  21   td_file = "../AArch64.td"
  22 }
  23
  24 tablegen("AArch64GenMCCodeEmitter") {
  25   visibility = [ ":MCTargetDesc" ]
  26   args = [ "-gen-emitter" ]
  27   td_file = "../AArch64.td"
  28 }
  29
  30 tablegen("AArch64GenRegisterInfo") {
  31   visibility = [ ":tablegen" ]
  32   args = [ "-gen-register-info" ]
  33   td_file = "../AArch64.td"
  34 }
  35
  36 tablegen("AArch64GenSubtargetInfo") {
  37   visibility = [ ":tablegen" ]
  38   args = [ "-gen-subtarget" ]
  39   td_file = "../AArch64.td"
  40 }
  41
  42 # This should contain tablegen targets generating .inc files included
  43 # by other targets. .inc files only used by .cpp files in this directory
  44 # should be in deps on the static_library instead.
  45 group("tablegen") {
  46   visibility = [
  47     ":MCTargetDesc",
  48     "../Utils",
  49   ]
  50   public_deps = [
  51     ":AArch64GenInstrInfo",
  52     ":AArch64GenRegisterInfo",
  53     ":AArch64GenSubtargetInfo",
  54   ]
  55 }
  56
  57 static_library("MCTargetDesc") {
  58   output_name = "LLVMAArch64Desc"
  59   public_deps = [
  60     ":tablegen",
  61   ]
  62   deps = [
  63     ":AArch64GenAsmWriter",
  64     ":AArch64GenAsmWriter1",
  65     ":AArch64GenMCCodeEmitter",
  66     "//llvm/lib/MC",
  67     "//llvm/lib/Support",
  68     "//llvm/lib/Target/AArch64/TargetInfo",
  69     "//llvm/lib/Target/AArch64/Utils",
  70   ]
  71   include_dirs = [ ".." ]
  72   sources = [
  73     "AArch64AsmBackend.cpp",
  74     "AArch64ELFObjectWriter.cpp",
  75     "AArch64ELFStreamer.cpp",
  76     "AArch64InstPrinter.cpp",
  77     "AArch64MCAsmInfo.cpp",
  78     "AArch64MCCodeEmitter.cpp",
  79     "AArch64MCExpr.cpp",
  80     "AArch64MCTargetDesc.cpp",
  81     "AArch64MachObjectWriter.cpp",
  82     "AArch64TargetStreamer.cpp",
  83     "AArch64WinCOFFObjectWriter.cpp",
  84     "AArch64WinCOFFStreamer.cpp",
  85   ]
  86 }