lib/AsmParser/Lexer.l.cvs

   1 /*===-- Lexer.l - Scanner for llvm assembly files --------------*- C++ -*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 //  This file implements the flex scanner for LLVM assembly languages files.
  11 //
  12 //===----------------------------------------------------------------------===*/
  13
  14 %option prefix="llvmAsm"
  15 %option yylineno
  16 %option nostdinit
  17 %option never-interactive
  18 %option batch
  19 %option noyywrap
  20 %option nodefault
  21 %option 8bit
  22 %option outfile="Lexer.cpp"
  23 %option ecs
  24 %option noreject
  25 %option noyymore
  26
  27 %{
  28 #include "ParserInternals.h"
  29 #include "llvm/Module.h"
  30 #include <list>
  31 #include "llvmAsmParser.h"
  32 #include <cctype>
  33 #include <cstdlib>
  34
  35 void set_scan_file(FILE * F){
  36   yy_switch_to_buffer(yy_create_buffer( F, YY_BUF_SIZE ) );
  37 }
  38 void set_scan_string (const char * str) {
  39   yy_scan_string (str);
  40 }
  41
  42 #define RET_TOK(type, Enum, sym) \
  43   llvmAsmlval.type = Instruction::Enum; return sym
  44
  45 namespace llvm {
  46
  47 // TODO: All of the static identifiers are figured out by the lexer,
  48 // these should be hashed to reduce the lexer size
  49
  50
  51 // atoull - Convert an ascii string of decimal digits into the unsigned long
  52 // long representation... this does not have to do input error checking,
  53 // because we know that the input will be matched by a suitable regex...
  54 //
  55 static uint64_t atoull(const char *Buffer) {
  56   uint64_t Result = 0;
  57   for (; *Buffer; Buffer++) {
  58     uint64_t OldRes = Result;
  59     Result *= 10;
  60     Result += *Buffer-'0';
  61     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  62       ThrowException("constant bigger than 64 bits detected!");
  63   }
  64   return Result;
  65 }
  66
  67 static uint64_t HexIntToVal(const char *Buffer) {
  68   uint64_t Result = 0;
  69   for (; *Buffer; ++Buffer) {
  70     uint64_t OldRes = Result;
  71     Result *= 16;
  72     char C = *Buffer;
  73     if (C >= '0' && C <= '9')
  74       Result += C-'0';
  75     else if (C >= 'A' && C <= 'F')
  76       Result += C-'A'+10;
  77     else if (C >= 'a' && C <= 'f')
  78       Result += C-'a'+10;
  79
  80     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  81       ThrowException("constant bigger than 64 bits detected!");
  82   }
  83   return Result;
  84 }
  85
  86
  87 // HexToFP - Convert the ascii string in hexidecimal format to the floating
  88 // point representation of it.
  89 //
  90 static double HexToFP(const char *Buffer) {
  91   // Behave nicely in the face of C TBAA rules... see:
  92   // http://www.nullstone.com/htmls/category/aliastyp.htm
  93   union {
  94     uint64_t UI;
  95     double FP;
  96   } UIntToFP;
  97   UIntToFP.UI = HexIntToVal(Buffer);
  98
  99   assert(sizeof(double) == sizeof(uint64_t) &&
 100          "Data sizes incompatible on this target!");
 101   return UIntToFP.FP;   // Cast Hex constant to double
 102 }
 103
 104
 105 // UnEscapeLexed - Run through the specified buffer and change \xx codes to the
 106 // appropriate character.  If AllowNull is set to false, a \00 value will cause
 107 // an exception to be thrown.
 108 //
 109 // If AllowNull is set to true, the return value of the function points to the
 110 // last character of the string in memory.
 111 //
 112 char *UnEscapeLexed(char *Buffer, bool AllowNull) {
 113   char *BOut = Buffer;
 114   for (char *BIn = Buffer; *BIn; ) {
 115     if (BIn[0] == '\\' && isxdigit(BIn[1]) && isxdigit(BIn[2])) {
 116       char Tmp = BIn[3]; BIn[3] = 0;     // Terminate string
 117       *BOut = (char)strtol(BIn+1, 0, 16);  // Convert to number
 118       if (!AllowNull && !*BOut)
 119         ThrowException("String literal cannot accept \\00 escape!");
 120
 121       BIn[3] = Tmp;                  // Restore character
 122       BIn += 3;                      // Skip over handled chars
 123       ++BOut;
 124     } else {
 125       *BOut++ = *BIn++;
 126     }
 127   }
 128
 129   return BOut;
 130 }
 131
 132 } // End llvm namespace
 133
 134 using namespace llvm;
 135
 136 #define YY_NEVER_INTERACTIVE 1
 137 %}
 138
 139
 140
 141 /* Comments start with a ; and go till end of line */
 142 Comment    ;.*
 143
 144 /* Variable(Value) identifiers start with a % sign */
 145 VarID       %[-a-zA-Z$._][-a-zA-Z$._0-9]*
 146
 147 /* Label identifiers end with a colon */
 148 Label       [-a-zA-Z$._0-9]+:
 149 QuoteLabel \"[^\"]+\":
 150
 151 /* Quoted names can contain any character except " and \ */
 152 StringConstant \"[^\"]*\"
 153
 154
 155 /* [PN]Integer: match positive and negative literal integer values that
 156  * are preceeded by a '%' character.  These represent unnamed variable slots.
 157  */
 158 EPInteger     %[0-9]+
 159 ENInteger    %-[0-9]+
 160
 161
 162 /* E[PN]Integer: match positive and negative literal integer values */
 163 PInteger   [0-9]+
 164 NInteger  -[0-9]+
 165
 166 /* FPConstant - A Floating point constant.
 167  */
 168 FPConstant [-+]?[0-9]+[.][0-9]*([eE][-+]?[0-9]+)?
 169
 170 /* HexFPConstant - Floating point constant represented in IEEE format as a
 171  *  hexadecimal number for when exponential notation is not precise enough.
 172  */
 173 HexFPConstant 0x[0-9A-Fa-f]+
 174
 175 /* HexIntConstant - Hexadecimal constant generated by the CFE to avoid forcing
 176  * it to deal with 64 bit numbers.
 177  */
 178 HexIntConstant [us]0x[0-9A-Fa-f]+
 179 %%
 180
 181 {Comment}       { /* Ignore comments for now */ }
 182
 183 begin           { return BEGINTOK; }
 184 end             { return ENDTOK; }
 185 true            { return TRUETOK;  }
 186 false           { return FALSETOK; }
 187 declare         { return DECLARE; }
 188 global          { return GLOBAL; }
 189 constant        { return CONSTANT; }
 190 internal        { return INTERNAL; }
 191 linkonce        { return LINKONCE; }
 192 weak            { return WEAK; }
 193 appending       { return APPENDING; }
 194 uninitialized   { return EXTERNAL; }    /* Deprecated, turn into external */
 195 external        { return EXTERNAL; }
 196 implementation  { return IMPLEMENTATION; }
 197 zeroinitializer { return ZEROINITIALIZER; }
 198 \.\.\.          { return DOTDOTDOT; }
 199 undef           { return UNDEF; }
 200 null            { return NULL_TOK; }
 201 to              { return TO; }
 202 except          { RET_TOK(TermOpVal, Unwind, UNWIND); }
 203 not             { return NOT; }  /* Deprecated, turned into XOR */
 204 tail            { return TAIL; }
 205 target          { return TARGET; }
 206 triple          { return TRIPLE; }
 207 deplibs         { return DEPLIBS; }
 208 endian          { return ENDIAN; }
 209 pointersize     { return POINTERSIZE; }
 210 little          { return LITTLE; }
 211 big             { return BIG; }
 212 volatile        { return VOLATILE; }
 213 align           { return ALIGN;  }
 214 section         { return SECTION; }
 215 module          { return MODULE; }
 216 asm             { return ASM_TOK; }
 217 sideeffect      { return SIDEEFFECT; }
 218
 219 cc              { return CC_TOK; }
 220 ccc             { return CCC_TOK; }
 221 csretcc         { return CSRETCC_TOK; }
 222 fastcc          { return FASTCC_TOK; }
 223 coldcc          { return COLDCC_TOK; }
 224
 225 void            { llvmAsmlval.PrimType = Type::VoidTy  ; return VOID;   }
 226 bool            { llvmAsmlval.PrimType = Type::BoolTy  ; return BOOL;   }
 227 sbyte           { llvmAsmlval.PrimType = Type::SByteTy ; return SBYTE;  }
 228 ubyte           { llvmAsmlval.PrimType = Type::UByteTy ; return UBYTE;  }
 229 short           { llvmAsmlval.PrimType = Type::ShortTy ; return SHORT;  }
 230 ushort          { llvmAsmlval.PrimType = Type::UShortTy; return USHORT; }
 231 int             { llvmAsmlval.PrimType = Type::IntTy   ; return INT;    }
 232 uint            { llvmAsmlval.PrimType = Type::UIntTy  ; return UINT;   }
 233 long            { llvmAsmlval.PrimType = Type::LongTy  ; return LONG;   }
 234 ulong           { llvmAsmlval.PrimType = Type::ULongTy ; return ULONG;  }
 235 float           { llvmAsmlval.PrimType = Type::FloatTy ; return FLOAT;  }
 236 double          { llvmAsmlval.PrimType = Type::DoubleTy; return DOUBLE; }
 237 label           { llvmAsmlval.PrimType = Type::LabelTy ; return LABEL;  }
 238 type            { return TYPE;   }
 239 opaque          { return OPAQUE; }
 240
 241 add             { RET_TOK(BinaryOpVal, Add, ADD); }
 242 sub             { RET_TOK(BinaryOpVal, Sub, SUB); }
 243 mul             { RET_TOK(BinaryOpVal, Mul, MUL); }
 244 div             { RET_TOK(BinaryOpVal, Div, DIV); }
 245 rem             { RET_TOK(BinaryOpVal, Rem, REM); }
 246 and             { RET_TOK(BinaryOpVal, And, AND); }
 247 or              { RET_TOK(BinaryOpVal, Or , OR ); }
 248 xor             { RET_TOK(BinaryOpVal, Xor, XOR); }
 249 setne           { RET_TOK(BinaryOpVal, SetNE, SETNE); }
 250 seteq           { RET_TOK(BinaryOpVal, SetEQ, SETEQ); }
 251 setlt           { RET_TOK(BinaryOpVal, SetLT, SETLT); }
 252 setgt           { RET_TOK(BinaryOpVal, SetGT, SETGT); }
 253 setle           { RET_TOK(BinaryOpVal, SetLE, SETLE); }
 254 setge           { RET_TOK(BinaryOpVal, SetGE, SETGE); }
 255
 256 phi             { RET_TOK(OtherOpVal, PHI, PHI_TOK); }
 257 call            { RET_TOK(OtherOpVal, Call, CALL); }
 258 cast            { RET_TOK(OtherOpVal, Cast, CAST); }
 259 select          { RET_TOK(OtherOpVal, Select, SELECT); }
 260 shl             { RET_TOK(OtherOpVal, Shl, SHL); }
 261 shr             { RET_TOK(OtherOpVal, Shr, SHR); }
 262 vanext          { return VANEXT_old; }
 263 vaarg           { return VAARG_old; }
 264 va_arg          { RET_TOK(OtherOpVal, VAArg , VAARG); }
 265 ret             { RET_TOK(TermOpVal, Ret, RET); }
 266 br              { RET_TOK(TermOpVal, Br, BR); }
 267 switch          { RET_TOK(TermOpVal, Switch, SWITCH); }
 268 invoke          { RET_TOK(TermOpVal, Invoke, INVOKE); }
 269 unwind          { RET_TOK(TermOpVal, Unwind, UNWIND); }
 270 unreachable     { RET_TOK(TermOpVal, Unreachable, UNREACHABLE); }
 271
 272 malloc          { RET_TOK(MemOpVal, Malloc, MALLOC); }
 273 alloca          { RET_TOK(MemOpVal, Alloca, ALLOCA); }
 274 free            { RET_TOK(MemOpVal, Free, FREE); }
 275 load            { RET_TOK(MemOpVal, Load, LOAD); }
 276 store           { RET_TOK(MemOpVal, Store, STORE); }
 277 getelementptr   { RET_TOK(MemOpVal, GetElementPtr, GETELEMENTPTR); }
 278
 279 extractelement  { RET_TOK(OtherOpVal, ExtractElement, EXTRACTELEMENT); }
 280 insertelement   { RET_TOK(OtherOpVal, InsertElement, INSERTELEMENT); }
 281 shufflevector   { RET_TOK(OtherOpVal, ShuffleVector, SHUFFLEVECTOR); }
 282
 283
 284 {VarID}         {
 285                   UnEscapeLexed(yytext+1);
 286                   llvmAsmlval.StrVal = strdup(yytext+1);             // Skip %
 287                   return VAR_ID;
 288                 }
 289 {Label}         {
 290                   yytext[strlen(yytext)-1] = 0;  // nuke colon
 291                   UnEscapeLexed(yytext);
 292                   llvmAsmlval.StrVal = strdup(yytext);
 293                   return LABELSTR;
 294                 }
 295 {QuoteLabel}    {
 296                   yytext[strlen(yytext)-2] = 0;  // nuke colon, end quote
 297                   UnEscapeLexed(yytext+1);
 298                   llvmAsmlval.StrVal = strdup(yytext+1);
 299                   return LABELSTR;
 300                 }
 301
 302 {StringConstant} { // Note that we cannot unescape a string constant here!  The
 303                    // string constant might contain a \00 which would not be
 304                    // understood by the string stuff.  It is valid to make a
 305                    // [sbyte] c"Hello World\00" constant, for example.
 306                    //
 307                    yytext[strlen(yytext)-1] = 0;           // nuke end quote
 308                    llvmAsmlval.StrVal = strdup(yytext+1);  // Nuke start quote
 309                    return STRINGCONSTANT;
 310                  }
 311
 312
 313 {PInteger}      { llvmAsmlval.UInt64Val = atoull(yytext); return EUINT64VAL; }
 314 {NInteger}      {
 315                   uint64_t Val = atoull(yytext+1);
 316                   // +1:  we have bigger negative range
 317                   if (Val > (uint64_t)INT64_MAX+1)
 318                     ThrowException("Constant too large for signed 64 bits!");
 319                   llvmAsmlval.SInt64Val = -Val;
 320                   return ESINT64VAL;
 321                 }
 322 {HexIntConstant} {
 323                    llvmAsmlval.UInt64Val = HexIntToVal(yytext+3);
 324                    return yytext[0] == 's' ? ESINT64VAL : EUINT64VAL;
 325                  }
 326
 327 {EPInteger}     {
 328                   uint64_t Val = atoull(yytext+1);
 329                   if ((unsigned)Val != Val)
 330                     ThrowException("Invalid value number (too large)!");
 331                   llvmAsmlval.UIntVal = unsigned(Val);
 332                   return UINTVAL;
 333                 }
 334 {ENInteger}     {
 335                   uint64_t Val = atoull(yytext+2);
 336                   // +1:  we have bigger negative range
 337                   if (Val > (uint64_t)INT32_MAX+1)
 338                     ThrowException("Constant too large for signed 32 bits!");
 339                   llvmAsmlval.SIntVal = (int)-Val;
 340                   return SINTVAL;
 341                 }
 342
 343 {FPConstant}    { llvmAsmlval.FPVal = atof(yytext); return FPVAL; }
 344 {HexFPConstant} { llvmAsmlval.FPVal = HexToFP(yytext); return FPVAL; }
 345
 346 <<EOF>>         {
 347                   /* Make sure to free the internal buffers for flex when we are
 348                    * done reading our input!
 349                    */
 350                   yy_delete_buffer(YY_CURRENT_BUFFER);
 351                   return EOF;
 352                 }
 353
 354 [ \r\t\n]       { /* Ignore whitespace */ }
 355 .               { return yytext[0]; }
 356
 357 %%
 358