utils/gn/secondary/llvm/lib/Target/AMDGPU/Utils/BUILD.gn

   1 import("//llvm/utils/TableGen/tablegen.gni")
   2
   3 tablegen("AMDGPUGenSearchableTables") {
   4   visibility = [ ":Utils" ]
   5   args = [ "-gen-searchable-tables" ]
   6   td_file = "../AMDGPU.td"
   7 }
   8
   9 static_library("Utils") {
  10   output_name = "LLVMAMDGPUUtils"
  11   public_deps = [
  12     ":AMDGPUGenSearchableTables",
  13   ]
  14   deps = [
  15     "//llvm/lib/BinaryFormat",
  16     "//llvm/lib/IR",
  17     "//llvm/lib/MC",
  18     "//llvm/lib/Support",
  19
  20     # MCTargetDesc depends on Utils, so we can't depend on the full
  21     # MCTargetDesc target here: it would form a cycle.
  22     "//llvm/lib/Target/AMDGPU/MCTargetDesc:tablegen",
  23   ]
  24
  25   # AMDGPUBaseInfo.h includes a header from MCTargetDesc :-/
  26   include_dirs = [ ".." ]
  27   sources = [
  28     "AMDGPUAsmUtils.cpp",
  29     "AMDGPUBaseInfo.cpp",
  30     "AMDGPUPALMetadata.cpp",
  31     "AMDKernelCodeTUtils.cpp",
  32   ]
  33 }