test/CodeGen/ARM/ParallelDSP/smlald0.ll

   1 ; RUN: opt -mtriple=arm-arm-eabi -mcpu=cortex-m33 < %s -arm-parallel-dsp -S | FileCheck %s
   2 ; RUN: opt -mtriple=armeb-arm-eabi -mcpu=cortex-m33 < %s -arm-parallel-dsp -S | FileCheck %s --check-prefix=CHECK-UNSUPPORTED
   3 ;
   4 ; The Cortex-M0 does not support unaligned accesses:
   5 ; RUN: opt -mtriple=arm-arm-eabi -mcpu=cortex-m0 < %s -arm-parallel-dsp -S | FileCheck %s --check-prefix=CHECK-UNSUPPORTED
   6 ;
   7 ; Check DSP extension:
   8 ; RUN: opt -mtriple=arm-arm-eabi -mcpu=cortex-m33 -mattr=-dsp < %s -arm-parallel-dsp -S | FileCheck %s --check-prefix=CHECK-UNSUPPORTED
   9
  10 define dso_local i64 @OneReduction(i32 %arg, i32* nocapture readnone %arg1, i16* nocapture readonly %arg2, i16* nocapture readonly %arg3) {
  11 ;
  12 ; CHECK-LABEL: @OneReduction
  13 ; CHECK:  %mac1{{\.}}026 = phi i64 [ [[V8:%[0-9]+]], %for.body ], [ 0, %for.body.preheader ]
  14 ; CHECK:  [[V6:%[0-9]+]] = bitcast i16* %arrayidx to i32*
  15 ; CHECK:  [[V7:%[0-9]+]] = load i32, i32* [[V6]], align 2
  16 ; CHECK:  [[V4:%[0-9]+]] = bitcast i16* %arrayidx3 to i32*
  17 ; CHECK:  [[V5:%[0-9]+]] = load i32, i32* [[V4]], align 2
  18 ; CHECK:  [[V8]] = call i64 @llvm.arm.smlald(i32 [[V5]], i32 [[V7]], i64 %mac1{{\.}}026)
  19 ; CHECK-NOT: call i64 @llvm.arm.smlald
  20 ;
  21 ; CHECK-UNSUPPORTED-NOT:  call i64 @llvm.arm.smlald
  22 ;
  23 entry:
  24   %cmp24 = icmp sgt i32 %arg, 0
  25   br i1 %cmp24, label %for.body.preheader, label %for.cond.cleanup
  26
  27 for.body.preheader:
  28   %.pre = load i16, i16* %arg3, align 2
  29   %.pre27 = load i16, i16* %arg2, align 2
  30   br label %for.body
  31
  32 for.cond.cleanup:
  33   %mac1.0.lcssa = phi i64 [ 0, %entry ], [ %add11, %for.body ]
  34   ret i64 %mac1.0.lcssa
  35
  36 for.body:
  37 ; One reduction statement here:
  38   %mac1.026 = phi i64 [ %add11, %for.body ], [ 0, %for.body.preheader ]
  39
  40   %i.025 = phi i32 [ %add, %for.body ], [ 0, %for.body.preheader ]
  41   %arrayidx = getelementptr inbounds i16, i16* %arg3, i32 %i.025
  42   %0 = load i16, i16* %arrayidx, align 2
  43   %add = add nuw nsw i32 %i.025, 1
  44   %arrayidx1 = getelementptr inbounds i16, i16* %arg3, i32 %add
  45   %1 = load i16, i16* %arrayidx1, align 2
  46   %arrayidx3 = getelementptr inbounds i16, i16* %arg2, i32 %i.025
  47   %2 = load i16, i16* %arrayidx3, align 2
  48   %conv = sext i16 %2 to i64
  49   %conv4 = sext i16 %0 to i64
  50   %mul = mul nsw i64 %conv, %conv4
  51   %arrayidx6 = getelementptr inbounds i16, i16* %arg2, i32 %add
  52   %3 = load i16, i16* %arrayidx6, align 2
  53   %conv7 = sext i16 %3 to i64
  54   %conv8 = sext i16 %1 to i64
  55   %mul9 = mul nsw i64 %conv7, %conv8
  56   %add10 = add i64 %mul, %mac1.026
  57
  58 ; Here the Mul is the LHS, and the Add the RHS.
  59   %add11 = add i64 %mul9, %add10
  60
  61   %exitcond = icmp ne i32 %add, %arg
  62   br i1 %exitcond, label %for.body, label %for.cond.cleanup
  63 }
  64
  65 define dso_local arm_aapcs_vfpcc i64 @TwoReductions(i32 %arg, i32* nocapture readnone %arg1, i16* nocapture readonly %arg2, i16* nocapture readonly %arg3) {
  66 ;
  67 ; CHECK-LABEL: @TwoReductions
  68 ;
  69 ; CHECK:  %mac1{{\.}}058 = phi i64 [ [[V10:%[0-9]+]], %for.body ], [ 0, %for.body.preheader ]
  70 ; CHECK:  %mac2{{\.}}057 = phi i64 [ [[V17:%[0-9]+]], %for.body ], [ 0, %for.body.preheader ]
  71 ; CHECK:  [[V10]] = call i64 @llvm.arm.smlald(i32 %{{.*}}, i32 %{{.*}}, i64 %mac1{{\.}}058)
  72 ; CHECK:  [[V17]] = call i64 @llvm.arm.smlald(i32 %{{.*}}, i32 %{{.*}}, i64 %mac2{{\.}}057)
  73 ; CHECK-NOT: call i64 @llvm.arm.smlald
  74 ;
  75 entry:
  76   %cmp55 = icmp sgt i32 %arg, 0
  77   br i1 %cmp55, label %for.body.preheader, label %for.cond.cleanup
  78
  79 for.cond.cleanup:
  80   %mac2.0.lcssa = phi i64 [ 0, %entry ], [ %add28, %for.body ]
  81   %mac1.0.lcssa = phi i64 [ 0, %entry ], [ %add16, %for.body ]
  82   %add30 = add nsw i64 %mac1.0.lcssa, %mac2.0.lcssa
  83   ret i64 %add30
  84
  85 for.body.preheader:
  86   br label %for.body
  87
  88 for.body:
  89 ; And two reduction statements here:
  90   %mac1.058 = phi i64 [ %add16, %for.body ], [ 0, %for.body.preheader ]
  91   %mac2.057 = phi i64 [ %add28, %for.body ], [ 0, %for.body.preheader ]
  92
  93   %i.056 = phi i32 [ %add29, %for.body ], [ 0, %for.body.preheader ]
  94   %arrayidx = getelementptr inbounds i16, i16* %arg3, i32 %i.056
  95   %0 = load i16, i16* %arrayidx, align 2
  96   %add1 = or i32 %i.056, 1
  97   %arrayidx2 = getelementptr inbounds i16, i16* %arg3, i32 %add1
  98   %1 = load i16, i16* %arrayidx2, align 2
  99   %add3 = or i32 %i.056, 2
 100   %arrayidx4 = getelementptr inbounds i16, i16* %arg3, i32 %add3
 101   %2 = load i16, i16* %arrayidx4, align 2
 102
 103   %add5 = or i32 %i.056, 3
 104   %arrayidx6 = getelementptr inbounds i16, i16* %arg3, i32 %add5
 105   %3 = load i16, i16* %arrayidx6, align 2
 106   %arrayidx8 = getelementptr inbounds i16, i16* %arg2, i32 %i.056
 107   %4 = load i16, i16* %arrayidx8, align 2
 108   %conv = sext i16 %4 to i64
 109   %conv9 = sext i16 %0 to i64
 110   %mul = mul nsw i64 %conv, %conv9
 111   %arrayidx11 = getelementptr inbounds i16, i16* %arg2, i32 %add1
 112   %5 = load i16, i16* %arrayidx11, align 2
 113   %conv12 = sext i16 %5 to i64
 114   %conv13 = sext i16 %1 to i64
 115   %mul14 = mul nsw i64 %conv12, %conv13
 116   %add15 = add i64 %mul, %mac1.058
 117   %add16 = add i64 %add15, %mul14
 118   %arrayidx18 = getelementptr inbounds i16, i16* %arg2, i32 %add3
 119   %6 = load i16, i16* %arrayidx18, align 2
 120   %conv19 = sext i16 %6 to i64
 121   %conv20 = sext i16 %2 to i64
 122   %mul21 = mul nsw i64 %conv19, %conv20
 123   %arrayidx23 = getelementptr inbounds i16, i16* %arg2, i32 %add5
 124   %7 = load i16, i16* %arrayidx23, align 2
 125   %conv24 = sext i16 %7 to i64
 126   %conv25 = sext i16 %3 to i64
 127   %mul26 = mul nsw i64 %conv24, %conv25
 128   %add27 = add i64 %mul21, %mac2.057
 129   %add28 = add i64 %add27, %mul26
 130   %add29 = add nuw nsw i32 %i.056, 4
 131   %cmp = icmp slt i32 %add29, %arg
 132   br i1 %cmp, label %for.body, label %for.cond.cleanup
 133 }
 134
 135 define i64 @reduction_zext(i32 %arg, i32* nocapture readnone %arg1, i16* nocapture readonly %arg2, i16* nocapture readonly %arg3) {
 136 ; CHECK-LABEL: @reduction_zext
 137 ; CHECK-NOT: call i64 @llvm.arm.smlald
 138 ; CHECK-NOT: call i32 @llvm.arm.smlad
 139 entry:
 140   %cmp24 = icmp sgt i32 %arg, 0
 141   br i1 %cmp24, label %for.body.preheader, label %for.cond.cleanup
 142
 143 for.body.preheader:
 144   %.pre = load i16, i16* %arg3, align 2
 145   %.pre27 = load i16, i16* %arg2, align 2
 146   br label %for.body
 147
 148 for.cond.cleanup:
 149   %mac1.0.lcssa = phi i64 [ 0, %entry ], [ %add11, %for.body ]
 150   ret i64 %mac1.0.lcssa
 151
 152 for.body:
 153   %mac1.026 = phi i64 [ %add11, %for.body ], [ 0, %for.body.preheader ]
 154   %i.025 = phi i32 [ %add, %for.body ], [ 0, %for.body.preheader ]
 155   %arrayidx = getelementptr inbounds i16, i16* %arg3, i32 %i.025
 156   %0 = load i16, i16* %arrayidx, align 2
 157   %add = add nuw nsw i32 %i.025, 1
 158   %arrayidx1 = getelementptr inbounds i16, i16* %arg3, i32 %add
 159   %1 = load i16, i16* %arrayidx1, align 2
 160   %arrayidx3 = getelementptr inbounds i16, i16* %arg2, i32 %i.025
 161   %2 = load i16, i16* %arrayidx3, align 2
 162   %conv = sext i16 %2 to i64
 163   %conv4 = zext i16 %0 to i64
 164   %mul = mul nsw i64 %conv, %conv4
 165   %arrayidx6 = getelementptr inbounds i16, i16* %arg2, i32 %add
 166   %3 = load i16, i16* %arrayidx6, align 2
 167   %conv7 = sext i16 %3 to i64
 168   %conv8 = zext i16 %1 to i64
 169   %mul9 = mul nsw i64 %conv7, %conv8
 170   %add10 = add i64 %mul, %mac1.026
 171   %add11 = add i64 %mul9, %add10
 172   %exitcond = icmp ne i32 %add, %arg
 173   br i1 %exitcond, label %for.body, label %for.cond.cleanup
 174 }