CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0068)
   6   cmake_policy(SET CMP0068 NEW)
   7   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
   8 endif()
   9
  10 if(POLICY CMP0075)
  11   cmake_policy(SET CMP0075 NEW)
  12 endif()
  13
  14 if(POLICY CMP0077)
  15   cmake_policy(SET CMP0077 NEW)
  16 endif()
  17
  18 if(NOT DEFINED LLVM_VERSION_MAJOR)
  19   set(LLVM_VERSION_MAJOR 9)
  20 endif()
  21 if(NOT DEFINED LLVM_VERSION_MINOR)
  22   set(LLVM_VERSION_MINOR 0)
  23 endif()
  24 if(NOT DEFINED LLVM_VERSION_PATCH)
  25   set(LLVM_VERSION_PATCH 0)
  26 endif()
  27 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  28   set(LLVM_VERSION_SUFFIX svn)
  29 endif()
  30
  31 if (NOT PACKAGE_VERSION)
  32   set(PACKAGE_VERSION
  33     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  34 endif()
  35
  36 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  37   message(WARNING "Visual Studio generators use the x86 host compiler by "
  38                   "default, even for 64-bit targets. This can result in linker "
  39                   "instability and out of memory errors. To use the 64-bit "
  40                   "host compiler, pass -Thost=x64 on the CMake command line.")
  41 endif()
  42
  43 project(LLVM
  44   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  45   LANGUAGES C CXX ASM)
  46
  47 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  48   message(STATUS "No build type selected, default to Debug")
  49   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  50 endif()
  51
  52 # This should only apply if you are both on an Apple host, and targeting Apple.
  53 if(CMAKE_HOST_APPLE AND APPLE)
  54   # if CMAKE_LIBTOOL is not set, try and find it with xcrun or find_program
  55   if(NOT CMAKE_LIBTOOL)
  56     if(NOT CMAKE_XCRUN)
  57       find_program(CMAKE_XCRUN NAMES xcrun)
  58     endif()
  59     if(CMAKE_XCRUN)
  60       execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  61         OUTPUT_VARIABLE CMAKE_LIBTOOL
  62         OUTPUT_STRIP_TRAILING_WHITESPACE)
  63     endif()
  64
  65     if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  66       find_program(CMAKE_LIBTOOL NAMES libtool)
  67     endif()
  68   endif()
  69
  70   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  71   if(CMAKE_LIBTOOL)
  72     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  73     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  74
  75     execute_process(COMMAND ${CMAKE_LIBTOOL} -V
  76       OUTPUT_VARIABLE LIBTOOL_V_OUTPUT
  77       OUTPUT_STRIP_TRAILING_WHITESPACE)
  78     if("${LIBTOOL_V_OUTPUT}" MATCHES ".*cctools-([0-9.]+).*")
  79       string(REGEX REPLACE ".*cctools-([0-9.]+).*" "\\1" LIBTOOL_VERSION
  80         ${LIBTOOL_V_OUTPUT})
  81       if(NOT LIBTOOL_VERSION VERSION_LESS "862")
  82         set(LIBTOOL_NO_WARNING_FLAG "-no_warning_for_no_symbols")
  83       endif()
  84     endif()
  85
  86     foreach(lang ${languages})
  87       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  88         "\"${CMAKE_LIBTOOL}\" -static ${LIBTOOL_NO_WARNING_FLAG} -o <TARGET> \
  89         <LINK_FLAGS> <OBJECTS> ")
  90     endforeach()
  91   endif()
  92
  93   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
  94   if(DYLD_LIBRARY_PATH)
  95     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
  96     foreach(lang ${languages})
  97       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
  98         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
  99              "${dyld_envar} ${cmd}")
 100       endforeach()
 101       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
 102         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
 103     endforeach()
 104   endif()
 105 endif()
 106
 107 # Side-by-side subprojects layout: automatically set the
 108 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 109 # This allows an easy way of setting up a build directory for llvm and another
 110 # one for llvm+clang+... using the same sources.
 111 set(LLVM_ALL_PROJECTS "clang;clang-tools-extra;compiler-rt;debuginfo-tests;libclc;libcxx;libcxxabi;libunwind;lld;lldb;llgo;openmp;parallel-libs;polly;pstl")
 112 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 113         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
 114 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 115   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 116 endif()
 117
 118 # LLVM_ENABLE_PROJECTS_USED is `ON` if the user has ever used the
 119 # `LLVM_ENABLE_PROJECTS` CMake cache variable.  This exists for
 120 # several reasons:
 121 #
 122 # * As an indicator that the `LLVM_ENABLE_PROJECTS` list is now the single
 123 # source of truth for which projects to build. This means we will ignore user
 124 # supplied `LLVM_TOOL_<project>_BUILD` CMake cache variables and overwrite
 125 # them.
 126 #
 127 # * The case where the user previously had `LLVM_ENABLE_PROJECTS` set to a
 128 # non-empty list but now the user wishes to disable building all other projects
 129 # by setting `LLVM_ENABLE_PROJECTS` to an empty string. In that case we still
 130 # need to set the `LLVM_TOOL_${upper_proj}_BUILD` variables so that we disable
 131 # building all the projects that were previously enabled.
 132 set(LLVM_ENABLE_PROJECTS_USED OFF CACHE BOOL "")
 133 mark_as_advanced(LLVM_ENABLE_PROJECTS_USED)
 134
 135 if (LLVM_ENABLE_PROJECTS_USED OR NOT LLVM_ENABLE_PROJECTS STREQUAL "")
 136   set(LLVM_ENABLE_PROJECTS_USED ON CACHE BOOL "" FORCE)
 137   foreach(proj ${LLVM_ALL_PROJECTS} ${LLVM_EXTERNAL_PROJECTS})
 138     string(TOUPPER "${proj}" upper_proj)
 139     string(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 140     if ("${proj}" IN_LIST LLVM_ENABLE_PROJECTS)
 141       message(STATUS "${proj} project is enabled")
 142       set(SHOULD_ENABLE_PROJECT TRUE)
 143       set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 144       if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 145         message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 146       endif()
 147       set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE STRING "")
 148     else()
 149       message(STATUS "${proj} project is disabled")
 150       set(SHOULD_ENABLE_PROJECT FALSE)
 151     endif()
 152     # Force `LLVM_TOOL_${upper_proj}_BUILD` variables to have values that
 153     # corresponds with `LLVM_ENABLE_PROJECTS`. This prevents the user setting
 154     # `LLVM_TOOL_${upper_proj}_BUILD` variables externally. At some point
 155     # we should deprecate allowing users to set these variables by turning them
 156     # into normal CMake variables rather than cache variables.
 157     set(LLVM_TOOL_${upper_proj}_BUILD
 158       ${SHOULD_ENABLE_PROJECT}
 159       CACHE
 160       BOOL "Whether to build ${upper_proj} as part of LLVM" FORCE
 161     )
 162   endforeach()
 163 endif()
 164 unset(SHOULD_ENABLE_PROJECT)
 165
 166 # Build llvm with ccache if the package is present
 167 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 168 if(LLVM_CCACHE_BUILD)
 169   find_program(CCACHE_PROGRAM ccache)
 170   if(CCACHE_PROGRAM)
 171       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 172       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 173       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 174           CACHE STRING "Parameters to pass through to ccache")
 175
 176       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 177       if (LLVM_CCACHE_MAXSIZE)
 178         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 179       endif()
 180       if (LLVM_CCACHE_DIR)
 181         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 182       endif()
 183       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 184   else()
 185     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 186   endif()
 187 endif()
 188
 189 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 190
 191 # Some features of the LLVM build may be disallowed when dependency debugging is
 192 # enabled. In particular you cannot use ccache because we want to force compile
 193 # operations to always happen.
 194 if(LLVM_DEPENDENCY_DEBUGGING)
 195   if(NOT CMAKE_HOST_APPLE)
 196     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 197   endif()
 198   if(LLVM_CCACHE_BUILD)
 199     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 200   endif()
 201 endif()
 202
 203 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 204 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 205 if(LLVM_ENABLE_GISEL_COV)
 206   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 207 endif()
 208
 209 # Add path for custom modules
 210 set(CMAKE_MODULE_PATH
 211   ${CMAKE_MODULE_PATH}
 212   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 213   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 214   )
 215
 216 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 217 # for use by clang_complete, YouCompleteMe, etc.
 218 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 219
 220 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 221   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 222
 223 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 224
 225 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 226
 227 # Unfortunatly Clang is too eager to search directories for module maps, which can cause the
 228 # installed version of the maps to be found when building LLVM from source. Therefore we turn off
 229 # the installation by default. See llvm.org/PR31905.
 230 option(LLVM_INSTALL_MODULEMAPS "Install the modulemap files in the 'install' target." OFF)
 231
 232 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 233 if ( LLVM_USE_FOLDERS )
 234   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 235 endif()
 236
 237 include(VersionFromVCS)
 238
 239 option(LLVM_APPEND_VC_REV
 240   "Embed the version control system revision in LLVM" ON)
 241
 242 set(PACKAGE_NAME LLVM)
 243 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 244 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
 245
 246 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 247   "Default URL where bug reports are to be submitted.")
 248
 249 # Configure CPack.
 250 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 251 set(CPACK_PACKAGE_VENDOR "LLVM")
 252 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 253 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 254 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 255 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 256 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 257 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 258 if(WIN32 AND NOT UNIX)
 259   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 260   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 261   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 262   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 263   set(CPACK_NSIS_MODIFY_PATH "ON")
 264   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 265   if( CMAKE_CL_64 )
 266     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 267   endif()
 268 endif()
 269 include(CPack)
 270
 271 # Sanity check our source directory to make sure that we are not trying to
 272 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 273 # sure that we don't have any stray generated files lying around in the tree
 274 # (which would end up getting picked up by header search, instead of the correct
 275 # versions).
 276 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 277   message(FATAL_ERROR "In-source builds are not allowed.
 278 Please create a directory and run cmake from there, passing the path
 279 to this source directory as the last argument.
 280 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 281 Please delete them.")
 282 endif()
 283
 284 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 285
 286 if (CMAKE_BUILD_TYPE AND
 287     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 288   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 289 endif()
 290
 291 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 292
 293 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 294 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 295
 296 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 297     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 298 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 299
 300 # They are used as destination of target generators.
 301 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 302 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 303 if(WIN32 OR CYGWIN)
 304   # DLL platform -- put DLLs into bin.
 305   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 306 else()
 307   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 308 endif()
 309
 310 # Each of them corresponds to llvm-config's.
 311 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 312 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 313 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 314 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 315 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 316
 317 # Note: LLVM_CMAKE_PATH does not include generated files
 318 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 319 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 320 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 321
 322 # List of all targets to be built by default:
 323 set(LLVM_ALL_TARGETS
 324   AArch64
 325   AMDGPU
 326   ARM
 327   BPF
 328   Hexagon
 329   Lanai
 330   Mips
 331   MSP430
 332   NVPTX
 333   PowerPC
 334   Sparc
 335   SystemZ
 336   WebAssembly
 337   X86
 338   XCore
 339   )
 340
 341 # List of targets with JIT support:
 342 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 343
 344 set(LLVM_TARGETS_TO_BUILD "all"
 345     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 346
 347 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 348   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 349
 350 option(BUILD_SHARED_LIBS
 351   "Build all libraries as shared libraries instead of static" OFF)
 352
 353 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 354 if(LLVM_ENABLE_BACKTRACES)
 355   set(ENABLE_BACKTRACES 1)
 356 endif()
 357
 358 option(LLVM_ENABLE_UNWIND_TABLES "Emit unwind tables for the libraries" ON)
 359
 360 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 361 if(LLVM_ENABLE_CRASH_OVERRIDES)
 362   set(ENABLE_CRASH_OVERRIDES 1)
 363 endif()
 364
 365 option(LLVM_ENABLE_CRASH_DUMPS "Turn on memory dumps on crashes. Currently only implemented on Windows." OFF)
 366
 367 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 368 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 369 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 370
 371 set(LLVM_TARGET_ARCH "host"
 372   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 373
 374 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 375
 376 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 377
 378 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 379
 380 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 381
 382 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 383
 384 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 385
 386 set(LLVM_Z3_INSTALL_DIR "" CACHE STRING "Install directory of the Z3 solver.")
 387
 388 find_package(Z3 4.7.1)
 389
 390 if (LLVM_Z3_INSTALL_DIR)
 391   if (NOT Z3_FOUND)
 392     message(FATAL_ERROR "Z3 >= 4.7.1 has not been found in LLVM_Z3_INSTALL_DIR: ${LLVM_Z3_INSTALL_DIR}.")
 393   endif()
 394 endif()
 395
 396 set(LLVM_ENABLE_Z3_SOLVER_DEFAULT "${Z3_FOUND}")
 397
 398 option(LLVM_ENABLE_Z3_SOLVER
 399   "Enable Support for the Z3 constraint solver in LLVM."
 400   ${LLVM_ENABLE_Z3_SOLVER_DEFAULT}
 401 )
 402
 403 if (LLVM_ENABLE_Z3_SOLVER)
 404   if (NOT Z3_FOUND)
 405     message(FATAL_ERROR "LLVM_ENABLE_Z3_SOLVER cannot be enabled when Z3 is not available.")
 406   endif()
 407
 408   set(LLVM_WITH_Z3 1)
 409 endif()
 410
 411 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 412   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 413 endif()
 414
 415 set(LLVM_TARGETS_TO_BUILD
 416    ${LLVM_TARGETS_TO_BUILD}
 417    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 418 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 419
 420 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 421 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 422 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 423 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 424   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 425   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 426 else()
 427   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 428   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 429 endif()
 430 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 431 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 432 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 433 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 434
 435 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 436
 437 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 438   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 439 else()
 440   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 441 endif()
 442
 443 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 444
 445 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 446   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 447
 448 option(LLVM_FORCE_USE_OLD_TOOLCHAIN
 449        "Set to ON to force using an old, unsupported host toolchain." OFF)
 450
 451 option(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN
 452        "Set to ON to only warn when using a toolchain which is about to be deprecated, instead of emitting an error." OFF)
 453
 454 option(LLVM_USE_INTEL_JITEVENTS
 455   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 456   OFF)
 457
 458 if( LLVM_USE_INTEL_JITEVENTS )
 459   # Verify we are on a supported platform
 460   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 461     message(FATAL_ERROR
 462       "Intel JIT API support is available on Linux and Windows only.")
 463   endif()
 464 endif( LLVM_USE_INTEL_JITEVENTS )
 465
 466 option(LLVM_USE_OPROFILE
 467   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 468
 469 option(LLVM_EXTERNALIZE_DEBUGINFO
 470   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 471
 472 set(LLVM_CODESIGNING_IDENTITY "" CACHE STRING
 473   "Sign executables and dylibs with the given identity or skip if empty (Darwin Only)")
 474
 475 # If enabled, verify we are on a platform that supports oprofile.
 476 if( LLVM_USE_OPROFILE )
 477   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 478     message(FATAL_ERROR "OProfile support is available on Linux only.")
 479   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 480 endif( LLVM_USE_OPROFILE )
 481
 482 option(LLVM_USE_PERF
 483   "Use perf JIT interface to inform perf about JIT code" OFF)
 484
 485 # If enabled, verify we are on a platform that supports perf.
 486 if( LLVM_USE_PERF )
 487   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 488     message(FATAL_ERROR "perf support is available on Linux only.")
 489   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 490 endif( LLVM_USE_PERF )
 491
 492 set(LLVM_USE_SANITIZER "" CACHE STRING
 493   "Define the sanitizer used to build binaries and tests.")
 494 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 495 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 496   "Path to fuzzing library for linking with fuzz targets")
 497
 498 option(LLVM_USE_SPLIT_DWARF
 499   "Use -gsplit-dwarf when compiling llvm." OFF)
 500
 501 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 502 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 503
 504 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 505   set(POLLY_IN_TREE TRUE)
 506 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 507   set(POLLY_IN_TREE TRUE)
 508 else()
 509   set(POLLY_IN_TREE FALSE)
 510 endif()
 511
 512 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 513   set(WITH_POLLY ON)
 514 else()
 515   set(WITH_POLLY OFF)
 516 endif()
 517
 518 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 519   set(LINK_POLLY_INTO_TOOLS ON)
 520 else()
 521   set(LINK_POLLY_INTO_TOOLS OFF)
 522 endif()
 523
 524 # Define an option controlling whether we should build for 32-bit on 64-bit
 525 # platforms, where supported.
 526 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 527   # TODO: support other platforms and toolchains.
 528   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 529 endif()
 530
 531 # Define the default arguments to use with 'lit', and an option for the user to
 532 # override.
 533 set(LIT_ARGS_DEFAULT "-sv")
 534 if (MSVC_IDE OR XCODE)
 535   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 536 endif()
 537 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 538
 539 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 540 if( WIN32 AND NOT CYGWIN )
 541   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 542 endif()
 543
 544 # Define options to control the inclusion and default build behavior for
 545 # components which may not strictly be necessary (tools, examples, and tests).
 546 #
 547 # This is primarily to support building smaller or faster project files.
 548 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 549 option(LLVM_BUILD_TOOLS
 550   "Build the LLVM tools. If OFF, just generate build targets." ON)
 551
 552 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 553 option(LLVM_BUILD_UTILS
 554   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 555
 556 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 557 option(LLVM_BUILD_RUNTIMES
 558   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 559
 560 option(LLVM_BUILD_RUNTIME
 561   "Build the LLVM runtime libraries." ON)
 562 option(LLVM_BUILD_EXAMPLES
 563   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 564 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 565
 566 option(LLVM_BUILD_TESTS
 567   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 568 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 569 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 570
 571 option(LLVM_BUILD_BENCHMARKS "Add LLVM benchmark targets to the list of default
 572 targets. If OFF, benchmarks still could be built using Benchmarks target." OFF)
 573 option(LLVM_INCLUDE_BENCHMARKS "Generate benchmark targets. If OFF, benchmarks can't be built." ON)
 574
 575 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 576 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 577 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 578 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 579 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 580 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 581
 582 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 583     CACHE STRING "Doxygen-generated HTML documentation install directory")
 584 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 585     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 586
 587 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 588   "Build compiler-rt as an external project." OFF)
 589
 590 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 591   "Show target and host info when tools are invoked with --version." ON)
 592
 593 # You can configure which libraries from LLVM you want to include in the
 594 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 595 # list of LLVM components. All component names handled by llvm-config are valid.
 596 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 597   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 598     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 599 endif()
 600 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 601 if(MSVC)
 602   option(LLVM_BUILD_LLVM_C_DYLIB "Build LLVM-C.dll (Windows only)" ON)
 603 else()
 604   option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin only)" OFF)
 605 endif()
 606 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 607 if(LLVM_LINK_LLVM_DYLIB OR (LLVM_BUILD_LLVM_C_DYLIB AND NOT MSVC))
 608   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 609 endif()
 610 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 611
 612 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 613 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 614   set(LLVM_USE_HOST_TOOLS ON)
 615 endif()
 616
 617 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 618   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 619 else()
 620   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 621 endif()
 622
 623 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 624     LLVM_ENABLE_IR_PGO)
 625   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 626     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 627     # for spining disks. Anything higher may only help on slower mediums.
 628     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 629   endif()
 630   if(NOT LLVM_PROFILE_FILE_PATTERN)
 631     if(NOT LLVM_PROFILE_DATA_DIR)
 632       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 633     endif()
 634                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 635   endif()
 636   if(NOT LLVM_CSPROFILE_FILE_PATTERN)
 637     if(NOT LLVM_CSPROFILE_DATA_DIR)
 638       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/csprofiles" LLVM_CSPROFILE_DATA_DIR)
 639     endif()
 640     file(TO_NATIVE_PATH "${LLVM_CSPROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_CSPROFILE_FILE_PATTERN)
 641   endif()
 642 endif()
 643
 644 if (LLVM_BUILD_STATIC)
 645   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 646 endif()
 647
 648 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 649 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 650 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 651
 652 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR OFF CACHE BOOL
 653   "Enable per-target runtimes directory")
 654
 655 # All options referred to from HandleLLVMOptions have to be specified
 656 # BEFORE this include, otherwise options will not be correctly set on
 657 # first cmake run
 658 include(config-ix)
 659
 660 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 661   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 662 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 663
 664 # By default, we target the host, but this can be overridden at CMake
 665 # invocation time.
 666 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 667   "Default target for which LLVM will generate code." )
 668 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 669 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 670 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 671
 672 include(HandleLLVMOptions)
 673
 674 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 675 # FIXME: We should support systems with only Python 3, but that requires work
 676 # on LLDB.
 677 set(Python_ADDITIONAL_VERSIONS 2.7)
 678 include(FindPythonInterp)
 679 if( NOT PYTHONINTERP_FOUND )
 680   message(FATAL_ERROR
 681 "Unable to find Python interpreter, required for builds and testing.
 682
 683 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 684 endif()
 685
 686 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 687   message(FATAL_ERROR "Python 2.7 or newer is required")
 688 endif()
 689
 690 ######
 691 # LLVMBuild Integration
 692 #
 693 # We use llvm-build to generate all the data required by the CMake based
 694 # build system in one swoop:
 695 #
 696 #  - We generate a file (a CMake fragment) in the object root which contains
 697 #    all the definitions that are required by CMake.
 698 #
 699 #  - We generate the library table used by llvm-config.
 700 #
 701 #  - We generate the dependencies for the CMake fragment, so that we will
 702 #    automatically reconfigure ourselves.
 703
 704 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 705 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 706   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 707 set(LLVMBUILDCMAKEFRAG
 708   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 709
 710 # Create the list of optional components that are enabled
 711 if (LLVM_USE_INTEL_JITEVENTS)
 712   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 713 endif (LLVM_USE_INTEL_JITEVENTS)
 714 if (LLVM_USE_OPROFILE)
 715   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 716 endif (LLVM_USE_OPROFILE)
 717 if (LLVM_USE_PERF)
 718   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} PerfJITEvents)
 719 endif (LLVM_USE_PERF)
 720
 721 message(STATUS "Constructing LLVMBuild project information")
 722 execute_process(
 723   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 724             --native-target "${LLVM_NATIVE_ARCH}"
 725             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 726             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 727             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 728             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 729             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 730             ERROR_VARIABLE LLVMBUILDERRORS
 731             OUTPUT_STRIP_TRAILING_WHITESPACE
 732             ERROR_STRIP_TRAILING_WHITESPACE
 733   RESULT_VARIABLE LLVMBUILDRESULT)
 734
 735 # On Win32, CMake doesn't properly handle piping the default output/error
 736 # streams into the GUI console. So, we explicitly catch and report them.
 737 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 738   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 739 endif()
 740 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 741   message(FATAL_ERROR
 742     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 743 endif()
 744
 745 # Include the generated CMake fragment. This will define properties from the
 746 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 747 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 748 # files change.
 749 include(${LLVMBUILDCMAKEFRAG})
 750
 751 ######
 752
 753 # Configure all of the various header file fragments LLVM uses which depend on
 754 # configuration variables.
 755 set(LLVM_ENUM_TARGETS "")
 756 set(LLVM_ENUM_ASM_PRINTERS "")
 757 set(LLVM_ENUM_ASM_PARSERS "")
 758 set(LLVM_ENUM_DISASSEMBLERS "")
 759 foreach(t ${LLVM_TARGETS_TO_BUILD})
 760   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 761
 762   list(FIND LLVM_ALL_TARGETS ${t} idx)
 763   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 764   # At this point, LLVMBUILDTOOL already checked all the targets passed in
 765   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
 766   # this test just makes sure that any experimental targets were passed via
 767   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 768   if( idx LESS 0 AND idy LESS 0 )
 769     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 770       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 771   else()
 772     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 773   endif()
 774
 775   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 776   if( asmp_file )
 777     set(LLVM_ENUM_ASM_PRINTERS
 778       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 779   endif()
 780   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 781     set(LLVM_ENUM_ASM_PARSERS
 782       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 783   endif()
 784   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 785     set(LLVM_ENUM_DISASSEMBLERS
 786       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 787   endif()
 788 endforeach(t)
 789
 790 # Produce the target definition files, which provide a way for clients to easily
 791 # include various classes of targets.
 792 configure_file(
 793   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 794   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 795   )
 796 configure_file(
 797   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 798   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 799   )
 800 configure_file(
 801   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 802   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 803   )
 804 configure_file(
 805   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 806   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 807   )
 808
 809 # Configure the three LLVM configuration header files.
 810 configure_file(
 811   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 812   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 813 configure_file(
 814   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 815   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 816 configure_file(
 817   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 818   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 819
 820 # Add target for generating source rpm package.
 821 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 822     CACHE FILEPATH ".spec file to use for srpm generation")
 823 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 824 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 825
 826 get_source_info(${CMAKE_CURRENT_SOURCE_DIR} revision repository)
 827 string(LENGTH "${revision}" revision_length)
 828 if(revision MATCHES "^[0-9]+$" AND revision_length LESS 40)
 829   set(LLVM_RPM_SPEC_REVISION "r${revision}")
 830 else()
 831   set(LLVM_RPM_SPEC_REVISION "${revision}")
 832 endif()
 833
 834 configure_file(
 835   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 836   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 837
 838 add_custom_target(srpm
 839   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 840   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 841 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 842
 843
 844 # They are not referenced. See set_output_directory().
 845 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 846 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 847 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 848
 849 if(APPLE AND DARWIN_LTO_LIBRARY)
 850   set(CMAKE_EXE_LINKER_FLAGS
 851     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 852   set(CMAKE_SHARED_LINKER_FLAGS
 853     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 854   set(CMAKE_MODULE_LINKER_FLAGS
 855     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 856 endif()
 857
 858 # Work around a broken bfd ld behavior. When linking a binary with a
 859 # foo.so library, it will try to find any library that foo.so uses and
 860 # check its symbols. This is wasteful (the check was done when foo.so
 861 # was created) and can fail since it is not the dynamic linker and
 862 # doesn't know how to handle search paths correctly.
 863 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 864   set(CMAKE_EXE_LINKER_FLAGS
 865       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 866 endif()
 867
 868 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 869
 870 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 871
 872 # when crosscompiling import the executable targets from a file
 873 if(LLVM_USE_HOST_TOOLS)
 874   include(CrossCompile)
 875 endif(LLVM_USE_HOST_TOOLS)
 876 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 877 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 878 # (this is a variable that CrossCompile sets on recursive invocations)
 879 endif()
 880
 881 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 882   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 883   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 884   include_directories(SYSTEM "/usr/local/include")
 885   link_directories("/usr/local/lib")
 886 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 887
 888 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 889    # special hack for Solaris to handle crazy system sys/regset.h
 890    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 891 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 892
 893 # Make sure we don't get -rdynamic in every binary. For those that need it,
 894 # use export_executable_symbols(target).
 895 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 896
 897 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 898   "Profiling data file to use when compiling in order to improve runtime performance.")
 899
 900 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 901   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 902     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 903   else()
 904     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 905   endif()
 906 endif()
 907
 908 include(AddLLVM)
 909 include(TableGen)
 910
 911 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 912   # People report that -O3 is unreliable on MinGW. The traditional
 913   # build also uses -O2 for that reason:
 914   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 915 endif()
 916
 917 # Put this before tblgen. Else we have a circular dependence.
 918 add_subdirectory(lib/Demangle)
 919 add_subdirectory(lib/Support)
 920 add_subdirectory(lib/TableGen)
 921
 922 add_subdirectory(utils/TableGen)
 923
 924 add_subdirectory(include/llvm)
 925
 926 add_subdirectory(lib)
 927
 928 if( LLVM_INCLUDE_UTILS )
 929   add_subdirectory(utils/FileCheck)
 930   add_subdirectory(utils/PerfectShuffle)
 931   add_subdirectory(utils/count)
 932   add_subdirectory(utils/not)
 933   add_subdirectory(utils/yaml-bench)
 934 else()
 935   if ( LLVM_INCLUDE_TESTS )
 936     message(FATAL_ERROR "Including tests when not building utils will not work.
 937     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLUDE_TESTS to Off.")
 938   endif()
 939 endif()
 940
 941 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 942 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 943   add_subdirectory(utils/LLVMVisualizers)
 944 endif()
 945
 946 foreach( binding ${LLVM_BINDINGS_LIST} )
 947   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 948     add_subdirectory(bindings/${binding})
 949   endif()
 950 endforeach()
 951
 952 add_subdirectory(projects)
 953
 954 if( LLVM_INCLUDE_TOOLS )
 955   add_subdirectory(tools)
 956 endif()
 957
 958 if( LLVM_INCLUDE_RUNTIMES )
 959   add_subdirectory(runtimes)
 960 endif()
 961
 962 if( LLVM_INCLUDE_EXAMPLES )
 963   add_subdirectory(examples)
 964 endif()
 965
 966 if( LLVM_INCLUDE_TESTS )
 967   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 968     include(LLVMExternalProjectUtils)
 969     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 970       USE_TOOLCHAIN
 971       EXCLUDE_FROM_ALL
 972       NO_INSTALL
 973       ALWAYS_CLEAN)
 974   endif()
 975   add_subdirectory(utils/lit)
 976   add_subdirectory(test)
 977   add_subdirectory(unittests)
 978   if( LLVM_INCLUDE_UTILS )
 979     add_subdirectory(utils/unittest)
 980   endif()
 981
 982   if (WIN32)
 983     # This utility is used to prevent crashing tests from calling Dr. Watson on
 984     # Windows.
 985     add_subdirectory(utils/KillTheDoctor)
 986   endif()
 987
 988   # Add a global check rule now that all subdirectories have been traversed
 989   # and we know the total set of lit testsuites.
 990   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 991   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 992   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 993   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 994   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 995                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 996   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 997                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 998   add_lit_target(check-all
 999     "Running all regression tests"
1000     ${LLVM_LIT_TESTSUITES}
1001     PARAMS ${LLVM_LIT_PARAMS}
1002     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
1003     ARGS ${LLVM_LIT_EXTRA_ARGS}
1004     )
1005   if(TARGET check-runtimes)
1006     add_dependencies(check-all check-runtimes)
1007   endif()
1008   add_custom_target(test-depends
1009                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
1010   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
1011 endif()
1012
1013 if (LLVM_INCLUDE_DOCS)
1014   add_subdirectory(docs)
1015 endif()
1016
1017 add_subdirectory(cmake/modules)
1018
1019 # Do this last so that all lit targets have already been created.
1020 if (LLVM_INCLUDE_UTILS)
1021   add_subdirectory(utils/llvm-lit)
1022 endif()
1023
1024 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1025   install(DIRECTORY include/llvm include/llvm-c
1026     DESTINATION include
1027     COMPONENT llvm-headers
1028     FILES_MATCHING
1029     PATTERN "*.def"
1030     PATTERN "*.h"
1031     PATTERN "*.td"
1032     PATTERN "*.inc"
1033     PATTERN "LICENSE.TXT"
1034     PATTERN ".svn" EXCLUDE
1035     )
1036
1037   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
1038     DESTINATION include
1039     COMPONENT llvm-headers
1040     FILES_MATCHING
1041     PATTERN "*.def"
1042     PATTERN "*.h"
1043     PATTERN "*.gen"
1044     PATTERN "*.inc"
1045     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
1046     PATTERN "CMakeFiles" EXCLUDE
1047     PATTERN "config.h" EXCLUDE
1048     PATTERN ".svn" EXCLUDE
1049     )
1050
1051   if (LLVM_INSTALL_MODULEMAPS)
1052     install(DIRECTORY include/llvm include/llvm-c
1053             DESTINATION include
1054             COMPONENT llvm-headers
1055             FILES_MATCHING
1056             PATTERN "module.modulemap"
1057             )
1058     install(FILES include/llvm/module.install.modulemap
1059             DESTINATION include/llvm
1060             COMPONENT llvm-headers
1061             RENAME "module.extern.modulemap"
1062             )
1063   endif(LLVM_INSTALL_MODULEMAPS)
1064
1065   # Installing the headers needs to depend on generating any public
1066   # tablegen'd headers.
1067   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
1068   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
1069
1070   if (NOT LLVM_ENABLE_IDE)
1071     add_llvm_install_targets(install-llvm-headers
1072                              DEPENDS llvm-headers
1073                              COMPONENT llvm-headers)
1074   endif()
1075
1076   # Custom target to install all libraries.
1077   add_custom_target(llvm-libraries)
1078   set_target_properties(llvm-libraries PROPERTIES FOLDER "Misc")
1079
1080   if (NOT LLVM_ENABLE_IDE)
1081     add_llvm_install_targets(install-llvm-libraries
1082                              DEPENDS llvm-libraries
1083                              COMPONENT llvm-libraries)
1084   endif()
1085
1086   get_property(LLVM_LIBS GLOBAL PROPERTY LLVM_LIBS)
1087   if(LLVM_LIBS)
1088     list(REMOVE_DUPLICATES LLVM_LIBS)
1089     foreach(lib ${LLVM_LIBS})
1090       add_dependencies(llvm-libraries ${lib})
1091       if (NOT LLVM_ENABLE_IDE)
1092         add_dependencies(install-llvm-libraries install-${lib})
1093       endif()
1094     endforeach()
1095   endif()
1096 endif()
1097
1098 # This must be at the end of the LLVM root CMakeLists file because it must run
1099 # after all targets are created.
1100 if(LLVM_DISTRIBUTION_COMPONENTS)
1101   if(LLVM_ENABLE_IDE)
1102     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
1103   endif()
1104
1105   add_custom_target(distribution)
1106   add_custom_target(install-distribution)
1107   add_custom_target(install-distribution-stripped)
1108   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS} ${LLVM_RUNTIME_DISTRIBUTION_COMPONENTS})
1109     if(TARGET ${target})
1110       add_dependencies(distribution ${target})
1111     else()
1112       message(SEND_ERROR "Specified distribution component '${target}' doesn't have a target")
1113     endif()
1114
1115     if(TARGET install-${target})
1116       add_dependencies(install-distribution install-${target})
1117     else()
1118       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install target")
1119     endif()
1120
1121     if(TARGET install-${target}-stripped)
1122       add_dependencies(install-distribution-stripped install-${target}-stripped)
1123     else()
1124       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install-stripped target."
1125                          " Its installation target creation should be changed to use add_llvm_install_targets,"
1126                          " or you should manually create the 'install-${target}-stripped' target.")
1127     endif()
1128   endforeach()
1129 endif()
1130
1131 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1132 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" AND CMAKE_INSTALL_UCRT_LIBRARIES)
1133   include(InstallRequiredSystemLibraries)
1134 endif()
1135
1136 if (LLVM_INCLUDE_BENCHMARKS)
1137   # Override benchmark defaults so that when the library itself is updated these
1138   # modifications are not lost.
1139   set(BENCHMARK_ENABLE_TESTING OFF CACHE BOOL "Disable benchmark testing" FORCE)
1140   set(BENCHMARK_ENABLE_EXCEPTIONS OFF CACHE BOOL "Disable benchmark exceptions" FORCE)
1141   set(BENCHMARK_ENABLE_INSTALL OFF CACHE BOOL "Don't install benchmark" FORCE)
1142   set(BENCHMARK_DOWNLOAD_DEPENDENCIES OFF CACHE BOOL "Don't download dependencies" FORCE)
1143   set(BENCHMARK_ENABLE_GTEST_TESTS OFF CACHE BOOL "Disable Google Test in benchmark" FORCE)
1144   # Since LLVM requires C++11 it is safe to assume that std::regex is available.
1145   set(HAVE_STD_REGEX ON CACHE BOOL "OK" FORCE)
1146
1147   add_subdirectory(utils/benchmark)
1148   add_subdirectory(benchmarks)
1149 endif()