test/Analysis/DivergenceAnalysis/AMDGPU/hidden_loopdiverge.ll

   1 ; RUN: opt -mtriple amdgcn-unknown-amdhsa -analyze -divergence -use-gpu-divergence-analysis %s | FileCheck %s
   2
   3 ; divergent loop (H<header><exiting to X>, B<exiting to Y>)
   4 ; the divergent join point in %exit is obscured by uniform control joining in %X
   5 define amdgpu_kernel void @hidden_loop_diverge(i32 %n, i32 %a, i32 %b) #0 {
   6 ; CHECK-LABEL: Printing analysis 'Legacy Divergence Analysis' for function 'hidden_loop_diverge':
   7 ; CHECK-NOT: DIVERGENT: %uni.
   8 ; CHECK-NOT: DIVERGENT: br i1 %uni.
   9
  10 entry:
  11   %tid = call i32 @llvm.amdgcn.workitem.id.x()
  12   %uni.cond = icmp slt i32 %a, 0
  13   br i1 %uni.cond, label %X, label %H  ; uniform
  14
  15 H:
  16   %uni.merge.h = phi i32 [ 0, %entry ], [ %uni.inc, %B ]
  17   %div.exitx = icmp slt i32 %tid, 0
  18   br i1 %div.exitx, label %X, label %B ; divergent branch
  19 ; CHECK: DIVERGENT: %div.exitx =
  20 ; CHECK: DIVERGENT: br i1 %div.exitx,
  21
  22 B:
  23   %uni.inc = add i32 %uni.merge.h, 1
  24   %div.exity = icmp sgt i32 %tid, 0
  25   br i1 %div.exity, label %Y, label %H ; divergent branch
  26 ; CHECK: DIVERGENT: %div.exity =
  27 ; CHECK: DIVERGENT: br i1 %div.exity,
  28
  29 X:
  30   %div.merge.x = phi i32 [ %a, %entry ], [ %uni.merge.h, %H ] ; temporal divergent phi
  31   br i1 %uni.cond, label %Y, label %exit
  32 ; CHECK: DIVERGENT: %div.merge.x =
  33
  34 Y:
  35   %div.merge.y = phi i32 [ 42, %X ], [ %b, %B ]
  36   br label %exit
  37 ; CHECK: DIVERGENT: %div.merge.y =
  38
  39 exit:
  40   %div.merge.exit = phi i32 [ %a, %X ], [ %b, %Y ]
  41   ret void
  42 ; CHECK: DIVERGENT: %div.merge.exit =
  43 }
  44
  45 ; divergent loop (H<header><exiting to X>, B<exiting to Y>)
  46 ; the phi nodes in X and Y don't actually receive divergent values
  47 define amdgpu_kernel void @unobserved_loop_diverge(i32 %n, i32 %a, i32 %b) #0 {
  48 ; CHECK-LABEL: Printing analysis 'Legacy Divergence Analysis' for function 'unobserved_loop_diverge':
  49 ; CHECK-NOT: DIVERGENT: %uni.
  50 ; CHECK-NOT: DIVERGENT: br i1 %uni.
  51
  52 entry:
  53   %tid = call i32 @llvm.amdgcn.workitem.id.x()
  54   %uni.cond = icmp slt i32 %a, 0
  55   br i1 %uni.cond, label %X, label %H  ; uniform
  56
  57 H:
  58   %uni.merge.h = phi i32 [ 0, %entry ], [ %uni.inc, %B ]
  59   %div.exitx = icmp slt i32 %tid, 0
  60   br i1 %div.exitx, label %X, label %B ; divergent branch
  61 ; CHECK: DIVERGENT: %div.exitx =
  62 ; CHECK: DIVERGENT: br i1 %div.exitx,
  63
  64 B:
  65   %uni.inc = add i32 %uni.merge.h, 1
  66   %div.exity = icmp sgt i32 %tid, 0
  67   br i1 %div.exity, label %Y, label %H ; divergent branch
  68 ; CHECK: DIVERGENT: %div.exity =
  69 ; CHECK: DIVERGENT: br i1 %div.exity,
  70
  71 X:
  72   %uni.merge.x = phi i32 [ %a, %entry ], [ %b, %H ]
  73   br label %exit
  74
  75 Y:
  76   %uni.merge.y = phi i32 [ %b, %B ]
  77   br label %exit
  78
  79 exit:
  80   %div.merge.exit = phi i32 [ %a, %X ], [ %b, %Y ]
  81   ret void
  82 ; CHECK: DIVERGENT: %div.merge.exit =
  83 }
  84
  85 ; divergent loop (G<header>, L<exiting to D>) inside divergent loop (H<header>, B<exiting to X>, C<exiting to Y>, D, G, L)
  86 ; the inner loop has no exit to top level.
  87 ; the outer loop becomes divergent as its exiting branch in C is control-dependent on the inner loop's divergent loop exit in D.
  88 define amdgpu_kernel void @hidden_nestedloop_diverge(i32 %n, i32 %a, i32 %b) #0 {
  89 ; CHECK-LABEL: Printing analysis 'Legacy Divergence Analysis' for function 'hidden_nestedloop_diverge':
  90 ; CHECK-NOT: DIVERGENT: %uni.
  91 ; CHECK-NOT: DIVERGENT: br i1 %uni.
  92
  93 entry:
  94   %tid = call i32 @llvm.amdgcn.workitem.id.x()
  95   %uni.cond = icmp slt i32 %a, 0
  96   %div.exitx = icmp slt i32 %tid, 0
  97   br i1 %uni.cond, label %X, label %H
  98
  99 H:
 100   %uni.merge.h = phi i32 [ 0, %entry ], [ %uni.inc, %D ]
 101   br i1 %uni.cond, label %G, label %B
 102 ; CHECK: DIVERGENT: %div.exitx =
 103
 104 B:
 105   br i1 %uni.cond, label %X, label %C
 106
 107 C:
 108   br i1 %uni.cond, label %Y, label %D
 109
 110 D:
 111   %uni.inc = add i32 %uni.merge.h, 1
 112   br label %H
 113
 114 G:
 115   br i1 %div.exitx, label %C, label %L
 116 ; CHECK: DIVERGENT: br i1 %div.exitx,
 117
 118 L:
 119   br i1 %uni.cond, label %D, label %G
 120
 121 X:
 122   %div.merge.x = phi i32 [ %a, %entry ], [ %uni.merge.h, %B ] ; temporal divergent phi
 123   br i1 %uni.cond, label %Y, label %exit
 124 ; CHECK: DIVERGENT: %div.merge.x =
 125
 126 Y:
 127   %div.merge.y = phi i32 [ 42, %X ], [ %b, %C ]
 128   br label %exit
 129 ; CHECK: DIVERGENT: %div.merge.y =
 130
 131 exit:
 132   %div.merge.exit = phi i32 [ %a, %X ], [ %b, %Y ]
 133   ret void
 134 ; CHECK: DIVERGENT: %div.merge.exit =
 135 }
 136
 137 ; divergent loop (G<header>, L<exiting to X>) in divergent loop (H<header>, B<exiting to C>, C, G, L)
 138 ; the outer loop has no immediately divergent exiting edge.
 139 ; the inner exiting edge is exiting to top-level through the outer loop causing both to become divergent.
 140 define amdgpu_kernel void @hidden_doublebreak_diverge(i32 %n, i32 %a, i32 %b) #0 {
 141 ; CHECK-LABEL: Printing analysis 'Legacy Divergence Analysis' for function 'hidden_doublebreak_diverge':
 142 ; CHECK-NOT: DIVERGENT: %uni.
 143 ; CHECK-NOT: DIVERGENT: br i1 %uni.
 144
 145 entry:
 146   %tid = call i32 @llvm.amdgcn.workitem.id.x()
 147   %uni.cond = icmp slt i32 %a, 0
 148   %div.exitx = icmp slt i32 %tid, 0
 149   br i1 %uni.cond, label %X, label %H
 150
 151 H:
 152   %uni.merge.h = phi i32 [ 0, %entry ], [ %uni.inc, %C ]
 153   br i1 %uni.cond, label %G, label %B
 154 ; CHECK: DIVERGENT: %div.exitx =
 155
 156 B:
 157   br i1 %uni.cond, label %Y, label %C
 158
 159 C:
 160   %uni.inc = add i32 %uni.merge.h, 1
 161   br label %H
 162
 163 G:
 164   br i1 %div.exitx, label %X, label %L ; two-level break
 165 ; CHECK: DIVERGENT: br i1 %div.exitx,
 166
 167 L:
 168   br i1 %uni.cond, label %C, label %G
 169
 170 X:
 171   %div.merge.x = phi i32 [ %a, %entry ], [ %uni.merge.h, %G ] ; temporal divergence
 172   br label %Y
 173 ; CHECK: DIVERGENT: %div.merge.x =
 174
 175 Y:
 176   %div.merge.y = phi i32 [ 42, %X ], [ %b, %B ]
 177   ret void
 178 ; CHECK: DIVERGENT: %div.merge.y =
 179 }
 180
 181 ; divergent loop (G<header>, L<exiting to D>) contained inside a uniform loop (H<header>, B, G, L , D<exiting to x>)
 182 define amdgpu_kernel void @hidden_containedloop_diverge(i32 %n, i32 %a, i32 %b) #0 {
 183 ; CHECK-LABEL: Printing analysis 'Legacy Divergence Analysis' for function 'hidden_containedloop_diverge':
 184 ; CHECK-NOT: DIVERGENT: %uni.
 185 ; CHECK-NOT: DIVERGENT: br i1 %uni.
 186
 187 entry:
 188   %tid = call i32 @llvm.amdgcn.workitem.id.x()
 189   %uni.cond = icmp slt i32 %a, 0
 190   %div.exitx = icmp slt i32 %tid, 0
 191   br i1 %uni.cond, label %X, label %H
 192
 193 H:
 194   %uni.merge.h = phi i32 [ 0, %entry ], [ %uni.inc.d, %D ]
 195   br i1 %uni.cond, label %G, label %B
 196 ; CHECK: DIVERGENT: %div.exitx =
 197
 198 B:
 199   %div.merge.b = phi i32 [ 42, %H ], [ %uni.merge.g, %G ]
 200   br label %D
 201 ; CHECK: DIVERGENT: %div.merge.b =
 202
 203 G:
 204   %uni.merge.g = phi i32 [ 123, %H ], [ %uni.inc.l, %L ]
 205   br i1 %div.exitx, label %B, label %L
 206 ; CHECK: DIVERGENT: br i1 %div.exitx,
 207
 208 L:
 209   %uni.inc.l = add i32 %uni.merge.g, 1
 210   br i1 %uni.cond, label %G, label %D
 211
 212 D:
 213   %uni.inc.d = add i32 %uni.merge.h, 1
 214   br i1 %uni.cond, label %X, label %H
 215
 216 X:
 217   %uni.merge.x = phi i32 [ %a, %entry ], [ %uni.inc.d, %D ]
 218   ret void
 219 }
 220
 221 declare i32 @llvm.amdgcn.workitem.id.x() #0
 222
 223 attributes #0 = { nounwind readnone }