utils/gn/secondary/llvm/lib/Target/BPF/MCTargetDesc/BUILD.gn

   1 import("//llvm/utils/TableGen/tablegen.gni")
   2
   3 tablegen("BPFGenAsmWriter") {
   4   visibility = [ ":MCTargetDesc" ]
   5   args = [ "-gen-asm-writer" ]
   6   td_file = "../BPF.td"
   7 }
   8
   9 tablegen("BPFGenInstrInfo") {
  10   visibility = [ ":MCTargetDesc" ]
  11   args = [ "-gen-instr-info" ]
  12   td_file = "../BPF.td"
  13 }
  14
  15 tablegen("BPFGenMCCodeEmitter") {
  16   visibility = [ ":MCTargetDesc" ]
  17   args = [ "-gen-emitter" ]
  18   td_file = "../BPF.td"
  19 }
  20
  21 tablegen("BPFGenRegisterInfo") {
  22   visibility = [ ":MCTargetDesc" ]
  23   args = [ "-gen-register-info" ]
  24   td_file = "../BPF.td"
  25 }
  26
  27 tablegen("BPFGenSubtargetInfo") {
  28   visibility = [ ":MCTargetDesc" ]
  29   args = [ "-gen-subtarget" ]
  30   td_file = "../BPF.td"
  31 }
  32
  33 static_library("MCTargetDesc") {
  34   output_name = "LLVMBPFDesc"
  35
  36   # This should contain tablegen targets generating .inc files included
  37   # by other targets. .inc files only used by .cpp files in this directory
  38   # should be in deps instead.
  39   public_deps = [
  40     ":BPFGenInstrInfo",
  41     ":BPFGenRegisterInfo",
  42     ":BPFGenSubtargetInfo",
  43   ]
  44   deps = [
  45     ":BPFGenAsmWriter",
  46     ":BPFGenMCCodeEmitter",
  47     "//llvm/lib/MC",
  48     "//llvm/lib/MC/MCDisassembler",
  49     "//llvm/lib/Support",
  50     "//llvm/lib/Target/BPF/TargetInfo",
  51   ]
  52   include_dirs = [ ".." ]
  53   sources = [
  54     "BPFAsmBackend.cpp",
  55     "BPFELFObjectWriter.cpp",
  56     "BPFInstPrinter.cpp",
  57     "BPFMCCodeEmitter.cpp",
  58     "BPFMCTargetDesc.cpp",
  59   ]
  60 }