cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckLibraryExists)
   8 include(CheckSymbolExists)
   9 include(CheckFunctionExists)
  10 include(CheckStructHasMember)
  11 include(CheckCCompilerFlag)
  12
  13 include(CheckCompilerVersion)
  14 include(HandleLLVMStdlib)
  15
  16 if( UNIX AND NOT (BEOS OR HAIKU) )
  17   # Used by check_symbol_exists:
  18   list(APPEND CMAKE_REQUIRED_LIBRARIES "m")
  19 endif()
  20 # x86_64 FreeBSD 9.2 requires libcxxrt to be specified explicitly.
  21 if( CMAKE_SYSTEM MATCHES "FreeBSD-9.2-RELEASE" AND
  22     CMAKE_SIZEOF_VOID_P EQUAL 8 )
  23   list(APPEND CMAKE_REQUIRED_LIBRARIES "cxxrt")
  24 endif()
  25
  26 # include checks
  27 check_include_file(dlfcn.h HAVE_DLFCN_H)
  28 check_include_file(errno.h HAVE_ERRNO_H)
  29 check_include_file(fcntl.h HAVE_FCNTL_H)
  30 check_include_file(link.h HAVE_LINK_H)
  31 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  32 if( NOT PURE_WINDOWS )
  33   check_include_file(pthread.h HAVE_PTHREAD_H)
  34 endif()
  35 check_include_file(signal.h HAVE_SIGNAL_H)
  36 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  37 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  38 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  39 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  40 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  41 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  42 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  43 check_include_file(termios.h HAVE_TERMIOS_H)
  44 check_include_file(unistd.h HAVE_UNISTD_H)
  45 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  46 check_include_file(zlib.h HAVE_ZLIB_H)
  47 check_include_file(fenv.h HAVE_FENV_H)
  48 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  49 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  50
  51 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  52 check_include_file(histedit.h HAVE_HISTEDIT_H)
  53 check_include_file(CrashReporterClient.h HAVE_CRASHREPORTERCLIENT_H)
  54 if(APPLE)
  55   include(CheckCSourceCompiles)
  56   CHECK_C_SOURCE_COMPILES("
  57      static const char *__crashreporter_info__ = 0;
  58      asm(\".desc ___crashreporter_info__, 0x10\");
  59      int main() { return 0; }"
  60     HAVE_CRASHREPORTER_INFO)
  61 endif()
  62
  63 if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
  64   check_include_file(linux/magic.h HAVE_LINUX_MAGIC_H)
  65   if(NOT HAVE_LINUX_MAGIC_H)
  66     # older kernels use split files
  67     check_include_file(linux/nfs_fs.h HAVE_LINUX_NFS_FS_H)
  68     check_include_file(linux/smb.h HAVE_LINUX_SMB_H)
  69   endif()
  70 endif()
  71
  72 # library checks
  73 if( NOT PURE_WINDOWS )
  74   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  75   if (HAVE_LIBPTHREAD)
  76     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  77     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  78     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  79   else()
  80     # this could be Android
  81     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
  82     if (PTHREAD_IN_LIBC)
  83       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  84       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  85       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  86     endif()
  87   endif()
  88   check_library_exists(dl dlopen "" HAVE_LIBDL)
  89   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
  90 endif()
  91
  92 # Check for libpfm.
  93 include(FindLibpfm)
  94
  95 if(HAVE_LIBPTHREAD)
  96   # We want to find pthreads library and at the moment we do want to
  97   # have it reported as '-l<lib>' instead of '-pthread'.
  98   # TODO: switch to -pthread once the rest of the build system can deal with it.
  99   set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
 100   set(THREADS_HAVE_PTHREAD_ARG Off)
 101   find_package(Threads REQUIRED)
 102   set(LLVM_PTHREAD_LIB ${CMAKE_THREAD_LIBS_INIT})
 103 endif()
 104
 105 # Don't look for these libraries if we're using MSan, since uninstrumented third
 106 # party code may call MSan interceptors like strlen, leading to false positives.
 107 if(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 108   set(HAVE_LIBZ 0)
 109   if(LLVM_ENABLE_ZLIB)
 110     foreach(library z zlib_static zlib)
 111       string(TOUPPER ${library} library_suffix)
 112       check_library_exists(${library} compress2 "" HAVE_LIBZ_${library_suffix})
 113       if(HAVE_LIBZ_${library_suffix})
 114         set(HAVE_LIBZ 1)
 115         set(ZLIB_LIBRARIES "${library}")
 116         break()
 117       endif()
 118     endforeach()
 119   endif()
 120
 121   # Don't look for these libraries on Windows.
 122   if (NOT PURE_WINDOWS)
 123     # Skip libedit if using ASan as it contains memory leaks.
 124     if (LLVM_ENABLE_LIBEDIT AND HAVE_HISTEDIT_H AND NOT LLVM_USE_SANITIZER MATCHES ".*Address.*")
 125       check_library_exists(edit el_init "" HAVE_LIBEDIT)
 126     else()
 127       set(HAVE_LIBEDIT 0)
 128     endif()
 129     if(LLVM_ENABLE_TERMINFO)
 130       set(HAVE_TERMINFO 0)
 131       foreach(library terminfo tinfo curses ncurses ncursesw)
 132         string(TOUPPER ${library} library_suffix)
 133         check_library_exists(${library} setupterm "" HAVE_TERMINFO_${library_suffix})
 134         if(HAVE_TERMINFO_${library_suffix})
 135           set(HAVE_TERMINFO 1)
 136           set(TERMINFO_LIBS "${library}")
 137           break()
 138         endif()
 139       endforeach()
 140     else()
 141       set(HAVE_TERMINFO 0)
 142     endif()
 143
 144     find_library(ICONV_LIBRARY_PATH NAMES iconv libiconv libiconv-2 c)
 145     set(LLVM_LIBXML2_ENABLED 0)
 146     set(LIBXML2_FOUND 0)
 147     if((LLVM_ENABLE_LIBXML2) AND ((CMAKE_SYSTEM_NAME MATCHES "Linux") AND (ICONV_LIBRARY_PATH) OR APPLE))
 148       find_package(LibXml2)
 149       if (LIBXML2_FOUND)
 150         set(LLVM_LIBXML2_ENABLED 1)
 151         if ((CMAKE_OSX_SYSROOT) AND (EXISTS ${CMAKE_OSX_SYSROOT}/${LIBXML2_INCLUDE_DIR}))
 152           include_directories(${CMAKE_OSX_SYSROOT}/${LIBXML2_INCLUDE_DIR})
 153         else()
 154           include_directories(${LIBXML2_INCLUDE_DIR})
 155         endif()
 156         set(LIBXML2_LIBS "xml2")
 157       endif()
 158     endif()
 159   endif()
 160 endif()
 161
 162 if (LLVM_ENABLE_LIBXML2 STREQUAL "FORCE_ON" AND NOT LLVM_LIBXML2_ENABLED)
 163   message(FATAL_ERROR "Failed to congifure libxml2")
 164 endif()
 165
 166 check_library_exists(xar xar_open "" HAVE_LIBXAR)
 167 if(HAVE_LIBXAR)
 168   set(XAR_LIB xar)
 169 endif()
 170
 171 # function checks
 172 check_symbol_exists(arc4random "stdlib.h" HAVE_DECL_ARC4RANDOM)
 173 find_package(Backtrace)
 174 set(HAVE_BACKTRACE ${Backtrace_FOUND})
 175 set(BACKTRACE_HEADER ${Backtrace_HEADER})
 176
 177 # Prevent check_symbol_exists from using API that is not supported for a given
 178 # deployment target.
 179 check_c_compiler_flag("-Werror=unguarded-availability-new" "C_SUPPORTS_WERROR_UNGUARDED_AVAILABILITY_NEW")
 180 if(C_SUPPORTS_WERROR_UNGUARDED_AVAILABILITY_NEW)
 181   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror=unguarded-availability-new")
 182 endif()
 183
 184 check_symbol_exists(_Unwind_Backtrace "unwind.h" HAVE__UNWIND_BACKTRACE)
 185 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 186 check_symbol_exists(sysconf unistd.h HAVE_SYSCONF)
 187 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 188 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 189 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 190 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 191 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 192 check_symbol_exists(posix_fallocate fcntl.h HAVE_POSIX_FALLOCATE)
 193 # AddressSanitizer conflicts with lib/Support/Unix/Signals.inc
 194 # Avoid sigaltstack on Apple platforms, where backtrace() cannot handle it
 195 # (rdar://7089625) and _Unwind_Backtrace is unusable because it cannot unwind
 196 # past the signal handler after an assertion failure (rdar://29866587).
 197 if( HAVE_SIGNAL_H AND NOT LLVM_USE_SANITIZER MATCHES ".*Address.*" AND NOT APPLE )
 198   check_symbol_exists(sigaltstack signal.h HAVE_SIGALTSTACK)
 199 endif()
 200 set(CMAKE_REQUIRED_DEFINITIONS "-D_LARGEFILE64_SOURCE")
 201 check_symbol_exists(lseek64 "sys/types.h;unistd.h" HAVE_LSEEK64)
 202 set(CMAKE_REQUIRED_DEFINITIONS "")
 203 check_symbol_exists(mallctl malloc_np.h HAVE_MALLCTL)
 204 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 205 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 206                     HAVE_MALLOC_ZONE_STATISTICS)
 207 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 208 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 209 check_symbol_exists(pread unistd.h HAVE_PREAD)
 210 check_symbol_exists(realpath stdlib.h HAVE_REALPATH)
 211 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 212 check_symbol_exists(strerror string.h HAVE_STRERROR)
 213 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 214 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 215 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 216 if( PURE_WINDOWS )
 217   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 218
 219   check_function_exists(_alloca HAVE__ALLOCA)
 220   check_function_exists(__alloca HAVE___ALLOCA)
 221   check_function_exists(__chkstk HAVE___CHKSTK)
 222   check_function_exists(__chkstk_ms HAVE___CHKSTK_MS)
 223   check_function_exists(___chkstk HAVE____CHKSTK)
 224   check_function_exists(___chkstk_ms HAVE____CHKSTK_MS)
 225
 226   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 227   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 228   check_function_exists(__divdi3 HAVE___DIVDI3)
 229   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 230   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 231   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 232   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 233   check_function_exists(__moddi3 HAVE___MODDI3)
 234   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 235   check_function_exists(__umoddi3 HAVE___UMODDI3)
 236
 237   check_function_exists(__main HAVE___MAIN)
 238   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 239 endif()
 240 if( HAVE_DLFCN_H )
 241   if( HAVE_LIBDL )
 242     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 243   endif()
 244   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 245   check_symbol_exists(dladdr dlfcn.h HAVE_DLADDR)
 246   if( HAVE_LIBDL )
 247     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 248   endif()
 249 endif()
 250
 251 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec
 252     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIMESPEC_TV_NSEC)
 253 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec
 254     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIM_TV_NSEC)
 255
 256 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 257 if( LLVM_USING_GLIBC )
 258   add_definitions( -D_GNU_SOURCE )
 259   list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_GNU_SOURCE")
 260 endif()
 261 # This check requires _GNU_SOURCE
 262 check_symbol_exists(sched_getaffinity sched.h HAVE_SCHED_GETAFFINITY)
 263 check_symbol_exists(CPU_COUNT sched.h HAVE_CPU_COUNT)
 264 if (NOT PURE_WINDOWS)
 265   if (LLVM_PTHREAD_LIB)
 266     list(APPEND CMAKE_REQUIRED_LIBRARIES ${LLVM_PTHREAD_LIB})
 267   endif()
 268   check_symbol_exists(pthread_getname_np pthread.h HAVE_PTHREAD_GETNAME_NP)
 269   check_symbol_exists(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 270   if (LLVM_PTHREAD_LIB)
 271     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${LLVM_PTHREAD_LIB})
 272   endif()
 273 endif()
 274
 275 # available programs checks
 276 function(llvm_find_program name)
 277   string(TOUPPER ${name} NAME)
 278   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 279
 280   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 281   mark_as_advanced(LLVM_PATH_${NAME})
 282   if(LLVM_PATH_${NAME})
 283     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 284     mark_as_advanced(HAVE_${NAME})
 285   else(LLVM_PATH_${NAME})
 286     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 287   endif(LLVM_PATH_${NAME})
 288 endfunction()
 289
 290 if (LLVM_ENABLE_DOXYGEN)
 291   llvm_find_program(dot)
 292 endif ()
 293
 294 if( LLVM_ENABLE_FFI )
 295   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 296   if( EXISTS "${FFI_INCLUDE_PATH}/ffi.h" )
 297     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 298     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 299   else()
 300     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 301     if( EXISTS "${FFI_INCLUDE_PATH}/ffi/ffi.h" )
 302       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 303       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 304     endif()
 305   endif()
 306
 307   if( NOT FFI_HEADER )
 308     message(FATAL_ERROR "libffi includes are not found.")
 309   endif()
 310
 311   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 312   if( NOT FFI_LIBRARY_PATH )
 313     message(FATAL_ERROR "libffi is not found.")
 314   endif()
 315
 316   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 317   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 318   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 319   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 320   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 321 else()
 322   unset(HAVE_FFI_FFI_H CACHE)
 323   unset(HAVE_FFI_H CACHE)
 324   unset(HAVE_FFI_CALL CACHE)
 325 endif( LLVM_ENABLE_FFI )
 326
 327 # Whether we can use std::is_trivially_copyable to verify llvm::is_trivially_copyable.
 328 CHECK_CXX_SOURCE_COMPILES("
 329 #include <type_traits>
 330 struct T { int val; };
 331 static_assert(std::is_trivially_copyable<T>::value, \"ok\");
 332 int main() { return 0;}
 333 " HAVE_STD_IS_TRIVIALLY_COPYABLE)
 334
 335
 336 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 337 include(CheckAtomic)
 338
 339 if( LLVM_ENABLE_PIC )
 340   set(ENABLE_PIC 1)
 341 else()
 342   set(ENABLE_PIC 0)
 343   check_cxx_compiler_flag("-fno-pie" SUPPORTS_NO_PIE_FLAG)
 344   if(SUPPORTS_NO_PIE_FLAG)
 345     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fno-pie")
 346   endif()
 347 endif()
 348
 349 check_cxx_compiler_flag("-Wvariadic-macros" SUPPORTS_VARIADIC_MACROS_FLAG)
 350 check_cxx_compiler_flag("-Wgnu-zero-variadic-macro-arguments"
 351                         SUPPORTS_GNU_ZERO_VARIADIC_MACRO_ARGUMENTS_FLAG)
 352
 353 set(USE_NO_MAYBE_UNINITIALIZED 0)
 354 set(USE_NO_UNINITIALIZED 0)
 355
 356 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 357 # false positives.
 358 if (CMAKE_COMPILER_IS_GNUCXX)
 359   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 360   if (HAS_MAYBE_UNINITIALIZED)
 361     set(USE_NO_MAYBE_UNINITIALIZED 1)
 362   else()
 363     # Only recent versions of gcc make the distinction between -Wuninitialized
 364     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 365     # turn off all uninitialized use warnings.
 366     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 367     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 368   endif()
 369 endif()
 370
 371 # By default, we target the host, but this can be overridden at CMake
 372 # invocation time.
 373 include(GetHostTriple)
 374 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 375
 376 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 377     "Host on which LLVM binaries will run")
 378
 379 # Determine the native architecture.
 380 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 381 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 382   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 383 endif ()
 384
 385 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 386   set(LLVM_NATIVE_ARCH X86)
 387 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 388   set(LLVM_NATIVE_ARCH X86)
 389 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 390   set(LLVM_NATIVE_ARCH X86)
 391 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 392   set(LLVM_NATIVE_ARCH X86)
 393 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 394   set(LLVM_NATIVE_ARCH Sparc)
 395 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 396   set(LLVM_NATIVE_ARCH PowerPC)
 397 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 398   set(LLVM_NATIVE_ARCH AArch64)
 399 elseif (LLVM_NATIVE_ARCH MATCHES "arm64")
 400   set(LLVM_NATIVE_ARCH AArch64)
 401 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 402   set(LLVM_NATIVE_ARCH ARM)
 403 elseif (LLVM_NATIVE_ARCH MATCHES "avr")
 404   set(LLVM_NATIVE_ARCH AVR)
 405 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 406   set(LLVM_NATIVE_ARCH Mips)
 407 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 408   set(LLVM_NATIVE_ARCH XCore)
 409 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 410   set(LLVM_NATIVE_ARCH MSP430)
 411 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 412   set(LLVM_NATIVE_ARCH Hexagon)
 413 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 414   set(LLVM_NATIVE_ARCH SystemZ)
 415 elseif (LLVM_NATIVE_ARCH MATCHES "wasm32")
 416   set(LLVM_NATIVE_ARCH WebAssembly)
 417 elseif (LLVM_NATIVE_ARCH MATCHES "wasm64")
 418   set(LLVM_NATIVE_ARCH WebAssembly)
 419 elseif (LLVM_NATIVE_ARCH MATCHES "riscv32")
 420   set(LLVM_NATIVE_ARCH RISCV)
 421 elseif (LLVM_NATIVE_ARCH MATCHES "riscv64")
 422   set(LLVM_NATIVE_ARCH RISCV)
 423 else ()
 424   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 425 endif ()
 426
 427 # If build targets includes "host", then replace with native architecture.
 428 list(FIND LLVM_TARGETS_TO_BUILD "host" idx)
 429 if( NOT idx LESS 0 )
 430   list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 431   list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 432   list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 433 endif()
 434
 435 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 436 if (NATIVE_ARCH_IDX EQUAL -1)
 437   message(STATUS
 438     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 439 else ()
 440   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 441   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 442   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 443   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 444   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 445
 446   # We don't have an ASM parser for all architectures yet.
 447   if (EXISTS ${PROJECT_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 448     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 449   endif ()
 450
 451   # We don't have an disassembler for all architectures yet.
 452   if (EXISTS ${PROJECT_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 453     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 454   endif ()
 455 endif ()
 456
 457 if( MSVC )
 458   set(SHLIBEXT ".lib")
 459   set(stricmp "_stricmp")
 460   set(strdup "_strdup")
 461
 462   # See if the DIA SDK is available and usable.
 463   set(MSVC_DIA_SDK_DIR "$ENV{VSINSTALLDIR}DIA SDK")
 464
 465   # Due to a bug in MSVC 2013's installation software, it is possible
 466   # for MSVC 2013 to write the DIA SDK into the Visual Studio 2012
 467   # install directory.  If this happens, the installation is corrupt
 468   # and there's nothing we can do.  It happens with enough frequency
 469   # though that we should handle it.  We do so by simply checking that
 470   # the DIA SDK folder exists.  Should this happen you will need to
 471   # uninstall VS 2012 and then re-install VS 2013.
 472   if (IS_DIRECTORY ${MSVC_DIA_SDK_DIR})
 473     set(HAVE_DIA_SDK 1)
 474   else()
 475     set(HAVE_DIA_SDK 0)
 476   endif()
 477
 478   option(LLVM_ENABLE_DIA_SDK "Use MSVC DIA SDK for debugging if available."
 479                              ${HAVE_DIA_SDK})
 480
 481   if(LLVM_ENABLE_DIA_SDK AND NOT HAVE_DIA_SDK)
 482     message(FATAL_ERROR "DIA SDK not found. If you have both VS 2012 and 2013 installed, you may need to uninstall the former and re-install the latter afterwards.")
 483   endif()
 484 else()
 485   set(LLVM_ENABLE_DIA_SDK 0)
 486 endif( MSVC )
 487
 488 # FIXME: Signal handler return type, currently hardcoded to 'void'
 489 set(RETSIGTYPE void)
 490
 491 if( LLVM_ENABLE_THREADS )
 492   # Check if threading primitives aren't supported on this platform
 493   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 494     set(LLVM_ENABLE_THREADS 0)
 495   endif()
 496 endif()
 497
 498 if( LLVM_ENABLE_THREADS )
 499   message(STATUS "Threads enabled.")
 500 else( LLVM_ENABLE_THREADS )
 501   message(STATUS "Threads disabled.")
 502 endif()
 503
 504 if (LLVM_ENABLE_ZLIB )
 505   # Check if zlib is available in the system.
 506   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 507     set(LLVM_ENABLE_ZLIB 0)
 508   endif()
 509 endif()
 510
 511 if (LLVM_ENABLE_DOXYGEN)
 512   message(STATUS "Doxygen enabled.")
 513   find_package(Doxygen REQUIRED)
 514
 515   if (DOXYGEN_FOUND)
 516     # If we find doxygen and we want to enable doxygen by default create a
 517     # global aggregate doxygen target for generating llvm and any/all
 518     # subprojects doxygen documentation.
 519     if (LLVM_BUILD_DOCS)
 520       add_custom_target(doxygen ALL)
 521     endif()
 522
 523     option(LLVM_DOXYGEN_EXTERNAL_SEARCH "Enable doxygen external search." OFF)
 524     if (LLVM_DOXYGEN_EXTERNAL_SEARCH)
 525       set(LLVM_DOXYGEN_SEARCHENGINE_URL "" CACHE STRING "URL to use for external search.")
 526       set(LLVM_DOXYGEN_SEARCH_MAPPINGS "" CACHE STRING "Doxygen Search Mappings")
 527     endif()
 528   endif()
 529 else()
 530   message(STATUS "Doxygen disabled.")
 531 endif()
 532
 533 set(LLVM_BINDINGS "")
 534 find_program(GO_EXECUTABLE NAMES go DOC "go executable")
 535 if(WIN32 OR NOT LLVM_ENABLE_BINDINGS)
 536   message(STATUS "Go bindings disabled.")
 537 else()
 538   if(GO_EXECUTABLE STREQUAL "GO_EXECUTABLE-NOTFOUND")
 539     message(STATUS "Go bindings disabled.")
 540   else()
 541     execute_process(COMMAND ${GO_EXECUTABLE} run ${PROJECT_SOURCE_DIR}/bindings/go/conftest.go
 542                     RESULT_VARIABLE GO_CONFTEST)
 543     if(GO_CONFTEST STREQUAL "0")
 544       set(LLVM_BINDINGS "${LLVM_BINDINGS} go")
 545       message(STATUS "Go bindings enabled.")
 546     else()
 547       message(STATUS "Go bindings disabled, need at least Go 1.2.")
 548     endif()
 549   endif()
 550 endif()
 551
 552 find_program(GOLD_EXECUTABLE NAMES ${LLVM_DEFAULT_TARGET_TRIPLE}-ld.gold ld.gold ${LLVM_DEFAULT_TARGET_TRIPLE}-ld ld DOC "The gold linker")
 553 set(LLVM_BINUTILS_INCDIR "" CACHE PATH
 554         "PATH to binutils/include containing plugin-api.h for gold plugin.")
 555
 556 if(CMAKE_HOST_APPLE AND APPLE)
 557   if(NOT CMAKE_XCRUN)
 558     find_program(CMAKE_XCRUN NAMES xcrun)
 559   endif()
 560   if(CMAKE_XCRUN)
 561     execute_process(COMMAND ${CMAKE_XCRUN} -find ld
 562       OUTPUT_VARIABLE LD64_EXECUTABLE
 563       OUTPUT_STRIP_TRAILING_WHITESPACE)
 564   else()
 565     find_program(LD64_EXECUTABLE NAMES ld DOC "The ld64 linker")
 566   endif()
 567
 568   if(LD64_EXECUTABLE)
 569     set(LD64_EXECUTABLE ${LD64_EXECUTABLE} CACHE PATH "ld64 executable")
 570     message(STATUS "Found ld64 - ${LD64_EXECUTABLE}")
 571   endif()
 572 endif()
 573
 574 # Keep the version requirements in sync with bindings/ocaml/README.txt.
 575 include(FindOCaml)
 576 include(AddOCaml)
 577 if(WIN32 OR NOT LLVM_ENABLE_BINDINGS)
 578   message(STATUS "OCaml bindings disabled.")
 579 else()
 580   find_package(OCaml)
 581   if( NOT OCAML_FOUND )
 582     message(STATUS "OCaml bindings disabled.")
 583   else()
 584     if( OCAML_VERSION VERSION_LESS "4.00.0" )
 585       message(STATUS "OCaml bindings disabled, need OCaml >=4.00.0.")
 586     else()
 587       find_ocamlfind_package(ctypes VERSION 0.4 OPTIONAL)
 588       if( HAVE_OCAML_CTYPES )
 589         message(STATUS "OCaml bindings enabled.")
 590         find_ocamlfind_package(oUnit VERSION 2 OPTIONAL)
 591         set(LLVM_BINDINGS "${LLVM_BINDINGS} ocaml")
 592
 593         set(LLVM_OCAML_INSTALL_PATH "${OCAML_STDLIB_PATH}" CACHE STRING
 594             "Install directory for LLVM OCaml packages")
 595       else()
 596         message(STATUS "OCaml bindings disabled, need ctypes >=0.4.")
 597       endif()
 598     endif()
 599   endif()
 600 endif()
 601
 602 string(REPLACE " " ";" LLVM_BINDINGS_LIST "${LLVM_BINDINGS}")
 603
 604 function(find_python_module module)
 605   string(REPLACE "." "_" module_name ${module})
 606   string(TOUPPER ${module_name} module_upper)
 607   set(FOUND_VAR PY_${module_upper}_FOUND)
 608
 609   execute_process(COMMAND "${PYTHON_EXECUTABLE}" "-c" "import ${module}"
 610     RESULT_VARIABLE status
 611     ERROR_QUIET)
 612
 613   if(status)
 614     set(${FOUND_VAR} 0 PARENT_SCOPE)
 615     message(STATUS "Could NOT find Python module ${module}")
 616   else()
 617     set(${FOUND_VAR} 1 PARENT_SCOPE)
 618     message(STATUS "Found Python module ${module}")
 619   endif()
 620 endfunction()
 621
 622 set (PYTHON_MODULES
 623   pygments
 624   # Some systems still don't have pygments.lexers.c_cpp which was introduced in
 625   # version 2.0 in 2014...
 626   pygments.lexers.c_cpp
 627   yaml
 628   )
 629 foreach(module ${PYTHON_MODULES})
 630   find_python_module(${module})
 631 endforeach()
 632
 633 if(PY_PYGMENTS_FOUND AND PY_PYGMENTS_LEXERS_C_CPP_FOUND AND PY_YAML_FOUND)
 634   set (LLVM_HAVE_OPT_VIEWER_MODULES 1)
 635 else()
 636   set (LLVM_HAVE_OPT_VIEWER_MODULES 0)
 637 endif()