test/Transforms/HotColdSplit/multiple-exits.ll

   1 ; RUN: opt -S -hotcoldsplit -hotcoldsplit-threshold=0 < %s | FileCheck %s
   2
   3 ; Source:
   4 ;
   5 ; extern void sideeffect(int);
   6 ; extern void __attribute__((cold)) sink();
   7 ; void foo(int cond) {
   8 ;   if (cond) { //< Start outlining here.
   9 ;     sink();
  10 ;     if (cond > 10)
  11 ;       goto exit1;
  12 ;     else
  13 ;       goto exit2;
  14 ;   }
  15 ; exit1:
  16 ;   sideeffect(1);
  17 ;   return;
  18 ; exit2:
  19 ;   sideeffect(2);
  20 ;   return;
  21 ; }
  22
  23 target datalayout = "e-m:o-i64:64-f80:128-n8:16:32:64-S128"
  24 target triple = "x86_64-apple-macosx10.14.0"
  25
  26 ; CHECK-LABEL: define {{.*}}@foo(
  27 ; CHECK: br i1 {{.*}}, label %exit1, label %codeRepl
  28 ; CHECK-LABEL: codeRepl:
  29 ; CHECK: [[targetBlock:%.*]] = call i1 @foo.cold.1(
  30 ; CHECK-NEXT: br i1 [[targetBlock]], label %exit1, label %[[return:.*]]
  31 ; CHECK-LABEL: exit1:
  32 ; CHECK: call {{.*}}@sideeffect(i32 1)
  33 ; CHECK: [[return]]:
  34 ; CHECK-NEXT: ret void
  35 define void @foo(i32 %cond) {
  36 entry:
  37   %tobool = icmp eq i32 %cond, 0
  38   br i1 %tobool, label %exit1, label %if.then
  39
  40 if.then:                                          ; preds = %entry
  41   tail call void (...) @sink()
  42   %cmp = icmp sgt i32 %cond, 10
  43   br i1 %cmp, label %exit1, label %exit2
  44
  45 exit1:                                            ; preds = %entry, %if.then
  46   call void @sideeffect(i32 1)
  47   br label %return
  48
  49 exit2:                                            ; preds = %if.then
  50   call void @sideeffect(i32 2)
  51   br label %return
  52
  53 return:                                           ; preds = %exit2, %exit1
  54   ret void
  55 }
  56
  57 ; CHECK-LABEL: define {{.*}}@foo.cold.1(
  58 ; CHECK: br
  59 ; CHECK: [[exit1Stub:.*]]:
  60 ; CHECK-NEXT: ret i1 true
  61 ; CHECK: [[returnStub:.*]]:
  62 ; CHECK-NEXT: ret i1 false
  63 ; CHECK: call {{.*}}@sink
  64 ; CHECK-NEXT: [[cmp:%.*]] = icmp
  65 ; CHECK-NEXT: br i1 [[cmp]], label %[[exit1Stub]], label %exit2
  66 ; CHECK-LABEL: exit2:
  67 ; CHECK-NEXT: call {{.*}}@sideeffect(i32 2)
  68 ; CHECK-NEXT: br label %[[returnStub]]
  69
  70 declare void @sink(...) cold
  71
  72 declare void @sideeffect(i32)