utils/gn/secondary/llvm/lib/Target/Mips/MCTargetDesc/BUILD.gn

   1 import("//llvm/utils/TableGen/tablegen.gni")
   2
   3 tablegen("MipsGenAsmWriter") {
   4   visibility = [ ":MCTargetDesc" ]
   5   args = [ "-gen-asm-writer" ]
   6   td_file = "../Mips.td"
   7 }
   8
   9 tablegen("MipsGenInstrInfo") {
  10   visibility = [ ":tablegen" ]
  11   args = [ "-gen-instr-info" ]
  12   td_file = "../Mips.td"
  13 }
  14
  15 tablegen("MipsGenMCCodeEmitter") {
  16   visibility = [ ":MCTargetDesc" ]
  17   args = [ "-gen-emitter" ]
  18   td_file = "../Mips.td"
  19 }
  20
  21 tablegen("MipsGenRegisterInfo") {
  22   visibility = [ ":tablegen" ]
  23   args = [ "-gen-register-info" ]
  24   td_file = "../Mips.td"
  25 }
  26
  27 tablegen("MipsGenSubtargetInfo") {
  28   visibility = [ ":tablegen" ]
  29   args = [ "-gen-subtarget" ]
  30   td_file = "../Mips.td"
  31 }
  32
  33 # This should contain tablegen targets generating .inc files included
  34 # by other targets. .inc files only used by .cpp files in this directory
  35 # should be in deps on the static_library instead.
  36 group("tablegen") {
  37   visibility = [
  38     ":MCTargetDesc",
  39     "../TargetInfo",
  40   ]
  41   public_deps = [
  42     ":MipsGenInstrInfo",
  43     ":MipsGenRegisterInfo",
  44     ":MipsGenSubtargetInfo",
  45   ]
  46 }
  47
  48 static_library("MCTargetDesc") {
  49   output_name = "LLVMMipsDesc"
  50   public_deps = [
  51     ":tablegen",
  52   ]
  53   deps = [
  54     ":MipsGenAsmWriter",
  55     ":MipsGenMCCodeEmitter",
  56     "//llvm/lib/MC",
  57     "//llvm/lib/Support",
  58     "//llvm/lib/Target/Mips/TargetInfo",
  59   ]
  60   include_dirs = [ ".." ]
  61   sources = [
  62     "MipsABIFlagsSection.cpp",
  63     "MipsABIInfo.cpp",
  64     "MipsAsmBackend.cpp",
  65     "MipsELFObjectWriter.cpp",
  66     "MipsELFStreamer.cpp",
  67     "MipsInstPrinter.cpp",
  68     "MipsMCAsmInfo.cpp",
  69     "MipsMCCodeEmitter.cpp",
  70     "MipsMCExpr.cpp",
  71     "MipsMCTargetDesc.cpp",
  72     "MipsNaClELFStreamer.cpp",
  73     "MipsOptionRecord.cpp",
  74     "MipsTargetStreamer.cpp",
  75   ]
  76 }