utils/gn/secondary/llvm/tools/llvm-ar/BUILD.gn

   1 import("//llvm/tools/binutils_symlinks.gni")
   2 import("//llvm/utils/gn/build/symlink_or_copy.gni")
   3
   4 symlinks = [
   5   "llvm-dlltool",
   6   "llvm-lib",
   7   "llvm-ranlib",
   8 ]
   9 if (llvm_install_binutils_symlinks) {
  10   symlinks += [
  11     "ar",
  12     "dlltool",
  13     "ranlib",
  14   ]
  15 }
  16 foreach(target, symlinks) {
  17   symlink_or_copy(target) {
  18     deps = [
  19       ":llvm-ar",
  20     ]
  21     source = "llvm-ar"
  22     output = "$root_out_dir/bin/$target"
  23   }
  24 }
  25
  26 # //:llvm-ar depends on this symlink target, see comment in //BUILD.gn.
  27 group("symlinks") {
  28   deps = []
  29   foreach(target, symlinks) {
  30     deps += [ ":$target" ]
  31   }
  32 }
  33
  34 executable("llvm-ar") {
  35   deps = [
  36     "//llvm/lib/IR",
  37     "//llvm/lib/Object",
  38     "//llvm/lib/Support",
  39     "//llvm/lib/Target:TargetsToBuild",
  40     "//llvm/lib/ToolDrivers/llvm-dlltool:DlltoolDriver",
  41     "//llvm/lib/ToolDrivers/llvm-lib:LibDriver",
  42   ]
  43   sources = [
  44     "llvm-ar.cpp",
  45   ]
  46 }