utils/gn/secondary/llvm/tools/llvm-dwp/BUILD.gn

   1 import("//llvm/tools/binutils_symlinks.gni")
   2 import("//llvm/utils/gn/build/symlink_or_copy.gni")
   3
   4 if (llvm_install_binutils_symlinks) {
   5   symlink_or_copy("dwp") {
   6     deps = [
   7       ":llvm-dwp",
   8     ]
   9     source = "llvm-dwp"
  10     output = "$root_out_dir/bin/dwp"
  11   }
  12 }
  13
  14 # //:llvm-dwp depends on this symlink target, see comment in //BUILD.gn.
  15 group("symlinks") {
  16   deps = [
  17     ":llvm-dwp",
  18   ]
  19   if (llvm_install_binutils_symlinks) {
  20     deps += [ ":dwp" ]
  21   }
  22 }
  23
  24 executable("llvm-dwp") {
  25   deps = [
  26     "//llvm/lib/CodeGen/AsmPrinter",
  27     "//llvm/lib/DebugInfo/DWARF",
  28     "//llvm/lib/MC",
  29     "//llvm/lib/Object",
  30     "//llvm/lib/Support",
  31     "//llvm/lib/Target",
  32     "//llvm/lib/Target:TargetsToBuild",
  33   ]
  34   sources = [
  35     "DWPError.cpp",
  36     "llvm-dwp.cpp",
  37   ]
  38 }