autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.2]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  80       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  81       *)
  82         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  83         ;;
  84     esac
  85   fi
  86 done
  87
  88 dnl===-----------------------------------------------------------------------===
  89 dnl===
  90 dnl=== SECTION 2: Architecture, target, and host checks
  91 dnl===
  92 dnl===-----------------------------------------------------------------------===
  93
  94 dnl Check the target for which we're compiling and the host that will do the
  95 dnl compilations. This will tell us which LLVM compiler will be used for
  96 dnl compiling SSA into object code. This needs to be done early because
  97 dnl following tests depend on it.
  98 AC_CANONICAL_TARGET
  99
 100 dnl Determine the platform type and cache its value. This helps us configure
 101 dnl the System library to the correct build platform.
 102 AC_CACHE_CHECK([type of operating system we're going to host on],
 103                [llvm_cv_os_type],
 104 [case $host in
 105   *-*-aix*)
 106     llvm_cv_link_all_option="-Wl,--whole-archive"
 107     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 108     llvm_cv_os_type="AIX"
 109     llvm_cv_platform_type="Unix" ;;
 110   *-*-irix*)
 111     llvm_cv_link_all_option="-Wl,--whole-archive"
 112     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 113     llvm_cv_os_type="IRIX"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-cygwin*)
 116     llvm_cv_link_all_option="-Wl,--whole-archive"
 117     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 118     llvm_cv_os_type="Cygwin"
 119     llvm_cv_platform_type="Unix" ;;
 120   *-*-darwin*)
 121     llvm_cv_link_all_option="-Wl,-all_load"
 122     llvm_cv_link_all_option="-Wl,-noall_load"
 123     llvm_cv_os_type="Darwin"
 124     llvm_cv_platform_type="Unix" ;;
 125   *-*-freebsd*)
 126     llvm_cv_link_all_option="-Wl,--whole-archive"
 127     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 128     llvm_cv_os_type="FreeBSD"
 129     llvm_cv_platform_type="Unix" ;;
 130   *-*-openbsd*)
 131     llvm_cv_link_all_option="-Wl,--whole-archive"
 132     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 133     llvm_cv_os_type="OpenBSD"
 134     llvm_cv_platform_type="Unix" ;;
 135   *-*-netbsd*)
 136     llvm_cv_link_all_option="-Wl,--whole-archive"
 137     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 138     llvm_cv_os_type="NetBSD"
 139     llvm_cv_platform_type="Unix" ;;
 140   *-*-hpux*)
 141     llvm_cv_link_all_option="-Wl,--whole-archive"
 142     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 143     llvm_cv_os_type="HP-UX"
 144     llvm_cv_platform_type="Unix" ;;
 145   *-*-interix*)
 146     llvm_cv_link_all_option="-Wl,--whole-archive"
 147     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 148     llvm_cv_os_type="Interix"
 149     llvm_cv_platform_type="Unix" ;;
 150   *-*-linux*)
 151     llvm_cv_link_all_option="-Wl,--whole-archive"
 152     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 153     llvm_cv_os_type="Linux"
 154     llvm_cv_platform_type="Unix" ;;
 155   *-*-solaris*)
 156     llvm_cv_link_all_option="-Wl,-z,allextract"
 157     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 158     llvm_cv_os_type="SunOS"
 159     llvm_cv_platform_type="Unix" ;;
 160   *-*-win32*)
 161     llvm_cv_link_all_option="-Wl,--whole-archive"
 162     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 163     llvm_cv_os_type="Win32"
 164     llvm_cv_platform_type="Win32" ;;
 165   *-*-mingw*)
 166     llvm_cv_link_all_option="-Wl,--whole-archive"
 167     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 168     llvm_cv_os_type="MingW"
 169     llvm_cv_platform_type="Win32" ;;
 170   *)
 171     llvm_cv_link_all_option=""
 172     llvm_cv_no_link_all_option=""
 173     llvm_cv_os_type="Unknown"
 174     llvm_cv_platform_type="Unknown" ;;
 175 esac])
 176
 177 dnl Make sure we aren't attempting to configure for an unknown system
 178 if test "$llvm_cv_os_type" = "Unknown" ; then
 179   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 180 fi
 181
 182 dnl Set the "OS" Makefile variable based on the platform type so the
 183 dnl makefile can configure itself to specific build hosts
 184 AC_SUBST(OS,$llvm_cv_os_type)
 185
 186 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 187 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 188 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 189
 190 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 191 dnl This is used by lib/System to determine the basic kind of implementation
 192 dnl to use.
 193 case $llvm_cv_platform_type in
 194   Unix)
 195     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 196     AC_SUBST(LLVM_ON_UNIX,[1])
 197     AC_SUBST(LLVM_ON_WIN32,[0])
 198     ;;
 199   Win32)
 200     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 201     AC_SUBST(LLVM_ON_UNIX,[0])
 202     AC_SUBST(LLVM_ON_WIN32,[1])
 203     ;;
 204 esac
 205
 206 dnl Determine what our target architecture is and configure accordingly.
 207 dnl This will allow Makefiles to make a distinction between the hardware and
 208 dnl the OS.
 209 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 210 [case $target in
 211   i?86-*)                 llvm_cv_target_arch="x86" ;;
 212   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 213   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 214   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 215   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 216   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 217   arm-*)                  llvm_cv_target_arch="ARM" ;;
 218   mips-*)                 llvm_cv_target_arch="Mips" ;;
 219   *)                      llvm_cv_target_arch="Unknown" ;;
 220 esac])
 221
 222 if test "$llvm_cv_target_arch" = "Unknown" ; then
 223   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 224 fi
 225
 226 dnl Define a substitution, ARCH, for the target architecture
 227 AC_SUBST(ARCH,$llvm_cv_target_arch)
 228
 229 dnl Check for the endianness of the target
 230 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 231
 232 dnl Check for build platform executable suffix if we're crosscompiling
 233 if test "$cross_compiling" = yes; then
 234   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 235   AC_BUILD_EXEEXT
 236 else
 237   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 238 fi
 239
 240 dnl Check to see if there's a "CVS" (or .svn) directory indicating that this
 241 dnl build is being done from a checkout. This sets up several defaults for the
 242 dnl command line switches. When we build with a CVS directory, we get a
 243 dnl debug with assertions turned on. Without, we assume a source release and we
 244 dnl get an optimized build without assertions. See --enable-optimized and
 245 dnl --enable-assertions below
 246 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn"; then
 247   cvsbuild="yes"
 248   optimize="no"
 249   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 250 else
 251   cvsbuild="no"
 252   optimize="yes"
 253 fi
 254
 255 dnl===-----------------------------------------------------------------------===
 256 dnl===
 257 dnl=== SECTION 3: Command line arguments for the configure script.
 258 dnl===
 259 dnl===-----------------------------------------------------------------------===
 260
 261 dnl --enable-optimized : check whether they want to do an optimized build:
 262 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 263  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 264 if test ${enableval} = "no" ; then
 265   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 266 else
 267   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 268 fi
 269
 270 dnl --enable-assertions : check whether they want to turn on assertions or not:
 271 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 272   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 273 if test ${enableval} = "yes" ; then
 274   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 275 else
 276   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 277 fi
 278
 279 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 280 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 281   [--enable-expensive-checks,Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 282 if test ${enableval} = "yes" ; then
 283   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 284   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 285 else
 286   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 287   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 288 fi
 289
 290 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 291 AC_ARG_ENABLE(debug-runtime,
 292    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 293 if test ${enableval} = "no" ; then
 294   AC_SUBST(DEBUG_RUNTIME,[[]])
 295 else
 296   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 297 fi
 298
 299 dnl --enable-jit: check whether they want to enable the jit
 300 AC_ARG_ENABLE(jit,
 301   AS_HELP_STRING(--enable-jit,
 302                  [Enable Just In Time Compiling (default is YES)]),,
 303   enableval=default)
 304 if test ${enableval} = "no"
 305 then
 306   AC_SUBST(JIT,[[]])
 307 else
 308   case "$llvm_cv_target_arch" in
 309     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 310     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 311     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 312     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 313     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 314     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 315     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 316     Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 317     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 318   esac
 319 fi
 320
 321 dnl Allow enablement of doxygen generated documentation
 322 AC_ARG_ENABLE(doxygen,
 323               AS_HELP_STRING([--enable-doxygen],
 324                              [Build doxygen documentation (default is NO)]),,
 325                              enableval=default)
 326 case "$enableval" in
 327   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 328   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 329   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 330   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 331 esac
 332
 333 dnl Allow disablement of threads
 334 AC_ARG_ENABLE(threads,
 335               AS_HELP_STRING([--enable-threads],
 336                              [Use threads if available (default is YES)]),,
 337                              enableval=default)
 338 case "$enableval" in
 339   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 340   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 341   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 342   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 343 esac
 344 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 345
 346 dnl Allow building with position independent code
 347 AC_ARG_ENABLE(pic,
 348   AS_HELP_STRING([--enable-pic],
 349                  [Build LLVM with Position Independent Code (default is NO)]),,
 350                  enableval=default)
 351 case "$enableval" in
 352   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 353   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 354   default) AC_SUBST(ENABLE_PIC,[0]) ;;
 355   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 356 esac
 357 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 358                    [Define if position independent code is enabled])
 359
 360 dnl Allow specific targets to be specified for building (or not)
 361 TARGETS_TO_BUILD=""
 362 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 363     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 364     enableval=all)
 365 case "$enableval" in
 366   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips CellSPU CBackend MSIL" ;;
 367   host-only)
 368     case "$llvm_cv_target_arch" in
 369       x86)     TARGETS_TO_BUILD="X86" ;;
 370       x86_64)  TARGETS_TO_BUILD="X86" ;;
 371       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 372       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 373       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 374       IA64)    TARGETS_TO_BUILD="IA64" ;;
 375       ARM)     TARGETS_TO_BUILD="ARM" ;;
 376       Mips)    TARGETS_TO_BUILD="Mips" ;;
 377       CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
 378       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 379     esac
 380     ;;
 381   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 382       case "$a_target" in
 383         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 384         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 385         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 386         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 387         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 388         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 389         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 390         mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 391         spu)     TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 392         cbe)     TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 393         msil)    TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 394         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 395       esac
 396   done
 397   ;;
 398 esac
 399 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 400
 401 dnl Prevent the CBackend from using printf("%a") for floating point so older
 402 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 403 dnl can still compile the CBE's output
 404 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 405   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 406   enableval=default)
 407 case "$enableval" in
 408   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 409   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 410   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 411   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 412 esac
 413 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 414                    [Define if CBE is enabled for printf %a output])
 415
 416 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 417 AC_ARG_WITH(llvmgccdir,
 418   AS_HELP_STRING([--with-llvmgccdir],
 419     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 420     withval=default)
 421 case "$withval" in
 422   default) WITH_LLVMGCCDIR=default ;;
 423   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 424   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 425 esac
 426
 427 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 428 AC_ARG_WITH(llvmgcc,
 429   AS_HELP_STRING([--with-llvmgcc],
 430     [Specify location of llvm-gcc driver (default searches PATH)]),
 431     LLVMGCC=$with_llvmgcc
 432       WITH_LLVMGCCDIR="",)
 433
 434 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 435 AC_ARG_WITH(llvmgxx,
 436   AS_HELP_STRING([--with-llvmgxx],
 437     [Specify location of llvm-g++ driver (default searches PATH)]),
 438     LLVMGXX=$with_llvmgxx
 439     WITH_LLVMGCCDIR="",)
 440
 441 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 442    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 443 fi
 444
 445 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 446    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 447 fi
 448
 449 dnl Specify extra build options
 450 AC_ARG_WITH(extra-options,
 451   AS_HELP_STRING([--with-extra-options],
 452                  [Specify addtional options to compile LLVM with]),,
 453                  withval=default)
 454 case "$withval" in
 455   default) EXTRA_OPTIONS= ;;
 456   *) EXTRA_OPTIONS=$withval ;;
 457 esac
 458 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 459
 460 dnl Allow specific bindings to be specified for building (or not)
 461 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 462     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 463     enableval=default)
 464 BINDINGS_TO_BUILD=""
 465 case "$enableval" in
 466   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 467   all ) BINDINGS_TO_BUILD="ocaml" ;;
 468   none | no) BINDINGS_TO_BUILD="" ;;
 469   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 470       case "$a_binding" in
 471         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 472         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 473       esac
 474   done
 475   ;;
 476 esac
 477
 478 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 479 dnl script for bindings/ocaml/configure, except that its auto value depends on
 480 dnl OCAMLC, which is found here to support tests.
 481 AC_ARG_WITH([ocaml-libdir],
 482   [AS_HELP_STRING([--with-ocaml-libdir],
 483     [Specify install location for ocaml bindings (default is stdlib)])],
 484   [],
 485   [withval=auto])
 486 case "$withval" in
 487   auto) with_ocaml_libdir="$withval" ;;
 488   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 489   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 490 esac
 491
 492 dnl===-----------------------------------------------------------------------===
 493 dnl===
 494 dnl=== SECTION 4: Check for programs we need and that they are the right version
 495 dnl===
 496 dnl===-----------------------------------------------------------------------===
 497
 498 dnl Check for compilation tools
 499 AC_PROG_CPP
 500 AC_PROG_CC(gcc)
 501 AC_PROG_CXX(g++)
 502 AC_PROG_FLEX
 503 AC_PROG_BISON
 504
 505 AC_PROG_NM
 506 AC_SUBST(NM)
 507
 508 dnl Check for the tools that the makefiles require
 509 AC_CHECK_GNU_MAKE
 510 AC_PROG_LN_S
 511 AC_PATH_PROG(CMP, [cmp], [cmp])
 512 AC_PATH_PROG(CP, [cp], [cp])
 513 AC_PATH_PROG(DATE, [date], [date])
 514 AC_PATH_PROG(FIND, [find], [find])
 515 AC_PATH_PROG(GREP, [grep], [grep])
 516 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 517 AC_PATH_PROG(MV,   [mv],   [mv])
 518 AC_PROG_RANLIB
 519 AC_PATH_PROG(RM,   [rm],   [rm])
 520 AC_PATH_PROG(SED,  [sed],  [sed])
 521 AC_PATH_PROG(TAR,  [tar],  [gtar])
 522 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 523
 524 dnl Looking for misc. graph plotting software
 525 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 526 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 527   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 528   dnl If we're targeting for mingw we should emit windows paths, not msys
 529   if test "$llvm_cv_os_type" = "MingW" ; then
 530     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 531   fi
 532   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 533    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 534 fi
 535 AC_PATH_PROG(DOT, [dot], [echo dot])
 536 if test "$DOT" != "echo dot" ; then
 537   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 538   dnl If we're targeting for mingw we should emit windows paths, not msys
 539   if test "$llvm_cv_os_type" = "MingW" ; then
 540     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 541   fi
 542   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 543    [Define to path to dot program if found or 'echo dot' otherwise])
 544 fi
 545 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 546 if test "$GV" != "echo gv" ; then
 547   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 548   dnl If we're targeting for mingw we should emit windows paths, not msys
 549   if test "$llvm_cv_os_type" = "MingW" ; then
 550     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 551   fi
 552   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 553    [Define to path to gv program if found or 'echo gv' otherwise])
 554 fi
 555 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 556 if test "$DOTTY" != "echo dotty" ; then
 557   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 558   dnl If we're targeting for mingw we should emit windows paths, not msys
 559   if test "$llvm_cv_os_type" = "MingW" ; then
 560     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 561   fi
 562   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 563    [Define to path to dotty program if found or 'echo dotty' otherwise])
 564 fi
 565
 566 dnl Look for a sufficiently recent version of Perl.
 567 LLVM_PROG_PERL([5.006])
 568 AC_SUBST(PERL)
 569 if test x"$PERL" = xnone; then
 570    AC_SUBST(HAVE_PERL,0)
 571    AC_MSG_ERROR([perl is required but was not found, please install it])
 572 else
 573    AC_SUBST(HAVE_PERL,1)
 574 fi
 575
 576 dnl Find the install program
 577 AC_PROG_INSTALL
 578
 579 dnl Checks for documentation and testing tools that we can do without. If these
 580 dnl are not found then they are set to "true" which always succeeds but does
 581 dnl nothing. This just lets the build output show that we could have done
 582 dnl something if the tool was available.
 583 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 584 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 585 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 586 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 587 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 588 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 589 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 590 DJ_AC_PATH_TCLSH
 591 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 592 AC_PATH_PROG(OCAMLC,[ocamlc],[echo "Skipped: ocamlc not found"])
 593 AC_PATH_PROG(OCAMLOPT,[ocamlopt],[echo "Skipped: ocamlopt not found"])
 594 AC_PATH_PROG(OCAMLDEP,[ocamldep],[echo "Skipped: ocamldep not found"])
 595
 596 dnl Determine if the linker supports the -R option.
 597 AC_LINK_USE_R
 598
 599 dnl Check for libtool and the library that has dlopen function (which must come
 600 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 601 dnl libtool).
 602 AC_LIBTOOL_DLOPEN
 603 AC_LIB_LTDL
 604 AC_PROG_LIBTOOL
 605
 606 if test "$lt_cv_dlopen_self" = "yes" ; then
 607   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 608               [Define if dlopen(0) will open the symbols of the program])
 609 fi
 610
 611 if test "$WITH_LLVMGCCDIR" = "default" ; then
 612   LLVMGCC="llvm-gcc${EXEEXT}"
 613   LLVMGXX="llvm-g++${EXEEXT}"
 614   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 615   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 616 else
 617   if test -z "$LLVMGCC"; then
 618     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 619   fi
 620   if test -z "$LLVMGXX"; then
 621     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 622   fi
 623   AC_SUBST(LLVMGCC,$LLVMGCC)
 624   AC_SUBST(LLVMGXX,$LLVMGXX)
 625 fi
 626
 627 AC_MSG_CHECKING([tool compatibility])
 628
 629 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 630 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 631 dnl to support those options.
 632 dnl "icc" emits gcc signatures
 633 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 634 ICC=no
 635 IXX=no
 636 case $CC in
 637   icc*|icpc*)
 638     ICC=yes
 639     IXX=yes
 640     ;;
 641    *)
 642     ;;
 643 esac
 644
 645 if test "$GCC" != "yes" && test "$ICC" != "yes"
 646 then
 647   AC_MSG_ERROR([gcc|icc required but not found])
 648 fi
 649
 650 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 651 if test "$GXX" != "yes" && test "$IXX" != "yes"
 652 then
 653   AC_MSG_ERROR([g++|icc required but not found])
 654 fi
 655
 656 dnl Verify that GCC is version 3.0 or higher
 657 if test "$GCC" = "yes"
 658 then
 659   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 660   if test "$gccmajor" -lt "3"
 661   then
 662     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 663   fi
 664 fi
 665
 666 dnl Check for GNU Make.  We use its extensions, so don't build without it
 667 if test -z "$llvm_cv_gnu_make_command"
 668 then
 669   AC_MSG_ERROR([GNU Make required but not found])
 670 fi
 671
 672 dnl Tool compatibility is okay if we make it here.
 673 AC_MSG_RESULT([ok])
 674
 675 dnl===-----------------------------------------------------------------------===
 676 dnl===
 677 dnl=== SECTION 5: Check for libraries
 678 dnl===
 679 dnl===-----------------------------------------------------------------------===
 680
 681 dnl libelf is for sparc only; we can ignore it if we don't have it
 682 AC_CHECK_LIB(elf, elf_begin)
 683 AC_CHECK_LIB(m,sin)
 684 if test "$llvm_cv_os_type" = "MingW" ; then
 685   AC_CHECK_LIB(imagehlp, main)
 686   AC_CHECK_LIB(psapi, main)
 687 fi
 688
 689 dnl lt_dlopen may be required for plugin support.
 690 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 691               [Define if lt_dlopen() is available on this platform]),
 692               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 693                            not be available]))
 694
 695 dnl dlopen() is required for plugin support.
 696 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 697                [Define if dlopen() is available on this platform.]),
 698                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 699
 700 dnl mallinfo is optional; the code can compile (minus features) without it
 701 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 702                [Define if mallinfo() is available on this platform.]))
 703
 704 dnl pthread locking functions are optional - but llvm will not be thread-safe
 705 dnl without locks.
 706 if test "$ENABLE_THREADS" -eq 1 ; then
 707   AC_CHECK_LIB(pthread,pthread_mutex_init)
 708   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 709                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 710                            [Have pthread_mutex_lock]))
 711 fi
 712
 713 dnl Allow extra x86-disassembler library
 714 AC_ARG_WITH(udis86,
 715   AS_HELP_STRING([--with-udis86=<path>],
 716     [Use udis86 external x86 disassembler library]),
 717     [
 718       AC_SUBST(USE_UDIS86, [1])
 719       case "$withval" in
 720         /usr/lib|yes) ;;
 721         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 722       esac
 723       AC_CHECK_LIB(udis86, ud_init, [], [
 724         echo "Error! You need to have libudis86 around."
 725         exit -1
 726       ])
 727     ],
 728     AC_SUBST(USE_UDIS86, [0]))
 729 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 730                    [Define if use udis86 library])
 731
 732 dnl===-----------------------------------------------------------------------===
 733 dnl===
 734 dnl=== SECTION 6: Check for header files
 735 dnl===
 736 dnl===-----------------------------------------------------------------------===
 737
 738 dnl First, use autoconf provided macros for specific headers that we need
 739 dnl We don't check for ancient stuff or things that are guaranteed to be there
 740 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 741 dnl Generally we're looking for POSIX headers.
 742 AC_HEADER_DIRENT
 743 AC_HEADER_MMAP_ANONYMOUS
 744 AC_HEADER_STAT
 745 AC_HEADER_STDC
 746 AC_HEADER_SYS_WAIT
 747 AC_HEADER_TIME
 748
 749 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 750 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 751 AC_CHECK_HEADERS([windows.h])
 752 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
 753 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
 754 if test "$ENABLE_THREADS" -eq 1 ; then
 755   AC_CHECK_HEADERS(pthread.h,
 756                   AC_SUBST(HAVE_PTHREAD, 1),
 757                    AC_SUBST(HAVE_PTHREAD, 0))
 758 else
 759   AC_SUBST(HAVE_PTHREAD, 0)
 760 fi
 761
 762 dnl===-----------------------------------------------------------------------===
 763 dnl===
 764 dnl=== SECTION 7: Check for types and structures
 765 dnl===
 766 dnl===-----------------------------------------------------------------------===
 767
 768 AC_HUGE_VAL_CHECK
 769 AC_TYPE_PID_T
 770 AC_TYPE_SIZE_T
 771 AC_TYPE_SIGNAL
 772 AC_STRUCT_TM
 773 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 774 AC_CHECK_TYPES([uint64_t],,
 775          AC_CHECK_TYPES([u_int64_t],,
 776          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 777
 778 dnl===-----------------------------------------------------------------------===
 779 dnl===
 780 dnl=== SECTION 8: Check for specific functions needed
 781 dnl===
 782 dnl===-----------------------------------------------------------------------===
 783
 784 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 785 AC_CHECK_FUNCS([powf fmodf strtof round ])
 786 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
 787 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 788 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 789 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 790 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 791 AC_C_PRINTF_A
 792 AC_FUNC_ALLOCA
 793 AC_FUNC_RAND48
 794
 795 dnl Check for variations in the Standard C++ library and STL. These macros are
 796 dnl provided by LLVM in the autoconf/m4 directory.
 797 AC_CXX_HAVE_HASH_MAP
 798 AC_CXX_HAVE_HASH_SET
 799 AC_CXX_HAVE_STD_ITERATOR
 800 AC_CXX_HAVE_BI_ITERATOR
 801 AC_CXX_HAVE_FWD_ITERATOR
 802 AC_FUNC_ISNAN
 803 AC_FUNC_ISINF
 804
 805 dnl Check for mmap support.We also need to know if /dev/zero is required to
 806 dnl be opened for allocating RWX memory.
 807 dnl Make sure we aren't attempting to configure for an unknown system
 808 if test "$llvm_cv_platform_type" = "Unix" ; then
 809   AC_FUNC_MMAP
 810   AC_FUNC_MMAP_FILE
 811   AC_NEED_DEV_ZERO_FOR_MMAP
 812
 813   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 814   then
 815     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 816   fi
 817   if test "$ac_cv_func_mmap_file" = "no"
 818   then
 819     AC_MSG_WARN([mmap() of files required but not found])
 820   fi
 821 fi
 822
 823 dnl===-----------------------------------------------------------------------===
 824 dnl===
 825 dnl=== SECTION 9: Additional checks, variables, etc.
 826 dnl===
 827 dnl===-----------------------------------------------------------------------===
 828
 829 dnl Check, whether __dso_handle is present
 830 AC_CHECK_FUNCS([__dso_handle])
 831
 832 dnl See if the llvm-gcc executable can compile to LLVM assembly
 833 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 834 [llvm_cv_llvmgcc_sanity="no"
 835 if test -x "$LLVMGCC" ; then
 836   cp /dev/null conftest.c
 837   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
 838       grep 'target datalayout =' > /dev/null 2>&1
 839   if test $? -eq 0 ; then
 840     llvm_cv_llvmgcc_sanity="yes"
 841   fi
 842   rm conftest.c
 843 fi])
 844
 845 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 846 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 847   AC_MSG_CHECKING([llvm-gcc component support])
 848   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 849   AC_SUBST(LLVMCC1,$llvmcc1path)
 850   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 851   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 852   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 853   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 854   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 855   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 856   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 857   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 858   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 859   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 860   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ -]*\).*/\1/'`]
 861   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
 862   AC_MSG_RESULT([ok])
 863 fi
 864
 865 dnl Propagate the shared library extension that the libltdl checks did to
 866 dnl the Makefiles so we can use it there too
 867 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 868
 869 # Translate the various configuration directories and other basic
 870 # information into substitutions that will end up in Makefile.config.in
 871 # that these configured values can be used by the makefiles
 872 if test "${prefix}" = "NONE" ; then
 873   prefix="/usr/local"
 874 fi
 875 eval LLVM_PREFIX="${prefix}";
 876 eval LLVM_BINDIR="${prefix}/bin";
 877 eval LLVM_LIBDIR="${prefix}/lib";
 878 eval LLVM_DATADIR="${prefix}/share/llvm";
 879 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 880 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 881 eval LLVM_INCLUDEDIR="${prefix}/include";
 882 eval LLVM_INFODIR="${prefix}/info";
 883 eval LLVM_MANDIR="${prefix}/man";
 884 LLVM_CONFIGTIME=`date`
 885 AC_SUBST(LLVM_PREFIX)
 886 AC_SUBST(LLVM_BINDIR)
 887 AC_SUBST(LLVM_LIBDIR)
 888 AC_SUBST(LLVM_DATADIR)
 889 AC_SUBST(LLVM_DOCSDIR)
 890 AC_SUBST(LLVM_ETCDIR)
 891 AC_SUBST(LLVM_INCLUDEDIR)
 892 AC_SUBST(LLVM_INFODIR)
 893 AC_SUBST(LLVM_MANDIR)
 894 AC_SUBST(LLVM_CONFIGTIME)
 895
 896 # Place the various directores into the config.h file as #defines so that we
 897 # can know about the installation paths within LLVM.
 898 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 899                    [Installation prefix directory])
 900 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 901                    [Installation directory for binary executables])
 902 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 903                    [Installation directory for libraries])
 904 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 905                    [Installation directory for data files])
 906 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
 907                    [Installation directory for documentation])
 908 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 909                    [Installation directory for config files])
 910 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 911                    [Installation directory for include files])
 912 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 913                    [Installation directory for .info files])
 914 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 915                    [Installation directory for man pages])
 916 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 917                    [Time at which LLVM was configured])
 918 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
 919                    [Host triple we were built on])
 920
 921 # Determine which bindings to build.
 922 if test "$BINDINGS_TO_BUILD" = auto ; then
 923   BINDINGS_TO_BUILD=""
 924   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
 925     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
 926   fi
 927 fi
 928 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
 929
 930 # This isn't really configurey, but it avoids having to repeat the list in
 931 # other files.
 932 AC_SUBST(ALL_BINDINGS,ocaml)
 933
 934 # Do any work necessary to ensure that bindings have what they need.
 935 binding_prereqs_failed=0
 936 for a_binding in $BINDINGS_TO_BUILD ; do
 937   case "$a_binding" in
 938   ocaml)
 939     if test "x$OCAMLC" = x ; then
 940       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
 941       binding_prereqs_failed=1
 942     fi
 943     if test "x$OCAMLDEP" = x ; then
 944       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
 945       binding_prereqs_failed=1
 946     fi
 947     if test "x$OCAMLOPT" = x ; then
 948       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
 949       dnl ocamlopt is optional!
 950     fi
 951     if test "x$with_ocaml_libdir" != xauto ; then
 952       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
 953     else
 954       ocaml_stdlib="`"$OCAMLC" -where`"
 955       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
 956       then
 957         # ocaml stdlib is beneath our prefix; use stdlib
 958         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
 959       else
 960         # ocaml stdlib is outside our prefix; use libdir/ocaml
 961         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
 962       fi
 963     fi
 964     ;;
 965   esac
 966 done
 967 if test "$binding_prereqs_failed" = 1 ; then
 968   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
 969 fi
 970
 971
 972 dnl===-----------------------------------------------------------------------===
 973 dnl===
 974 dnl=== SECTION 10: Specify the output files and generate it
 975 dnl===
 976 dnl===-----------------------------------------------------------------------===
 977
 978 dnl Configure header files
 979 dnl WARNING: dnl If you add or remove any of the following config headers, then
 980 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 981 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 982 dnl files can be updated automatically when their *.in sources change.
 983 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 984 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 985 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 986 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 987 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 988
 989 dnl Configure the makefile's configuration data
 990 AC_CONFIG_FILES([Makefile.config])
 991
 992 dnl Configure the RPM spec file for LLVM
 993 AC_CONFIG_FILES([llvm.spec])
 994
 995 dnl Configure doxygen's configuration file
 996 AC_CONFIG_FILES([docs/doxygen.cfg])
 997
 998 dnl Do the first stage of configuration for llvm-config.in.
 999 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1000
1001 dnl Do special configuration of Makefiles
1002 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1003 AC_CONFIG_MAKEFILE(Makefile)
1004 AC_CONFIG_MAKEFILE(Makefile.common)
1005 AC_CONFIG_MAKEFILE(examples/Makefile)
1006 AC_CONFIG_MAKEFILE(lib/Makefile)
1007 AC_CONFIG_MAKEFILE(runtime/Makefile)
1008 AC_CONFIG_MAKEFILE(test/Makefile)
1009 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1010 AC_CONFIG_MAKEFILE(tools/Makefile)
1011 AC_CONFIG_MAKEFILE(utils/Makefile)
1012 AC_CONFIG_MAKEFILE(projects/Makefile)
1013 AC_CONFIG_MAKEFILE(bindings/Makefile)
1014 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1015
1016 dnl Finally, crank out the output
1017 AC_OUTPUT