test/Transforms/LoopLoadElim/forward.ll

   1 ; RUN: opt -loop-load-elim -S < %s | FileCheck %s
   2 ; RUN: opt -passes=loop-load-elim -S < %s | FileCheck %s
   3
   4 ; Simple st->ld forwarding derived from a lexical forward dep.
   5 ;
   6 ;   for (unsigned i = 0; i < 100; i++) {
   7 ;     A[i+1] = B[i] + 2;
   8 ;     C[i] = A[i] * 2;
   9 ;   }
  10
  11 target datalayout = "e-m:o-i64:64-f80:128-n8:16:32:64-S128"
  12
  13 define void @f(i32* %A, i32* %B, i32* %C, i64 %N) {
  14
  15 ; CHECK:   for.body.lver.check:
  16 ; CHECK:     %found.conflict{{.*}} =
  17 ; CHECK-NOT: %found.conflict{{.*}} =
  18
  19 entry:
  20 ; Make sure the hoisted load keeps the alignment
  21 ; CHECK: %load_initial = load i32, i32* %A, align 1
  22   br label %for.body
  23
  24 for.body:                                         ; preds = %for.body, %entry
  25 ; CHECK: %store_forwarded = phi i32 [ %load_initial, %for.body.ph ], [ %a_p1, %for.body ]
  26   %indvars.iv = phi i64 [ 0, %entry ], [ %indvars.iv.next, %for.body ]
  27   %indvars.iv.next = add nuw nsw i64 %indvars.iv, 1
  28
  29   %Aidx_next = getelementptr inbounds i32, i32* %A, i64 %indvars.iv.next
  30   %Bidx = getelementptr inbounds i32, i32* %B, i64 %indvars.iv
  31   %Cidx = getelementptr inbounds i32, i32* %C, i64 %indvars.iv
  32   %Aidx = getelementptr inbounds i32, i32* %A, i64 %indvars.iv
  33
  34   %b = load i32, i32* %Bidx, align 4
  35   %a_p1 = add i32 %b, 2
  36   store i32 %a_p1, i32* %Aidx_next, align 4
  37
  38   %a = load i32, i32* %Aidx, align 1
  39 ; CHECK: %c = mul i32 %store_forwarded, 2
  40   %c = mul i32 %a, 2
  41   store i32 %c, i32* %Cidx, align 4
  42
  43   %exitcond = icmp eq i64 %indvars.iv.next, %N
  44   br i1 %exitcond, label %for.end, label %for.body
  45
  46 for.end:                                          ; preds = %for.body
  47   ret void
  48 }