CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 cmake_policy(SET CMP0022 NEW)
   6
   7 cmake_policy(SET CMP0048 NEW)
   8
   9 # CMake 3.1 and higher include generator expressions of the form
  10 # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  11 # stripped everywhere that access the SOURCES property, so we just
  12 # defer to the OLD behavior of not including generator expressions
  13 # in the output for now.
  14 cmake_policy(SET CMP0051 OLD)
  15
  16 cmake_policy(SET CMP0056 NEW)
  17
  18 cmake_policy(SET CMP0057 NEW)
  19
  20 if(NOT DEFINED LLVM_VERSION_MAJOR)
  21   set(LLVM_VERSION_MAJOR 6)
  22 endif()
  23 if(NOT DEFINED LLVM_VERSION_MINOR)
  24   set(LLVM_VERSION_MINOR 0)
  25 endif()
  26 if(NOT DEFINED LLVM_VERSION_PATCH)
  27   set(LLVM_VERSION_PATCH 0)
  28 endif()
  29 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  30   set(LLVM_VERSION_SUFFIX svn)
  31 endif()
  32
  33 if (NOT PACKAGE_VERSION)
  34   set(PACKAGE_VERSION
  35     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  36 endif()
  37
  38 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  39   message(WARNING "Visual Studio generators use the x86 host compiler by "
  40                   "default, even for 64-bit targets. This can result in linker "
  41                   "instability and out of memory errors. To use the 64-bit "
  42                   "host compiler, pass -Thost=x64 on the CMake command line.")
  43 endif()
  44
  45 project(LLVM
  46   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  47   LANGUAGES C CXX ASM)
  48
  49 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  50   message(STATUS "No build type selected, default to Debug")
  51   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  52 endif()
  53
  54 # This should only apply if you are both on an Apple host, and targeting Apple.
  55 if(CMAKE_HOST_APPLE AND APPLE)
  56   # if CMAKE_LIBTOOL is not set, try and find it with xcrun or find_program
  57   if(NOT CMAKE_LIBTOOL)
  58     if(NOT CMAKE_XCRUN)
  59       find_program(CMAKE_XCRUN NAMES xcrun)
  60     endif()
  61     if(CMAKE_XCRUN)
  62       execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  63         OUTPUT_VARIABLE CMAKE_LIBTOOL
  64         OUTPUT_STRIP_TRAILING_WHITESPACE)
  65     endif()
  66
  67     if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  68       find_program(CMAKE_LIBTOOL NAMES libtool)
  69     endif()
  70   endif()
  71
  72   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  73   if(CMAKE_LIBTOOL)
  74     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  75     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  76
  77     execute_process(COMMAND ${CMAKE_LIBTOOL} -V
  78       OUTPUT_VARIABLE LIBTOOL_V_OUTPUT
  79       OUTPUT_STRIP_TRAILING_WHITESPACE)
  80     if("${LIBTOOL_V_OUTPUT}" MATCHES ".*cctools-([0-9.]+).*")
  81       string(REGEX REPLACE ".*cctools-([0-9.]+).*" "\\1" LIBTOOL_VERSION
  82         ${LIBTOOL_V_OUTPUT})
  83       if(NOT LIBTOOL_VERSION VERSION_LESS "862")
  84         set(LIBTOOL_NO_WARNING_FLAG "-no_warning_for_no_symbols")
  85       endif()
  86     endif()
  87
  88     foreach(lang ${languages})
  89       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  90         "${CMAKE_LIBTOOL} -static ${LIBTOOL_NO_WARNING_FLAG} -o <TARGET> \
  91         <LINK_FLAGS> <OBJECTS> ")
  92     endforeach()
  93   endif()
  94
  95   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
  96   if(DYLD_LIBRARY_PATH)
  97     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
  98     foreach(lang ${languages})
  99       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
 100         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
 101              "${dyld_envar} ${cmd}")
 102       endforeach()
 103       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
 104         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
 105     endforeach()
 106   endif()
 107 endif()
 108
 109 # Side-by-side subprojects layout: automatically set the
 110 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 111 # This allows an easy way of setting up a build directory for llvm and another
 112 # one for llvm+clang+... using the same sources.
 113 set(LLVM_ALL_PROJECTS "clang;libcxx;libcxxabi;lldb;compiler-rt;lld;polly")
 114 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 115         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
 116 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 117   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 118 endif()
 119 foreach(proj ${LLVM_ENABLE_PROJECTS})
 120   set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 121   if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 122     message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 123   endif()
 124   string(TOUPPER "${proj}" upper_proj)
 125   STRING(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 126   set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR   "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 127   # There is a widely spread opinion that clang-tools-extra should be merged
 128   # into clang. The following simulates it by always enabling clang-tools-extra
 129   # when enabling clang.
 130   if (proj STREQUAL "clang")
 131     set(LLVM_EXTERNAL_CLANG_TOOLS_EXTRA_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../clang-tools-extra")
 132   endif()
 133 endforeach()
 134
 135 # Build llvm with ccache if the package is present
 136 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 137 if(LLVM_CCACHE_BUILD)
 138   find_program(CCACHE_PROGRAM ccache)
 139   if(CCACHE_PROGRAM)
 140       set(LLVM_CCACHE_SIZE "" CACHE STRING "Size of ccache")
 141       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 142       set(CCACHE_PROGRAM "CCACHE_CPP2=yes CCACHE_HASHDIR=yes ${CCACHE_PROGRAM}")
 143       if (LLVM_CCACHE_SIZE)
 144         set(CCACHE_PROGRAM "CCACHE_SIZE=${LLVM_CCACHE_SIZE} ${CCACHE_PROGRAM}")
 145       endif()
 146       if (LLVM_CCACHE_DIR)
 147         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 148       endif()
 149       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 150   else()
 151     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 152   endif()
 153 endif()
 154
 155 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 156
 157 # Some features of the LLVM build may be disallowed when dependency debugging is
 158 # enabled. In particular you cannot use ccache because we want to force compile
 159 # operations to always happen.
 160 if(LLVM_DEPENDENCY_DEBUGGING)
 161   if(NOT CMAKE_HOST_APPLE)
 162     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 163   endif()
 164   if(LLVM_CCACHE_BUILD)
 165     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 166   endif()
 167 endif()
 168
 169 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 170 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 171 if(LLVM_ENABLE_GISEL_COV)
 172   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 173 endif()
 174
 175 # Add path for custom modules
 176 set(CMAKE_MODULE_PATH
 177   ${CMAKE_MODULE_PATH}
 178   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 179   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 180   )
 181
 182 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 183 # for use by clang_complete, YouCompleteMe, etc.
 184 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 185
 186 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 187   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 188
 189 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 190
 191 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 192
 193 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 194 if ( LLVM_USE_FOLDERS )
 195   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 196 endif()
 197
 198 include(VersionFromVCS)
 199
 200 option(LLVM_APPEND_VC_REV
 201   "Embed the version control system revision id in LLVM" ON)
 202
 203 set(PACKAGE_NAME LLVM)
 204 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 205 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
 206
 207 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 208   "Default URL where bug reports are to be submitted.")
 209
 210 # Configure CPack.
 211 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 212 set(CPACK_PACKAGE_VENDOR "LLVM")
 213 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 214 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 215 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 216 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 217 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 218 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 219 if(WIN32 AND NOT UNIX)
 220   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 221   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 222   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 223   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 224   set(CPACK_NSIS_MODIFY_PATH "ON")
 225   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 226   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 227     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 228   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 229     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 230   if( CMAKE_CL_64 )
 231     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 232   endif()
 233 endif()
 234 include(CPack)
 235
 236 # Sanity check our source directory to make sure that we are not trying to
 237 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 238 # sure that we don't have any stray generated files lying around in the tree
 239 # (which would end up getting picked up by header search, instead of the correct
 240 # versions).
 241 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 242   message(FATAL_ERROR "In-source builds are not allowed.
 243 CMake would overwrite the makefiles distributed with LLVM.
 244 Please create a directory and run cmake from there, passing the path
 245 to this source directory as the last argument.
 246 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 247 Please delete them.")
 248 endif()
 249 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 250   file(GLOB_RECURSE
 251     tablegenned_files_on_include_dir
 252     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 253   file(GLOB_RECURSE
 254     tablegenned_files_on_lib_dir
 255     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 256   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 257     message(FATAL_ERROR "Apparently there is a previous in-source build,
 258 probably as the result of running `configure' and `make' on
 259 ${CMAKE_CURRENT_SOURCE_DIR}.
 260 This may cause problems. The suspicious files are:
 261 ${tablegenned_files_on_lib_dir}
 262 ${tablegenned_files_on_include_dir}
 263 Please clean the source directory.")
 264   endif()
 265 endif()
 266
 267 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 268
 269 if (CMAKE_BUILD_TYPE AND
 270     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 271   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 272 endif()
 273
 274 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 275
 276 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 277 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 278
 279 set(LLVM_UTILS_INSTALL_DIR "bin" CACHE STRING
 280     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 281 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 282
 283 # They are used as destination of target generators.
 284 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 285 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 286 if(WIN32 OR CYGWIN)
 287   # DLL platform -- put DLLs into bin.
 288   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 289 else()
 290   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 291 endif()
 292
 293 # Each of them corresponds to llvm-config's.
 294 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 295 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 296 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 297 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 298 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 299
 300 # Note: LLVM_CMAKE_PATH does not include generated files
 301 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 302 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 303 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 304
 305 # List of all targets to be built by default:
 306 set(LLVM_ALL_TARGETS
 307   AArch64
 308   AMDGPU
 309   ARM
 310   BPF
 311   Hexagon
 312   Lanai
 313   Mips
 314   MSP430
 315   NVPTX
 316   PowerPC
 317   Sparc
 318   SystemZ
 319   X86
 320   XCore
 321   )
 322
 323 # List of targets with JIT support:
 324 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 325
 326 set(LLVM_TARGETS_TO_BUILD "all"
 327     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 328
 329 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 330   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 331
 332 option(BUILD_SHARED_LIBS
 333   "Build all libraries as shared libraries instead of static" OFF)
 334
 335 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 336 if(LLVM_ENABLE_BACKTRACES)
 337   set(ENABLE_BACKTRACES 1)
 338 endif()
 339
 340 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 341 if(LLVM_ENABLE_CRASH_OVERRIDES)
 342   set(ENABLE_CRASH_OVERRIDES 1)
 343 endif()
 344
 345 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 346 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 347 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 348
 349 set(LLVM_TARGET_ARCH "host"
 350   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 351
 352 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 353
 354 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 355
 356 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 357
 358 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 359
 360 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 361
 362 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 363   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 364 endif()
 365
 366 set(LLVM_TARGETS_TO_BUILD
 367    ${LLVM_TARGETS_TO_BUILD}
 368    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 369 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 370
 371 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 372 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 373 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 374 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 375   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 376   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 377 else()
 378   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 379   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 380 endif()
 381 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 382 option(LLVM_ENABLE_CXX1Z "Compile with C++1z enabled." OFF)
 383 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 384 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 385 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 386 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 387
 388 option(LLVM_ENABLE_DUMP "Enable dump functions in release builds" OFF)
 389
 390 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 391   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 392 else()
 393   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 394 endif()
 395
 396 if( LLVM_ENABLE_ASSERTIONS )
 397   set(LLVM_ENABLE_DUMP ON)
 398 endif()
 399
 400 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 401
 402 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 403   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 404
 405 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 406        "Set to ON to force using an old, unsupported host toolchain." OFF)
 407
 408 option(LLVM_USE_INTEL_JITEVENTS
 409   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 410   OFF)
 411
 412 if( LLVM_USE_INTEL_JITEVENTS )
 413   # Verify we are on a supported platform
 414   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 415     message(FATAL_ERROR
 416       "Intel JIT API support is available on Linux and Windows only.")
 417   endif()
 418 endif( LLVM_USE_INTEL_JITEVENTS )
 419
 420 option(LLVM_USE_OPROFILE
 421   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 422
 423 option(LLVM_EXTERNALIZE_DEBUGINFO
 424   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 425
 426 # If enabled, verify we are on a platform that supports oprofile.
 427 if( LLVM_USE_OPROFILE )
 428   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 429     message(FATAL_ERROR "OProfile support is available on Linux only.")
 430   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 431 endif( LLVM_USE_OPROFILE )
 432
 433 set(LLVM_USE_SANITIZER "" CACHE STRING
 434   "Define the sanitizer used to build binaries and tests.")
 435 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 436   "Path to fuzzing library for linking with fuzz targets")
 437
 438 option(LLVM_USE_SPLIT_DWARF
 439   "Use -gsplit-dwarf when compiling llvm." OFF)
 440
 441 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 442 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 443
 444 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 445   set(POLLY_IN_TREE TRUE)
 446 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 447   set(POLLY_IN_TREE TRUE)
 448 else()
 449   set(POLLY_IN_TREE FALSE)
 450 endif()
 451
 452 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 453   set(WITH_POLLY ON)
 454 else()
 455   set(WITH_POLLY OFF)
 456 endif()
 457
 458 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 459   set(LINK_POLLY_INTO_TOOLS ON)
 460 else()
 461   set(LINK_POLLY_INTO_TOOLS OFF)
 462 endif()
 463
 464 # Define an option controlling whether we should build for 32-bit on 64-bit
 465 # platforms, where supported.
 466 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 467   # TODO: support other platforms and toolchains.
 468   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 469 endif()
 470
 471 # Define the default arguments to use with 'lit', and an option for the user to
 472 # override.
 473 set(LIT_ARGS_DEFAULT "-sv")
 474 if (MSVC_IDE OR XCODE)
 475   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 476 endif()
 477 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 478
 479 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 480 if( WIN32 AND NOT CYGWIN )
 481   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 482 endif()
 483
 484 # Define options to control the inclusion and default build behavior for
 485 # components which may not strictly be necessary (tools, examples, and tests).
 486 #
 487 # This is primarily to support building smaller or faster project files.
 488 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 489 option(LLVM_BUILD_TOOLS
 490   "Build the LLVM tools. If OFF, just generate build targets." ON)
 491
 492 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 493 option(LLVM_BUILD_UTILS
 494   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 495
 496 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 497 option(LLVM_BUILD_RUNTIMES
 498   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 499
 500 option(LLVM_BUILD_RUNTIME
 501   "Build the LLVM runtime libraries." ON)
 502 option(LLVM_BUILD_EXAMPLES
 503   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 504 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 505
 506 option(LLVM_BUILD_TESTS
 507   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 508 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 509 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 510
 511 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 512 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 513 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 514 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 515 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 516
 517 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 518     CACHE STRING "Doxygen-generated HTML documentation install directory")
 519 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 520     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 521
 522 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 523   "Build compiler-rt as an external project." OFF)
 524
 525 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 526   "Show target and host info when tools are invoked with --version." ON)
 527
 528 # You can configure which libraries from LLVM you want to include in the
 529 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 530 # list of LLVM components. All component names handled by llvm-config are valid.
 531 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 532   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 533     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 534 endif()
 535 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 536 option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin Only)" OFF)
 537 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 538 if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
 539   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 540 endif()
 541 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 542
 543 option(LLVM_DYLIB_SYMBOL_VERSIONING OFF)
 544
 545 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 546 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 547   set(LLVM_USE_HOST_TOOLS ON)
 548 endif()
 549
 550 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 551   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 552 else()
 553   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 554 endif()
 555
 556 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 557     LLVM_ENABLE_IR_PGO)
 558   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 559     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 560     # for spining disks. Anything higher may only help on slower mediums.
 561     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 562   endif()
 563   if(NOT LLVM_PROFILE_FILE_PATTERN)
 564     if(NOT LLVM_PROFILE_DATA_DIR)
 565       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 566     endif()
 567                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 568   endif()
 569 endif()
 570
 571 if (LLVM_BUILD_STATIC)
 572   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 573 endif()
 574
 575 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 576 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 577 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 578
 579 # All options referred to from HandleLLVMOptions have to be specified
 580 # BEFORE this include, otherwise options will not be correctly set on
 581 # first cmake run
 582 include(config-ix)
 583
 584 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 585   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 586 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 587
 588 # By default, we target the host, but this can be overridden at CMake
 589 # invocation time.
 590 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 591   "Default target for which LLVM will generate code." )
 592 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 593 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 594 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 595
 596 include(HandleLLVMOptions)
 597
 598 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 599 # FIXME: We should support systems with only Python 3, but that requires work
 600 # on LLDB.
 601 set(Python_ADDITIONAL_VERSIONS 2.7)
 602 include(FindPythonInterp)
 603 if( NOT PYTHONINTERP_FOUND )
 604   message(FATAL_ERROR
 605 "Unable to find Python interpreter, required for builds and testing.
 606
 607 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 608 endif()
 609
 610 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 611   message(FATAL_ERROR "Python 2.7 or newer is required")
 612 endif()
 613
 614 ######
 615 # LLVMBuild Integration
 616 #
 617 # We use llvm-build to generate all the data required by the CMake based
 618 # build system in one swoop:
 619 #
 620 #  - We generate a file (a CMake fragment) in the object root which contains
 621 #    all the definitions that are required by CMake.
 622 #
 623 #  - We generate the library table used by llvm-config.
 624 #
 625 #  - We generate the dependencies for the CMake fragment, so that we will
 626 #    automatically reconfigure outselves.
 627
 628 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 629 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 630   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 631 set(LLVMBUILDCMAKEFRAG
 632   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 633
 634 # Create the list of optional components that are enabled
 635 if (LLVM_USE_INTEL_JITEVENTS)
 636   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 637 endif (LLVM_USE_INTEL_JITEVENTS)
 638 if (LLVM_USE_OPROFILE)
 639   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 640 endif (LLVM_USE_OPROFILE)
 641
 642 message(STATUS "Constructing LLVMBuild project information")
 643 execute_process(
 644   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 645             --native-target "${LLVM_NATIVE_ARCH}"
 646             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 647             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 648             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 649             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 650             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 651             ERROR_VARIABLE LLVMBUILDERRORS
 652             OUTPUT_STRIP_TRAILING_WHITESPACE
 653             ERROR_STRIP_TRAILING_WHITESPACE
 654   RESULT_VARIABLE LLVMBUILDRESULT)
 655
 656 # On Win32, CMake doesn't properly handle piping the default output/error
 657 # streams into the GUI console. So, we explicitly catch and report them.
 658 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 659   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 660 endif()
 661 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 662   message(FATAL_ERROR
 663     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 664 endif()
 665
 666 # Include the generated CMake fragment. This will define properties from the
 667 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 668 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 669 # files change.
 670 include(${LLVMBUILDCMAKEFRAG})
 671
 672 ######
 673
 674 # Configure all of the various header file fragments LLVM uses which depend on
 675 # configuration variables.
 676 set(LLVM_ENUM_TARGETS "")
 677 set(LLVM_ENUM_ASM_PRINTERS "")
 678 set(LLVM_ENUM_ASM_PARSERS "")
 679 set(LLVM_ENUM_DISASSEMBLERS "")
 680 foreach(t ${LLVM_TARGETS_TO_BUILD})
 681   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 682
 683   list(FIND LLVM_ALL_TARGETS ${t} idx)
 684   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 685   if( idx LESS 0 AND idy LESS 0 )
 686     message(FATAL_ERROR "The target `${t}' does not exist.
 687     It should be one of\n${LLVM_ALL_TARGETS}")
 688   else()
 689     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 690   endif()
 691
 692   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 693   if( asmp_file )
 694     set(LLVM_ENUM_ASM_PRINTERS
 695       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 696   endif()
 697   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 698     set(LLVM_ENUM_ASM_PARSERS
 699       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 700   endif()
 701   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 702     set(LLVM_ENUM_DISASSEMBLERS
 703       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 704   endif()
 705 endforeach(t)
 706
 707 # Produce the target definition files, which provide a way for clients to easily
 708 # include various classes of targets.
 709 configure_file(
 710   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 711   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 712   )
 713 configure_file(
 714   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 715   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 716   )
 717 configure_file(
 718   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 719   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 720   )
 721 configure_file(
 722   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 723   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 724   )
 725
 726 # Configure the three LLVM configuration header files.
 727 configure_file(
 728   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 729   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 730 configure_file(
 731   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 732   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 733 configure_file(
 734   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 735   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 736 configure_file(
 737   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 738   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 739
 740 # Add target for generating source rpm package.
 741 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 742     CACHE FILEPATH ".spec file to use for srpm generation")
 743 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 744 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 745
 746 # SVN_REVISION and GIT_COMMIT get set by the call to add_version_info_from_vcs.
 747 # DUMMY_VAR contains a version string which we don't care about.
 748 add_version_info_from_vcs(DUMMY_VAR)
 749 if ( SVN_REVISION )
 750   set(LLVM_RPM_SPEC_REVISION "r${SVN_REVISION}")
 751 elseif ( GIT_COMMIT )
 752   set (LLVM_RPM_SPEC_REVISION "g${GIT_COMMIT}")
 753 endif()
 754
 755 configure_file(
 756   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 757   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 758
 759 add_custom_target(srpm
 760   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 761   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 762 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 763
 764
 765 # They are not referenced. See set_output_directory().
 766 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 767 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 768 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 769
 770 if(APPLE AND DARWIN_LTO_LIBRARY)
 771   set(CMAKE_EXE_LINKER_FLAGS
 772     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 773   set(CMAKE_SHARED_LINKER_FLAGS
 774     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 775   set(CMAKE_MODULE_LINKER_FLAGS
 776     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 777 endif()
 778
 779 # Work around a broken bfd ld behavior. When linking a binary with a
 780 # foo.so library, it will try to find any library that foo.so uses and
 781 # check its symbols. This is wasteful (the check was done when foo.so
 782 # was created) and can fail since it is not the dynamic linker and
 783 # doesn't know how to handle search paths correctly.
 784 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 785   set(CMAKE_EXE_LINKER_FLAGS
 786       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 787 endif()
 788
 789 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 790
 791 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 792
 793 # when crosscompiling import the executable targets from a file
 794 if(LLVM_USE_HOST_TOOLS)
 795   include(CrossCompile)
 796 endif(LLVM_USE_HOST_TOOLS)
 797 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 798 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 799 # (this is a variable that CrossCompile sets on recursive invocations)
 800 endif()
 801
 802 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 803   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 804   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 805   include_directories(SYSTEM "/usr/local/include")
 806   link_directories("/usr/local/lib")
 807 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 808
 809 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 810    # special hack for Solaris to handle crazy system sys/regset.h
 811    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 812 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 813
 814 # Make sure we don't get -rdynamic in every binary. For those that need it,
 815 # use export_executable_symbols(target).
 816 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 817
 818 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 819   "Profiling data file to use when compiling in order to improve runtime performance.")
 820
 821 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 822   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 823     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 824   else()
 825     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 826   endif()
 827 endif()
 828
 829 include(AddLLVM)
 830 include(TableGen)
 831
 832 if( MINGW )
 833   # People report that -O3 is unreliable on MinGW. The traditional
 834   # build also uses -O2 for that reason:
 835   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 836 endif()
 837
 838 # Put this before tblgen. Else we have a circular dependence.
 839 add_subdirectory(lib/Demangle)
 840 add_subdirectory(lib/Support)
 841 add_subdirectory(lib/TableGen)
 842
 843 add_subdirectory(utils/TableGen)
 844
 845 add_subdirectory(include/llvm)
 846
 847 add_subdirectory(lib)
 848
 849 if( LLVM_INCLUDE_UTILS )
 850   add_subdirectory(utils/FileCheck)
 851   add_subdirectory(utils/PerfectShuffle)
 852   add_subdirectory(utils/count)
 853   add_subdirectory(utils/not)
 854   add_subdirectory(utils/yaml-bench)
 855 else()
 856   if ( LLVM_INCLUDE_TESTS )
 857     message(FATAL_ERROR "Including tests when not building utils will not work.
 858     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 859   endif()
 860 endif()
 861
 862 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 863 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 864   add_subdirectory(utils/LLVMVisualizers)
 865 endif()
 866
 867 foreach( binding ${LLVM_BINDINGS_LIST} )
 868   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 869     add_subdirectory(bindings/${binding})
 870   endif()
 871 endforeach()
 872
 873 add_subdirectory(projects)
 874
 875 if( LLVM_INCLUDE_TOOLS )
 876   add_subdirectory(tools)
 877 endif()
 878
 879 if( LLVM_INCLUDE_RUNTIMES )
 880   add_subdirectory(runtimes)
 881 endif()
 882
 883 if( LLVM_INCLUDE_EXAMPLES )
 884   add_subdirectory(examples)
 885 endif()
 886
 887 if( LLVM_INCLUDE_TESTS )
 888   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 889     include(LLVMExternalProjectUtils)
 890     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 891       USE_TOOLCHAIN
 892       EXCLUDE_FROM_ALL
 893       NO_INSTALL
 894       ALWAYS_CLEAN)
 895   endif()
 896   add_subdirectory(utils/lit)
 897   add_subdirectory(test)
 898   add_subdirectory(unittests)
 899   if( LLVM_INCLUDE_UTILS )
 900     add_subdirectory(utils/unittest)
 901   endif()
 902
 903   if (WIN32)
 904     # This utility is used to prevent crashing tests from calling Dr. Watson on
 905     # Windows.
 906     add_subdirectory(utils/KillTheDoctor)
 907   endif()
 908
 909   # Add a global check rule now that all subdirectories have been traversed
 910   # and we know the total set of lit testsuites.
 911   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 912   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 913   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 914   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 915   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 916                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 917   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 918                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 919   add_lit_target(check-all
 920     "Running all regression tests"
 921     ${LLVM_LIT_TESTSUITES}
 922     PARAMS ${LLVM_LIT_PARAMS}
 923     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 924     ARGS ${LLVM_LIT_EXTRA_ARGS}
 925     )
 926   if(TARGET check-runtimes)
 927     add_dependencies(check-all check-runtimes)
 928   endif()
 929   add_custom_target(test-depends
 930                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 931   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 932 endif()
 933
 934 if (LLVM_INCLUDE_DOCS)
 935   add_subdirectory(docs)
 936 endif()
 937
 938 add_subdirectory(cmake/modules)
 939
 940 # Do this last so that all lit targets have already been created.
 941 if (LLVM_INCLUDE_UTILS)
 942   add_subdirectory(utils/llvm-lit)
 943 endif()
 944
 945 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 946   install(DIRECTORY include/llvm include/llvm-c
 947     DESTINATION include
 948     COMPONENT llvm-headers
 949     FILES_MATCHING
 950     PATTERN "*.def"
 951     PATTERN "*.h"
 952     PATTERN "*.td"
 953     PATTERN "*.inc"
 954     PATTERN "LICENSE.TXT"
 955     PATTERN ".svn" EXCLUDE
 956     )
 957
 958   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 959     DESTINATION include
 960     COMPONENT llvm-headers
 961     FILES_MATCHING
 962     PATTERN "*.def"
 963     PATTERN "*.h"
 964     PATTERN "*.gen"
 965     PATTERN "*.inc"
 966     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 967     PATTERN "CMakeFiles" EXCLUDE
 968     PATTERN "config.h" EXCLUDE
 969     PATTERN ".svn" EXCLUDE
 970     )
 971
 972   # Installing the headers needs to depend on generating any public
 973   # tablegen'd headers.
 974   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
 975   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
 976
 977   if (NOT CMAKE_CONFIGURATION_TYPES)
 978     add_custom_target(install-llvm-headers
 979                       DEPENDS llvm-headers
 980                       COMMAND "${CMAKE_COMMAND}"
 981                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 982                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 983   endif()
 984 endif()
 985
 986 # This must be at the end of the LLVM root CMakeLists file because it must run
 987 # after all targets are created.
 988 if(LLVM_DISTRIBUTION_COMPONENTS)
 989   if(CMAKE_CONFIGURATION_TYPES)
 990     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
 991   endif()
 992
 993   add_custom_target(distribution)
 994   add_custom_target(install-distribution)
 995   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS})
 996     if(TARGET ${target})
 997       add_dependencies(distribution ${target})
 998     else()
 999       message(SEND_ERROR "Specified distribution component '${target}' doesn't have a target")
1000     endif()
1001
1002     if(TARGET install-${target})
1003       add_dependencies(install-distribution install-${target})
1004     else()
1005       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install target")
1006     endif()
1007   endforeach()
1008 endif()
1009
1010 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1011 if (MSVC)
1012   include(InstallRequiredSystemLibraries)
1013 endif()
1014