cmake/modules/TableGen.cmake

   1 # LLVM_TARGET_DEFINITIONS must contain the name of the .td file to process.
   2 # Extra parameters for `tblgen' may come after `ofn' parameter.
   3 # Adds the name of the generated file to TABLEGEN_OUTPUT.
   4
   5 include(LLVMExternalProjectUtils)
   6
   7 if(LLVM_MAIN_INCLUDE_DIR)
   8   set(LLVM_TABLEGEN_FLAGS -I ${LLVM_MAIN_INCLUDE_DIR})
   9 endif()
  10
  11 function(tablegen project ofn)
  12   # Validate calling context.
  13   if(NOT ${project}_TABLEGEN_EXE)
  14     message(FATAL_ERROR "${project}_TABLEGEN_EXE not set")
  15   endif()
  16
  17   # Use depfile instead of globbing arbitrary *.td(s)
  18   # DEPFILE is available for Ninja Generator with CMake>=3.7.
  19   if(CMAKE_GENERATOR STREQUAL "Ninja" AND NOT CMAKE_VERSION VERSION_LESS 3.7)
  20     # Make output path relative to build.ninja, assuming located on
  21     # ${CMAKE_BINARY_DIR}.
  22     # CMake emits build targets as relative paths but Ninja doesn't identify
  23     # absolute path (in *.d) as relative path (in build.ninja)
  24     # Note that tblgen is executed on ${CMAKE_BINARY_DIR} as working directory.
  25     file(RELATIVE_PATH ofn_rel
  26       ${CMAKE_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR}/${ofn})
  27     set(additional_cmdline
  28       -o ${ofn_rel}
  29       -d ${ofn_rel}.d
  30       WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
  31       DEPFILE ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.d
  32       )
  33     set(local_tds)
  34     set(global_tds)
  35   else()
  36     file(GLOB local_tds "*.td")
  37     file(GLOB_RECURSE global_tds "${LLVM_MAIN_INCLUDE_DIR}/llvm/*.td")
  38     set(additional_cmdline
  39       -o ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  40       )
  41   endif()
  42
  43   if (IS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  44     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  45   else()
  46     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE
  47       ${CMAKE_CURRENT_SOURCE_DIR}/${LLVM_TARGET_DEFINITIONS})
  48   endif()
  49   if (LLVM_ENABLE_DAGISEL_COV)
  50     list(FIND ARGN "-gen-dag-isel" idx)
  51     if( NOT idx EQUAL -1 )
  52       list(APPEND LLVM_TABLEGEN_FLAGS "-instrument-coverage")
  53     endif()
  54   endif()
  55   if (LLVM_ENABLE_GISEL_COV)
  56     list(FIND ARGN "-gen-global-isel" idx)
  57     if( NOT idx EQUAL -1 )
  58       list(APPEND LLVM_TABLEGEN_FLAGS "-instrument-gisel-coverage")
  59       list(APPEND LLVM_TABLEGEN_FLAGS "-gisel-coverage-file=${LLVM_GISEL_COV_PREFIX}all")
  60     endif()
  61   endif()
  62
  63   # We need both _TABLEGEN_TARGET and _TABLEGEN_EXE in the  DEPENDS list
  64   # (both the target and the file) to have .inc files rebuilt on
  65   # a tablegen change, as cmake does not propagate file-level dependencies
  66   # of custom targets. See the following ticket for more information:
  67   # https://cmake.org/Bug/view.php?id=15858
  68   # The dependency on both, the target and the file, produces the same
  69   # dependency twice in the result file when
  70   # ("${${project}_TABLEGEN_TARGET}" STREQUAL "${${project}_TABLEGEN_EXE}")
  71   # but lets us having smaller and cleaner code here.
  72   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  73     COMMAND ${${project}_TABLEGEN_EXE} ${ARGN} -I ${CMAKE_CURRENT_SOURCE_DIR}
  74     ${LLVM_TABLEGEN_FLAGS}
  75     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  76     ${additional_cmdline}
  77     # The file in LLVM_TARGET_DEFINITIONS may be not in the current
  78     # directory and local_tds may not contain it, so we must
  79     # explicitly list it here:
  80     DEPENDS ${${project}_TABLEGEN_TARGET} ${${project}_TABLEGEN_EXE}
  81       ${local_tds} ${global_tds}
  82     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  83     COMMENT "Building ${ofn}..."
  84     )
  85
  86   # `make clean' must remove all those generated files:
  87   set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${ofn})
  88
  89   set(TABLEGEN_OUTPUT ${TABLEGEN_OUTPUT} ${CMAKE_CURRENT_BINARY_DIR}/${ofn} PARENT_SCOPE)
  90   set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/${ofn} PROPERTIES
  91     GENERATED 1)
  92 endfunction()
  93
  94 # Creates a target for publicly exporting tablegen dependencies.
  95 function(add_public_tablegen_target target)
  96   if(NOT TABLEGEN_OUTPUT)
  97     message(FATAL_ERROR "Requires tablegen() definitions as TABLEGEN_OUTPUT.")
  98   endif()
  99   add_custom_target(${target}
 100     DEPENDS ${TABLEGEN_OUTPUT})
 101   if(LLVM_COMMON_DEPENDS)
 102     add_dependencies(${target} ${LLVM_COMMON_DEPENDS})
 103   endif()
 104   set_target_properties(${target} PROPERTIES FOLDER "Tablegenning")
 105   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${target} PARENT_SCOPE)
 106 endfunction()
 107
 108 macro(add_tablegen target project)
 109   set(${target}_OLD_LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS})
 110   set(LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS} TableGen)
 111
 112   # CMake-3.9 doesn't let compilation units depend on their dependent libraries.
 113   if(NOT (CMAKE_GENERATOR STREQUAL "Ninja" AND NOT CMAKE_VERSION VERSION_LESS 3.9) AND NOT XCODE)
 114     # FIXME: It leaks to user, callee of add_tablegen.
 115     set(LLVM_ENABLE_OBJLIB ON)
 116   endif()
 117
 118   add_llvm_executable(${target} DISABLE_LLVM_LINK_LLVM_DYLIB ${ARGN})
 119   set(LLVM_LINK_COMPONENTS ${${target}_OLD_LLVM_LINK_COMPONENTS})
 120
 121   set(${project}_TABLEGEN "${target}" CACHE
 122       STRING "Native TableGen executable. Saves building one when cross-compiling.")
 123
 124   # Upgrade existing LLVM_TABLEGEN setting.
 125   if(${project} STREQUAL LLVM)
 126     if(${LLVM_TABLEGEN} STREQUAL tblgen)
 127       set(LLVM_TABLEGEN "${target}" CACHE
 128           STRING "Native TableGen executable. Saves building one when cross-compiling."
 129           FORCE)
 130     endif()
 131   endif()
 132
 133   # Effective tblgen executable to be used:
 134   set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN} PARENT_SCOPE)
 135   set(${project}_TABLEGEN_TARGET ${${project}_TABLEGEN} PARENT_SCOPE)
 136
 137   if(LLVM_USE_HOST_TOOLS)
 138     if( ${${project}_TABLEGEN} STREQUAL "${target}" )
 139       if (NOT CMAKE_CONFIGURATION_TYPES)
 140         set(${project}_TABLEGEN_EXE "${LLVM_NATIVE_BUILD}/bin/${target}")
 141       else()
 142         set(${project}_TABLEGEN_EXE "${LLVM_NATIVE_BUILD}/Release/bin/${target}")
 143       endif()
 144       set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN_EXE} PARENT_SCOPE)
 145
 146       llvm_ExternalProject_BuildCmd(tblgen_build_cmd ${target}
 147                                     ${LLVM_NATIVE_BUILD}
 148                                     CONFIGURATION Release)
 149       # Create an artificial dependency between tablegen projects, because they
 150       # compile the same dependencies, thus using the same build folders.
 151       # FIXME: A proper fix requires sequentially chaining tablegens.
 152       if (NOT ${project} STREQUAL LLVM AND TARGET ${project}-tablegen-host)
 153         add_dependencies(${project}-tablegen-host LLVM-tablegen-host)
 154       endif()
 155       add_custom_command(OUTPUT ${${project}_TABLEGEN_EXE}
 156         COMMAND ${tblgen_build_cmd}
 157         DEPENDS CONFIGURE_LLVM_NATIVE ${target}
 158         WORKING_DIRECTORY ${LLVM_NATIVE_BUILD}
 159         COMMENT "Building native TableGen..."
 160         USES_TERMINAL)
 161       add_custom_target(${project}-tablegen-host DEPENDS ${${project}_TABLEGEN_EXE})
 162       set(${project}_TABLEGEN_TARGET ${project}-tablegen-host PARENT_SCOPE)
 163     endif()
 164   endif()
 165
 166   if (${project} STREQUAL LLVM AND NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 167     if(${target} IN_LIST LLVM_DISTRIBUTION_COMPONENTS OR
 168         NOT LLVM_DISTRIBUTION_COMPONENTS)
 169       set(export_to_llvmexports EXPORT LLVMExports)
 170     endif()
 171
 172     install(TARGETS ${target}
 173             ${export_to_llvmexports}
 174             RUNTIME DESTINATION ${LLVM_TOOLS_INSTALL_DIR})
 175   endif()
 176   set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${target})
 177 endmacro()