lib/Target/TargetSelectionDAG.td

   1 //===- TargetSelectionDAG.td - Common code for DAG isels ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the target-independent interfaces used by SelectionDAG
  11 // instruction selection generators.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // Selection DAG Type Constraint definitions.
  17 //
  18 // Note that the semantics of these constraints are hard coded into tblgen.  To
  19 // modify or add constraints, you have to hack tblgen.
  20 //
  21
  22 class SDTypeConstraint<int opnum> {
  23   int OperandNum = opnum;
  24 }
  25
  26 // SDTCisVT - The specified operand has exactly this VT.
  27 class SDTCisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  28   ValueType VT = vt;
  29 }
  30
  31 class SDTCisPtrTy<int OpNum> : SDTypeConstraint<OpNum>;
  32
  33 // SDTCisInt - The specified operand is has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand is has floating point type.
  37 class SDTCisFP<int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisSameAs - The two specified operands have identical types.
  40 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  41   int OtherOperandNum = OtherOp;
  42 }
  43
  44 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  45 // smaller than the 'Other' operand.
  46 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  47   int OtherOperandNum = OtherOp;
  48 }
  49
  50 class SDTCisOpSmallerThanOp<int SmallOp, int BigOp> : SDTypeConstraint<SmallOp>{
  51   int BigOperandNum = BigOp;
  52 }
  53
  54 /// SDTCisIntVectorOfSameSize - This indicates that ThisOp and OtherOp are
  55 /// vector types, and that ThisOp is the result of
  56 /// MVT::getIntVectorWithNumElements with the number of elements that ThisOp
  57 /// has.
  58 class SDTCisIntVectorOfSameSize<int ThisOp, int OtherOp>
  59   : SDTypeConstraint<ThisOp> {
  60   int OtherOpNum = OtherOp;
  61 }
  62
  63 //===----------------------------------------------------------------------===//
  64 // Selection DAG Type Profile definitions.
  65 //
  66 // These use the constraints defined above to describe the type requirements of
  67 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  68 // add their own if needed.
  69 //
  70
  71 // SDTypeProfile - This profile describes the type requirements of a Selection
  72 // DAG node.
  73 class SDTypeProfile<int numresults, int numoperands,
  74                     list<SDTypeConstraint> constraints> {
  75   int NumResults = numresults;
  76   int NumOperands = numoperands;
  77   list<SDTypeConstraint> Constraints = constraints;
  78 }
  79
  80 // Builtin profiles.
  81 def SDTIntLeaf: SDTypeProfile<1, 0, [SDTCisInt<0>]>;      // for 'imm'.
  82 def SDTFPLeaf : SDTypeProfile<1, 0, [SDTCisFP<0>]>;       // for 'fpimm'.
  83 def SDTPtrLeaf: SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;      // for '&g'.
  84 def SDTOther  : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'.
  85 def SDTUNDEF  : SDTypeProfile<1, 0, []>; // for 'undef'.
  86 def SDTUnaryOp  : SDTypeProfile<1, 1, []>; // bitconvert
  87
  88 def SDTIntBinOp : SDTypeProfile<1, 2, [   // add, and, or, xor, udiv, etc.
  89   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
  90 ]>;
  91 def SDTIntShiftOp : SDTypeProfile<1, 2, [   // shl, sra, srl
  92   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisInt<2>
  93 ]>;
  94 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
  95   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
  96 ]>;
  97 def SDTFPSignOp : SDTypeProfile<1, 2, [      // fcopysign.
  98   SDTCisSameAs<0, 1>, SDTCisFP<0>, SDTCisFP<2>
  99 ]>;
 100 def SDTFPTernaryOp : SDTypeProfile<1, 3, [      // fmadd, fnmsub, etc.
 101   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>, SDTCisFP<0>
 102 ]>;
 103 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
 104   SDTCisSameAs<0, 1>, SDTCisInt<0>
 105 ]>;
 106 def SDTIntExtendOp : SDTypeProfile<1, 1, [  // sext, zext, anyext
 107   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<1, 0>
 108 ]>;
 109 def SDTIntTruncOp  : SDTypeProfile<1, 1, [  // trunc
 110   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<0, 1>
 111 ]>;
 112 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
 113   SDTCisSameAs<0, 1>, SDTCisFP<0>
 114 ]>;
 115 def SDTFPRoundOp  : SDTypeProfile<1, 1, [   // fround
 116   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<0, 1>
 117 ]>;
 118 def SDTFPExtendOp  : SDTypeProfile<1, 1, [   // fextend
 119   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<1, 0>
 120 ]>;
 121 def SDTIntToFPOp : SDTypeProfile<1, 1, [   // [su]int_to_fp
 122   SDTCisFP<0>, SDTCisInt<1>
 123 ]>;
 124 def SDTFPToIntOp : SDTypeProfile<1, 1, [   // fp_to_[su]int
 125   SDTCisInt<0>, SDTCisFP<1>
 126 ]>;
 127 def SDTExtInreg : SDTypeProfile<1, 2, [   // sext_inreg
 128   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
 129   SDTCisVTSmallerThanOp<2, 1>
 130 ]>;
 131
 132 def SDTSetCC : SDTypeProfile<1, 3, [ // setcc
 133   SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 134 ]>;
 135
 136 def SDTSelect : SDTypeProfile<1, 3, [ // select
 137   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 138 ]>;
 139
 140 def SDTSelectCC : SDTypeProfile<1, 5, [ // select_cc
 141   SDTCisSameAs<1, 2>, SDTCisSameAs<3, 4>, SDTCisSameAs<0, 3>,
 142   SDTCisVT<5, OtherVT>
 143 ]>;
 144
 145 def SDTBr : SDTypeProfile<0, 1, [ // br
 146   SDTCisVT<0, OtherVT>
 147 ]>;
 148
 149 def SDTBrcond : SDTypeProfile<0, 2, [ // brcond
 150   SDTCisInt<0>, SDTCisVT<1, OtherVT>
 151 ]>;
 152
 153 def SDTBrind : SDTypeProfile<0, 1, [ // brind
 154   SDTCisPtrTy<0>
 155 ]>;
 156
 157 def SDTRet : SDTypeProfile<0, 0, []>; // ret
 158
 159 def SDTLoad : SDTypeProfile<1, 1, [ // load
 160   SDTCisPtrTy<1>
 161 ]>;
 162
 163 def SDTStore : SDTypeProfile<0, 2, [ // store
 164   SDTCisPtrTy<1>
 165 ]>;
 166
 167 def SDTIStore : SDTypeProfile<1, 3, [ // indexed store
 168   SDTCisSameAs<0, 2>, SDTCisPtrTy<0>, SDTCisPtrTy<3>
 169 ]>;
 170
 171 def SDTVecShuffle : SDTypeProfile<1, 3, [
 172   SDTCisSameAs<0, 1>, SDTCisSameAs<1, 2>, SDTCisIntVectorOfSameSize<3, 0>
 173 ]>;
 174
 175 //===----------------------------------------------------------------------===//
 176 // Selection DAG Node Properties.
 177 //
 178 // Note: These are hard coded into tblgen.
 179 //
 180 class SDNodeProperty;
 181 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
 182 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
 183 def SDNPHasChain    : SDNodeProperty;   // R/W chain operand and result
 184 def SDNPOutFlag     : SDNodeProperty;   // Write a flag result
 185 def SDNPInFlag      : SDNodeProperty;   // Read a flag operand
 186 def SDNPOptInFlag   : SDNodeProperty;   // Optionally read a flag operand
 187
 188 //===----------------------------------------------------------------------===//
 189 // Selection DAG Node definitions.
 190 //
 191 class SDNode<string opcode, SDTypeProfile typeprof,
 192              list<SDNodeProperty> props = [], string sdclass = "SDNode"> {
 193   string Opcode  = opcode;
 194   string SDClass = sdclass;
 195   list<SDNodeProperty> Properties = props;
 196   SDTypeProfile TypeProfile = typeprof;
 197 }
 198
 199 def set;
 200 def implicit;
 201 def parallel;
 202 def node;
 203 def srcvalue;
 204
 205 def imm        : SDNode<"ISD::Constant"  , SDTIntLeaf , [], "ConstantSDNode">;
 206 def fpimm      : SDNode<"ISD::TargetConstantFP",
 207                          SDTFPLeaf, [], "ConstantFPSDNode">;
 208 def vt         : SDNode<"ISD::VALUETYPE" , SDTOther   , [], "VTSDNode">;
 209 def bb         : SDNode<"ISD::BasicBlock", SDTOther   , [], "BasicBlockSDNode">;
 210 def cond       : SDNode<"ISD::CONDCODE"  , SDTOther   , [], "CondCodeSDNode">;
 211 def undef      : SDNode<"ISD::UNDEF"     , SDTUNDEF   , []>;
 212 def globaladdr : SDNode<"ISD::GlobalAddress",         SDTPtrLeaf, [],
 213                         "GlobalAddressSDNode">;
 214 def tglobaladdr : SDNode<"ISD::TargetGlobalAddress",  SDTPtrLeaf, [],
 215                          "GlobalAddressSDNode">;
 216 def globaltlsaddr : SDNode<"ISD::GlobalTLSAddress",         SDTPtrLeaf, [],
 217                           "GlobalAddressSDNode">;
 218 def tglobaltlsaddr : SDNode<"ISD::TargetGlobalTLSAddress",  SDTPtrLeaf, [],
 219                            "GlobalAddressSDNode">;
 220 def constpool   : SDNode<"ISD::ConstantPool",         SDTPtrLeaf, [],
 221                          "ConstantPoolSDNode">;
 222 def tconstpool  : SDNode<"ISD::TargetConstantPool",   SDTPtrLeaf, [],
 223                          "ConstantPoolSDNode">;
 224 def jumptable   : SDNode<"ISD::JumpTable",            SDTPtrLeaf, [],
 225                          "JumpTableSDNode">;
 226 def tjumptable  : SDNode<"ISD::TargetJumpTable",      SDTPtrLeaf, [],
 227                          "JumpTableSDNode">;
 228 def frameindex  : SDNode<"ISD::FrameIndex",           SDTPtrLeaf, [],
 229                          "FrameIndexSDNode">;
 230 def tframeindex : SDNode<"ISD::TargetFrameIndex",     SDTPtrLeaf, [],
 231                          "FrameIndexSDNode">;
 232 def externalsym : SDNode<"ISD::ExternalSymbol",       SDTPtrLeaf, [],
 233                          "ExternalSymbolSDNode">;
 234 def texternalsym: SDNode<"ISD::TargetExternalSymbol", SDTPtrLeaf, [],
 235                          "ExternalSymbolSDNode">;
 236
 237 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 238                         [SDNPCommutative, SDNPAssociative]>;
 239 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 240 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 241                         [SDNPCommutative, SDNPAssociative]>;
 242 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 243 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 244 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 245 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 246 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 247 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 248 def srl        : SDNode<"ISD::SRL"       , SDTIntShiftOp>;
 249 def sra        : SDNode<"ISD::SRA"       , SDTIntShiftOp>;
 250 def shl        : SDNode<"ISD::SHL"       , SDTIntShiftOp>;
 251 def rotl       : SDNode<"ISD::ROTL"      , SDTIntShiftOp>;
 252 def rotr       : SDNode<"ISD::ROTR"      , SDTIntShiftOp>;
 253 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 254                         [SDNPCommutative, SDNPAssociative]>;
 255 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 256                         [SDNPCommutative, SDNPAssociative]>;
 257 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 258                         [SDNPCommutative, SDNPAssociative]>;
 259 def addc       : SDNode<"ISD::ADDC"      , SDTIntBinOp,
 260                         [SDNPCommutative, SDNPOutFlag]>;
 261 def adde       : SDNode<"ISD::ADDE"      , SDTIntBinOp,
 262                         [SDNPCommutative, SDNPOutFlag, SDNPInFlag]>;
 263 def subc       : SDNode<"ISD::SUBC"      , SDTIntBinOp,
 264                         [SDNPOutFlag]>;
 265 def sube       : SDNode<"ISD::SUBE"      , SDTIntBinOp,
 266                         [SDNPOutFlag, SDNPInFlag]>;
 267
 268 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 269 def bswap      : SDNode<"ISD::BSWAP"      , SDTIntUnaryOp>;
 270 def ctlz       : SDNode<"ISD::CTLZ"       , SDTIntUnaryOp>;
 271 def cttz       : SDNode<"ISD::CTTZ"       , SDTIntUnaryOp>;
 272 def ctpop      : SDNode<"ISD::CTPOP"      , SDTIntUnaryOp>;
 273 def sext       : SDNode<"ISD::SIGN_EXTEND", SDTIntExtendOp>;
 274 def zext       : SDNode<"ISD::ZERO_EXTEND", SDTIntExtendOp>;
 275 def anyext     : SDNode<"ISD::ANY_EXTEND" , SDTIntExtendOp>;
 276 def trunc      : SDNode<"ISD::TRUNCATE"   , SDTIntTruncOp>;
 277 def bitconvert : SDNode<"ISD::BIT_CONVERT", SDTUnaryOp>;
 278
 279 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 280 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 281 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 282 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 283 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 284 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 285 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 286 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 287 def fsin       : SDNode<"ISD::FSIN"       , SDTFPUnaryOp>;
 288 def fcos       : SDNode<"ISD::FCOS"       , SDTFPUnaryOp>;
 289
 290 def fround     : SDNode<"ISD::FP_ROUND"   , SDTFPRoundOp>;
 291 def fextend    : SDNode<"ISD::FP_EXTEND"  , SDTFPExtendOp>;
 292 def fcopysign  : SDNode<"ISD::FCOPYSIGN"  , SDTFPSignOp>;
 293
 294 def sint_to_fp : SDNode<"ISD::SINT_TO_FP" , SDTIntToFPOp>;
 295 def uint_to_fp : SDNode<"ISD::UINT_TO_FP" , SDTIntToFPOp>;
 296 def fp_to_sint : SDNode<"ISD::FP_TO_SINT" , SDTFPToIntOp>;
 297 def fp_to_uint : SDNode<"ISD::FP_TO_UINT" , SDTFPToIntOp>;
 298
 299 def setcc      : SDNode<"ISD::SETCC"      , SDTSetCC>;
 300 def select     : SDNode<"ISD::SELECT"     , SDTSelect>;
 301 def selectcc   : SDNode<"ISD::SELECT_CC"  , SDTSelectCC>;
 302
 303 def brcond     : SDNode<"ISD::BRCOND"     , SDTBrcond, [SDNPHasChain]>;
 304 def brind      : SDNode<"ISD::BRIND"      , SDTBrind,  [SDNPHasChain]>;
 305 def br         : SDNode<"ISD::BR"         , SDTBr,     [SDNPHasChain]>;
 306 def ret        : SDNode<"ISD::RET"        , SDTRet,    [SDNPHasChain]>;
 307
 308 // Do not use ld, st directly. Use load, extload, sextload, zextload, store,
 309 // and truncst (see below).
 310 def ld         : SDNode<"ISD::LOAD"       , SDTLoad,  [SDNPHasChain]>;
 311 def st         : SDNode<"ISD::STORE"      , SDTStore, [SDNPHasChain]>;
 312 def ist        : SDNode<"ISD::STORE"      , SDTIStore, [SDNPHasChain]>;
 313
 314 def vector_shuffle : SDNode<"ISD::VECTOR_SHUFFLE", SDTVecShuffle, []>;
 315 def build_vector : SDNode<"ISD::BUILD_VECTOR", SDTypeProfile<1, 0, []>, []>;
 316 def scalar_to_vector : SDNode<"ISD::SCALAR_TO_VECTOR", SDTypeProfile<1, 1, []>,
 317                               []>;
 318 def vector_extract : SDNode<"ISD::EXTRACT_VECTOR_ELT",
 319     SDTypeProfile<1, 2, [SDTCisPtrTy<2>]>, []>;
 320 def vector_insert : SDNode<"ISD::INSERT_VECTOR_ELT",
 321     SDTypeProfile<1, 3, [SDTCisSameAs<0, 1>, SDTCisPtrTy<3>]>, []>;
 322
 323 def extract_subreg : SDNode<"ISD::EXTRACT_SUBREG",
 324     SDTypeProfile<1, 2, []>>;
 325 def insert_subreg : SDNode<"ISD::INSERT_SUBREG",
 326     SDTypeProfile<1, 3, []>>;
 327
 328 // Nodes for intrinsics, you should use the intrinsic itself and let tblgen use
 329 // these internally.  Don't reference these directly.
 330 def intrinsic_void : SDNode<"ISD::INTRINSIC_VOID",
 331                             SDTypeProfile<0, -1, [SDTCisPtrTy<0>]>,
 332                             [SDNPHasChain]>;
 333 def intrinsic_w_chain : SDNode<"ISD::INTRINSIC_W_CHAIN",
 334                                SDTypeProfile<1, -1, [SDTCisPtrTy<1>]>,
 335                                [SDNPHasChain]>;
 336 def intrinsic_wo_chain : SDNode<"ISD::INTRINSIC_WO_CHAIN",
 337                                 SDTypeProfile<1, -1, [SDTCisPtrTy<1>]>, []>;
 338
 339
 340 //===----------------------------------------------------------------------===//
 341 // Selection DAG Condition Codes
 342
 343 class CondCode; // ISD::CondCode enums
 344 def SETOEQ : CondCode; def SETOGT : CondCode;
 345 def SETOGE : CondCode; def SETOLT : CondCode; def SETOLE : CondCode;
 346 def SETONE : CondCode; def SETO   : CondCode; def SETUO  : CondCode;
 347 def SETUEQ : CondCode; def SETUGT : CondCode; def SETUGE : CondCode;
 348 def SETULT : CondCode; def SETULE : CondCode; def SETUNE : CondCode;
 349
 350 def SETEQ : CondCode; def SETGT : CondCode; def SETGE : CondCode;
 351 def SETLT : CondCode; def SETLE : CondCode; def SETNE : CondCode;
 352
 353
 354 //===----------------------------------------------------------------------===//
 355 // Selection DAG Node Transformation Functions.
 356 //
 357 // This mechanism allows targets to manipulate nodes in the output DAG once a
 358 // match has been formed.  This is typically used to manipulate immediate
 359 // values.
 360 //
 361 class SDNodeXForm<SDNode opc, code xformFunction> {
 362   SDNode Opcode = opc;
 363   code XFormFunction = xformFunction;
 364 }
 365
 366 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 367
 368
 369 //===----------------------------------------------------------------------===//
 370 // Selection DAG Pattern Fragments.
 371 //
 372 // Pattern fragments are reusable chunks of dags that match specific things.
 373 // They can take arguments and have C++ predicates that control whether they
 374 // match.  They are intended to make the patterns for common instructions more
 375 // compact and readable.
 376 //
 377
 378 /// PatFrag - Represents a pattern fragment.  This can match something on the
 379 /// DAG, frame a single node to multiply nested other fragments.
 380 ///
 381 class PatFrag<dag ops, dag frag, code pred = [{}],
 382               SDNodeXForm xform = NOOP_SDNodeXForm> {
 383   dag Operands = ops;
 384   dag Fragment = frag;
 385   code Predicate = pred;
 386   SDNodeXForm OperandTransform = xform;
 387 }
 388
 389 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 390 // to define immediates and other common things concisely.
 391 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 392  : PatFrag<(ops), frag, pred, xform>;
 393
 394 // Leaf fragments.
 395
 396 def vtInt      : PatLeaf<(vt),  [{ return MVT::isInteger(N->getVT()); }]>;
 397 def vtFP       : PatLeaf<(vt),  [{ return MVT::isFloatingPoint(N->getVT()); }]>;
 398
 399 def immAllOnes : PatLeaf<(imm), [{ return N->isAllOnesValue(); }]>;
 400 def immAllOnesV: PatLeaf<(build_vector), [{
 401   return ISD::isBuildVectorAllOnes(N);
 402 }]>;
 403 def immAllZerosV: PatLeaf<(build_vector), [{
 404   return ISD::isBuildVectorAllZeros(N);
 405 }]>;
 406
 407 def immAllOnesV_bc: PatLeaf<(bitconvert), [{
 408   return ISD::isBuildVectorAllOnes(N);
 409 }]>;
 410
 411
 412 // Other helper fragments.
 413 def not  : PatFrag<(ops node:$in), (xor node:$in, immAllOnes)>;
 414 def vnot : PatFrag<(ops node:$in), (xor node:$in, immAllOnesV)>;
 415 def vnot_conv : PatFrag<(ops node:$in), (xor node:$in, immAllOnesV_bc)>;
 416 def ineg : PatFrag<(ops node:$in), (sub 0, node:$in)>;
 417
 418 // load fragments.
 419 def load : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 420   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 421     return LD->getExtensionType() == ISD::NON_EXTLOAD &&
 422            LD->getAddressingMode() == ISD::UNINDEXED;
 423   return false;
 424 }]>;
 425
 426 // extending load fragments.
 427 def extloadi1  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 428   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 429     return LD->getExtensionType() == ISD::EXTLOAD &&
 430            LD->getAddressingMode() == ISD::UNINDEXED &&
 431            LD->getLoadedVT() == MVT::i1;
 432   return false;
 433 }]>;
 434 def extloadi8  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 435   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 436     return LD->getExtensionType() == ISD::EXTLOAD &&
 437            LD->getAddressingMode() == ISD::UNINDEXED &&
 438            LD->getLoadedVT() == MVT::i8;
 439   return false;
 440 }]>;
 441 def extloadi16 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 442   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 443     return LD->getExtensionType() == ISD::EXTLOAD &&
 444            LD->getAddressingMode() == ISD::UNINDEXED &&
 445            LD->getLoadedVT() == MVT::i16;
 446   return false;
 447 }]>;
 448 def extloadi32 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 449   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 450     return LD->getExtensionType() == ISD::EXTLOAD &&
 451            LD->getAddressingMode() == ISD::UNINDEXED &&
 452            LD->getLoadedVT() == MVT::i32;
 453   return false;
 454 }]>;
 455 def extloadf32 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 456   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 457     return LD->getExtensionType() == ISD::EXTLOAD &&
 458            LD->getAddressingMode() == ISD::UNINDEXED &&
 459            LD->getLoadedVT() == MVT::f32;
 460   return false;
 461 }]>;
 462 def extloadf64 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 463   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 464     return LD->getExtensionType() == ISD::EXTLOAD &&
 465            LD->getAddressingMode() == ISD::UNINDEXED &&
 466            LD->getLoadedVT() == MVT::f64;
 467   return false;
 468 }]>;
 469
 470 def sextloadi1  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 471   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 472     return LD->getExtensionType() == ISD::SEXTLOAD &&
 473            LD->getAddressingMode() == ISD::UNINDEXED &&
 474            LD->getLoadedVT() == MVT::i1;
 475   return false;
 476 }]>;
 477 def sextloadi8  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 478   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 479     return LD->getExtensionType() == ISD::SEXTLOAD &&
 480            LD->getAddressingMode() == ISD::UNINDEXED &&
 481            LD->getLoadedVT() == MVT::i8;
 482   return false;
 483 }]>;
 484 def sextloadi16 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 485   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 486     return LD->getExtensionType() == ISD::SEXTLOAD &&
 487            LD->getAddressingMode() == ISD::UNINDEXED &&
 488            LD->getLoadedVT() == MVT::i16;
 489   return false;
 490 }]>;
 491 def sextloadi32 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 492   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 493     return LD->getExtensionType() == ISD::SEXTLOAD &&
 494            LD->getAddressingMode() == ISD::UNINDEXED &&
 495            LD->getLoadedVT() == MVT::i32;
 496   return false;
 497 }]>;
 498
 499 def zextloadi1  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 500   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 501     return LD->getExtensionType() == ISD::ZEXTLOAD &&
 502            LD->getAddressingMode() == ISD::UNINDEXED &&
 503            LD->getLoadedVT() == MVT::i1;
 504   return false;
 505 }]>;
 506 def zextloadi8  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 507   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 508     return LD->getExtensionType() == ISD::ZEXTLOAD &&
 509            LD->getAddressingMode() == ISD::UNINDEXED &&
 510            LD->getLoadedVT() == MVT::i8;
 511   return false;
 512 }]>;
 513 def zextloadi16 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 514   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 515     return LD->getExtensionType() == ISD::ZEXTLOAD &&
 516            LD->getAddressingMode() == ISD::UNINDEXED &&
 517            LD->getLoadedVT() == MVT::i16;
 518   return false;
 519 }]>;
 520 def zextloadi32 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 521   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 522     return LD->getExtensionType() == ISD::ZEXTLOAD &&
 523            LD->getAddressingMode() == ISD::UNINDEXED &&
 524            LD->getLoadedVT() == MVT::i32;
 525   return false;
 526 }]>;
 527
 528 // store fragments.
 529 def store : PatFrag<(ops node:$val, node:$ptr),
 530                     (st node:$val, node:$ptr), [{
 531   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 532     return !ST->isTruncatingStore() &&
 533            ST->getAddressingMode() == ISD::UNINDEXED;
 534   return false;
 535 }]>;
 536
 537 // truncstore fragments.
 538 def truncstorei1 : PatFrag<(ops node:$val, node:$ptr),
 539                            (st node:$val, node:$ptr), [{
 540   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 541     return ST->isTruncatingStore() && ST->getStoredVT() == MVT::i1 &&
 542            ST->getAddressingMode() == ISD::UNINDEXED;
 543   return false;
 544 }]>;
 545 def truncstorei8 : PatFrag<(ops node:$val, node:$ptr),
 546                            (st node:$val, node:$ptr), [{
 547   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 548     return ST->isTruncatingStore() && ST->getStoredVT() == MVT::i8 &&
 549            ST->getAddressingMode() == ISD::UNINDEXED;
 550   return false;
 551 }]>;
 552 def truncstorei16 : PatFrag<(ops node:$val, node:$ptr),
 553                             (st node:$val, node:$ptr), [{
 554   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 555     return ST->isTruncatingStore() && ST->getStoredVT() == MVT::i16 &&
 556            ST->getAddressingMode() == ISD::UNINDEXED;
 557   return false;
 558 }]>;
 559 def truncstorei32 : PatFrag<(ops node:$val, node:$ptr),
 560                             (st node:$val, node:$ptr), [{
 561   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 562     return ST->isTruncatingStore() && ST->getStoredVT() == MVT::i32 &&
 563            ST->getAddressingMode() == ISD::UNINDEXED;
 564   return false;
 565 }]>;
 566 def truncstoref32 : PatFrag<(ops node:$val, node:$ptr),
 567                             (st node:$val, node:$ptr), [{
 568   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 569     return ST->isTruncatingStore() && ST->getStoredVT() == MVT::f32 &&
 570            ST->getAddressingMode() == ISD::UNINDEXED;
 571   return false;
 572 }]>;
 573 def truncstoref64 : PatFrag<(ops node:$val, node:$ptr),
 574                             (st node:$val, node:$ptr), [{
 575   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 576     return ST->isTruncatingStore() && ST->getStoredVT() == MVT::f64 &&
 577            ST->getAddressingMode() == ISD::UNINDEXED;
 578   return false;
 579 }]>;
 580
 581 // indexed store fragments.
 582 def pre_store : PatFrag<(ops node:$val, node:$base, node:$offset),
 583                         (ist node:$val, node:$base, node:$offset), [{
 584   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 585     ISD::MemIndexedMode AM = ST->getAddressingMode();
 586     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 587            !ST->isTruncatingStore();
 588   }
 589   return false;
 590 }]>;
 591
 592 def pre_truncsti1 : PatFrag<(ops node:$val, node:$base, node:$offset),
 593                             (ist node:$val, node:$base, node:$offset), [{
 594   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 595     ISD::MemIndexedMode AM = ST->getAddressingMode();
 596     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 597            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i1;
 598   }
 599   return false;
 600 }]>;
 601 def pre_truncsti8 : PatFrag<(ops node:$val, node:$base, node:$offset),
 602                             (ist node:$val, node:$base, node:$offset), [{
 603   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 604     ISD::MemIndexedMode AM = ST->getAddressingMode();
 605     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 606            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i8;
 607   }
 608   return false;
 609 }]>;
 610 def pre_truncsti16 : PatFrag<(ops node:$val, node:$base, node:$offset),
 611                              (ist node:$val, node:$base, node:$offset), [{
 612   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 613     ISD::MemIndexedMode AM = ST->getAddressingMode();
 614     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 615            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i16;
 616   }
 617   return false;
 618 }]>;
 619 def pre_truncsti32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 620                              (ist node:$val, node:$base, node:$offset), [{
 621   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 622     ISD::MemIndexedMode AM = ST->getAddressingMode();
 623     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 624            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i32;
 625   }
 626   return false;
 627 }]>;
 628 def pre_truncstf32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 629                              (ist node:$val, node:$base, node:$offset), [{
 630   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 631     ISD::MemIndexedMode AM = ST->getAddressingMode();
 632     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 633            ST->isTruncatingStore() && ST->getStoredVT() == MVT::f32;
 634   }
 635   return false;
 636 }]>;
 637
 638 def post_store : PatFrag<(ops node:$val, node:$ptr, node:$offset),
 639                          (ist node:$val, node:$ptr, node:$offset), [{
 640   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 641     ISD::MemIndexedMode AM = ST->getAddressingMode();
 642     return !ST->isTruncatingStore() &&
 643             (AM == ISD::POST_INC || AM == ISD::POST_DEC);
 644   }
 645   return false;
 646 }]>;
 647
 648 def post_truncsti1 : PatFrag<(ops node:$val, node:$base, node:$offset),
 649                              (ist node:$val, node:$base, node:$offset), [{
 650   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 651     ISD::MemIndexedMode AM = ST->getAddressingMode();
 652     return (AM == ISD::POST_INC || AM == ISD::POST_DEC) &&
 653            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i1;
 654   }
 655   return false;
 656 }]>;
 657 def post_truncsti8 : PatFrag<(ops node:$val, node:$base, node:$offset),
 658                              (ist node:$val, node:$base, node:$offset), [{
 659   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 660     ISD::MemIndexedMode AM = ST->getAddressingMode();
 661     return (AM == ISD::POST_INC || AM == ISD::POST_DEC) &&
 662            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i8;
 663   }
 664   return false;
 665 }]>;
 666 def post_truncsti16 : PatFrag<(ops node:$val, node:$base, node:$offset),
 667                               (ist node:$val, node:$base, node:$offset), [{
 668   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 669     ISD::MemIndexedMode AM = ST->getAddressingMode();
 670     return (AM == ISD::POST_INC || AM == ISD::POST_DEC) &&
 671            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i16;
 672   }
 673   return false;
 674 }]>;
 675 def post_truncsti32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 676                               (ist node:$val, node:$base, node:$offset), [{
 677   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 678     ISD::MemIndexedMode AM = ST->getAddressingMode();
 679     return (AM == ISD::POST_INC || AM == ISD::POST_DEC) &&
 680            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i32;
 681   }
 682   return false;
 683 }]>;
 684 def post_truncstf32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 685                               (ist node:$val, node:$base, node:$offset), [{
 686   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 687     ISD::MemIndexedMode AM = ST->getAddressingMode();
 688     return (AM == ISD::POST_INC || AM == ISD::POST_DEC) &&
 689            ST->isTruncatingStore() && ST->getStoredVT() == MVT::f32;
 690   }
 691   return false;
 692 }]>;
 693
 694 // setcc convenience fragments.
 695 def setoeq : PatFrag<(ops node:$lhs, node:$rhs),
 696                      (setcc node:$lhs, node:$rhs, SETOEQ)>;
 697 def setogt : PatFrag<(ops node:$lhs, node:$rhs),
 698                      (setcc node:$lhs, node:$rhs, SETOGT)>;
 699 def setoge : PatFrag<(ops node:$lhs, node:$rhs),
 700                      (setcc node:$lhs, node:$rhs, SETOGE)>;
 701 def setolt : PatFrag<(ops node:$lhs, node:$rhs),
 702                      (setcc node:$lhs, node:$rhs, SETOLT)>;
 703 def setole : PatFrag<(ops node:$lhs, node:$rhs),
 704                      (setcc node:$lhs, node:$rhs, SETOLE)>;
 705 def setone : PatFrag<(ops node:$lhs, node:$rhs),
 706                      (setcc node:$lhs, node:$rhs, SETONE)>;
 707 def seto   : PatFrag<(ops node:$lhs, node:$rhs),
 708                      (setcc node:$lhs, node:$rhs, SETO)>;
 709 def setuo  : PatFrag<(ops node:$lhs, node:$rhs),
 710                      (setcc node:$lhs, node:$rhs, SETUO)>;
 711 def setueq : PatFrag<(ops node:$lhs, node:$rhs),
 712                      (setcc node:$lhs, node:$rhs, SETUEQ)>;
 713 def setugt : PatFrag<(ops node:$lhs, node:$rhs),
 714                      (setcc node:$lhs, node:$rhs, SETUGT)>;
 715 def setuge : PatFrag<(ops node:$lhs, node:$rhs),
 716                      (setcc node:$lhs, node:$rhs, SETUGE)>;
 717 def setult : PatFrag<(ops node:$lhs, node:$rhs),
 718                      (setcc node:$lhs, node:$rhs, SETULT)>;
 719 def setule : PatFrag<(ops node:$lhs, node:$rhs),
 720                      (setcc node:$lhs, node:$rhs, SETULE)>;
 721 def setune : PatFrag<(ops node:$lhs, node:$rhs),
 722                      (setcc node:$lhs, node:$rhs, SETUNE)>;
 723 def seteq  : PatFrag<(ops node:$lhs, node:$rhs),
 724                      (setcc node:$lhs, node:$rhs, SETEQ)>;
 725 def setgt  : PatFrag<(ops node:$lhs, node:$rhs),
 726                      (setcc node:$lhs, node:$rhs, SETGT)>;
 727 def setge  : PatFrag<(ops node:$lhs, node:$rhs),
 728                      (setcc node:$lhs, node:$rhs, SETGE)>;
 729 def setlt  : PatFrag<(ops node:$lhs, node:$rhs),
 730                      (setcc node:$lhs, node:$rhs, SETLT)>;
 731 def setle  : PatFrag<(ops node:$lhs, node:$rhs),
 732                      (setcc node:$lhs, node:$rhs, SETLE)>;
 733 def setne  : PatFrag<(ops node:$lhs, node:$rhs),
 734                      (setcc node:$lhs, node:$rhs, SETNE)>;
 735
 736 //===----------------------------------------------------------------------===//
 737 // Selection DAG Pattern Support.
 738 //
 739 // Patterns are what are actually matched against the target-flavored
 740 // instruction selection DAG.  Instructions defined by the target implicitly
 741 // define patterns in most cases, but patterns can also be explicitly added when
 742 // an operation is defined by a sequence of instructions (e.g. loading a large
 743 // immediate value on RISC targets that do not support immediates as large as
 744 // their GPRs).
 745 //
 746
 747 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
 748   dag             PatternToMatch  = patternToMatch;
 749   list<dag>       ResultInstrs    = resultInstrs;
 750   list<Predicate> Predicates      = [];  // See class Instruction in Target.td.
 751   int             AddedComplexity = 0;  // See class Instruction in Target.td.
 752 }
 753
 754 // Pat - A simple (but common) form of a pattern, which produces a simple result
 755 // not needing a full list.
 756 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
 757
 758 //===----------------------------------------------------------------------===//
 759 // Complex pattern definitions.
 760 //
 761 // Complex patterns, e.g. X86 addressing mode, requires pattern matching code
 762 // in C++. NumOperands is the number of operands returned by the select function;
 763 // SelectFunc is the name of the function used to pattern match the max. pattern;
 764 // RootNodes are the list of possible root nodes of the sub-dags to match.
 765 // e.g. X86 addressing mode - def addr : ComplexPattern<4, "SelectAddr", [add]>;
 766 //
 767 class ComplexPattern<ValueType ty, int numops, string fn,
 768                      list<SDNode> roots = [], list<SDNodeProperty> props = []> {
 769   ValueType Ty = ty;
 770   int NumOperands = numops;
 771   string SelectFunc = fn;
 772   list<SDNode> RootNodes = roots;
 773   list<SDNodeProperty> Properties = props;
 774 }
 775
 776 //===----------------------------------------------------------------------===//
 777 // Dwarf support.
 778 //
 779 def SDT_dwarf_loc : SDTypeProfile<0, 3,
 780                       [SDTCisInt<0>, SDTCisInt<1>, SDTCisInt<2>]>;
 781 def dwarf_loc : SDNode<"ISD::DEBUG_LOC", SDT_dwarf_loc,[SDNPHasChain]>;
 782
 783
 784