test/Analysis/ScalarEvolution/min-max-exprs.ll

   1 ; RUN: opt -scalar-evolution -analyze < %s | FileCheck %s
   2 ;
   3 ; This checks if the min and max expressions are properly recognized by
   4 ; ScalarEvolution even though they the ICmpInst and SelectInst have different
   5 ; types.
   6 ;
   7 ;    #define max(a, b) (a > b ? a : b)
   8 ;    #define min(a, b) (a < b ? a : b)
   9 ;
  10 ;    void f(int *A, int N) {
  11 ;      for (int i = 0; i < N; i++) {
  12 ;        A[max(0, i - 3)] = A[min(N, i + 3)] * 2;
  13 ;      }
  14 ;    }
  15 ;
  16 target datalayout = "e-m:e-i64:64-f80:128-n8:16:32:64-S128"
  17
  18 define void @f(i32* %A, i32 %N) {
  19 bb:
  20   br label %bb1
  21
  22 bb1:                                              ; preds = %bb2, %bb
  23   %i.0 = phi i32 [ 0, %bb ], [ %tmp23, %bb2 ]
  24   %i.0.1 = sext i32 %i.0 to i64
  25   %tmp = icmp slt i32 %i.0, %N
  26   br i1 %tmp, label %bb2, label %bb24
  27
  28 bb2:                                              ; preds = %bb1
  29   %tmp3 = add nuw nsw i32 %i.0, 3
  30   %tmp4 = icmp slt i32 %tmp3, %N
  31   %tmp5 = sext i32 %tmp3 to i64
  32   %tmp6 = sext i32 %N to i64
  33   %tmp9 = select i1 %tmp4, i64 %tmp5, i64 %tmp6
  34 ;                  min(N, i+3)
  35 ; CHECK:           select i1 %tmp4, i64 %tmp5, i64 %tmp6
  36 ; CHECK-NEXT:  --> ((sext i32 {3,+,1}<nuw><%bb1> to i64) smin (sext i32 %N to i64))
  37   %tmp11 = getelementptr inbounds i32, i32* %A, i64 %tmp9
  38   %tmp12 = load i32, i32* %tmp11, align 4
  39   %tmp13 = shl nsw i32 %tmp12, 1
  40   %tmp14 = icmp sge i32 3, %i.0
  41   %tmp17 = add nsw i64 %i.0.1, -3
  42   %tmp19 = select i1 %tmp14, i64 0, i64 %tmp17
  43 ;                  max(0, i - 3)
  44 ; CHECK:           select i1 %tmp14, i64 0, i64 %tmp17
  45 ; CHECK-NEXT: -->  (-3 + (3 smax {0,+,1}<nuw><nsw><%bb1>))
  46   %tmp21 = getelementptr inbounds i32, i32* %A, i64 %tmp19
  47   store i32 %tmp13, i32* %tmp21, align 4
  48   %tmp23 = add nuw nsw i32 %i.0, 1
  49   br label %bb1
  50
  51 bb24:                                             ; preds = %bb1
  52   ret void
  53 }