CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0068)
   6   cmake_policy(SET CMP0068 NEW)
   7   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
   8 endif()
   9
  10 if(POLICY CMP0075)
  11   cmake_policy(SET CMP0075 NEW)
  12 endif()
  13
  14 if(POLICY CMP0077)
  15   cmake_policy(SET CMP0077 NEW)
  16 endif()
  17
  18 if(NOT DEFINED LLVM_VERSION_MAJOR)
  19   set(LLVM_VERSION_MAJOR 9)
  20 endif()
  21 if(NOT DEFINED LLVM_VERSION_MINOR)
  22   set(LLVM_VERSION_MINOR 0)
  23 endif()
  24 if(NOT DEFINED LLVM_VERSION_PATCH)
  25   set(LLVM_VERSION_PATCH 0)
  26 endif()
  27 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  28   set(LLVM_VERSION_SUFFIX svn)
  29 endif()
  30
  31 if (NOT PACKAGE_VERSION)
  32   set(PACKAGE_VERSION
  33     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  34 endif()
  35
  36 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  37   message(WARNING "Visual Studio generators use the x86 host compiler by "
  38                   "default, even for 64-bit targets. This can result in linker "
  39                   "instability and out of memory errors. To use the 64-bit "
  40                   "host compiler, pass -Thost=x64 on the CMake command line.")
  41 endif()
  42
  43 if (CMAKE_GENERATOR STREQUAL "Xcode" AND NOT CMAKE_OSX_ARCHITECTURES)
  44   # Some CMake features like object libraries get confused if you don't
  45   # explicitly specify an architecture setting with the Xcode generator.
  46   set(CMAKE_OSX_ARCHITECTURES "x86_64")
  47 endif()
  48
  49 project(LLVM
  50   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  51   LANGUAGES C CXX ASM)
  52
  53 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  54   message(STATUS "No build type selected, default to Debug")
  55   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  56 endif()
  57
  58 # Side-by-side subprojects layout: automatically set the
  59 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
  60 # This allows an easy way of setting up a build directory for llvm and another
  61 # one for llvm+clang+... using the same sources.
  62 set(LLVM_ALL_PROJECTS "clang;clang-tools-extra;compiler-rt;debuginfo-tests;libclc;libcxx;libcxxabi;libunwind;lld;lldb;llgo;openmp;parallel-libs;polly;pstl")
  63 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
  64         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
  65 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
  66   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
  67 endif()
  68
  69 # LLVM_ENABLE_PROJECTS_USED is `ON` if the user has ever used the
  70 # `LLVM_ENABLE_PROJECTS` CMake cache variable.  This exists for
  71 # several reasons:
  72 #
  73 # * As an indicator that the `LLVM_ENABLE_PROJECTS` list is now the single
  74 # source of truth for which projects to build. This means we will ignore user
  75 # supplied `LLVM_TOOL_<project>_BUILD` CMake cache variables and overwrite
  76 # them.
  77 #
  78 # * The case where the user previously had `LLVM_ENABLE_PROJECTS` set to a
  79 # non-empty list but now the user wishes to disable building all other projects
  80 # by setting `LLVM_ENABLE_PROJECTS` to an empty string. In that case we still
  81 # need to set the `LLVM_TOOL_${upper_proj}_BUILD` variables so that we disable
  82 # building all the projects that were previously enabled.
  83 set(LLVM_ENABLE_PROJECTS_USED OFF CACHE BOOL "")
  84 mark_as_advanced(LLVM_ENABLE_PROJECTS_USED)
  85
  86 if (LLVM_ENABLE_PROJECTS_USED OR NOT LLVM_ENABLE_PROJECTS STREQUAL "")
  87   set(LLVM_ENABLE_PROJECTS_USED ON CACHE BOOL "" FORCE)
  88   foreach(proj ${LLVM_ALL_PROJECTS} ${LLVM_EXTERNAL_PROJECTS})
  89     string(TOUPPER "${proj}" upper_proj)
  90     string(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
  91     if ("${proj}" IN_LIST LLVM_ENABLE_PROJECTS)
  92       message(STATUS "${proj} project is enabled")
  93       set(SHOULD_ENABLE_PROJECT TRUE)
  94       set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
  95       if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
  96         message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
  97       endif()
  98       set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE STRING "")
  99     elseif ("${proj}" IN_LIST LLVM_EXTERNAL_PROJECTS)
 100       message(STATUS "${proj} project is enabled")
 101       set(SHOULD_ENABLE_PROJECT TRUE)
 102     else()
 103       message(STATUS "${proj} project is disabled")
 104       set(SHOULD_ENABLE_PROJECT FALSE)
 105     endif()
 106     # Force `LLVM_TOOL_${upper_proj}_BUILD` variables to have values that
 107     # corresponds with `LLVM_ENABLE_PROJECTS`. This prevents the user setting
 108     # `LLVM_TOOL_${upper_proj}_BUILD` variables externally. At some point
 109     # we should deprecate allowing users to set these variables by turning them
 110     # into normal CMake variables rather than cache variables.
 111     set(LLVM_TOOL_${upper_proj}_BUILD
 112       ${SHOULD_ENABLE_PROJECT}
 113       CACHE
 114       BOOL "Whether to build ${upper_proj} as part of LLVM" FORCE
 115     )
 116   endforeach()
 117 endif()
 118 unset(SHOULD_ENABLE_PROJECT)
 119
 120 # Build llvm with ccache if the package is present
 121 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 122 if(LLVM_CCACHE_BUILD)
 123   find_program(CCACHE_PROGRAM ccache)
 124   if(CCACHE_PROGRAM)
 125       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 126       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 127       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 128           CACHE STRING "Parameters to pass through to ccache")
 129
 130       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 131       if (LLVM_CCACHE_MAXSIZE)
 132         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 133       endif()
 134       if (LLVM_CCACHE_DIR)
 135         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 136       endif()
 137       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 138   else()
 139     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 140   endif()
 141 endif()
 142
 143 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 144
 145 # Some features of the LLVM build may be disallowed when dependency debugging is
 146 # enabled. In particular you cannot use ccache because we want to force compile
 147 # operations to always happen.
 148 if(LLVM_DEPENDENCY_DEBUGGING)
 149   if(NOT CMAKE_HOST_APPLE)
 150     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 151   endif()
 152   if(LLVM_CCACHE_BUILD)
 153     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 154   endif()
 155 endif()
 156
 157 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 158 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 159 if(LLVM_ENABLE_GISEL_COV)
 160   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 161 endif()
 162
 163 # Add path for custom modules
 164 set(CMAKE_MODULE_PATH
 165   ${CMAKE_MODULE_PATH}
 166   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 167   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 168   )
 169
 170 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 171 # for use by clang_complete, YouCompleteMe, etc.
 172 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 173
 174 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 175   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 176
 177 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 178
 179 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 180
 181 # Unfortunatly Clang is too eager to search directories for module maps, which can cause the
 182 # installed version of the maps to be found when building LLVM from source. Therefore we turn off
 183 # the installation by default. See llvm.org/PR31905.
 184 option(LLVM_INSTALL_MODULEMAPS "Install the modulemap files in the 'install' target." OFF)
 185
 186 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 187 if ( LLVM_USE_FOLDERS )
 188   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 189 endif()
 190
 191 include(VersionFromVCS)
 192
 193 option(LLVM_APPEND_VC_REV
 194   "Embed the version control system revision in LLVM" ON)
 195
 196 set(PACKAGE_NAME LLVM)
 197 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 198 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
 199
 200 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 201   "Default URL where bug reports are to be submitted.")
 202
 203 # Configure CPack.
 204 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 205 set(CPACK_PACKAGE_VENDOR "LLVM")
 206 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 207 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 208 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 209 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 210 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 211 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 212 if(WIN32 AND NOT UNIX)
 213   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 214   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 215   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 216   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 217   set(CPACK_NSIS_MODIFY_PATH "ON")
 218   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 219   if( CMAKE_CL_64 )
 220     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 221   endif()
 222 endif()
 223 include(CPack)
 224
 225 # Sanity check our source directory to make sure that we are not trying to
 226 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 227 # sure that we don't have any stray generated files lying around in the tree
 228 # (which would end up getting picked up by header search, instead of the correct
 229 # versions).
 230 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 231   message(FATAL_ERROR "In-source builds are not allowed.
 232 Please create a directory and run cmake from there, passing the path
 233 to this source directory as the last argument.
 234 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 235 Please delete them.")
 236 endif()
 237
 238 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 239
 240 if (CMAKE_BUILD_TYPE AND
 241     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 242   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 243 endif()
 244
 245 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 246
 247 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 248 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 249
 250 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 251     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 252 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 253
 254 # They are used as destination of target generators.
 255 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 256 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 257 if(WIN32 OR CYGWIN)
 258   # DLL platform -- put DLLs into bin.
 259   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 260 else()
 261   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 262 endif()
 263
 264 # Each of them corresponds to llvm-config's.
 265 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 266 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 267 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 268 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 269 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 270
 271 # Note: LLVM_CMAKE_PATH does not include generated files
 272 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 273 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 274 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 275
 276 # List of all targets to be built by default:
 277 set(LLVM_ALL_TARGETS
 278   AArch64
 279   AMDGPU
 280   ARM
 281   BPF
 282   Hexagon
 283   Lanai
 284   Mips
 285   MSP430
 286   NVPTX
 287   PowerPC
 288   Sparc
 289   SystemZ
 290   WebAssembly
 291   X86
 292   XCore
 293   )
 294
 295 # List of targets with JIT support:
 296 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 297
 298 set(LLVM_TARGETS_TO_BUILD "all"
 299     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 300
 301 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 302   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 303
 304 option(BUILD_SHARED_LIBS
 305   "Build all libraries as shared libraries instead of static" OFF)
 306
 307 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 308 if(LLVM_ENABLE_BACKTRACES)
 309   set(ENABLE_BACKTRACES 1)
 310 endif()
 311
 312 option(LLVM_ENABLE_UNWIND_TABLES "Emit unwind tables for the libraries" ON)
 313
 314 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 315 if(LLVM_ENABLE_CRASH_OVERRIDES)
 316   set(ENABLE_CRASH_OVERRIDES 1)
 317 endif()
 318
 319 option(LLVM_ENABLE_CRASH_DUMPS "Turn on memory dumps on crashes. Currently only implemented on Windows." OFF)
 320
 321 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 322 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 323 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 324
 325 set(LLVM_TARGET_ARCH "host"
 326   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 327
 328 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 329
 330 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 331
 332 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 333
 334 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 335
 336 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 337
 338 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 339
 340 set(LLVM_Z3_INSTALL_DIR "" CACHE STRING "Install directory of the Z3 solver.")
 341
 342 find_package(Z3 4.7.1)
 343
 344 if (LLVM_Z3_INSTALL_DIR)
 345   if (NOT Z3_FOUND)
 346     message(FATAL_ERROR "Z3 >= 4.7.1 has not been found in LLVM_Z3_INSTALL_DIR: ${LLVM_Z3_INSTALL_DIR}.")
 347   endif()
 348 endif()
 349
 350 set(LLVM_ENABLE_Z3_SOLVER_DEFAULT "${Z3_FOUND}")
 351
 352 option(LLVM_ENABLE_Z3_SOLVER
 353   "Enable Support for the Z3 constraint solver in LLVM."
 354   ${LLVM_ENABLE_Z3_SOLVER_DEFAULT}
 355 )
 356
 357 if (LLVM_ENABLE_Z3_SOLVER)
 358   if (NOT Z3_FOUND)
 359     message(FATAL_ERROR "LLVM_ENABLE_Z3_SOLVER cannot be enabled when Z3 is not available.")
 360   endif()
 361
 362   set(LLVM_WITH_Z3 1)
 363 endif()
 364
 365 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 366   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 367 endif()
 368
 369 set(LLVM_TARGETS_TO_BUILD
 370    ${LLVM_TARGETS_TO_BUILD}
 371    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 372 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 373
 374 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 375 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 376 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 377 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 378   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 379   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 380 else()
 381   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 382   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 383 endif()
 384 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 385 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 386 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 387 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 388
 389 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 390
 391 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 392   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 393 else()
 394   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 395 endif()
 396
 397 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 398
 399 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 400   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 401
 402 option(LLVM_FORCE_USE_OLD_TOOLCHAIN
 403        "Set to ON to force using an old, unsupported host toolchain." OFF)
 404
 405 option(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN
 406        "Set to ON to only warn when using a toolchain which is about to be deprecated, instead of emitting an error." OFF)
 407
 408 option(LLVM_USE_INTEL_JITEVENTS
 409   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 410   OFF)
 411
 412 if( LLVM_USE_INTEL_JITEVENTS )
 413   # Verify we are on a supported platform
 414   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 415     message(FATAL_ERROR
 416       "Intel JIT API support is available on Linux and Windows only.")
 417   endif()
 418 endif( LLVM_USE_INTEL_JITEVENTS )
 419
 420 option(LLVM_USE_OPROFILE
 421   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 422
 423 option(LLVM_EXTERNALIZE_DEBUGINFO
 424   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 425
 426 set(LLVM_CODESIGNING_IDENTITY "" CACHE STRING
 427   "Sign executables and dylibs with the given identity or skip if empty (Darwin Only)")
 428
 429 # If enabled, verify we are on a platform that supports oprofile.
 430 if( LLVM_USE_OPROFILE )
 431   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 432     message(FATAL_ERROR "OProfile support is available on Linux only.")
 433   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 434 endif( LLVM_USE_OPROFILE )
 435
 436 option(LLVM_USE_PERF
 437   "Use perf JIT interface to inform perf about JIT code" OFF)
 438
 439 # If enabled, verify we are on a platform that supports perf.
 440 if( LLVM_USE_PERF )
 441   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 442     message(FATAL_ERROR "perf support is available on Linux only.")
 443   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 444 endif( LLVM_USE_PERF )
 445
 446 set(LLVM_USE_SANITIZER "" CACHE STRING
 447   "Define the sanitizer used to build binaries and tests.")
 448 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 449 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 450   "Path to fuzzing library for linking with fuzz targets")
 451
 452 option(LLVM_USE_SPLIT_DWARF
 453   "Use -gsplit-dwarf when compiling llvm." OFF)
 454
 455 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 456 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 457
 458 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 459   set(POLLY_IN_TREE TRUE)
 460 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 461   set(POLLY_IN_TREE TRUE)
 462 else()
 463   set(POLLY_IN_TREE FALSE)
 464 endif()
 465
 466 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 467   set(WITH_POLLY ON)
 468 else()
 469   set(WITH_POLLY OFF)
 470 endif()
 471
 472 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 473   set(LINK_POLLY_INTO_TOOLS ON)
 474 else()
 475   set(LINK_POLLY_INTO_TOOLS OFF)
 476 endif()
 477
 478 # Define an option controlling whether we should build for 32-bit on 64-bit
 479 # platforms, where supported.
 480 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 481   # TODO: support other platforms and toolchains.
 482   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 483 endif()
 484
 485 # Define the default arguments to use with 'lit', and an option for the user to
 486 # override.
 487 set(LIT_ARGS_DEFAULT "-sv")
 488 if (MSVC_IDE OR XCODE)
 489   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 490 endif()
 491 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 492
 493 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 494 if( WIN32 AND NOT CYGWIN )
 495   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 496 endif()
 497
 498 # Define options to control the inclusion and default build behavior for
 499 # components which may not strictly be necessary (tools, examples, and tests).
 500 #
 501 # This is primarily to support building smaller or faster project files.
 502 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 503 option(LLVM_BUILD_TOOLS
 504   "Build the LLVM tools. If OFF, just generate build targets." ON)
 505
 506 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 507 option(LLVM_BUILD_UTILS
 508   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 509
 510 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 511 option(LLVM_BUILD_RUNTIMES
 512   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 513
 514 option(LLVM_BUILD_RUNTIME
 515   "Build the LLVM runtime libraries." ON)
 516 option(LLVM_BUILD_EXAMPLES
 517   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 518 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 519
 520 option(LLVM_BUILD_TESTS
 521   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 522 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 523 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 524
 525 option(LLVM_BUILD_BENCHMARKS "Add LLVM benchmark targets to the list of default
 526 targets. If OFF, benchmarks still could be built using Benchmarks target." OFF)
 527 option(LLVM_INCLUDE_BENCHMARKS "Generate benchmark targets. If OFF, benchmarks can't be built." ON)
 528
 529 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 530 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 531 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 532 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 533 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 534 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 535
 536 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 537     CACHE STRING "Doxygen-generated HTML documentation install directory")
 538 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 539     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 540
 541 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 542   "Build compiler-rt as an external project." OFF)
 543
 544 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 545   "Show target and host info when tools are invoked with --version." ON)
 546
 547 # You can configure which libraries from LLVM you want to include in the
 548 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 549 # list of LLVM components. All component names handled by llvm-config are valid.
 550 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 551   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 552     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 553 endif()
 554 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 555 if(MSVC)
 556   option(LLVM_BUILD_LLVM_C_DYLIB "Build LLVM-C.dll (Windows only)" ON)
 557 else()
 558   option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin only)" OFF)
 559 endif()
 560 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 561 if(LLVM_LINK_LLVM_DYLIB OR (LLVM_BUILD_LLVM_C_DYLIB AND NOT MSVC))
 562   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 563 endif()
 564 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 565
 566 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 567 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 568   set(LLVM_USE_HOST_TOOLS ON)
 569 endif()
 570
 571 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 572   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 573 else()
 574   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 575 endif()
 576
 577 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 578     LLVM_ENABLE_IR_PGO)
 579   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 580     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 581     # for spining disks. Anything higher may only help on slower mediums.
 582     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 583   endif()
 584   if(NOT LLVM_PROFILE_FILE_PATTERN)
 585     if(NOT LLVM_PROFILE_DATA_DIR)
 586       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 587     endif()
 588                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 589   endif()
 590   if(NOT LLVM_CSPROFILE_FILE_PATTERN)
 591     if(NOT LLVM_CSPROFILE_DATA_DIR)
 592       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/csprofiles" LLVM_CSPROFILE_DATA_DIR)
 593     endif()
 594     file(TO_NATIVE_PATH "${LLVM_CSPROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_CSPROFILE_FILE_PATTERN)
 595   endif()
 596 endif()
 597
 598 if (LLVM_BUILD_STATIC)
 599   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 600 endif()
 601
 602 # Use libtool instead of ar if you are both on an Apple host, and targeting Apple.
 603 if(CMAKE_HOST_APPLE AND APPLE)
 604   include(UseLibtool)
 605 endif()
 606
 607 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 608 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 609 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 610
 611 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR OFF CACHE BOOL
 612   "Enable per-target runtimes directory")
 613
 614 # All options referred to from HandleLLVMOptions have to be specified
 615 # BEFORE this include, otherwise options will not be correctly set on
 616 # first cmake run
 617 include(config-ix)
 618
 619 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 620   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 621 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 622
 623 # By default, we target the host, but this can be overridden at CMake
 624 # invocation time.
 625 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 626   "Default target for which LLVM will generate code." )
 627 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 628 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 629 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 630
 631 if(WIN32 OR CYGWIN)
 632   if(BUILD_SHARED_LIBS OR LLVM_BUILD_LLVM_DYLIB)
 633     set(LLVM_ENABLE_PLUGINS_default ON)
 634   else()
 635     set(LLVM_ENABLE_PLUGINS_default OFF)
 636   endif()
 637 else()
 638   set(LLVM_ENABLE_PLUGINS_default ${LLVM_ENABLE_PIC})
 639 endif()
 640 option(LLVM_ENABLE_PLUGINS "Enable plugin support" ${LLVM_ENABLE_PLUGINS_default})
 641
 642 include(HandleLLVMOptions)
 643
 644 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 645 # FIXME: We should support systems with only Python 3, but that requires work
 646 # on LLDB.
 647 set(Python_ADDITIONAL_VERSIONS 2.7)
 648 include(FindPythonInterp)
 649 if( NOT PYTHONINTERP_FOUND )
 650   message(FATAL_ERROR
 651 "Unable to find Python interpreter, required for builds and testing.
 652
 653 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 654 endif()
 655
 656 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 657   message(FATAL_ERROR "Python 2.7 or newer is required")
 658 endif()
 659
 660 ######
 661 # LLVMBuild Integration
 662 #
 663 # We use llvm-build to generate all the data required by the CMake based
 664 # build system in one swoop:
 665 #
 666 #  - We generate a file (a CMake fragment) in the object root which contains
 667 #    all the definitions that are required by CMake.
 668 #
 669 #  - We generate the library table used by llvm-config.
 670 #
 671 #  - We generate the dependencies for the CMake fragment, so that we will
 672 #    automatically reconfigure ourselves.
 673
 674 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 675 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 676   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 677 set(LLVMBUILDCMAKEFRAG
 678   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 679
 680 # Create the list of optional components that are enabled
 681 if (LLVM_USE_INTEL_JITEVENTS)
 682   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 683 endif (LLVM_USE_INTEL_JITEVENTS)
 684 if (LLVM_USE_OPROFILE)
 685   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 686 endif (LLVM_USE_OPROFILE)
 687 if (LLVM_USE_PERF)
 688   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} PerfJITEvents)
 689 endif (LLVM_USE_PERF)
 690
 691 message(STATUS "Constructing LLVMBuild project information")
 692 execute_process(
 693   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 694             --native-target "${LLVM_NATIVE_ARCH}"
 695             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 696             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 697             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 698             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 699             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 700             ERROR_VARIABLE LLVMBUILDERRORS
 701             OUTPUT_STRIP_TRAILING_WHITESPACE
 702             ERROR_STRIP_TRAILING_WHITESPACE
 703   RESULT_VARIABLE LLVMBUILDRESULT)
 704
 705 # On Win32, CMake doesn't properly handle piping the default output/error
 706 # streams into the GUI console. So, we explicitly catch and report them.
 707 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 708   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 709 endif()
 710 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 711   message(FATAL_ERROR
 712     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 713 endif()
 714
 715 # Include the generated CMake fragment. This will define properties from the
 716 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 717 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 718 # files change.
 719 include(${LLVMBUILDCMAKEFRAG})
 720
 721 ######
 722
 723 # Configure all of the various header file fragments LLVM uses which depend on
 724 # configuration variables.
 725 set(LLVM_ENUM_TARGETS "")
 726 set(LLVM_ENUM_ASM_PRINTERS "")
 727 set(LLVM_ENUM_ASM_PARSERS "")
 728 set(LLVM_ENUM_DISASSEMBLERS "")
 729 foreach(t ${LLVM_TARGETS_TO_BUILD})
 730   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 731
 732   list(FIND LLVM_ALL_TARGETS ${t} idx)
 733   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 734   # At this point, LLVMBUILDTOOL already checked all the targets passed in
 735   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
 736   # this test just makes sure that any experimental targets were passed via
 737   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 738   if( idx LESS 0 AND idy LESS 0 )
 739     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 740       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 741   else()
 742     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 743   endif()
 744
 745   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 746   if( asmp_file )
 747     set(LLVM_ENUM_ASM_PRINTERS
 748       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 749   endif()
 750   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 751     set(LLVM_ENUM_ASM_PARSERS
 752       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 753   endif()
 754   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 755     set(LLVM_ENUM_DISASSEMBLERS
 756       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 757   endif()
 758 endforeach(t)
 759
 760 # Produce the target definition files, which provide a way for clients to easily
 761 # include various classes of targets.
 762 configure_file(
 763   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 764   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 765   )
 766 configure_file(
 767   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 768   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 769   )
 770 configure_file(
 771   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 772   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 773   )
 774 configure_file(
 775   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 776   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 777   )
 778
 779 # Configure the three LLVM configuration header files.
 780 configure_file(
 781   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 782   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 783 configure_file(
 784   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 785   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 786 configure_file(
 787   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 788   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 789
 790 # Add target for generating source rpm package.
 791 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 792     CACHE FILEPATH ".spec file to use for srpm generation")
 793 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 794 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 795
 796 get_source_info(${CMAKE_CURRENT_SOURCE_DIR} revision repository)
 797 string(LENGTH "${revision}" revision_length)
 798 if(revision MATCHES "^[0-9]+$" AND revision_length LESS 40)
 799   set(LLVM_RPM_SPEC_REVISION "r${revision}")
 800 else()
 801   set(LLVM_RPM_SPEC_REVISION "${revision}")
 802 endif()
 803
 804 configure_file(
 805   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 806   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 807
 808 add_custom_target(srpm
 809   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 810   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 811 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 812
 813
 814 # They are not referenced. See set_output_directory().
 815 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 816 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 817 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 818
 819 if(APPLE AND DARWIN_LTO_LIBRARY)
 820   set(CMAKE_EXE_LINKER_FLAGS
 821     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 822   set(CMAKE_SHARED_LINKER_FLAGS
 823     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 824   set(CMAKE_MODULE_LINKER_FLAGS
 825     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 826 endif()
 827
 828 # Build with _XOPEN_SOURCE on AIX, as stray macros in _ALL_SOURCE mode tend to
 829 # break things. In this case we need to enable the large-file API as well.
 830 if (UNIX AND ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 831           add_definitions("-D_XOPEN_SOURCE=700")
 832           add_definitions("-D_LARGE_FILE_API")
 833 endif()
 834
 835 # Work around a broken bfd ld behavior. When linking a binary with a
 836 # foo.so library, it will try to find any library that foo.so uses and
 837 # check its symbols. This is wasteful (the check was done when foo.so
 838 # was created) and can fail since it is not the dynamic linker and
 839 # doesn't know how to handle search paths correctly.
 840 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 841   set(CMAKE_EXE_LINKER_FLAGS
 842       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 843 endif()
 844
 845 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 846
 847 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 848
 849 # when crosscompiling import the executable targets from a file
 850 if(LLVM_USE_HOST_TOOLS)
 851   include(CrossCompile)
 852 endif(LLVM_USE_HOST_TOOLS)
 853 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 854 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 855 # (this is a variable that CrossCompile sets on recursive invocations)
 856 endif()
 857
 858 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 859   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 860   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 861   include_directories(SYSTEM "/usr/local/include")
 862   link_directories("/usr/local/lib")
 863 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 864
 865 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 866    # special hack for Solaris to handle crazy system sys/regset.h
 867    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 868 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 869
 870 # Make sure we don't get -rdynamic in every binary. For those that need it,
 871 # use export_executable_symbols(target).
 872 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 873
 874 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 875   "Profiling data file to use when compiling in order to improve runtime performance.")
 876
 877 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 878   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 879     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 880   else()
 881     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 882   endif()
 883 endif()
 884
 885 include(AddLLVM)
 886 include(TableGen)
 887
 888 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 889   # People report that -O3 is unreliable on MinGW. The traditional
 890   # build also uses -O2 for that reason:
 891   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 892 endif()
 893
 894 # Put this before tblgen. Else we have a circular dependence.
 895 add_subdirectory(lib/Demangle)
 896 add_subdirectory(lib/Support)
 897 add_subdirectory(lib/TableGen)
 898
 899 add_subdirectory(utils/TableGen)
 900
 901 add_subdirectory(include/llvm)
 902
 903 add_subdirectory(lib)
 904
 905 if( LLVM_INCLUDE_UTILS )
 906   add_subdirectory(utils/FileCheck)
 907   add_subdirectory(utils/PerfectShuffle)
 908   add_subdirectory(utils/count)
 909   add_subdirectory(utils/not)
 910   add_subdirectory(utils/yaml-bench)
 911 else()
 912   if ( LLVM_INCLUDE_TESTS )
 913     message(FATAL_ERROR "Including tests when not building utils will not work.
 914     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLUDE_TESTS to Off.")
 915   endif()
 916 endif()
 917
 918 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 919 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 920   add_subdirectory(utils/LLVMVisualizers)
 921 endif()
 922
 923 foreach( binding ${LLVM_BINDINGS_LIST} )
 924   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 925     add_subdirectory(bindings/${binding})
 926   endif()
 927 endforeach()
 928
 929 add_subdirectory(projects)
 930
 931 if( LLVM_INCLUDE_TOOLS )
 932   add_subdirectory(tools)
 933 endif()
 934
 935 if( LLVM_INCLUDE_RUNTIMES )
 936   add_subdirectory(runtimes)
 937 endif()
 938
 939 if( LLVM_INCLUDE_EXAMPLES )
 940   add_subdirectory(examples)
 941 endif()
 942
 943 if( LLVM_INCLUDE_TESTS )
 944   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 945     include(LLVMExternalProjectUtils)
 946     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 947       USE_TOOLCHAIN
 948       EXCLUDE_FROM_ALL
 949       NO_INSTALL
 950       ALWAYS_CLEAN)
 951   endif()
 952   add_subdirectory(utils/lit)
 953   add_subdirectory(test)
 954   add_subdirectory(unittests)
 955   if( LLVM_INCLUDE_UTILS )
 956     add_subdirectory(utils/unittest)
 957   endif()
 958
 959   if (WIN32)
 960     # This utility is used to prevent crashing tests from calling Dr. Watson on
 961     # Windows.
 962     add_subdirectory(utils/KillTheDoctor)
 963   endif()
 964
 965   # Add a global check rule now that all subdirectories have been traversed
 966   # and we know the total set of lit testsuites.
 967   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 968   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 969   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 970   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 971   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 972                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 973   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 974                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 975   add_lit_target(check-all
 976     "Running all regression tests"
 977     ${LLVM_LIT_TESTSUITES}
 978     PARAMS ${LLVM_LIT_PARAMS}
 979     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 980     ARGS ${LLVM_LIT_EXTRA_ARGS}
 981     )
 982   if(TARGET check-runtimes)
 983     add_dependencies(check-all check-runtimes)
 984   endif()
 985   add_custom_target(test-depends
 986                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 987   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 988 endif()
 989
 990 if (LLVM_INCLUDE_DOCS)
 991   add_subdirectory(docs)
 992 endif()
 993
 994 add_subdirectory(cmake/modules)
 995
 996 # Do this last so that all lit targets have already been created.
 997 if (LLVM_INCLUDE_UTILS)
 998   add_subdirectory(utils/llvm-lit)
 999 endif()
1000
1001 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1002   install(DIRECTORY include/llvm include/llvm-c
1003     DESTINATION include
1004     COMPONENT llvm-headers
1005     FILES_MATCHING
1006     PATTERN "*.def"
1007     PATTERN "*.h"
1008     PATTERN "*.td"
1009     PATTERN "*.inc"
1010     PATTERN "LICENSE.TXT"
1011     PATTERN ".svn" EXCLUDE
1012     )
1013
1014   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
1015     DESTINATION include
1016     COMPONENT llvm-headers
1017     FILES_MATCHING
1018     PATTERN "*.def"
1019     PATTERN "*.h"
1020     PATTERN "*.gen"
1021     PATTERN "*.inc"
1022     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
1023     PATTERN "CMakeFiles" EXCLUDE
1024     PATTERN "config.h" EXCLUDE
1025     PATTERN ".svn" EXCLUDE
1026     )
1027
1028   if (LLVM_INSTALL_MODULEMAPS)
1029     install(DIRECTORY include/llvm include/llvm-c
1030             DESTINATION include
1031             COMPONENT llvm-headers
1032             FILES_MATCHING
1033             PATTERN "module.modulemap"
1034             )
1035     install(FILES include/llvm/module.install.modulemap
1036             DESTINATION include/llvm
1037             COMPONENT llvm-headers
1038             RENAME "module.extern.modulemap"
1039             )
1040   endif(LLVM_INSTALL_MODULEMAPS)
1041
1042   # Installing the headers needs to depend on generating any public
1043   # tablegen'd headers.
1044   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
1045   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
1046
1047   if (NOT LLVM_ENABLE_IDE)
1048     add_llvm_install_targets(install-llvm-headers
1049                              DEPENDS llvm-headers
1050                              COMPONENT llvm-headers)
1051   endif()
1052
1053   # Custom target to install all libraries.
1054   add_custom_target(llvm-libraries)
1055   set_target_properties(llvm-libraries PROPERTIES FOLDER "Misc")
1056
1057   if (NOT LLVM_ENABLE_IDE)
1058     add_llvm_install_targets(install-llvm-libraries
1059                              DEPENDS llvm-libraries
1060                              COMPONENT llvm-libraries)
1061   endif()
1062
1063   get_property(LLVM_LIBS GLOBAL PROPERTY LLVM_LIBS)
1064   if(LLVM_LIBS)
1065     list(REMOVE_DUPLICATES LLVM_LIBS)
1066     foreach(lib ${LLVM_LIBS})
1067       add_dependencies(llvm-libraries ${lib})
1068       if (NOT LLVM_ENABLE_IDE)
1069         add_dependencies(install-llvm-libraries install-${lib})
1070       endif()
1071     endforeach()
1072   endif()
1073 endif()
1074
1075 # This must be at the end of the LLVM root CMakeLists file because it must run
1076 # after all targets are created.
1077 include(LLVMDistributionSupport)
1078 llvm_distribution_add_targets()
1079
1080 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1081 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" AND CMAKE_INSTALL_UCRT_LIBRARIES)
1082   include(InstallRequiredSystemLibraries)
1083 endif()
1084
1085 if (LLVM_INCLUDE_BENCHMARKS)
1086   # Override benchmark defaults so that when the library itself is updated these
1087   # modifications are not lost.
1088   set(BENCHMARK_ENABLE_TESTING OFF CACHE BOOL "Disable benchmark testing" FORCE)
1089   set(BENCHMARK_ENABLE_EXCEPTIONS OFF CACHE BOOL "Disable benchmark exceptions" FORCE)
1090   set(BENCHMARK_ENABLE_INSTALL OFF CACHE BOOL "Don't install benchmark" FORCE)
1091   set(BENCHMARK_DOWNLOAD_DEPENDENCIES OFF CACHE BOOL "Don't download dependencies" FORCE)
1092   set(BENCHMARK_ENABLE_GTEST_TESTS OFF CACHE BOOL "Disable Google Test in benchmark" FORCE)
1093   # Since LLVM requires C++11 it is safe to assume that std::regex is available.
1094   set(HAVE_STD_REGEX ON CACHE BOOL "OK" FORCE)
1095
1096   add_subdirectory(utils/benchmark)
1097   add_subdirectory(benchmarks)
1098 endif()