test/Instrumentation/AddressSanitizer/stack_dynamic_alloca.ll

   1 ; RUN: opt < %s -asan -asan-module -asan-stack-dynamic-alloca \
   2 ; RUN:       -asan-use-after-return -S | FileCheck %s
   3 ; RUN: opt < %s -asan -asan-module -asan-stack-dynamic-alloca -asan-mapping-scale=5 \
   4 ; RUN:       -asan-use-after-return -S | FileCheck %s
   5 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64-S128"
   6 target triple = "x86_64-unknown-linux-gnu"
   7
   8 define void @Func1() sanitize_address {
   9 entry:
  10 ; CHECK-LABEL: Func1
  11
  12 ; CHECK: entry:
  13 ; CHECK: load i32, i32* @__asan_option_detect_stack_use_after_return
  14
  15 ; CHECK: [[UAR_ENABLED_BB:^[0-9]+]]:
  16 ; CHECK: [[FAKE_STACK_RT:%[0-9]+]] = call i64 @__asan_stack_malloc_
  17
  18 ; CHECK: [[FAKE_STACK_BB:^[0-9]+]]:
  19 ; CHECK: [[FAKE_STACK:%[0-9]+]] = phi i64 [ 0, %entry ], [ [[FAKE_STACK_RT]], %[[UAR_ENABLED_BB]] ]
  20 ; CHECK: icmp eq i64 [[FAKE_STACK]], 0
  21
  22 ; CHECK: [[NO_FAKE_STACK_BB:^[0-9]+]]:
  23 ; CHECK: %MyAlloca = alloca i8, i64
  24 ; CHECK: [[ALLOCA:%[0-9]+]] = ptrtoint i8* %MyAlloca
  25
  26 ; CHECK: phi i64 [ [[FAKE_STACK]], %[[FAKE_STACK_BB]] ], [ [[ALLOCA]], %[[NO_FAKE_STACK_BB]] ]
  27
  28 ; CHECK: ret void
  29
  30   %XXX = alloca [20 x i8], align 1
  31   %arr.ptr = bitcast [20 x i8]* %XXX to i8*
  32   store volatile i8 0, i8* %arr.ptr
  33   ret void
  34 }
  35
  36 ; Test that dynamic alloca is not used for functions with inline assembly.
  37 define void @Func2() sanitize_address {
  38 entry:
  39 ; CHECK-LABEL: Func2
  40 ; CHECK: alloca [96 x i8]
  41 ; CHECK: ret void
  42
  43   %XXX = alloca [20 x i8], align 1
  44   %arr.ptr = bitcast [20 x i8]* %XXX to i8*
  45   store volatile i8 0, i8* %arr.ptr
  46   call void asm sideeffect "mov %%rbx, %%rcx", "~{dirflag},~{fpsr},~{flags}"() nounwind
  47   ret void
  48 }
  49
  50 ; Test that dynamic alloca is not used when setjmp is present.
  51 %struct.__jmp_buf_tag = type { [8 x i64], i32, %struct.__sigset_t }
  52 %struct.__sigset_t = type { [16 x i64] }
  53 @_ZL3buf = internal global [1 x %struct.__jmp_buf_tag] zeroinitializer, align 16
  54
  55 define void @Func3() uwtable sanitize_address {
  56 ; CHECK-LABEL: define void @Func3
  57 ; CHECK-NOT: __asan_option_detect_stack_use_after_return
  58 ; CHECK-NOT: __asan_stack_malloc
  59 ; CHECK: call void @__asan_handle_no_return
  60 ; CHECK: call void @longjmp
  61 ; CHECK: ret void
  62 entry:
  63   %a = alloca i32, align 4
  64   %call = call i32 @_setjmp(%struct.__jmp_buf_tag* getelementptr inbounds ([1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* @_ZL3buf, i32 0, i32 0)) nounwind returns_twice
  65   %cmp = icmp eq i32 0, %call
  66   br i1 %cmp, label %if.then, label %if.end
  67
  68 if.then:                                          ; preds = %entry
  69   call void @longjmp(%struct.__jmp_buf_tag* getelementptr inbounds ([1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* @_ZL3buf, i32 0, i32 0), i32 1) noreturn nounwind
  70   unreachable
  71
  72 if.end:                                           ; preds = %entry
  73   call void @_Z10escape_ptrPi(i32* %a)
  74   ret void
  75 }
  76
  77 declare i32 @_setjmp(%struct.__jmp_buf_tag*) nounwind returns_twice
  78 declare void @longjmp(%struct.__jmp_buf_tag*, i32) noreturn nounwind
  79 declare void @_Z10escape_ptrPi(i32*)