tools/llvm-shlib/CMakeLists.txt

   1 # This tool creates a shared library from the LLVM libraries. Generating this
   2 # library is enabled by setting LLVM_BUILD_LLVM_DYLIB=yes on the CMake
   3 # commandline. By default the shared library only exports the LLVM C API.
   4
   5 set(SOURCES
   6   libllvm.cpp
   7   )
   8
   9 llvm_map_components_to_libnames(LIB_NAMES ${LLVM_DYLIB_COMPONENTS})
  10
  11 if(LLVM_LINK_LLVM_DYLIB AND LLVM_DYLIB_EXPORTED_SYMBOL_FILE)
  12   message(WARNING "Using LLVM_LINK_LLVM_DYLIB with LLVM_DYLIB_EXPORTED_SYMBOL_FILE may not work. Use at your own risk.")
  13 endif()
  14
  15 # libLLVM.so should not have any dependencies on any other LLVM
  16 # shared libraries. When using the "all" pseudo-component,
  17 # LLVM_AVAILABLE_LIBS is added to the dependencies, which may
  18 # contain shared libraries (e.g. libLTO).
  19 #
  20 # Also exclude libLLVMTableGen for the following reasons:
  21 #  - it is only used by internal *-tblgen utilities;
  22 #  - it pollutes the global options space.
  23 foreach(lib ${LIB_NAMES})
  24   get_target_property(t ${lib} TYPE)
  25   if("${lib}" STREQUAL "LLVMTableGen")
  26   elseif("x${t}" STREQUAL "xSTATIC_LIBRARY")
  27     list(APPEND FILTERED_LIB_NAMES ${lib})
  28   endif()
  29 endforeach()
  30 set(LIB_NAMES ${FILTERED_LIB_NAMES})
  31
  32 if(LLVM_DYLIB_EXPORTED_SYMBOL_FILE)
  33   set(LLVM_EXPORTED_SYMBOL_FILE ${LLVM_DYLIB_EXPORTED_SYMBOL_FILE})
  34   add_custom_target(libLLVMExports DEPENDS ${LLVM_EXPORTED_SYMBOL_FILE})
  35 endif()
  36
  37 add_llvm_library(LLVM SHARED DISABLE_LLVM_LINK_LLVM_DYLIB SONAME ${SOURCES})
  38
  39 list(REMOVE_DUPLICATES LIB_NAMES)
  40 if(("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux") OR (MINGW) OR (HAIKU)
  41    OR ("${CMAKE_SYSTEM_NAME}" STREQUAL "FreeBSD")
  42    OR ("${CMAKE_SYSTEM_NAME}" STREQUAL "DragonFly")
  43    OR ("${CMAKE_SYSTEM_NAME}" STREQUAL "SunOS")) # FIXME: It should be "GNU ld for elf"
  44   configure_file(
  45   ${CMAKE_CURRENT_SOURCE_DIR}/simple_version_script.map.in
  46   ${LLVM_LIBRARY_DIR}/tools/llvm-shlib/simple_version_script.map)
  47
  48   # GNU ld doesn't resolve symbols in the version script.
  49   set(LIB_NAMES -Wl,--whole-archive ${LIB_NAMES} -Wl,--no-whole-archive)
  50   if (NOT LLVM_LINKER_IS_SOLARISLD)
  51     # Solaris ld does not accept global: *; so there is no way to version *all* global symbols
  52     set(LIB_NAMES -Wl,--version-script,${LLVM_LIBRARY_DIR}/tools/llvm-shlib/simple_version_script.map ${LIB_NAMES})
  53   endif()
  54 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
  55   set(LIB_NAMES -Wl,-all_load ${LIB_NAMES})
  56 endif()
  57
  58 target_link_libraries(LLVM PRIVATE ${LIB_NAMES})
  59
  60 if (LLVM_DYLIB_SYMBOL_VERSIONING)
  61   set_property(TARGET LLVM APPEND_STRING PROPERTY LINK_FLAGS " -Wl,--default-symver")
  62 endif()
  63
  64 if (APPLE)
  65   set_property(TARGET LLVM APPEND_STRING PROPERTY
  66               LINK_FLAGS
  67               " -compatibility_version 1 -current_version ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}")
  68 endif()
  69
  70 if(TARGET libLLVMExports)
  71   add_dependencies(LLVM libLLVMExports)
  72 endif()
  73
  74 if(LLVM_BUILD_LLVM_C_DYLIB)
  75   # To get the export list for a single llvm library:
  76   # nm ${LIB_PATH} | awk "/T _LLVM/ { print $3 }" | sort -u | sed -e "s/^_//g" > ${LIB_PATH}.exports
  77
  78   if(NOT APPLE)
  79     message(FATAL_ERROR "Generating libLLVM-c is only supported on Darwin")
  80   endif()
  81
  82   set(LLVM_EXPORTED_SYMBOL_FILE ${CMAKE_BINARY_DIR}/libllvm-c.exports)
  83
  84   set(LIB_DIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
  85   set(LIB_NAME ${LIB_DIR}/${CMAKE_SHARED_LIBRARY_PREFIX}LLVM)
  86   set(LIB_PATH ${LIB_NAME}${CMAKE_SHARED_LIBRARY_SUFFIX})
  87   set(LIB_EXPORTS_PATH ${LIB_NAME}.exports)
  88   list(APPEND LLVM_DYLIB_REQUIRED_EXPORTS ${LIB_EXPORTS_PATH})
  89
  90   add_custom_command(OUTPUT ${LLVM_EXPORTED_SYMBOL_FILE}
  91     COMMAND nm ${LIB_PATH} | awk "/T _LLVM/ || /T LLVM/ { print $3 }" | sort -u | sed -e "s/^_//g" > ${LLVM_EXPORTED_SYMBOL_FILE}
  92     WORKING_DIRECTORY ${LIB_DIR}
  93     DEPENDS LLVM
  94     COMMENT "Generating Export list for LLVM..."
  95     VERBATIM )
  96
  97   add_custom_target(libLLVMCExports DEPENDS ${LLVM_EXPORTED_SYMBOL_FILE})
  98
  99   add_llvm_library(LLVM-C SHARED ${SOURCES})
 100
 101   target_link_libraries(LLVM-C PUBLIC LLVM)
 102   add_dependencies(LLVM-C libLLVMCExports)
 103
 104   set_property(TARGET LLVM-C APPEND_STRING PROPERTY
 105               LINK_FLAGS
 106               " -compatibility_version 1 -current_version ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH} -Wl,-reexport_library ${LIB_PATH}")
 107 endif()
 108