utils/gn/secondary/llvm/lib/Target/ARM/MCTargetDesc/BUILD.gn

   1 import("//llvm/utils/TableGen/tablegen.gni")
   2
   3 tablegen("ARMGenAsmWriter") {
   4   visibility = [ ":MCTargetDesc" ]
   5   args = [ "-gen-asm-writer" ]
   6   td_file = "../ARM.td"
   7 }
   8
   9 tablegen("ARMGenInstrInfo") {
  10   visibility = [ ":tablegen" ]
  11   args = [ "-gen-instr-info" ]
  12   td_file = "../ARM.td"
  13 }
  14
  15 tablegen("ARMGenMCCodeEmitter") {
  16   visibility = [ ":MCTargetDesc" ]
  17   args = [ "-gen-emitter" ]
  18   td_file = "../ARM.td"
  19 }
  20
  21 tablegen("ARMGenRegisterInfo") {
  22   visibility = [ ":tablegen" ]
  23   args = [ "-gen-register-info" ]
  24   td_file = "../ARM.td"
  25 }
  26
  27 tablegen("ARMGenSubtargetInfo") {
  28   visibility = [ ":tablegen" ]
  29   args = [ "-gen-subtarget" ]
  30   td_file = "../ARM.td"
  31 }
  32
  33 # This should contain tablegen targets generating .inc files included
  34 # by other targets. .inc files only used by .cpp files in this directory
  35 # should be in deps on the static_library instead.
  36 group("tablegen") {
  37   visibility = [
  38     ":MCTargetDesc",
  39     "../Utils",
  40   ]
  41   public_deps = [
  42     ":ARMGenInstrInfo",
  43     ":ARMGenRegisterInfo",
  44     ":ARMGenSubtargetInfo",
  45   ]
  46 }
  47
  48 static_library("MCTargetDesc") {
  49   output_name = "LLVMARMDesc"
  50   public_deps = [
  51     ":tablegen",
  52   ]
  53   deps = [
  54     ":ARMGenAsmWriter",
  55     ":ARMGenMCCodeEmitter",
  56     "//llvm/lib/MC",
  57     "//llvm/lib/MC/MCDisassembler",
  58     "//llvm/lib/Support",
  59     "//llvm/lib/Target/ARM/TargetInfo",
  60     "//llvm/lib/Target/ARM/Utils",
  61   ]
  62   include_dirs = [ ".." ]
  63   sources = [
  64     "ARMAsmBackend.cpp",
  65     "ARMELFObjectWriter.cpp",
  66     "ARMELFStreamer.cpp",
  67     "ARMInstPrinter.cpp",
  68     "ARMMCAsmInfo.cpp",
  69     "ARMMCCodeEmitter.cpp",
  70     "ARMMCExpr.cpp",
  71     "ARMMCTargetDesc.cpp",
  72     "ARMMachORelocationInfo.cpp",
  73     "ARMMachObjectWriter.cpp",
  74     "ARMTargetStreamer.cpp",
  75     "ARMUnwindOpAsm.cpp",
  76     "ARMWinCOFFObjectWriter.cpp",
  77     "ARMWinCOFFStreamer.cpp",
  78   ]
  79 }