CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 # CMake 3.1 and higher include generator expressions of the form
   6 # $<TARGETLIB:obj> in the SOURCES property.  These need to be
   7 # stripped everywhere that access the SOURCES property, so we just
   8 # defer to the OLD behavior of not including generator expressions
   9 # in the output for now.
  10 cmake_policy(SET CMP0051 OLD)
  11
  12 if(POLICY CMP0068)
  13   cmake_policy(SET CMP0068 NEW)
  14   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
  15 endif()
  16
  17 if(NOT DEFINED LLVM_VERSION_MAJOR)
  18   set(LLVM_VERSION_MAJOR 8)
  19 endif()
  20 if(NOT DEFINED LLVM_VERSION_MINOR)
  21   set(LLVM_VERSION_MINOR 0)
  22 endif()
  23 if(NOT DEFINED LLVM_VERSION_PATCH)
  24   set(LLVM_VERSION_PATCH 0)
  25 endif()
  26 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  27   set(LLVM_VERSION_SUFFIX svn)
  28 endif()
  29
  30 if (NOT PACKAGE_VERSION)
  31   set(PACKAGE_VERSION
  32     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  33 endif()
  34
  35 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  36   message(WARNING "Visual Studio generators use the x86 host compiler by "
  37                   "default, even for 64-bit targets. This can result in linker "
  38                   "instability and out of memory errors. To use the 64-bit "
  39                   "host compiler, pass -Thost=x64 on the CMake command line.")
  40 endif()
  41
  42 project(LLVM
  43   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  44   LANGUAGES C CXX ASM)
  45
  46 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  47   message(STATUS "No build type selected, default to Debug")
  48   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  49 endif()
  50
  51 # This should only apply if you are both on an Apple host, and targeting Apple.
  52 if(CMAKE_HOST_APPLE AND APPLE)
  53   # if CMAKE_LIBTOOL is not set, try and find it with xcrun or find_program
  54   if(NOT CMAKE_LIBTOOL)
  55     if(NOT CMAKE_XCRUN)
  56       find_program(CMAKE_XCRUN NAMES xcrun)
  57     endif()
  58     if(CMAKE_XCRUN)
  59       execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  60         OUTPUT_VARIABLE CMAKE_LIBTOOL
  61         OUTPUT_STRIP_TRAILING_WHITESPACE)
  62     endif()
  63
  64     if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  65       find_program(CMAKE_LIBTOOL NAMES libtool)
  66     endif()
  67   endif()
  68
  69   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  70   if(CMAKE_LIBTOOL)
  71     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  72     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  73
  74     execute_process(COMMAND ${CMAKE_LIBTOOL} -V
  75       OUTPUT_VARIABLE LIBTOOL_V_OUTPUT
  76       OUTPUT_STRIP_TRAILING_WHITESPACE)
  77     if("${LIBTOOL_V_OUTPUT}" MATCHES ".*cctools-([0-9.]+).*")
  78       string(REGEX REPLACE ".*cctools-([0-9.]+).*" "\\1" LIBTOOL_VERSION
  79         ${LIBTOOL_V_OUTPUT})
  80       if(NOT LIBTOOL_VERSION VERSION_LESS "862")
  81         set(LIBTOOL_NO_WARNING_FLAG "-no_warning_for_no_symbols")
  82       endif()
  83     endif()
  84
  85     foreach(lang ${languages})
  86       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  87         "\"${CMAKE_LIBTOOL}\" -static ${LIBTOOL_NO_WARNING_FLAG} -o <TARGET> \
  88         <LINK_FLAGS> <OBJECTS> ")
  89     endforeach()
  90   endif()
  91
  92   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
  93   if(DYLD_LIBRARY_PATH)
  94     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
  95     foreach(lang ${languages})
  96       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
  97         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
  98              "${dyld_envar} ${cmd}")
  99       endforeach()
 100       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
 101         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
 102     endforeach()
 103   endif()
 104 endif()
 105
 106 # Side-by-side subprojects layout: automatically set the
 107 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 108 # This allows an easy way of setting up a build directory for llvm and another
 109 # one for llvm+clang+... using the same sources.
 110 set(LLVM_ALL_PROJECTS "clang;libcxx;libcxxabi;lldb;compiler-rt;lld;polly;debuginfo-tests")
 111 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 112         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
 113 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 114   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 115 endif()
 116 foreach(proj ${LLVM_ENABLE_PROJECTS})
 117   set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 118   if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 119     message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 120   endif()
 121   string(TOUPPER "${proj}" upper_proj)
 122   STRING(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 123   set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR   "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 124   # There is a widely spread opinion that clang-tools-extra should be merged
 125   # into clang. The following simulates it by always enabling clang-tools-extra
 126   # when enabling clang.
 127   if (proj STREQUAL "clang")
 128     set(LLVM_EXTERNAL_CLANG_TOOLS_EXTRA_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../clang-tools-extra")
 129   endif()
 130 endforeach()
 131
 132 # Build llvm with ccache if the package is present
 133 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 134 if(LLVM_CCACHE_BUILD)
 135   find_program(CCACHE_PROGRAM ccache)
 136   if(CCACHE_PROGRAM)
 137       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 138       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 139       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 140           CACHE STRING "Parameters to pass through to ccache")
 141
 142       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 143       if (LLVM_CCACHE_MAXSIZE)
 144         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 145       endif()
 146       if (LLVM_CCACHE_DIR)
 147         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 148       endif()
 149       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 150   else()
 151     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 152   endif()
 153 endif()
 154
 155 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 156
 157 # Some features of the LLVM build may be disallowed when dependency debugging is
 158 # enabled. In particular you cannot use ccache because we want to force compile
 159 # operations to always happen.
 160 if(LLVM_DEPENDENCY_DEBUGGING)
 161   if(NOT CMAKE_HOST_APPLE)
 162     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 163   endif()
 164   if(LLVM_CCACHE_BUILD)
 165     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 166   endif()
 167 endif()
 168
 169 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 170 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 171 if(LLVM_ENABLE_GISEL_COV)
 172   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 173 endif()
 174
 175 # Add path for custom modules
 176 set(CMAKE_MODULE_PATH
 177   ${CMAKE_MODULE_PATH}
 178   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 179   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 180   )
 181
 182 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 183 # for use by clang_complete, YouCompleteMe, etc.
 184 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 185
 186 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 187   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 188
 189 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 190
 191 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 192
 193 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 194 if ( LLVM_USE_FOLDERS )
 195   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 196 endif()
 197
 198 include(VersionFromVCS)
 199
 200 option(LLVM_APPEND_VC_REV
 201   "Embed the version control system revision id in LLVM" ON)
 202
 203 set(PACKAGE_NAME LLVM)
 204 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 205 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
 206
 207 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 208   "Default URL where bug reports are to be submitted.")
 209
 210 # Configure CPack.
 211 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 212 set(CPACK_PACKAGE_VENDOR "LLVM")
 213 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 214 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 215 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 216 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 217 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 218 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 219 if(WIN32 AND NOT UNIX)
 220   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 221   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 222   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 223   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 224   set(CPACK_NSIS_MODIFY_PATH "ON")
 225   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 226   if( CMAKE_CL_64 )
 227     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 228   endif()
 229 endif()
 230 include(CPack)
 231
 232 # Sanity check our source directory to make sure that we are not trying to
 233 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 234 # sure that we don't have any stray generated files lying around in the tree
 235 # (which would end up getting picked up by header search, instead of the correct
 236 # versions).
 237 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 238   message(FATAL_ERROR "In-source builds are not allowed.
 239 Please create a directory and run cmake from there, passing the path
 240 to this source directory as the last argument.
 241 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 242 Please delete them.")
 243 endif()
 244
 245 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 246
 247 if (CMAKE_BUILD_TYPE AND
 248     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 249   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 250 endif()
 251
 252 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 253
 254 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 255 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 256
 257 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 258     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 259 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 260
 261 # They are used as destination of target generators.
 262 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 263 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 264 if(WIN32 OR CYGWIN)
 265   # DLL platform -- put DLLs into bin.
 266   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 267 else()
 268   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 269 endif()
 270
 271 # Each of them corresponds to llvm-config's.
 272 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 273 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 274 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 275 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 276 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 277
 278 # Note: LLVM_CMAKE_PATH does not include generated files
 279 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 280 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 281 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 282
 283 # List of all targets to be built by default:
 284 set(LLVM_ALL_TARGETS
 285   AArch64
 286   AMDGPU
 287   ARM
 288   BPF
 289   Hexagon
 290   Lanai
 291   Mips
 292   MSP430
 293   NVPTX
 294   PowerPC
 295   Sparc
 296   SystemZ
 297   X86
 298   XCore
 299   )
 300
 301 # List of targets with JIT support:
 302 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 303
 304 set(LLVM_TARGETS_TO_BUILD "all"
 305     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 306
 307 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 308   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 309
 310 option(BUILD_SHARED_LIBS
 311   "Build all libraries as shared libraries instead of static" OFF)
 312
 313 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 314 if(LLVM_ENABLE_BACKTRACES)
 315   set(ENABLE_BACKTRACES 1)
 316 endif()
 317
 318 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 319 if(LLVM_ENABLE_CRASH_OVERRIDES)
 320   set(ENABLE_CRASH_OVERRIDES 1)
 321 endif()
 322
 323 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 324 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 325 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 326
 327 set(LLVM_TARGET_ARCH "host"
 328   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 329
 330 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 331
 332 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 333
 334 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 335
 336 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 337
 338 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 339
 340 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 341
 342 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 343   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 344 endif()
 345
 346 set(LLVM_TARGETS_TO_BUILD
 347    ${LLVM_TARGETS_TO_BUILD}
 348    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 349 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 350
 351 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 352 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 353 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 354 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 355   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 356   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 357 else()
 358   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 359   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 360 endif()
 361 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 362 option(LLVM_ENABLE_CXX1Z "Compile with C++1z enabled." OFF)
 363 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 364 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 365 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 366 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 367
 368 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 369
 370 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 371   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 372 else()
 373   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 374 endif()
 375
 376 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 377
 378 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 379   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 380
 381 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 382        "Set to ON to force using an old, unsupported host toolchain." OFF)
 383
 384 option(LLVM_USE_INTEL_JITEVENTS
 385   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 386   OFF)
 387
 388 if( LLVM_USE_INTEL_JITEVENTS )
 389   # Verify we are on a supported platform
 390   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 391     message(FATAL_ERROR
 392       "Intel JIT API support is available on Linux and Windows only.")
 393   endif()
 394 endif( LLVM_USE_INTEL_JITEVENTS )
 395
 396 option(LLVM_USE_OPROFILE
 397   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 398
 399 option(LLVM_EXTERNALIZE_DEBUGINFO
 400   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 401
 402 option(LLVM_CODESIGNING_IDENTITY
 403   "Sign executables and dylibs with the given identity (Darwin Only)" OFF)
 404
 405 # If enabled, verify we are on a platform that supports oprofile.
 406 if( LLVM_USE_OPROFILE )
 407   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 408     message(FATAL_ERROR "OProfile support is available on Linux only.")
 409   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 410 endif( LLVM_USE_OPROFILE )
 411
 412 option(LLVM_USE_PERF
 413   "Use perf JIT interface to inform perf about JIT code" OFF)
 414
 415 # If enabled, verify we are on a platform that supports perf.
 416 if( LLVM_USE_PERF )
 417   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 418     message(FATAL_ERROR "perf support is available on Linux only.")
 419   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 420 endif( LLVM_USE_PERF )
 421
 422 set(LLVM_USE_SANITIZER "" CACHE STRING
 423   "Define the sanitizer used to build binaries and tests.")
 424 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 425 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 426   "Path to fuzzing library for linking with fuzz targets")
 427
 428 option(LLVM_USE_SPLIT_DWARF
 429   "Use -gsplit-dwarf when compiling llvm." OFF)
 430
 431 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 432 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 433
 434 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 435   set(POLLY_IN_TREE TRUE)
 436 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 437   set(POLLY_IN_TREE TRUE)
 438 else()
 439   set(POLLY_IN_TREE FALSE)
 440 endif()
 441
 442 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 443   set(WITH_POLLY ON)
 444 else()
 445   set(WITH_POLLY OFF)
 446 endif()
 447
 448 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 449   set(LINK_POLLY_INTO_TOOLS ON)
 450 else()
 451   set(LINK_POLLY_INTO_TOOLS OFF)
 452 endif()
 453
 454 # Define an option controlling whether we should build for 32-bit on 64-bit
 455 # platforms, where supported.
 456 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 457   # TODO: support other platforms and toolchains.
 458   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 459 endif()
 460
 461 # Define the default arguments to use with 'lit', and an option for the user to
 462 # override.
 463 set(LIT_ARGS_DEFAULT "-sv")
 464 if (MSVC_IDE OR XCODE)
 465   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 466 endif()
 467 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 468
 469 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 470 if( WIN32 AND NOT CYGWIN )
 471   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 472 endif()
 473
 474 # Define options to control the inclusion and default build behavior for
 475 # components which may not strictly be necessary (tools, examples, and tests).
 476 #
 477 # This is primarily to support building smaller or faster project files.
 478 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 479 option(LLVM_BUILD_TOOLS
 480   "Build the LLVM tools. If OFF, just generate build targets." ON)
 481
 482 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 483 option(LLVM_BUILD_UTILS
 484   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 485
 486 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 487 option(LLVM_BUILD_RUNTIMES
 488   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 489
 490 option(LLVM_BUILD_RUNTIME
 491   "Build the LLVM runtime libraries." ON)
 492 option(LLVM_BUILD_EXAMPLES
 493   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 494 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 495
 496 option(LLVM_BUILD_TESTS
 497   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 498 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 499 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 500
 501 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 502 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 503 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 504 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 505 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 506 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 507
 508 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 509     CACHE STRING "Doxygen-generated HTML documentation install directory")
 510 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 511     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 512
 513 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 514   "Build compiler-rt as an external project." OFF)
 515
 516 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 517   "Show target and host info when tools are invoked with --version." ON)
 518
 519 # You can configure which libraries from LLVM you want to include in the
 520 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 521 # list of LLVM components. All component names handled by llvm-config are valid.
 522 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 523   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 524     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 525 endif()
 526 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 527 if(MSVC)
 528   option(LLVM_BUILD_LLVM_C_DYLIB "Build LLVM-C.dll (Windows only)" OFF)
 529 else()
 530   option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin only)" OFF)
 531 endif()
 532 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 533 if(LLVM_LINK_LLVM_DYLIB OR (LLVM_BUILD_LLVM_C_DYLIB AND NOT MSVC))
 534   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 535 endif()
 536 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 537
 538 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 539 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 540   set(LLVM_USE_HOST_TOOLS ON)
 541 endif()
 542
 543 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 544   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 545 else()
 546   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 547 endif()
 548
 549 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 550     LLVM_ENABLE_IR_PGO)
 551   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 552     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 553     # for spining disks. Anything higher may only help on slower mediums.
 554     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 555   endif()
 556   if(NOT LLVM_PROFILE_FILE_PATTERN)
 557     if(NOT LLVM_PROFILE_DATA_DIR)
 558       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 559     endif()
 560                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 561   endif()
 562 endif()
 563
 564 if (LLVM_BUILD_STATIC)
 565   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 566 endif()
 567
 568 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 569 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 570 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 571
 572 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR OFF CACHE BOOL
 573   "Enable per-target runtimes directory")
 574
 575 # All options referred to from HandleLLVMOptions have to be specified
 576 # BEFORE this include, otherwise options will not be correctly set on
 577 # first cmake run
 578 include(config-ix)
 579
 580 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 581   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 582 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 583
 584 # By default, we target the host, but this can be overridden at CMake
 585 # invocation time.
 586 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 587   "Default target for which LLVM will generate code." )
 588 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 589 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 590 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 591
 592 include(HandleLLVMOptions)
 593
 594 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 595 # FIXME: We should support systems with only Python 3, but that requires work
 596 # on LLDB.
 597 set(Python_ADDITIONAL_VERSIONS 2.7)
 598 include(FindPythonInterp)
 599 if( NOT PYTHONINTERP_FOUND )
 600   message(FATAL_ERROR
 601 "Unable to find Python interpreter, required for builds and testing.
 602
 603 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 604 endif()
 605
 606 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 607   message(FATAL_ERROR "Python 2.7 or newer is required")
 608 endif()
 609
 610 ######
 611 # LLVMBuild Integration
 612 #
 613 # We use llvm-build to generate all the data required by the CMake based
 614 # build system in one swoop:
 615 #
 616 #  - We generate a file (a CMake fragment) in the object root which contains
 617 #    all the definitions that are required by CMake.
 618 #
 619 #  - We generate the library table used by llvm-config.
 620 #
 621 #  - We generate the dependencies for the CMake fragment, so that we will
 622 #    automatically reconfigure ourselves.
 623
 624 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 625 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 626   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 627 set(LLVMBUILDCMAKEFRAG
 628   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 629
 630 # Create the list of optional components that are enabled
 631 if (LLVM_USE_INTEL_JITEVENTS)
 632   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 633 endif (LLVM_USE_INTEL_JITEVENTS)
 634 if (LLVM_USE_OPROFILE)
 635   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 636 endif (LLVM_USE_OPROFILE)
 637 if (LLVM_USE_PERF)
 638   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} PerfJITEvents)
 639 endif (LLVM_USE_PERF)
 640
 641 message(STATUS "Constructing LLVMBuild project information")
 642 execute_process(
 643   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 644             --native-target "${LLVM_NATIVE_ARCH}"
 645             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 646             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 647             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 648             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 649             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 650             ERROR_VARIABLE LLVMBUILDERRORS
 651             OUTPUT_STRIP_TRAILING_WHITESPACE
 652             ERROR_STRIP_TRAILING_WHITESPACE
 653   RESULT_VARIABLE LLVMBUILDRESULT)
 654
 655 # On Win32, CMake doesn't properly handle piping the default output/error
 656 # streams into the GUI console. So, we explicitly catch and report them.
 657 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 658   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 659 endif()
 660 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 661   message(FATAL_ERROR
 662     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 663 endif()
 664
 665 # Include the generated CMake fragment. This will define properties from the
 666 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 667 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 668 # files change.
 669 include(${LLVMBUILDCMAKEFRAG})
 670
 671 ######
 672
 673 # Configure all of the various header file fragments LLVM uses which depend on
 674 # configuration variables.
 675 set(LLVM_ENUM_TARGETS "")
 676 set(LLVM_ENUM_ASM_PRINTERS "")
 677 set(LLVM_ENUM_ASM_PARSERS "")
 678 set(LLVM_ENUM_DISASSEMBLERS "")
 679 foreach(t ${LLVM_TARGETS_TO_BUILD})
 680   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 681
 682   list(FIND LLVM_ALL_TARGETS ${t} idx)
 683   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 684   # At this point, LLVMBUILDTOOL already checked all the targets passed in
 685   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
 686   # this test just makes sure that any experimental targets were passed via
 687   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 688   if( idx LESS 0 AND idy LESS 0 )
 689     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 690       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 691   else()
 692     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 693   endif()
 694
 695   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 696   if( asmp_file )
 697     set(LLVM_ENUM_ASM_PRINTERS
 698       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 699   endif()
 700   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 701     set(LLVM_ENUM_ASM_PARSERS
 702       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 703   endif()
 704   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 705     set(LLVM_ENUM_DISASSEMBLERS
 706       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 707   endif()
 708 endforeach(t)
 709
 710 # Produce the target definition files, which provide a way for clients to easily
 711 # include various classes of targets.
 712 configure_file(
 713   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 714   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 715   )
 716 configure_file(
 717   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 718   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 719   )
 720 configure_file(
 721   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 722   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 723   )
 724 configure_file(
 725   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 726   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 727   )
 728
 729 # Configure the three LLVM configuration header files.
 730 configure_file(
 731   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 732   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 733 configure_file(
 734   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 735   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 736 configure_file(
 737   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 738   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 739
 740 # Add target for generating source rpm package.
 741 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 742     CACHE FILEPATH ".spec file to use for srpm generation")
 743 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 744 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 745
 746 # SVN_REVISION and GIT_COMMIT get set by the call to add_version_info_from_vcs.
 747 # DUMMY_VAR contains a version string which we don't care about.
 748 add_version_info_from_vcs(DUMMY_VAR)
 749 if ( SVN_REVISION )
 750   set(LLVM_RPM_SPEC_REVISION "r${SVN_REVISION}")
 751 elseif ( GIT_COMMIT )
 752   set (LLVM_RPM_SPEC_REVISION "g${GIT_COMMIT}")
 753 endif()
 754
 755 configure_file(
 756   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 757   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 758
 759 add_custom_target(srpm
 760   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 761   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 762 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 763
 764
 765 # They are not referenced. See set_output_directory().
 766 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 767 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 768 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 769
 770 if(APPLE AND DARWIN_LTO_LIBRARY)
 771   set(CMAKE_EXE_LINKER_FLAGS
 772     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 773   set(CMAKE_SHARED_LINKER_FLAGS
 774     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 775   set(CMAKE_MODULE_LINKER_FLAGS
 776     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 777 endif()
 778
 779 # Work around a broken bfd ld behavior. When linking a binary with a
 780 # foo.so library, it will try to find any library that foo.so uses and
 781 # check its symbols. This is wasteful (the check was done when foo.so
 782 # was created) and can fail since it is not the dynamic linker and
 783 # doesn't know how to handle search paths correctly.
 784 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 785   set(CMAKE_EXE_LINKER_FLAGS
 786       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 787 endif()
 788
 789 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 790
 791 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 792
 793 # when crosscompiling import the executable targets from a file
 794 if(LLVM_USE_HOST_TOOLS)
 795   include(CrossCompile)
 796 endif(LLVM_USE_HOST_TOOLS)
 797 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 798 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 799 # (this is a variable that CrossCompile sets on recursive invocations)
 800 endif()
 801
 802 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 803   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 804   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 805   include_directories(SYSTEM "/usr/local/include")
 806   link_directories("/usr/local/lib")
 807 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 808
 809 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 810    # special hack for Solaris to handle crazy system sys/regset.h
 811    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 812 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 813
 814 # Make sure we don't get -rdynamic in every binary. For those that need it,
 815 # use export_executable_symbols(target).
 816 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 817
 818 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 819   "Profiling data file to use when compiling in order to improve runtime performance.")
 820
 821 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 822   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 823     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 824   else()
 825     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 826   endif()
 827 endif()
 828
 829 include(AddLLVM)
 830 include(TableGen)
 831
 832 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 833   # People report that -O3 is unreliable on MinGW. The traditional
 834   # build also uses -O2 for that reason:
 835   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 836 endif()
 837
 838 # Put this before tblgen. Else we have a circular dependence.
 839 add_subdirectory(lib/Demangle)
 840 add_subdirectory(lib/Support)
 841 add_subdirectory(lib/TableGen)
 842
 843 add_subdirectory(utils/TableGen)
 844
 845 add_subdirectory(include/llvm)
 846
 847 add_subdirectory(lib)
 848
 849 if( LLVM_INCLUDE_UTILS )
 850   add_subdirectory(utils/FileCheck)
 851   add_subdirectory(utils/PerfectShuffle)
 852   add_subdirectory(utils/count)
 853   add_subdirectory(utils/not)
 854   add_subdirectory(utils/yaml-bench)
 855 else()
 856   if ( LLVM_INCLUDE_TESTS )
 857     message(FATAL_ERROR "Including tests when not building utils will not work.
 858     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 859   endif()
 860 endif()
 861
 862 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 863 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 864   add_subdirectory(utils/LLVMVisualizers)
 865 endif()
 866
 867 foreach( binding ${LLVM_BINDINGS_LIST} )
 868   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 869     add_subdirectory(bindings/${binding})
 870   endif()
 871 endforeach()
 872
 873 add_subdirectory(projects)
 874
 875 if( LLVM_INCLUDE_TOOLS )
 876   add_subdirectory(tools)
 877 endif()
 878
 879 if( LLVM_INCLUDE_RUNTIMES )
 880   add_subdirectory(runtimes)
 881 endif()
 882
 883 if( LLVM_INCLUDE_EXAMPLES )
 884   add_subdirectory(examples)
 885 endif()
 886
 887 if( LLVM_INCLUDE_TESTS )
 888   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 889     include(LLVMExternalProjectUtils)
 890     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 891       USE_TOOLCHAIN
 892       EXCLUDE_FROM_ALL
 893       NO_INSTALL
 894       ALWAYS_CLEAN)
 895   endif()
 896   add_subdirectory(utils/lit)
 897   add_subdirectory(test)
 898   add_subdirectory(unittests)
 899   if( LLVM_INCLUDE_UTILS )
 900     add_subdirectory(utils/unittest)
 901   endif()
 902
 903   if (WIN32)
 904     # This utility is used to prevent crashing tests from calling Dr. Watson on
 905     # Windows.
 906     add_subdirectory(utils/KillTheDoctor)
 907   endif()
 908
 909   # Add a global check rule now that all subdirectories have been traversed
 910   # and we know the total set of lit testsuites.
 911   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 912   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 913   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 914   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 915   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 916                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 917   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
 918                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
 919   add_lit_target(check-all
 920     "Running all regression tests"
 921     ${LLVM_LIT_TESTSUITES}
 922     PARAMS ${LLVM_LIT_PARAMS}
 923     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 924     ARGS ${LLVM_LIT_EXTRA_ARGS}
 925     )
 926   if(TARGET check-runtimes)
 927     add_dependencies(check-all check-runtimes)
 928   endif()
 929   add_custom_target(test-depends
 930                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
 931   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
 932 endif()
 933
 934 if (LLVM_INCLUDE_DOCS)
 935   add_subdirectory(docs)
 936 endif()
 937
 938 add_subdirectory(cmake/modules)
 939
 940 # Do this last so that all lit targets have already been created.
 941 if (LLVM_INCLUDE_UTILS)
 942   add_subdirectory(utils/llvm-lit)
 943 endif()
 944
 945 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 946   install(DIRECTORY include/llvm include/llvm-c
 947     DESTINATION include
 948     COMPONENT llvm-headers
 949     FILES_MATCHING
 950     PATTERN "*.def"
 951     PATTERN "*.h"
 952     PATTERN "*.td"
 953     PATTERN "*.inc"
 954     PATTERN "LICENSE.TXT"
 955     PATTERN ".svn" EXCLUDE
 956     )
 957
 958   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
 959     DESTINATION include
 960     COMPONENT llvm-headers
 961     FILES_MATCHING
 962     PATTERN "*.def"
 963     PATTERN "*.h"
 964     PATTERN "*.gen"
 965     PATTERN "*.inc"
 966     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 967     PATTERN "CMakeFiles" EXCLUDE
 968     PATTERN "config.h" EXCLUDE
 969     PATTERN ".svn" EXCLUDE
 970     )
 971
 972   # Installing the headers needs to depend on generating any public
 973   # tablegen'd headers.
 974   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
 975   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
 976
 977   if (NOT CMAKE_CONFIGURATION_TYPES)
 978     add_llvm_install_targets(install-llvm-headers
 979                              DEPENDS llvm-headers
 980                              COMPONENT llvm-headers)
 981   endif()
 982 endif()
 983
 984 # This must be at the end of the LLVM root CMakeLists file because it must run
 985 # after all targets are created.
 986 if(LLVM_DISTRIBUTION_COMPONENTS)
 987   if(CMAKE_CONFIGURATION_TYPES)
 988     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
 989   endif()
 990
 991   add_custom_target(distribution)
 992   add_custom_target(install-distribution)
 993   add_custom_target(install-distribution-stripped)
 994   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS} ${LLVM_RUNTIME_DISTRIBUTION_COMPONENTS})
 995     if(TARGET ${target})
 996       add_dependencies(distribution ${target})
 997     else()
 998       message(SEND_ERROR "Specified distribution component '${target}' doesn't have a target")
 999     endif()
1000
1001     if(TARGET install-${target})
1002       add_dependencies(install-distribution install-${target})
1003     else()
1004       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install target")
1005     endif()
1006
1007     if(TARGET install-${target}-stripped)
1008       add_dependencies(install-distribution-stripped install-${target}-stripped)
1009     else()
1010       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install-stripped target."
1011                          " Its installation target creation should be changed to use add_llvm_install_targets,"
1012                          " or you should manually create the 'install-${target}-stripped' target.")
1013     endif()
1014   endforeach()
1015 endif()
1016
1017 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1018 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" AND CMAKE_INSTALL_UCRT_LIBRARIES)
1019   include(InstallRequiredSystemLibraries)
1020 endif()