CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 cmake_policy(SET CMP0022 NEW)
   6
   7 cmake_policy(SET CMP0048 NEW)
   8
   9 # CMake 3.1 and higher include generator expressions of the form
  10 # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  11 # stripped everywhere that access the SOURCES property, so we just
  12 # defer to the OLD behavior of not including generator expressions
  13 # in the output for now.
  14 cmake_policy(SET CMP0051 OLD)
  15
  16 cmake_policy(SET CMP0056 NEW)
  17
  18 cmake_policy(SET CMP0057 NEW)
  19
  20 if(NOT DEFINED LLVM_VERSION_MAJOR)
  21   set(LLVM_VERSION_MAJOR 6)
  22 endif()
  23 if(NOT DEFINED LLVM_VERSION_MINOR)
  24   set(LLVM_VERSION_MINOR 0)
  25 endif()
  26 if(NOT DEFINED LLVM_VERSION_PATCH)
  27   set(LLVM_VERSION_PATCH 0)
  28 endif()
  29 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  30   set(LLVM_VERSION_SUFFIX svn)
  31 endif()
  32
  33 if (NOT PACKAGE_VERSION)
  34   set(PACKAGE_VERSION
  35     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  36 endif()
  37
  38 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  39   message(WARNING "Visual Studio generators use the x86 host compiler by "
  40                   "default, even for 64-bit targets. This can result in linker "
  41                   "instability and out of memory errors. To use the 64-bit "
  42                   "host compiler, pass -Thost=x64 on the CMake command line.")
  43 endif()
  44
  45 project(LLVM
  46   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  47   LANGUAGES C CXX ASM)
  48
  49 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  50   message(STATUS "No build type selected, default to Debug")
  51   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  52 endif()
  53
  54 # This should only apply if you are both on an Apple host, and targeting Apple.
  55 if(CMAKE_HOST_APPLE AND APPLE)
  56   # if CMAKE_LIBTOOL is not set, try and find it with xcrun or find_program
  57   if(NOT CMAKE_LIBTOOL)
  58     if(NOT CMAKE_XCRUN)
  59       find_program(CMAKE_XCRUN NAMES xcrun)
  60     endif()
  61     if(CMAKE_XCRUN)
  62       execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  63         OUTPUT_VARIABLE CMAKE_LIBTOOL
  64         OUTPUT_STRIP_TRAILING_WHITESPACE)
  65     endif()
  66
  67     if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  68       find_program(CMAKE_LIBTOOL NAMES libtool)
  69     endif()
  70   endif()
  71
  72   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  73   if(CMAKE_LIBTOOL)
  74     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  75     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  76
  77     execute_process(COMMAND ${CMAKE_LIBTOOL} -V
  78       OUTPUT_VARIABLE LIBTOOL_V_OUTPUT
  79       OUTPUT_STRIP_TRAILING_WHITESPACE)
  80     if("${LIBTOOL_V_OUTPUT}" MATCHES ".*cctools-([0-9.]+).*")
  81       string(REGEX REPLACE ".*cctools-([0-9.]+).*" "\\1" LIBTOOL_VERSION
  82         ${LIBTOOL_V_OUTPUT})
  83       if(NOT LIBTOOL_VERSION VERSION_LESS "862")
  84         set(LIBTOOL_NO_WARNING_FLAG "-no_warning_for_no_symbols")
  85       endif()
  86     endif()
  87
  88     foreach(lang ${languages})
  89       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  90         "${CMAKE_LIBTOOL} -static ${LIBTOOL_NO_WARNING_FLAG} -o <TARGET> \
  91         <LINK_FLAGS> <OBJECTS> ")
  92     endforeach()
  93   endif()
  94
  95   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
  96   if(DYLD_LIBRARY_PATH)
  97     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
  98     foreach(lang ${languages})
  99       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
 100         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
 101              "${dyld_envar} ${cmd}")
 102       endforeach()
 103       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
 104         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
 105     endforeach()
 106   endif()
 107 endif()
 108
 109 # Side-by-side subprojects layout: automatically set the
 110 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 111 # This allows an easy way of setting up a build directory for llvm and another
 112 # one for llvm+clang+... using the same sources.
 113 set(LLVM_ALL_PROJECTS "clang;libcxx;libcxxabi;lldb;compiler-rt;lld;polly;debuginfo-tests")
 114 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 115         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
 116 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 117   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 118 endif()
 119 foreach(proj ${LLVM_ENABLE_PROJECTS})
 120   set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 121   if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 122     message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 123   endif()
 124   string(TOUPPER "${proj}" upper_proj)
 125   STRING(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 126   set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR   "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 127   # There is a widely spread opinion that clang-tools-extra should be merged
 128   # into clang. The following simulates it by always enabling clang-tools-extra
 129   # when enabling clang.
 130   if (proj STREQUAL "clang")
 131     set(LLVM_EXTERNAL_CLANG_TOOLS_EXTRA_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../clang-tools-extra")
 132   endif()
 133 endforeach()
 134
 135 # Build llvm with ccache if the package is present
 136 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 137 if(LLVM_CCACHE_BUILD)
 138   find_program(CCACHE_PROGRAM ccache)
 139   if(CCACHE_PROGRAM)
 140       set(LLVM_CCACHE_SIZE "" CACHE STRING "Size of ccache")
 141       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 142       set(CCACHE_PROGRAM "CCACHE_CPP2=yes CCACHE_HASHDIR=yes ${CCACHE_PROGRAM}")
 143       if (LLVM_CCACHE_SIZE)
 144         set(CCACHE_PROGRAM "CCACHE_SIZE=${LLVM_CCACHE_SIZE} ${CCACHE_PROGRAM}")
 145       endif()
 146       if (LLVM_CCACHE_DIR)
 147         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 148       endif()
 149       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 150   else()
 151     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 152   endif()
 153 endif()
 154
 155 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 156
 157 # Some features of the LLVM build may be disallowed when dependency debugging is
 158 # enabled. In particular you cannot use ccache because we want to force compile
 159 # operations to always happen.
 160 if(LLVM_DEPENDENCY_DEBUGGING)
 161   if(NOT CMAKE_HOST_APPLE)
 162     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 163   endif()
 164   if(LLVM_CCACHE_BUILD)
 165     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 166   endif()
 167 endif()
 168
 169 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 170 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 171 if(LLVM_ENABLE_GISEL_COV)
 172   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 173 endif()
 174
 175 # Add path for custom modules
 176 set(CMAKE_MODULE_PATH
 177   ${CMAKE_MODULE_PATH}
 178   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 179   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 180   )
 181
 182 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 183 # for use by clang_complete, YouCompleteMe, etc.
 184 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 185
 186 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 187   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 188
 189 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 190
 191 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 192
 193 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 194 if ( LLVM_USE_FOLDERS )
 195   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 196 endif()
 197
 198 include(VersionFromVCS)
 199
 200 option(LLVM_APPEND_VC_REV
 201   "Embed the version control system revision id in LLVM" ON)
 202
 203 set(PACKAGE_NAME LLVM)
 204 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 205 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
 206
 207 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 208   "Default URL where bug reports are to be submitted.")
 209
 210 # Configure CPack.
 211 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 212 set(CPACK_PACKAGE_VENDOR "LLVM")
 213 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 214 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 215 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 216 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 217 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 218 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 219 if(WIN32 AND NOT UNIX)
 220   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 221   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 222   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 223   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 224   set(CPACK_NSIS_MODIFY_PATH "ON")
 225   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 226   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 227     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 228   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 229     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 230   if( CMAKE_CL_64 )
 231     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 232   endif()
 233 endif()
 234 include(CPack)
 235
 236 # Sanity check our source directory to make sure that we are not trying to
 237 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 238 # sure that we don't have any stray generated files lying around in the tree
 239 # (which would end up getting picked up by header search, instead of the correct
 240 # versions).
 241 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 242   message(FATAL_ERROR "In-source builds are not allowed.
 243 CMake would overwrite the makefiles distributed with LLVM.
 244 Please create a directory and run cmake from there, passing the path
 245 to this source directory as the last argument.
 246 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 247 Please delete them.")
 248 endif()
 249 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 250   file(GLOB_RECURSE
 251     tablegenned_files_on_include_dir
 252     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 253   file(GLOB_RECURSE
 254     tablegenned_files_on_lib_dir
 255     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 256   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 257     message(FATAL_ERROR "Apparently there is a previous in-source build,
 258 probably as the result of running `configure' and `make' on
 259 ${CMAKE_CURRENT_SOURCE_DIR}.
 260 This may cause problems. The suspicious files are:
 261 ${tablegenned_files_on_lib_dir}
 262 ${tablegenned_files_on_include_dir}
 263 Please clean the source directory.")
 264   endif()
 265 endif()
 266
 267 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 268
 269 if (CMAKE_BUILD_TYPE AND
 270     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 271   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 272 endif()
 273
 274 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 275
 276 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 277 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 278
 279 set(LLVM_UTILS_INSTALL_DIR "bin" CACHE STRING
 280     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 281 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 282
 283 # They are used as destination of target generators.
 284 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 285 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 286 if(WIN32 OR CYGWIN)
 287   # DLL platform -- put DLLs into bin.
 288   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 289 else()
 290   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 291 endif()
 292
 293 # Each of them corresponds to llvm-config's.
 294 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 295 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 296 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 297 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 298 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 299
 300 # Note: LLVM_CMAKE_PATH does not include generated files
 301 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 302 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 303 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 304
 305 # List of all targets to be built by default:
 306 set(LLVM_ALL_TARGETS
 307   AArch64
 308   AMDGPU
 309   ARM
 310   BPF
 311   Hexagon
 312   Lanai
 313   Mips
 314   MSP430
 315   NVPTX
 316   PowerPC
 317   Sparc
 318   SystemZ
 319   X86
 320   XCore
 321   )
 322
 323 # List of targets with JIT support:
 324 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 325
 326 set(LLVM_TARGETS_TO_BUILD "all"
 327     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 328
 329 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 330   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 331
 332 option(BUILD_SHARED_LIBS
 333   "Build all libraries as shared libraries instead of static" OFF)
 334
 335 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 336 if(LLVM_ENABLE_BACKTRACES)
 337   set(ENABLE_BACKTRACES 1)
 338 endif()
 339
 340 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 341 if(LLVM_ENABLE_CRASH_OVERRIDES)
 342   set(ENABLE_CRASH_OVERRIDES 1)
 343 endif()
 344
 345 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 346 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 347 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 348
 349 set(LLVM_TARGET_ARCH "host"
 350   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 351
 352 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 353
 354 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 355
 356 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 357
 358 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 359
 360 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 361
 362 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 363   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 364 endif()
 365
 366 set(LLVM_TARGETS_TO_BUILD
 367    ${LLVM_TARGETS_TO_BUILD}
 368    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 369 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 370
 371 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 372 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 373 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 374 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 375   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 376   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 377 else()
 378   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 379   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 380 endif()
 381 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 382 option(LLVM_ENABLE_CXX1Z "Compile with C++1z enabled." OFF)
 383 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 384 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 385 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 386 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 387
 388 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 389
 390 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 391   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 392 else()
 393   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 394 endif()
 395
 396 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 397
 398 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 399   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 400
 401 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 402        "Set to ON to force using an old, unsupported host toolchain." OFF)
 403
 404 option(LLVM_USE_INTEL_JITEVENTS
 405   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 406   OFF)
 407
 408 if( LLVM_USE_INTEL_JITEVENTS )
 409   # Verify we are on a supported platform
 410   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 411     message(FATAL_ERROR
 412       "Intel JIT API support is available on Linux and Windows only.")
 413   endif()
 414 endif( LLVM_USE_INTEL_JITEVENTS )
 415
 416 option(LLVM_USE_OPROFILE
 417   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 418
 419 option(LLVM_EXTERNALIZE_DEBUGINFO
 420   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 421
 422 # If enabled, verify we are on a platform that supports oprofile.
 423 if( LLVM_USE_OPROFILE )
 424   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 425     message(FATAL_ERROR "OProfile support is available on Linux only.")
 426   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 427 endif( LLVM_USE_OPROFILE )
 428
 429 set(LLVM_USE_SANITIZER "" CACHE STRING
 430   "Define the sanitizer used to build binaries and tests.")
 431 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 432   "Path to fuzzing library for linking with fuzz targets")
 433
 434 option(LLVM_USE_SPLIT_DWARF
 435   "Use -gsplit-dwarf when compiling llvm." OFF)
 436
 437 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 438 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 439
 440 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 441   set(POLLY_IN_TREE TRUE)
 442 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 443   set(POLLY_IN_TREE TRUE)
 444 else()
 445   set(POLLY_IN_TREE FALSE)
 446 endif()
 447
 448 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 449   set(WITH_POLLY ON)
 450 else()
 451   set(WITH_POLLY OFF)
 452 endif()
 453
 454 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 455   set(LINK_POLLY_INTO_TOOLS ON)
 456 else()
 457   set(LINK_POLLY_INTO_TOOLS OFF)
 458 endif()
 459
 460 # Define an option controlling whether we should build for 32-bit on 64-bit
 461 # platforms, where supported.
 462 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 463   # TODO: support other platforms and toolchains.
 464   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 465 endif()
 466
 467 # Define the default arguments to use with 'lit', and an option for the user to
 468 # override.
 469 set(LIT_ARGS_DEFAULT "-sv")
 470 if (MSVC_IDE OR XCODE)
 471   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 472 endif()
 473 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 474
 475 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 476 if( WIN32 AND NOT CYGWIN )
 477   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 478 endif()
 479
 480 # Define options to control the inclusion and default build behavior for
 481 # components which may not strictly be necessary (tools, examples, and tests).
 482 #
 483 # This is primarily to support building smaller or faster project files.
 484 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 485 option(LLVM_BUILD_TOOLS
 486   "Build the LLVM tools. If OFF, just generate build targets." ON)
 487
 488 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 489 option(LLVM_BUILD_UTILS
 490   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 491
 492 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 493 option(LLVM_BUILD_RUNTIMES
 494   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 495
 496 option(LLVM_BUILD_RUNTIME
 497   "Build the LLVM runtime libraries." ON)
 498 option(LLVM_BUILD_EXAMPLES
 499   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 500 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 501
 502 option(LLVM_BUILD_TESTS
 503   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 504 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 505 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 506
 507 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 508 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 509 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 510 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 511 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 512
 513 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 514     CACHE STRING "Doxygen-generated HTML documentation install directory")
 515 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 516     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 517
 518 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 519   "Build compiler-rt as an external project." OFF)
 520
 521 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 522   "Show target and host info when tools are invoked with --version." ON)
 523
 524 # You can configure which libraries from LLVM you want to include in the
 525 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 526 # list of LLVM components. All component names handled by llvm-config are valid.
 527 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 528   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 529     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 530 endif()
 531 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 532 option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin Only)" OFF)
 533 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 534 if(LLVM_LINK_LLVM_DYLIB OR LLVM_BUILD_LLVM_C_DYLIB)
 535   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 536 endif()
 537 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 538
 539 option(LLVM_DYLIB_SYMBOL_VERSIONING OFF)
 540
 541 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 542 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 543   set(LLVM_USE_HOST_TOOLS ON)
 544 endif()
 545
 546 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 547   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 548 else()
 549   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 550 endif()
 551
 552 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 553     LLVM_ENABLE_IR_PGO)
 554   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 555     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 556     # for spining disks. Anything higher may only help on slower mediums.
 557     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 558   endif()
 559   if(NOT LLVM_PROFILE_FILE_PATTERN)
 560     if(NOT LLVM_PROFILE_DATA_DIR)
 561       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 562     endif()
 563                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 564   endif()
 565 endif()
 566
 567 if (LLVM_BUILD_STATIC)
 568   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 569 endif()
 570
 571 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 572 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 573 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 574
 575 # All options referred to from HandleLLVMOptions have to be specified
 576 # BEFORE this include, otherwise options will not be correctly set on
 577 # first cmake run
 578 include(config-ix)
 579
 580 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 581   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 582 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 583
 584 # By default, we target the host, but this can be overridden at CMake
 585 # invocation time.
 586 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 587   "Default target for which LLVM will generate code." )
 588 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 589 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 590 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 591
 592 include(HandleLLVMOptions)
 593
 594 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 595 # FIXME: We should support systems with only Python 3, but that requires work
 596 # on LLDB.
 597 set(Python_ADDITIONAL_VERSIONS 2.7)
 598 include(FindPythonInterp)
 599 if( NOT PYTHONINTERP_FOUND )
 600   message(FATAL_ERROR
 601 "Unable to find Python interpreter, required for builds and testing.
 602
 603 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 604 endif()
 605
 606 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 607   message(FATAL_ERROR "Python 2.7 or newer is required")
 608 endif()
 609
 610 ######
 611 # LLVMBuild Integration
 612 #
 613 # We use llvm-build to generate all the data required by the CMake based
 614 # build system in one swoop:
 615 #
 616 #  - We generate a file (a CMake fragment) in the object root which contains
 617 #    all the definitions that are required by CMake.
 618 #
 619 #  - We generate the library table used by llvm-config.
 620 #
 621 #  - We generate the dependencies for the CMake fragment, so that we will
 622 #    automatically reconfigure outselves.
 623
 624 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 625 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 626   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 627 set(LLVMBUILDCMAKEFRAG
 628   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 629
 630 # Create the list of optional components that are enabled
 631 if (LLVM_USE_INTEL_JITEVENTS)
 632   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 633 endif (LLVM_USE_INTEL_JITEVENTS)
 634 if (LLVM_USE_OPROFILE)
 635   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 636 endif (LLVM_USE_OPROFILE)
 637
 638 message(STATUS "Constructing LLVMBuild project information")
 639 execute_process(
 640   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 641             --native-target "${LLVM_NATIVE_ARCH}"
 642             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 643             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 644             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 645             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 646             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 647             ERROR_VARIABLE LLVMBUILDERRORS
 648             OUTPUT_STRIP_TRAILING_WHITESPACE
 649             ERROR_STRIP_TRAILING_WHITESPACE
 650   RESULT_VARIABLE LLVMBUILDRESULT)
 651
 652 # On Win32, CMake doesn't properly handle piping the default output/error
 653 # streams into the GUI console. So, we explicitly catch and report them.
 654 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 655   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 656 endif()
 657 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 658   message(FATAL_ERROR
 659     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 660 endif()
 661
 662 # Include the generated CMake fragment. This will define properties from the
 663 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 664 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 665 # files change.
 666 include(${LLVMBUILDCMAKEFRAG})
 667
 668 ######
 669
 670 # Configure all of the various header file fragments LLVM uses which depend on
 671 # configuration variables.
 672 set(LLVM_ENUM_TARGETS "")
 673 set(LLVM_ENUM_ASM_PRINTERS "")
 674 set(LLVM_ENUM_ASM_PARSERS "")
 675 set(LLVM_ENUM_DISASSEMBLERS "")
 676 foreach(t ${LLVM_TARGETS_TO_BUILD})
 677   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 678
 679   list(FIND LLVM_ALL_TARGETS ${t} idx)
 680   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 681   if( idx LESS 0 AND idy LESS 0 )
 682     message(FATAL_ERROR "The target `${t}' does not exist.
 683     It should be one of\n${LLVM_ALL_TARGETS}")
 684   else()
 685     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 686   endif()
 687
 688   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 689   if( asmp_file )
 690     set(LLVM_ENUM_ASM_PRINTERS
 691       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 692   endif()
 693   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 694     set(LLVM_ENUM_ASM_PARSERS
 695       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 696   endif()
 697   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 698     set(LLVM_ENUM_DISASSEMBLERS
 699       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 700   endif()
 701 endforeach(t)
 702
 703 # Produce the target definition files, which provide a way for clients to easily
 704 # include various classes of targets.
 705 configure_file(
 706   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 707   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 708   )
 709 configure_file(
 710   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 711   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 712   )
 713 configure_file(
 714   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 715   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 716   )
 717 configure_file(
 718   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 719   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 720   )
 721
 722 # Configure the three LLVM configuration header files.
 723 configure_file(
 724   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 725   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 726 configure_file(
 727   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 728   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 729 configure_file(
 730   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 731   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 732 configure_file(
 733   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 734   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 735
 736 # Add target for generating source rpm package.
 737 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 738     CACHE FILEPATH ".spec file to use for srpm generation")
 739 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 740 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 741
 742 # SVN_REVISION and GIT_COMMIT get set by the call to add_version_info_from_vcs.
 743 # DUMMY_VAR contains a version string which we don't care about.
 744 add_version_info_from_vcs(DUMMY_VAR)
 745 if ( SVN_REVISION )
 746   set(LLVM_RPM_SPEC_REVISION "r${SVN_REVISION}")
 747 elseif ( GIT_COMMIT )
 748   set (LLVM_RPM_SPEC_REVISION "g${GIT_COMMIT}")
 749 endif()
 750
 751 configure_file(
 752   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 753   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 754
 755 add_custom_target(srpm
 756   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 757   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 758 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 759
 760
 761 # They are not referenced. See set_output_directory().
 762 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 763 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 764 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 765
 766 if(APPLE AND DARWIN_LTO_LIBRARY)
 767   set(CMAKE_EXE_LINKER_FLAGS
 768     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 769   set(CMAKE_SHARED_LINKER_FLAGS
 770     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 771   set(CMAKE_MODULE_LINKER_FLAGS
 772     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 773 endif()
 774
 775 # Work around a broken bfd ld behavior. When linking a binary with a
 776 # foo.so library, it will try to find any library that foo.so uses and
 777 # check its symbols. This is wasteful (the check was done when foo.so
 778 # was created) and can fail since it is not the dynamic linker and
 779 # doesn't know how to handle search paths correctly.
 780 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 781   set(CMAKE_EXE_LINKER_FLAGS
 782       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 783 endif()
 784
 785 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 786
 787 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 788
 789 # when crosscompiling import the executable targets from a file
 790 if(LLVM_USE_HOST_TOOLS)
 791   include(CrossCompile)
 792 endif(LLVM_USE_HOST_TOOLS)
 793 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 794 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 795 # (this is a variable that CrossCompile sets on recursive invocations)
 796 endif()
 797
 798 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 799   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 800   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 801   include_directories(SYSTEM "/usr/local/include")
 802   link_directories("/usr/local/lib")
 803 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 804
 805 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 806    # special hack for Solaris to handle crazy system sys/regset.h
 807    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 808 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 809
 810 # Make sure we don't get -rdynamic in every binary. For those that need it,
 811 # use export_executable_symbols(target).
 812 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 813
 814 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 815   "Profiling data file to use when compiling in order to improve runtime performance.")
 816
 817 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 818   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 819     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 820   else()
 821     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 822   endif()
 823 endif()
 824
 825 include(AddLLVM)
 826 include(TableGen)
 827
 828 if( MINGW )
 829   # People report that -O3 is unreliable on MinGW. The traditional
 830   # build also uses -O2 for that reason:
 831   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 832 endif()
 833
 834 # Put this before tblgen. Else we have a circular dependence.
 835 add_subdirectory(lib/Demangle)
 836 add_subdirectory(lib/Support)
 837 add_subdirectory(lib/TableGen)
 838
 839 add_subdirectory(utils/TableGen)
 840
 841 add_subdirectory(include/llvm)
 842
 843 add_subdirectory(lib)
 844
 845 if( LLVM_INCLUDE_UTILS )
 846   add_subdirectory(utils/FileCheck)
 847   add_subdirectory(utils/PerfectShuffle)
 848   add_subdirectory(utils/count)
 849   add_subdirectory(utils/not)
 850   add_subdirectory(utils/yaml-bench)
 851 else()
 852   if ( LLVM_INCLUDE_TESTS )
 853     message(FATAL_ERROR "Including tests when not building utils will not work.
 854     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 855   endif()
 856 endif()
 857
 858 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 859 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 860   add_subdirectory(utils/LLVMVisualizers)
 861 endif()
 862
 863 foreach( binding ${LLVM_BINDINGS_LIST} )
 864   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 865     add_subdirectory(bindings/${binding})
 866   endif()
 867 endforeach()
 868
 869 add_subdirectory(projects)
 870
 871 if( LLVM_INCLUDE_TOOLS )
 872   add_subdirectory(tools)
 873 endif()
 874
 875 if( LLVM_INCLUDE_RUNTIMES )
 876   add_subdirectory(runtimes)
 877 endif()
 878
 879 if( LLVM_INCLUDE_EXAMPLES )
 880   add_subdirectory(examples)
 881 endif()
 882
 883 if( LLVM_INCLUDE_TESTS )
 884   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 885     include(LLVMExternalProjectUtils)
 886     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 887       USE_TOOLCHAIN
 888       EXCLUDE_FROM_ALL
 889       NO_INSTALL
 890       ALWAYS_CLEAN)
 891   endif()
 892   add_subdirectory(utils/lit)
 893   add_subdirectory(test)
 894   add_subdirectory(unittests)
 895   if( LLVM_INCLUDE_UTILS )
 896     add_subdirectory(utils/unittest)
 897   endif()
 898
 899   if (WIN32)
 900     # This utility is used to prevent crashing tests from calling Dr. Watson on
 901     # Windows.
 902     add_subdirectory(utils/KillTheDoctor)
 903   endif()
 904
 905   # Add a global check rule now that all subdirectories have been traversed
 906   # and we know the total set of lit testsuites.
 907   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 908   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 909   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 910   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 911   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 912                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 913   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 914                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 915   add_lit_target(check-all
 916     "Running all regression tests"
 917     ${LLVM_LIT_TESTSUITES}
 918     PARAMS ${LLVM_LIT_PARAMS}
 919     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 920     ARGS ${LLVM_LIT_EXTRA_ARGS}
 921     )
 922   if(TARGET check-runtimes)
 923     add_dependencies(check-all check-runtimes)
 924   endif()
 925   add_custom_target(test-depends
 926                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 927   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 928 endif()
 929
 930 if (LLVM_INCLUDE_DOCS)
 931   add_subdirectory(docs)
 932 endif()
 933
 934 add_subdirectory(cmake/modules)
 935
 936 # Do this last so that all lit targets have already been created.
 937 if (LLVM_INCLUDE_UTILS)
 938   add_subdirectory(utils/llvm-lit)
 939 endif()
 940
 941 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 942   install(DIRECTORY include/llvm include/llvm-c
 943     DESTINATION include
 944     COMPONENT llvm-headers
 945     FILES_MATCHING
 946     PATTERN "*.def"
 947     PATTERN "*.h"
 948     PATTERN "*.td"
 949     PATTERN "*.inc"
 950     PATTERN "LICENSE.TXT"
 951     PATTERN ".svn" EXCLUDE
 952     )
 953
 954   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 955     DESTINATION include
 956     COMPONENT llvm-headers
 957     FILES_MATCHING
 958     PATTERN "*.def"
 959     PATTERN "*.h"
 960     PATTERN "*.gen"
 961     PATTERN "*.inc"
 962     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 963     PATTERN "CMakeFiles" EXCLUDE
 964     PATTERN "config.h" EXCLUDE
 965     PATTERN ".svn" EXCLUDE
 966     )
 967
 968   # Installing the headers needs to depend on generating any public
 969   # tablegen'd headers.
 970   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
 971   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
 972
 973   if (NOT CMAKE_CONFIGURATION_TYPES)
 974     add_llvm_install_targets(install-llvm-headers
 975                              COMPONENT llvm-headers)
 976   endif()
 977 endif()
 978
 979 # This must be at the end of the LLVM root CMakeLists file because it must run
 980 # after all targets are created.
 981 if(LLVM_DISTRIBUTION_COMPONENTS)
 982   if(CMAKE_CONFIGURATION_TYPES)
 983     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
 984   endif()
 985
 986   add_custom_target(distribution)
 987   add_custom_target(install-distribution)
 988   add_custom_target(install-distribution-stripped)
 989   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS})
 990     if(TARGET ${target})
 991       add_dependencies(distribution ${target})
 992     else()
 993       message(SEND_ERROR "Specified distribution component '${target}' doesn't have a target")
 994     endif()
 995
 996     if(TARGET install-${target})
 997       add_dependencies(install-distribution install-${target})
 998     else()
 999       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install target")
1000     endif()
1001
1002     if(TARGET install-${target}-stripped)
1003       add_dependencies(install-distribution-stripped install-${target}-stripped)
1004     else()
1005       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install-stripped target."
1006                          " Its installation target creation should be changed to use add_llvm_install_targets,"
1007                          " or you should manually create the 'install-${target}-stripped' target.")
1008     endif()
1009   endforeach()
1010 endif()
1011
1012 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1013 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows")
1014   include(InstallRequiredSystemLibraries)
1015 endif()
1016