test/Transforms/SCCP/ip-constant-ranges.ll

   1 ; RUN: opt < %s -ipsccp -S | FileCheck %s
   2
   3 ; Constant range for %a is [1, 48) and for %b is [301, 1000)
   4 ; CHECK-LABEL: f1
   5 ; CHECK: ret i32 undef
   6 define internal i32 @f1(i32 %a, i32 %b) {
   7 entry:
   8   %cmp.a = icmp sgt i32 %a, 300
   9   %cmp.b = icmp sgt i32 %b, 300
  10   %cmp.a2 = icmp ugt i32 %a, 300
  11   %cmp.b2 = icmp ugt i32 %b, 300
  12
  13   %a.1 = select i1 %cmp.a, i32 1, i32 2
  14   %b.1 = select i1 %cmp.b, i32 1, i32 2
  15   %a.2 = select i1 %cmp.a2, i32 1, i32 2
  16   %b.2 = select i1 %cmp.b2, i32 1, i32 2
  17   %res1 = add i32 %a.1, %b.1
  18   %res2 = add i32 %a.2, %b.2
  19   %res3 = add i32 %res1, %res2
  20   ret i32 %res3
  21 }
  22
  23 ; Constant range for %x is [47, 302)
  24 ; CHECK-LABEL: f2
  25 ; CHECK: %cmp = icmp sgt i32 %x, 300
  26 ; CHECK: %res1 = select i1 %cmp, i32 1, i32 2
  27 ; CHECK-NEXT: %res4 = select i1 %cmp4, i32 3, i32 4
  28 ; CHECK-NEXT: %res6 = add i32 %res1, 3
  29 ; CHECK-NEXT: %res7 = add i32 5, %res4
  30 ; CHECK-NEXT: %res = add i32 %res6, 5
  31 ; CHECK-NEXT: ret i32 %res
  32 define internal i32 @f2(i32 %x) {
  33 entry:
  34   %cmp = icmp sgt i32 %x, 300
  35   %cmp2 = icmp ne i32 %x, 10
  36   %cmp3 = icmp sge i32 %x, 47
  37   %cmp4 = icmp ugt i32 %x, 300
  38   %cmp5 = icmp uge i32 %x, 47
  39   %res1 = select i1 %cmp, i32 1, i32 2
  40   %res2 = select i1 %cmp2, i32 3, i32 4
  41   %res3 = select i1 %cmp3, i32 5, i32 6
  42   %res4 = select i1 %cmp4, i32 3, i32 4
  43   %res5 = select i1 %cmp5, i32 5, i32 6
  44
  45   %res6 = add i32 %res1, %res2
  46   %res7 = add i32 %res3, %res4
  47   %res = add i32 %res6, %res5
  48   ret i32 %res
  49 }
  50
  51 define i32 @caller1() {
  52 entry:
  53   %call1 = tail call i32 @f1(i32 1, i32 301)
  54   %call2 = tail call i32 @f1(i32 47, i32 999)
  55   %call3 = tail call i32 @f2(i32 47)
  56   %call4 = tail call i32 @f2(i32 301)
  57   %res.1 = add nsw i32 12, %call3
  58   %res.2 = add nsw i32 %res.1, %call4
  59   ret i32 %res.2
  60 }
  61
  62 ; x is overdefined, because constant ranges are only used for parameter
  63 ; values.
  64 ; CHECK-LABEL: f3
  65 ; CHECK: %cmp = icmp sgt i32 %x, 300
  66 ; CHECK: %res = select i1 %cmp, i32 1, i32 2
  67 ; CHECK: ret i32 %res
  68 define internal i32 @f3(i32 %x) {
  69 entry:
  70   %cmp = icmp sgt i32 %x, 300
  71   %res = select i1 %cmp, i32 1, i32 2
  72   ret i32 %res
  73 }
  74
  75 ; The phi node could be converted in a ConstantRange.
  76 define i32 @caller2(i1 %cmp) {
  77 entry:
  78   br i1 %cmp, label %if.true, label %end
  79
  80 if.true:
  81   br label %end
  82
  83 end:
  84   %res = phi i32 [ 0, %entry], [ 1, %if.true ]
  85   %call1 = tail call i32 @f3(i32 %res)
  86   ret i32 %call1
  87 }
  88
  89 ; CHECK-LABEL: f4
  90 ; CHECK: %cmp = icmp sgt i32 %x, 300
  91 ; CHECK: %res = select i1 %cmp, i32 1, i32 2
  92 ; CHECK: ret i32 %res
  93 define internal i32 @f4(i32 %x) {
  94 entry:
  95   %cmp = icmp sgt i32 %x, 300
  96   %res = select i1 %cmp, i32 1, i32 2
  97   ret i32 %res
  98 }
  99
 100 ; ICmp could introduce bounds on ConstantRanges.
 101 define i32 @caller3(i32 %x) {
 102 entry:
 103   %cmp = icmp sgt i32 %x, 300
 104   br i1 %cmp, label %if.true, label %end
 105
 106 if.true:
 107   %x.1 = tail call i32 @f4(i32 %x)
 108   br label %end
 109
 110 end:
 111   %res = phi i32 [ 0, %entry], [ %x.1, %if.true ]
 112   ret i32 %res
 113 }
 114
 115 ; Check to make sure we do not attempt to access lattice values in unreachable
 116 ; blocks.
 117 define i32 @test_unreachable() {
 118 entry:
 119   call i1 @test_unreachable_callee(i32 1)
 120   call i1 @test_unreachable_callee(i32 2)
 121   ret i32 1
 122 }
 123
 124 define internal i1 @test_unreachable_callee(i32 %a) {
 125 entry:
 126   ret i1 true
 127
 128 unreachablebb:
 129   %cmp = icmp eq i32 undef, %a
 130   unreachable
 131 }
 132
 133 ; Check that we do not attempt to get range info for non-integer types and
 134 ; crash.
 135 define double @test_struct({ double, double } %test) {
 136     %v = extractvalue { double, double } %test, 0
 137     %r = fmul double %v, %v
 138     ret double %r
 139 }
 140
 141 ; Constant range for %x is [47, 302)
 142 ; CHECK-LABEL: @f5
 143 ; CHECK-NEXT: entry:
 144 ; CHECK-NEXT: %cmp = icmp sgt i32 %x, undef
 145 ; CHECK-NEXT: %res1 = select i1 %cmp, i32 1, i32 2
 146 ; CHECK-NEXT: %res = add i32 %res1, 3
 147 ; CHECK-NEXT: ret i32 %res
 148 define internal i32 @f5(i32 %x) {
 149 entry:
 150   %cmp = icmp sgt i32 %x, undef
 151   %cmp2 = icmp ne i32 undef, %x
 152   %res1 = select i1 %cmp, i32 1, i32 2
 153   %res2 = select i1 %cmp2, i32 3, i32 4
 154
 155   %res = add i32 %res1, %res2
 156   ret i32 %res
 157 }
 158
 159 define i32 @caller4() {
 160 entry:
 161   %call1 = tail call i32 @f5(i32 47)
 162   %call2 = tail call i32 @f5(i32 301)
 163   %res = add nsw i32 %call1, %call2
 164   ret i32 %res
 165 }
 166
 167 ; Make sure we do re-evaluate the function after ParamState changes.
 168 ; CHECK-LABEL: @recursive_f
 169 ; CHECK-LABEL: entry:
 170 ; CHECK:  %cmp = icmp eq i32 %i, 0
 171 ; CHECK-NEXT: br i1 %cmp, label %if.then, label %if.else
 172 define internal i32 @recursive_f(i32 %i) {
 173 entry:
 174   %cmp = icmp eq i32 %i, 0
 175   br i1 %cmp, label %if.then, label %if.else
 176
 177 if.then:                                          ; preds = %entry
 178   br label %return
 179
 180 if.else:                                          ; preds = %entry
 181   %sub = sub nsw i32 %i, 1
 182   %call = call i32 @recursive_f(i32 %sub)
 183   %add = add i32 %i, %call
 184   br label %return
 185
 186 return:                                           ; preds = %if.else, %if.then
 187   %retval.0 = phi i32 [ 0, %if.then ], [ %add, %if.else ]
 188   ret i32 %retval.0
 189 }
 190
 191 ; CHECK-LABEL: @caller5
 192 ; CHECK: %call = call i32 @recursive_f(i32 42)
 193 ; CHECK-NEXT: ret i32 %call
 194 define i32 @caller5() {
 195 entry:
 196   %call = call i32 @recursive_f(i32 42)
 197   ret i32 %call
 198 }