test/Analysis/CFLAliasAnalysis/Steensgaard/interproc-ret-ref-arg-multilevel.ll

   1 ; This testcase ensures that CFL AA answers queries soundly when callee tries
   2 ; to return the multi-level reference of one of its parameters
   3
   4 ; RUN: opt < %s -disable-basicaa -cfl-steens-aa -aa-eval -print-all-alias-modref-info -disable-output 2>&1 | FileCheck %s
   5 ; RUN: opt < %s -aa-pipeline=cfl-steens-aa -passes=aa-eval -print-all-alias-modref-info -disable-output 2>&1 | FileCheck %s
   6
   7 declare noalias i8* @malloc(i64)
   8
   9 define i32*** @return_ref_arg_multilevel_callee(i32* %arg1) {
  10         %ptr = call noalias i8* @malloc(i64 8)
  11         %ptr_cast = bitcast i8* %ptr to i32***
  12   %ptr2 = call noalias i8* @malloc(i64 8)
  13   %ptr_cast2 = bitcast i8* %ptr2 to i32**
  14         store i32* %arg1, i32** %ptr_cast2
  15   store i32** %ptr_cast2, i32*** %ptr_cast
  16         ret i32*** %ptr_cast
  17 }
  18 ; CHECK-LABEL: Function: test_return_ref_arg_multilevel
  19 ; CHECK: NoAlias: i32* %a, i32*** %b
  20 ; CHECK: NoAlias: i32** %p, i32*** %b
  21 ; CHECK: NoAlias: i32* %a, i32** %lb
  22 ; CHECK: NoAlias: i32** %lb, i32*** %pp
  23 ; CHECK: NoAlias: i32** %lb, i32*** %b
  24 ; CHECK: MayAlias: i32* %a, i32* %lb_deref
  25 ; CHECK: NoAlias: i32* %lb_deref, i32** %lpp
  26 ; CHECK: MayAlias: i32* %lb_deref, i32* %lpp_deref
  27 ; CHECK: NoAlias: i32* %lpp_deref, i32** %lpp
  28 ; CHECK: MayAlias: i32* %lb_deref, i32* %lp
  29 ; CHECK: NoAlias: i32* %lp, i32** %lpp
  30 ; CHECK: MayAlias: i32* %lp, i32* %lpp_deref
  31
  32 ; We could've proven the following facts if the analysis were inclusion-based:
  33 ; NoAlias: i32*** %b, i32*** %pp
  34 ; NoAlias: i32** %lb, i32** %p
  35 define void @test_return_ref_arg_multilevel() {
  36   %a = alloca i32, align 4
  37   %p = alloca i32*, align 8
  38   %pp = alloca i32**, align 8
  39
  40   store i32* %a, i32** %p
  41   store i32** %p, i32*** %pp
  42   %b = call i32*** @return_ref_arg_multilevel_callee(i32* %a)
  43
  44   %lb = load i32**, i32*** %b
  45   %lb_deref = load i32*, i32** %lb
  46   %lpp = load i32**, i32*** %pp
  47   %lpp_deref = load i32*, i32** %lpp
  48   %lp = load i32*, i32** %p
  49
  50   ret void
  51 }