test/Transforms/Coroutines/coro-split-eh.ll

   1 ; Tests that coro-split removes cleanup code after coro.end in resume functions
   2 ; and retains it in the start function.
   3 ; RUN: opt < %s -coro-split -S | FileCheck %s
   4
   5 define i8* @f(i1 %val) "coroutine.presplit"="1" personality i32 3 {
   6 entry:
   7   %id = call token @llvm.coro.id(i32 0, i8* null, i8* null, i8* null)
   8   %hdl = call i8* @llvm.coro.begin(token %id, i8* null)
   9   call void @print(i32 0)
  10   br i1 %val, label %resume, label %susp
  11
  12 susp:
  13   %0 = call i8 @llvm.coro.suspend(token none, i1 false)
  14   switch i8 %0, label %suspend [i8 0, label %resume
  15                                 i8 1, label %suspend]
  16 resume:
  17   invoke void @print(i32 1) to label %suspend unwind label %lpad
  18
  19 suspend:
  20   call i1 @llvm.coro.end(i8* %hdl, i1 0)
  21   call void @print(i32 0) ; should not be present in f.resume
  22   ret i8* %hdl
  23
  24 lpad:
  25   %lpval = landingpad { i8*, i32 }
  26      cleanup
  27
  28   call void @print(i32 2)
  29   %need.resume = call i1 @llvm.coro.end(i8* null, i1 true)
  30   br i1 %need.resume, label %eh.resume, label %cleanup.cont
  31
  32 cleanup.cont:
  33   call void @print(i32 3) ; should not be present in f.resume
  34   br label %eh.resume
  35
  36 eh.resume:
  37   resume { i8*, i32 } %lpval
  38 }
  39
  40 ; Verify that start function contains both print calls the one before and after coro.end
  41 ; CHECK-LABEL: define i8* @f(
  42 ; CHECK: invoke void @print(i32 1)
  43 ; CHECK:   to label %AfterCoroEnd unwind label %lpad
  44
  45 ; CHECK: AfterCoroEnd:
  46 ; CHECK:   call void @print(i32 0)
  47 ; CHECK:   ret i8* %hdl
  48
  49 ; CHECK:         lpad:
  50 ; CHECK-NEXT:      %lpval = landingpad { i8*, i32 }
  51 ; CHECK-NEXT:         cleanup
  52 ; CHECK-NEXT:      call void @print(i32 2)
  53 ; CHECK-NEXT:      call void @print(i32 3)
  54 ; CHECK-NEXT:      resume { i8*, i32 } %lpval
  55
  56 define i8* @f2(i1 %val) "coroutine.presplit"="1" personality i32 4 {
  57 entry:
  58   %id = call token @llvm.coro.id(i32 0, i8* null, i8* null, i8* null)
  59   %hdl = call i8* @llvm.coro.begin(token %id, i8* null)
  60   call void @print(i32 0)
  61   br i1 %val, label %resume, label %susp
  62
  63 susp:
  64   %0 = call i8 @llvm.coro.suspend(token none, i1 false)
  65   switch i8 %0, label %suspend [i8 0, label %resume
  66                                 i8 1, label %suspend]
  67 resume:
  68   invoke void @print(i32 1) to label %suspend unwind label %lpad
  69
  70 suspend:
  71   call i1 @llvm.coro.end(i8* %hdl, i1 0)
  72   call void @print(i32 0) ; should not be present in f.resume
  73   ret i8* %hdl
  74
  75 lpad:
  76   %tok = cleanuppad within none []
  77   call void @print(i32 2)
  78   %unused = call i1 @llvm.coro.end(i8* null, i1 true) [ "funclet"(token %tok) ]
  79   cleanupret from %tok unwind label %cleanup.cont
  80
  81 cleanup.cont:
  82   %tok2 = cleanuppad within none []
  83   call void @print(i32 3) ; should not be present in f.resume
  84   cleanupret from %tok2 unwind to caller
  85 }
  86
  87 ; Verify that start function contains both print calls the one before and after coro.end
  88 ; CHECK-LABEL: define i8* @f2(
  89 ; CHECK: invoke void @print(i32 1)
  90 ; CHECK:   to label %AfterCoroEnd unwind label %lpad
  91
  92 ; CHECK: AfterCoroEnd:
  93 ; CHECK:   call void @print(i32 0)
  94 ; CHECK:   ret i8* %hdl
  95
  96 ; CHECK:      lpad:
  97 ; CHECK-NEXT:   %tok = cleanuppad within none []
  98 ; CHECK-NEXT:   call void @print(i32 2)
  99 ; CHECK-NEXT:   call void @print(i32 3)
 100 ; CHECK-NEXT:   cleanupret from %tok unwind to caller
 101
 102 ; VERIFY Resume Parts
 103
 104 ; Verify that resume function does not contains both print calls appearing after coro.end
 105 ; CHECK-LABEL: define internal fastcc void @f.resume
 106 ; CHECK: invoke void @print(i32 1)
 107 ; CHECK:   to label %CoroEnd unwind label %lpad
 108
 109 ; CHECK:      CoroEnd:
 110 ; CHECK-NEXT:   ret void
 111
 112 ; CHECK:         lpad:
 113 ; CHECK-NEXT:      %lpval = landingpad { i8*, i32 }
 114 ; CHECK-NEXT:         cleanup
 115 ; CHECK-NEXT:      call void @print(i32 2)
 116 ; CHECK-NEXT:      resume { i8*, i32 } %lpval
 117
 118 ; Verify that resume function does not contains both print calls appearing after coro.end
 119 ; CHECK-LABEL: define internal fastcc void @f2.resume
 120 ; CHECK: invoke void @print(i32 1)
 121 ; CHECK:   to label %CoroEnd unwind label %lpad
 122
 123 ; CHECK:      CoroEnd:
 124 ; CHECK-NEXT:   ret void
 125
 126 ; CHECK:      lpad:
 127 ; CHECK-NEXT:   %tok = cleanuppad within none []
 128 ; CHECK-NEXT:   call void @print(i32 2)
 129 ; CHECK-NEXT:   cleanupret from %tok unwind to caller
 130
 131 declare i8* @llvm.coro.free(token, i8*)
 132 declare i32 @llvm.coro.size.i32()
 133 declare i8  @llvm.coro.suspend(token, i1)
 134 declare void @llvm.coro.resume(i8*)
 135 declare void @llvm.coro.destroy(i8*)
 136
 137 declare token @llvm.coro.id(i32, i8*, i8*, i8*)
 138 declare i8* @llvm.coro.alloc(token)
 139 declare i8* @llvm.coro.begin(token, i8*)
 140 declare i1 @llvm.coro.end(i8*, i1)
 141
 142 declare noalias i8* @malloc(i32)
 143 declare void @print(i32)
 144 declare void @free(i8*)
 145