utils/gn/secondary/llvm/lib/Target/AVR/BUILD.gn

   1 import("//llvm/utils/TableGen/tablegen.gni")
   2
   3 tablegen("AVRGenCallingConv") {
   4   visibility = [ ":LLVMAVRCodeGen" ]
   5   args = [ "-gen-callingconv" ]
   6   td_file = "AVR.td"
   7 }
   8
   9 tablegen("AVRGenDAGISel") {
  10   visibility = [ ":LLVMAVRCodeGen" ]
  11   args = [ "-gen-dag-isel" ]
  12   td_file = "AVR.td"
  13 }
  14
  15 static_library("LLVMAVRCodeGen") {
  16   deps = [
  17     ":AVRGenCallingConv",
  18     ":AVRGenDAGISel",
  19     "MCTargetDesc",
  20     "TargetInfo",
  21     "//llvm/include/llvm/Config:llvm-config",
  22     "//llvm/lib/CodeGen",
  23     "//llvm/lib/CodeGen/AsmPrinter",
  24     "//llvm/lib/CodeGen/SelectionDAG",
  25     "//llvm/lib/IR",
  26     "//llvm/lib/MC",
  27     "//llvm/lib/Support",
  28     "//llvm/lib/Target",
  29   ]
  30   include_dirs = [ "." ]
  31   sources = [
  32     "AVRAsmPrinter.cpp",
  33     "AVRExpandPseudoInsts.cpp",
  34     "AVRFrameLowering.cpp",
  35     "AVRISelDAGToDAG.cpp",
  36     "AVRISelLowering.cpp",
  37     "AVRInstrInfo.cpp",
  38     "AVRMCInstLower.cpp",
  39     "AVRRegisterInfo.cpp",
  40     "AVRRelaxMemOperations.cpp",
  41     "AVRSubtarget.cpp",
  42     "AVRTargetMachine.cpp",
  43     "AVRTargetObjectFile.cpp",
  44   ]
  45 }
  46
  47 # This is a bit different from most build files: Due to this group
  48 # having the directory's name, "//llvm/lib/Target/AVR" will refer to this
  49 # target, which pulls in the code in this directory *and all subdirectories*.
  50 # For most other directories, "//llvm/lib/Foo" only pulls in the code directly
  51 # in "llvm/lib/Foo". The forwarding targets in //llvm/lib/Target expect this
  52 # different behavior.
  53 group("AVR") {
  54   deps = [
  55     ":LLVMAVRCodeGen",
  56     "AsmParser",
  57     "Disassembler",
  58     "MCTargetDesc",
  59     "TargetInfo",
  60   ]
  61 }