cmake/modules/CheckCompilerVersion.cmake

   1 # Check if the host compiler is new enough.
   2 # These versions are updated based on the following policy:
   3 #   llvm.org/docs/DeveloperPolicy.html#toolchain
   4
   5 include(CheckCXXSourceCompiles)
   6
   7 set(GCC_MIN 5.1)
   8 set(GCC_SOFT_ERROR 5.1)
   9 set(CLANG_MIN 3.5)
  10 set(CLANG_SOFT_ERROR 3.5)
  11 set(APPLECLANG_MIN 6.0)
  12 set(APPLECLANG_SOFT_ERROR 6.0)
  13
  14 # https://en.wikipedia.org/wiki/Microsoft_Visual_C#Internal_version_numbering
  15 # _MSC_VER == 1910 MSVC++ 14.1 (Visual Studio 2017 version 15.0)
  16 set(MSVC_MIN 19.1)
  17 set(MSVC_SOFT_ERROR 19.1)
  18
  19 # Map the above GCC versions to dates: https://gcc.gnu.org/develop.html#timeline
  20 set(GCC_MIN_DATE 20150422)
  21 set(GCC_SOFT_ERROR_DATE 20150422)
  22
  23
  24 if(DEFINED LLVM_COMPILER_CHECKED)
  25   return()
  26 endif()
  27 set(LLVM_COMPILER_CHECKED ON)
  28
  29 if(LLVM_FORCE_USE_OLD_TOOLCHAIN)
  30   return()
  31 endif()
  32
  33 function(check_compiler_version NAME NICE_NAME MINIMUM_VERSION SOFT_ERROR_VERSION)
  34   if(NOT CMAKE_CXX_COMPILER_ID STREQUAL NAME)
  35     return()
  36   endif()
  37   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS MINIMUM_VERSION)
  38     message(FATAL_ERROR "Host ${NICE_NAME} version must be at least ${MINIMUM_VERSION}, your version is ${CMAKE_CXX_COMPILER_VERSION}.")
  39   elseif(CMAKE_CXX_COMPILER_VERSION VERSION_LESS SOFT_ERROR_VERSION)
  40     if(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN)
  41       message(WARNING "Host ${NICE_NAME} version should be at least ${SOFT_ERROR_VERSION} because LLVM will soon use new C++ features which your toolchain version doesn't support. Your version is ${CMAKE_CXX_COMPILER_VERSION}. Ignoring because you've set LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN, but very soon your toolchain won't be supported.")
  42     else()
  43       message(FATAL_ERROR "Host ${NICE_NAME} version should be at least ${SOFT_ERROR_VERSION} because LLVM will soon use new C++ features which your toolchain version doesn't support. Your version is ${CMAKE_CXX_COMPILER_VERSION}. You can temporarily opt out using LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN, but very soon your toolchain won't be supported.")
  44     endif()
  45   endif()
  46 endfunction(check_compiler_version)
  47
  48 check_compiler_version("GNU" "GCC" ${GCC_MIN} ${GCC_SOFT_ERROR})
  49 check_compiler_version("Clang" "Clang" ${CLANG_MIN} ${CLANG_SOFT_ERROR})
  50 check_compiler_version("AppleClang" "Apple Clang" ${APPLECLANG_MIN} ${APPLECLANG_SOFT_ERROR})
  51 check_compiler_version("MSVC" "Visual Studio" ${MSVC_MIN} ${MSVC_SOFT_ERROR})
  52
  53 if(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  54   if (CMAKE_CXX_SIMULATE_ID MATCHES "MSVC")
  55     if (CMAKE_CXX_SIMULATE_VERSION VERSION_LESS MSVC_MIN)
  56       message(FATAL_ERROR "Host Clang must have at least -fms-compatibility-version=${MSVC_MIN}, your version is ${CMAKE_CXX_SIMULATE_VERSION}.")
  57     endif()
  58     set(CLANG_CL 1)
  59   elseif(NOT LLVM_ENABLE_LIBCXX)
  60     # Test that we aren't using too old of a version of libstdc++.
  61     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
  62     set(OLD_CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
  63     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++0x")
  64     # Test for libstdc++ version of at least 4.8 by checking for _ZNKSt17bad_function_call4whatEv.
  65     # Note: We should check _GLIBCXX_RELEASE when possible (i.e., for GCC 7.1 and up).
  66     check_cxx_source_compiles("
  67 #include <iosfwd>
  68 #if defined(__GLIBCXX__)
  69 #if __GLIBCXX__ < ${GCC_MIN_DATE}
  70 #error Unsupported libstdc++ version
  71 #endif
  72 #endif
  73 #if defined(__GLIBCXX__)
  74 extern const char _ZNKSt17bad_function_call4whatEv[];
  75 const char *chk = _ZNKSt17bad_function_call4whatEv;
  76 #else
  77 const char *chk = \"\";
  78 #endif
  79 int main() { ++chk; return 0; }
  80 "
  81       LLVM_LIBSTDCXX_MIN)
  82     if(NOT LLVM_LIBSTDCXX_MIN)
  83       message(FATAL_ERROR "libstdc++ version must be at least ${GCC_MIN}.")
  84     endif()
  85     # Test for libstdc++ version of at least 5.1 by checking for std::iostream_category().
  86     # Note: We should check _GLIBCXX_RELEASE when possible (i.e., for GCC 7.1 and up).
  87     check_cxx_source_compiles("
  88 #include <iosfwd>
  89 #if defined(__GLIBCXX__)
  90 #if __GLIBCXX__ < ${GCC_SOFT_ERROR_DATE}
  91 #error Unsupported libstdc++ version
  92 #endif
  93 #endif
  94 #if defined(__GLIBCXX__)
  95 #include <ios>
  96 void foo(void) { (void) std::iostream_category(); }
  97 #endif
  98 int main() { return 0; }
  99 "
 100       LLVM_LIBSTDCXX_SOFT_ERROR)
 101     if(NOT LLVM_LIBSTDCXX_SOFT_ERROR)
 102       if(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN)
 103         message(WARNING "libstdc++ version should be at least ${GCC_SOFT_ERROR} because LLVM will soon use new C++ features which your toolchain version doesn't support. Ignoring because you've set LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN, but very soon your toolchain won't be supported.")
 104       else()
 105         message(FATAL_ERROR "libstdc++ version should be at least ${GCC_SOFT_ERROR} because LLVM will soon use new C++ features which your toolchain version doesn't support. You can temporarily opt out using LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN, but very soon your toolchain won't be supported.")
 106       endif()
 107     endif()
 108     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 109     set(CMAKE_REQUIRED_LIBRARIES ${OLD_CMAKE_REQUIRED_LIBRARIES})
 110   endif()
 111 endif()