utils/gn/secondary/llvm/tools/llvm-readobj/BUILD.gn

   1 import("//llvm/tools/binutils_symlinks.gni")
   2 import("//llvm/utils/gn/build/symlink_or_copy.gni")
   3
   4 symlinks = [ "llvm-readelf" ]
   5 if (llvm_install_binutils_symlinks) {
   6   symlinks += [ "readelf" ]
   7 }
   8 foreach(target, symlinks) {
   9   symlink_or_copy(target) {
  10     deps = [
  11       ":llvm-readobj",
  12     ]
  13     source = "llvm-readobj"
  14     output = "$root_out_dir/bin/$target"
  15   }
  16 }
  17
  18 # //:llvm-readobj depends on this symlink target, see comment in //BUILD.gn.
  19 group("symlinks") {
  20   deps = []
  21   foreach(target, symlinks) {
  22     deps += [ ":$target" ]
  23   }
  24 }
  25
  26 executable("llvm-readobj") {
  27   deps = [
  28     "//llvm/lib/BinaryFormat",
  29     "//llvm/lib/DebugInfo/CodeView",
  30     "//llvm/lib/DebugInfo/DWARF",
  31     "//llvm/lib/DebugInfo/MSF",
  32     "//llvm/lib/DebugInfo/PDB",
  33     "//llvm/lib/Object",
  34     "//llvm/lib/Support",
  35   ]
  36   sources = [
  37     "ARMWinEHPrinter.cpp",
  38     "COFFDumper.cpp",
  39     "COFFImportDumper.cpp",
  40     "ELFDumper.cpp",
  41     "Error.cpp",
  42     "MachODumper.cpp",
  43     "ObjDumper.cpp",
  44     "WasmDumper.cpp",
  45     "Win64EHDumper.cpp",
  46     "WindowsResourceDumper.cpp",
  47     "XCOFFDumper.cpp",
  48     "llvm-readobj.cpp",
  49   ]
  50 }