cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 # This is commonly needed so make sure it's defined before we include anything
   6 # else.
   7 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
   8
   9 include(CheckCompilerVersion)
  10 include(HandleLLVMStdlib)
  11 include(CheckCCompilerFlag)
  12 include(CheckCXXCompilerFlag)
  13
  14 if(CMAKE_LINKER MATCHES "lld-link.exe" OR (WIN32 AND LLVM_USE_LINKER STREQUAL "lld"))
  15   set(LINKER_IS_LLD_LINK TRUE)
  16 else()
  17   set(LINKER_IS_LLD_LINK FALSE)
  18 endif()
  19
  20 set(LLVM_ENABLE_LTO OFF CACHE STRING "Build LLVM with LTO. May be specified as Thin or Full to use a particular kind of LTO")
  21 string(TOUPPER "${LLVM_ENABLE_LTO}" uppercase_LLVM_ENABLE_LTO)
  22
  23 # Ninja Job Pool support
  24 # The following only works with the Ninja generator in CMake >= 3.0.
  25 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  26   "Define the maximum number of concurrent compilation jobs.")
  27 if(LLVM_PARALLEL_COMPILE_JOBS)
  28   if(NOT CMAKE_MAKE_PROGRAM MATCHES "ninja")
  29     message(WARNING "Job pooling is only available with Ninja generators.")
  30   else()
  31     set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  32     set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  33   endif()
  34 endif()
  35
  36 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  37   "Define the maximum number of concurrent link jobs.")
  38 if(CMAKE_MAKE_PROGRAM MATCHES "ninja")
  39   if(NOT LLVM_PARALLEL_LINK_JOBS AND uppercase_LLVM_ENABLE_LTO STREQUAL "THIN")
  40     message(STATUS "ThinLTO provides its own parallel linking - limiting parallel link jobs to 2.")
  41     set(LLVM_PARALLEL_LINK_JOBS "2")
  42   endif()
  43   if(LLVM_PARALLEL_LINK_JOBS)
  44     set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  45     set(CMAKE_JOB_POOL_LINK link_job_pool)
  46   endif()
  47 elseif(LLVM_PARALLEL_LINK_JOBS)
  48   message(WARNING "Job pooling is only available with Ninja generators.")
  49 endif()
  50
  51 if (LINKER_IS_LLD_LINK)
  52   # Pass /MANIFEST:NO so that CMake doesn't run mt.exe on our binaries.  Adding
  53   # manifests with mt.exe breaks LLD's symbol tables and takes as much time as
  54   # the link. See PR24476.
  55   append("/MANIFEST:NO"
  56     CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
  57 endif()
  58
  59 if( LLVM_ENABLE_ASSERTIONS )
  60   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  61   if( NOT MSVC )
  62     add_definitions( -D_DEBUG )
  63   endif()
  64   # On non-Debug builds cmake automatically defines NDEBUG, so we
  65   # explicitly undefine it:
  66   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  67     add_definitions( -UNDEBUG )
  68     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  69     foreach (flags_var_to_scrub
  70         CMAKE_CXX_FLAGS_RELEASE
  71         CMAKE_CXX_FLAGS_RELWITHDEBINFO
  72         CMAKE_CXX_FLAGS_MINSIZEREL
  73         CMAKE_C_FLAGS_RELEASE
  74         CMAKE_C_FLAGS_RELWITHDEBINFO
  75         CMAKE_C_FLAGS_MINSIZEREL)
  76       string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
  77         "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
  78     endforeach()
  79   endif()
  80 endif()
  81
  82 if(LLVM_ENABLE_EXPENSIVE_CHECKS)
  83   add_definitions(-DEXPENSIVE_CHECKS)
  84   add_definitions(-D_GLIBCXX_DEBUG)
  85 endif()
  86
  87 string(TOUPPER "${LLVM_ABI_BREAKING_CHECKS}" uppercase_LLVM_ABI_BREAKING_CHECKS)
  88
  89 if( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "WITH_ASSERTS" )
  90   if( LLVM_ENABLE_ASSERTIONS )
  91     set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  92   endif()
  93 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_ON" )
  94   set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  95 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_OFF" )
  96   # We don't need to do anything special to turn off ABI breaking checks.
  97 elseif( NOT DEFINED LLVM_ABI_BREAKING_CHECKS )
  98   # Treat LLVM_ABI_BREAKING_CHECKS like "FORCE_OFF" when it has not been
  99   # defined.
 100 else()
 101   message(FATAL_ERROR "Unknown value for LLVM_ABI_BREAKING_CHECKS: \"${LLVM_ABI_BREAKING_CHECKS}\"!")
 102 endif()
 103
 104 if( LLVM_REVERSE_ITERATION )
 105   set( LLVM_ENABLE_REVERSE_ITERATION 1 )
 106 endif()
 107
 108 if(WIN32)
 109   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
 110   if(CYGWIN)
 111     set(LLVM_ON_WIN32 0)
 112     set(LLVM_ON_UNIX 1)
 113   else(CYGWIN)
 114     set(LLVM_ON_WIN32 1)
 115     set(LLVM_ON_UNIX 0)
 116   endif(CYGWIN)
 117 else(WIN32)
 118   if(UNIX)
 119     set(LLVM_ON_WIN32 0)
 120     set(LLVM_ON_UNIX 1)
 121     if(APPLE OR ${CMAKE_SYSTEM_NAME} MATCHES "AIX")
 122       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
 123     else()
 124       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
 125     endif()
 126   else(UNIX)
 127     MESSAGE(SEND_ERROR "Unable to determine platform")
 128   endif(UNIX)
 129 endif(WIN32)
 130
 131 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
 132 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 133
 134 # We use *.dylib rather than *.so on darwin.
 135 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 136
 137 if(APPLE)
 138   if(LLVM_ENABLE_LLD AND LLVM_ENABLE_LTO)
 139     message(FATAL_ERROR "lld does not support LTO on Darwin")
 140   endif()
 141   # Darwin-specific linker flags for loadable modules.
 142   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 143 endif()
 144
 145 # Pass -Wl,-z,defs. This makes sure all symbols are defined. Otherwise a DSO
 146 # build might work on ELF but fail on MachO/COFF.
 147 if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32 OR CYGWIN OR
 148         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD" OR
 149         ${CMAKE_SYSTEM_NAME} MATCHES "OpenBSD") AND
 150    NOT LLVM_USE_SANITIZER)
 151   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,defs")
 152 endif()
 153
 154
 155 function(append value)
 156   foreach(variable ${ARGN})
 157     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 158   endforeach(variable)
 159 endfunction()
 160
 161 function(append_if condition value)
 162   if (${condition})
 163     foreach(variable ${ARGN})
 164       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 165     endforeach(variable)
 166   endif()
 167 endfunction()
 168
 169 macro(add_flag_if_supported flag name)
 170   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 171   append_if("C_SUPPORTS_${name}" "${flag}" CMAKE_C_FLAGS)
 172   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 173   append_if("CXX_SUPPORTS_${name}" "${flag}" CMAKE_CXX_FLAGS)
 174 endmacro()
 175
 176 function(add_flag_or_print_warning flag name)
 177   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 178   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 179   if (C_SUPPORTS_${name} AND CXX_SUPPORTS_${name})
 180     message(STATUS "Building with ${flag}")
 181     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
 182     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
 183     set(CMAKE_ASM_FLAGS "${CMAKE_ASM_FLAGS} ${flag}" PARENT_SCOPE)
 184   else()
 185     message(WARNING "${flag} is not supported.")
 186   endif()
 187 endfunction()
 188
 189 if( LLVM_ENABLE_LLD )
 190         if ( LLVM_USE_LINKER )
 191                 message(FATAL_ERROR "LLVM_ENABLE_LLD and LLVM_USE_LINKER can't be set at the same time")
 192         endif()
 193         set(LLVM_USE_LINKER "lld")
 194 endif()
 195
 196 if( LLVM_USE_LINKER )
 197   check_cxx_compiler_flag("-fuse-ld=${LLVM_USE_LINKER}" CXX_SUPPORTS_CUSTOM_LINKER)
 198   if ( NOT CXX_SUPPORTS_CUSTOM_LINKER )
 199           message(FATAL_ERROR "Host compiler does not support '-fuse-ld=${LLVM_USE_LINKER}'")
 200   endif()
 201   append("-fuse-ld=${LLVM_USE_LINKER}"
 202     CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 203 endif()
 204
 205 if( LLVM_ENABLE_PIC )
 206   if( XCODE )
 207     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
 208     # know how to disable this, so just force ENABLE_PIC off for now.
 209     message(WARNING "-fPIC not supported with Xcode.")
 210   elseif( WIN32 OR CYGWIN)
 211     # On Windows all code is PIC. MinGW warns if -fPIC is used.
 212   else()
 213     add_flag_or_print_warning("-fPIC" FPIC)
 214   endif()
 215 endif()
 216
 217 if(NOT WIN32 AND NOT CYGWIN)
 218   # MinGW warns if -fvisibility-inlines-hidden is used.
 219   check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 220   append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 221 endif()
 222
 223 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 224   # TODO: support other platforms and toolchains.
 225   if( LLVM_BUILD_32_BITS )
 226     message(STATUS "Building 32 bits executables and libraries.")
 227     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m32")
 228     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -m32")
 229     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 230     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 231     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 232   endif( LLVM_BUILD_32_BITS )
 233 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 234
 235 # If building on a GNU specific 32-bit system, make sure off_t is 64 bits
 236 # so that off_t can stored offset > 2GB.
 237 # Android until version N (API 24) doesn't support it.
 238 if (ANDROID AND (ANDROID_NATIVE_API_LEVEL LESS 24))
 239   set(LLVM_FORCE_SMALLFILE_FOR_ANDROID TRUE)
 240 endif()
 241 if( CMAKE_SIZEOF_VOID_P EQUAL 4 AND NOT LLVM_FORCE_SMALLFILE_FOR_ANDROID)
 242   add_definitions( -D_LARGEFILE_SOURCE )
 243   add_definitions( -D_FILE_OFFSET_BITS=64 )
 244 endif()
 245
 246 if( XCODE )
 247   # For Xcode enable several build settings that correspond to
 248   # many warnings that are on by default in Clang but are
 249   # not enabled for historical reasons.  For versions of Xcode
 250   # that do not support these options they will simply
 251   # be ignored.
 252   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_RETURN_TYPE "YES")
 253   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_MISSING_NEWLINE "YES")
 254   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VALUE "YES")
 255   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VARIABLE "YES")
 256   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_SIGN_COMPARE "YES")
 257   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_FUNCTION "YES")
 258   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_INITIALIZER_NOT_FULLY_BRACKETED "YES")
 259   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_HIDDEN_VIRTUAL_FUNCTIONS "YES")
 260   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNINITIALIZED_AUTOS "YES")
 261   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_BOOL_CONVERSION "YES")
 262   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_EMPTY_BODY "YES")
 263   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_ENUM_CONVERSION "YES")
 264   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_INT_CONVERSION "YES")
 265   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_CONSTANT_CONVERSION "YES")
 266   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_NON_VIRTUAL_DESTRUCTOR "YES")
 267 endif()
 268
 269 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 270 # to use.
 271 if( MSVC_IDE )
 272   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 273     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 274   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 275     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 276       add_definitions( /MP )
 277     else()
 278       message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 279       add_definitions( /MP${LLVM_COMPILER_JOBS} )
 280     endif()
 281   else()
 282     message(STATUS "Parallel compilation disabled")
 283   endif()
 284 endif()
 285
 286 # set stack reserved size to ~10MB
 287 if(MSVC)
 288   # CMake previously automatically set this value for MSVC builds, but the
 289   # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
 290   # value (1 MB) which is not enough for us in tasks such as parsing recursive
 291   # C++ templates in Clang.
 292   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
 293 elseif(MINGW) # FIXME: Also cygwin?
 294   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--stack,16777216")
 295
 296   # Pass -mbig-obj to mingw gas on Win64. COFF has a 2**16 section limit, and
 297   # on Win64, every COMDAT function creates at least 3 sections: .text, .pdata,
 298   # and .xdata.
 299   if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 300     append("-Wa,-mbig-obj" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 301   endif()
 302 endif()
 303
 304 if( MSVC )
 305   if( CMAKE_CXX_COMPILER_VERSION VERSION_LESS 19.0 )
 306     # For MSVC 2013, disable iterator null pointer checking in debug mode,
 307     # especially so std::equal(nullptr, nullptr, nullptr) will not assert.
 308     add_definitions("-D_DEBUG_POINTER_IMPL=")
 309   endif()
 310
 311   include(ChooseMSVCCRT)
 312
 313   if( MSVC11 )
 314     add_definitions(-D_VARIADIC_MAX=10)
 315   endif()
 316
 317   # Add definitions that make MSVC much less annoying.
 318   add_definitions(
 319     # For some reason MS wants to deprecate a bunch of standard functions...
 320     -D_CRT_SECURE_NO_DEPRECATE
 321     -D_CRT_SECURE_NO_WARNINGS
 322     -D_CRT_NONSTDC_NO_DEPRECATE
 323     -D_CRT_NONSTDC_NO_WARNINGS
 324     -D_SCL_SECURE_NO_DEPRECATE
 325     -D_SCL_SECURE_NO_WARNINGS
 326     )
 327
 328   # Tell MSVC to use the Unicode version of the Win32 APIs instead of ANSI.
 329   add_definitions(
 330     -DUNICODE
 331     -D_UNICODE
 332   )
 333
 334   if (LLVM_ENABLE_WERROR)
 335     append("/WX" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 336   endif (LLVM_ENABLE_WERROR)
 337
 338   append("/Zc:inline" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 339
 340   # /Zc:strictStrings is incompatible with VS12's (Visual Studio 2013's)
 341   # debug mode headers. Instead of only enabling them in VS2013's debug mode,
 342   # we'll just enable them for Visual Studio 2015 (VS 14, MSVC_VERSION 1900)
 343   # and up.
 344   if (NOT (MSVC_VERSION LESS 1900))
 345     # Disable string literal const->non-const type conversion.
 346     # "When specified, the compiler requires strict const-qualification
 347     # conformance for pointers initialized by using string literals."
 348     append("/Zc:strictStrings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 349   endif(NOT (MSVC_VERSION LESS 1900))
 350
 351   # "Generate Intrinsic Functions".
 352   append("/Oi" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 353
 354   # "Enforce type conversion rules".
 355   append("/Zc:rvalueCast" CMAKE_CXX_FLAGS)
 356
 357   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND NOT LLVM_ENABLE_LTO)
 358     # clang-cl and cl by default produce non-deterministic binaries because
 359     # link.exe /incremental requires a timestamp in the .obj file.  clang-cl
 360     # has the flag /Brepro to force deterministic binaries. We want to pass that
 361     # whenever you're building with clang unless you're passing /incremental
 362     # or using LTO (/Brepro with LTO would result in a warning about the flag
 363     # being unused, because we're not generating object files).
 364     # This checks CMAKE_CXX_COMPILER_ID in addition to check_cxx_compiler_flag()
 365     # because cl.exe does not emit an error on flags it doesn't understand,
 366     # letting check_cxx_compiler_flag() claim it understands all flags.
 367     check_cxx_compiler_flag("/Brepro" SUPPORTS_BREPRO)
 368     if (SUPPORTS_BREPRO)
 369       # Check if /INCREMENTAL is passed to the linker and complain that it
 370       # won't work with /Brepro.
 371       string(TOUPPER "${CMAKE_EXE_LINKER_FLAGS}" upper_exe_flags)
 372       string(TOUPPER "${CMAKE_MODULE_LINKER_FLAGS}" upper_module_flags)
 373       string(TOUPPER "${CMAKE_SHARED_LINKER_FLAGS}" upper_shared_flags)
 374
 375       string(FIND "${upper_exe_flags} ${upper_module_flags} ${upper_shared_flags}"
 376         "/INCREMENTAL" linker_flag_idx)
 377
 378       if (${linker_flag_idx} GREATER -1)
 379         message(WARNING "/Brepro not compatible with /INCREMENTAL linking - builds will be non-deterministic")
 380       else()
 381         append("/Brepro" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 382       endif()
 383     endif()
 384   endif()
 385
 386 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 387   append_if(LLVM_ENABLE_WERROR "-Werror" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 388   append_if(LLVM_ENABLE_WERROR "-Wno-error" CMAKE_REQUIRED_FLAGS)
 389   add_flag_if_supported("-Werror=date-time" WERROR_DATE_TIME)
 390   add_flag_if_supported("-Werror=unguarded-availability-new" WERROR_UNGUARDED_AVAILABILITY_NEW)
 391   if (LLVM_ENABLE_CXX1Y)
 392     check_cxx_compiler_flag("-std=c++1y" CXX_SUPPORTS_CXX1Y)
 393     append_if(CXX_SUPPORTS_CXX1Y "-std=c++1y" CMAKE_CXX_FLAGS)
 394   elseif(LLVM_ENABLE_CXX1Z)
 395     check_cxx_compiler_flag("-std=c++1z" CXX_SUPPORTS_CXX1Z)
 396     append_if(CXX_SUPPORTS_CXX1Z "-std=c++1z" CMAKE_CXX_FLAGS)
 397   else()
 398     check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
 399     if (CXX_SUPPORTS_CXX11)
 400       if (CYGWIN OR MINGW)
 401         # MinGW and Cygwin are a bit stricter and lack things like
 402         # 'strdup', 'stricmp', etc in c++11 mode.
 403         append("-std=gnu++11" CMAKE_CXX_FLAGS)
 404       else()
 405         append("-std=c++11" CMAKE_CXX_FLAGS)
 406       endif()
 407     else()
 408       message(FATAL_ERROR "LLVM requires C++11 support but the '-std=c++11' flag isn't supported.")
 409     endif()
 410   endif()
 411   if (LLVM_ENABLE_MODULES)
 412     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 413     set(module_flags "-fmodules -fmodules-cache-path=${PROJECT_BINARY_DIR}/module.cache")
 414     if (${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 415       # On Darwin -fmodules does not imply -fcxx-modules.
 416       set(module_flags "${module_flags} -fcxx-modules")
 417     endif()
 418     if (LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY)
 419       set(module_flags "${module_flags} -Xclang -fmodules-local-submodule-visibility")
 420     endif()
 421     if (LLVM_ENABLE_MODULE_DEBUGGING AND
 422         ((uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG") OR
 423          (uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")))
 424       set(module_flags "${module_flags} -gmodules")
 425     endif()
 426     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${module_flags}")
 427
 428     # Check that we can build code with modules enabled, and that repeatedly
 429     # including <cassert> still manages to respect NDEBUG properly.
 430     CHECK_CXX_SOURCE_COMPILES("#undef NDEBUG
 431                                #include <cassert>
 432                                #define NDEBUG
 433                                #include <cassert>
 434                                int main() { assert(this code is not compiled); }"
 435                                CXX_SUPPORTS_MODULES)
 436     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 437     if (CXX_SUPPORTS_MODULES)
 438       append("${module_flags}" CMAKE_CXX_FLAGS)
 439     else()
 440       message(FATAL_ERROR "LLVM_ENABLE_MODULES is not supported by this compiler")
 441     endif()
 442   endif(LLVM_ENABLE_MODULES)
 443 endif( MSVC )
 444
 445 if (MSVC AND NOT CLANG_CL)
 446   set(msvc_warning_flags
 447     # Disabled warnings.
 448     -wd4141 # Suppress ''modifier' : used more than once' (because of __forceinline combined with inline)
 449     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 450     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 451     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 452     -wd4258 # Suppress ''var' : definition from the for loop is ignored; the definition from the enclosing scope is used'
 453     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 454     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 455     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 456     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 457     -wd4355 # Suppress ''this' : used in base member initializer list'
 458     -wd4456 # Suppress 'declaration of 'var' hides local variable'
 459     -wd4457 # Suppress 'declaration of 'var' hides function parameter'
 460     -wd4458 # Suppress 'declaration of 'var' hides class member'
 461     -wd4459 # Suppress 'declaration of 'var' hides global declaration'
 462     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 463     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 464     -wd4722 # Suppress 'function' : destructor never returns, potential memory leak
 465     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 466     -wd4100 # Suppress 'unreferenced formal parameter'
 467     -wd4127 # Suppress 'conditional expression is constant'
 468     -wd4512 # Suppress 'assignment operator could not be generated'
 469     -wd4505 # Suppress 'unreferenced local function has been removed'
 470     -wd4610 # Suppress '<class> can never be instantiated'
 471     -wd4510 # Suppress 'default constructor could not be generated'
 472     -wd4702 # Suppress 'unreachable code'
 473     -wd4245 # Suppress 'signed/unsigned mismatch'
 474     -wd4706 # Suppress 'assignment within conditional expression'
 475     -wd4310 # Suppress 'cast truncates constant value'
 476     -wd4701 # Suppress 'potentially uninitialized local variable'
 477     -wd4703 # Suppress 'potentially uninitialized local pointer variable'
 478     -wd4389 # Suppress 'signed/unsigned mismatch'
 479     -wd4611 # Suppress 'interaction between '_setjmp' and C++ object destruction is non-portable'
 480     -wd4805 # Suppress 'unsafe mix of type <type> and type <type> in operation'
 481     -wd4204 # Suppress 'nonstandard extension used : non-constant aggregate initializer'
 482     -wd4577 # Suppress 'noexcept used with no exception handling mode specified; termination on exception is not guaranteed'
 483     -wd4091 # Suppress 'typedef: ignored on left of '' when no variable is declared'
 484         # C4592 is disabled because of false positives in Visual Studio 2015
 485         # Update 1. Re-evaluate the usefulness of this diagnostic with Update 2.
 486     -wd4592 # Suppress ''var': symbol will be dynamically initialized (implementation limitation)
 487     -wd4319 # Suppress ''operator' : zero extending 'type' to 'type' of greater size'
 488
 489     # Ideally, we'd like this warning to be enabled, but MSVC 2013 doesn't
 490     # support the 'aligned' attribute in the way that clang sources requires (for
 491     # any code that uses the LLVM_ALIGNAS macro), so this is must be disabled to
 492     # avoid unwanted alignment warnings.
 493     # When we switch to requiring a version of MSVC that supports the 'alignas'
 494     # specifier (MSVC 2015?) this warning can be re-enabled.
 495     -wd4324 # Suppress 'structure was padded due to __declspec(align())'
 496
 497     # Promoted warnings.
 498     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 499
 500     # Promoted warnings to errors.
 501     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 502     )
 503
 504   # Enable warnings
 505   if (LLVM_ENABLE_WARNINGS)
 506     # Put /W4 in front of all the -we flags. cl.exe doesn't care, but for
 507     # clang-cl having /W4 after the -we flags will re-enable the warnings
 508     # disabled by -we.
 509     set(msvc_warning_flags "/W4 ${msvc_warning_flags}")
 510     # CMake appends /W3 by default, and having /W3 followed by /W4 will result in
 511     # cl : Command line warning D9025 : overriding '/W3' with '/W4'.  Since this is
 512     # a command line warning and not a compiler warning, it cannot be suppressed except
 513     # by fixing the command line.
 514     string(REGEX REPLACE " /W[0-4]" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 515     string(REGEX REPLACE " /W[0-4]" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 516
 517     if (LLVM_ENABLE_PEDANTIC)
 518       # No MSVC equivalent available
 519     endif (LLVM_ENABLE_PEDANTIC)
 520   endif (LLVM_ENABLE_WARNINGS)
 521
 522   foreach(flag ${msvc_warning_flags})
 523     append("${flag}" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 524   endforeach(flag)
 525 endif (MSVC AND NOT CLANG_CL)
 526
 527 if (LLVM_ENABLE_WARNINGS AND (LLVM_COMPILER_IS_GCC_COMPATIBLE OR CLANG_CL))
 528   append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 529   append("-Wcast-qual" CMAKE_CXX_FLAGS)
 530
 531   # Turn off missing field initializer warnings for gcc to avoid noise from
 532   # false positives with empty {}. Turn them on otherwise (they're off by
 533   # default for clang).
 534   check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 535   if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 536     if (CMAKE_COMPILER_IS_GNUCXX)
 537       append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 538     else()
 539       append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 540     endif()
 541   endif()
 542
 543   if (LLVM_ENABLE_PEDANTIC AND LLVM_COMPILER_IS_GCC_COMPATIBLE)
 544     append("-pedantic" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 545     append("-Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 546   endif()
 547
 548   add_flag_if_supported("-Wcovered-switch-default" COVERED_SWITCH_DEFAULT_FLAG)
 549   append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 550   append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 551
 552   # Check if -Wnon-virtual-dtor warns even though the class is marked final.
 553   # If it does, don't add it. So it won't be added on clang 3.4 and older.
 554   # This also catches cases when -Wnon-virtual-dtor isn't supported by
 555   # the compiler at all.  This flag is not activated for gcc since it will
 556   # incorrectly identify a protected non-virtual base when there is a friend
 557   # declaration. Don't activate this in general on Windows as this warning has
 558   # too many false positives on COM-style classes, which are destroyed with
 559   # Release() (PR32286).
 560   if (NOT CMAKE_COMPILER_IS_GNUCXX AND NOT WIN32)
 561     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 562     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++11 -Werror=non-virtual-dtor")
 563     CHECK_CXX_SOURCE_COMPILES("class base {public: virtual void anchor();protected: ~base();};
 564                                class derived final : public base { public: ~derived();};
 565                                int main() { return 0; }"
 566                               CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR)
 567     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 568     append_if(CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR
 569               "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 570   endif()
 571
 572   # Enable -Wdelete-non-virtual-dtor if available.
 573   add_flag_if_supported("-Wdelete-non-virtual-dtor" DELETE_NON_VIRTUAL_DTOR_FLAG)
 574
 575   # Check if -Wcomment is OK with an // comment ending with '\' if the next
 576   # line is also a // comment.
 577   set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 578   set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror -Wcomment")
 579   CHECK_C_SOURCE_COMPILES("// \\\\\\n//\\nint main() {return 0;}"
 580                           C_WCOMMENT_ALLOWS_LINE_WRAP)
 581   set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 582   if (NOT C_WCOMMENT_ALLOWS_LINE_WRAP)
 583     append("-Wno-comment" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 584   endif()
 585
 586   # Enable -Wstring-conversion to catch misuse of string literals.
 587   add_flag_if_supported("-Wstring-conversion" STRING_CONVERSION_FLAG)
 588 endif (LLVM_ENABLE_WARNINGS AND (LLVM_COMPILER_IS_GCC_COMPATIBLE OR CLANG_CL))
 589
 590 if (LLVM_COMPILER_IS_GCC_COMPATIBLE AND NOT LLVM_ENABLE_WARNINGS)
 591   append("-w" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 592 endif()
 593
 594 macro(append_common_sanitizer_flags)
 595   if (NOT MSVC)
 596     # Append -fno-omit-frame-pointer and turn on debug info to get better
 597     # stack traces.
 598     add_flag_if_supported("-fno-omit-frame-pointer" FNO_OMIT_FRAME_POINTER)
 599     if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 600         NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 601       add_flag_if_supported("-gline-tables-only" GLINE_TABLES_ONLY)
 602     endif()
 603     # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
 604     if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 605       add_flag_if_supported("-O1" O1)
 606     endif()
 607   elseif (CLANG_CL)
 608     # Keep frame pointers around.
 609     append("/Oy-" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 610     if (LINKER_IS_LLD_LINK)
 611       # Use DWARF debug info with LLD.
 612       append("-gdwarf" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 613     else()
 614       # Enable codeview otherwise.
 615       append("/Z7" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 616     endif()
 617     # Always ask the linker to produce symbols with asan.
 618     append("-debug" CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 619   endif()
 620 endmacro()
 621
 622 # Turn on sanitizers if necessary.
 623 if(LLVM_USE_SANITIZER)
 624   if (LLVM_ON_UNIX)
 625     if (LLVM_USE_SANITIZER STREQUAL "Address")
 626       append_common_sanitizer_flags()
 627       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 628     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 629       append_common_sanitizer_flags()
 630       append("-fsanitize=memory" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 631       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 632         append("-fsanitize-memory-track-origins" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 633       endif()
 634     elseif (LLVM_USE_SANITIZER STREQUAL "Undefined")
 635       append_common_sanitizer_flags()
 636       append("-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 637               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 638       set(BLACKLIST_FILE "${CMAKE_SOURCE_DIR}/utils/sanitizers/ubsan_blacklist.txt")
 639       if (EXISTS "${BLACKLIST_FILE}")
 640         append("-fsanitize-blacklist=${BLACKLIST_FILE}"
 641                       CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 642       endif()
 643     elseif (LLVM_USE_SANITIZER STREQUAL "Thread")
 644       append_common_sanitizer_flags()
 645       append("-fsanitize=thread" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 646     elseif (LLVM_USE_SANITIZER STREQUAL "Address;Undefined" OR
 647             LLVM_USE_SANITIZER STREQUAL "Undefined;Address")
 648       append_common_sanitizer_flags()
 649       append("-fsanitize=address,undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 650               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 651     elseif (LLVM_USE_SANITIZER STREQUAL "Leaks")
 652       append_common_sanitizer_flags()
 653       append("-fsanitize=leak" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 654     else()
 655       message(FATAL_ERROR "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 656     endif()
 657   elseif(MSVC)
 658     if (LLVM_USE_SANITIZER STREQUAL "Address")
 659       append_common_sanitizer_flags()
 660       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 661     else()
 662       message(FATAL_ERROR "This sanitizer not yet supported in the MSVC environment: ${LLVM_USE_SANITIZER}")
 663     endif()
 664   else()
 665     message(FATAL_ERROR "LLVM_USE_SANITIZER is not supported on this platform.")
 666   endif()
 667   if (LLVM_USE_SANITIZER MATCHES "(Undefined;)?Address(;Undefined)?")
 668     add_flag_if_supported("-fsanitize-address-use-after-scope"
 669                           FSANITIZE_USE_AFTER_SCOPE_FLAG)
 670   endif()
 671   if (LLVM_USE_SANITIZE_COVERAGE)
 672     append("-fsanitize=fuzzer-no-link" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 673   endif()
 674 endif()
 675
 676 # Turn on -gsplit-dwarf if requested
 677 if(LLVM_USE_SPLIT_DWARF)
 678   add_definitions("-gsplit-dwarf")
 679 endif()
 680
 681 add_definitions( -D__STDC_CONSTANT_MACROS )
 682 add_definitions( -D__STDC_FORMAT_MACROS )
 683 add_definitions( -D__STDC_LIMIT_MACROS )
 684
 685 # clang doesn't print colored diagnostics when invoked from Ninja
 686 if (UNIX AND
 687     CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND
 688     CMAKE_GENERATOR STREQUAL "Ninja")
 689   append("-fcolor-diagnostics" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 690 endif()
 691
 692 # lld doesn't print colored diagnostics when invoked from Ninja
 693 if (UNIX AND CMAKE_GENERATOR STREQUAL "Ninja")
 694   include(CheckLinkerFlag)
 695   check_linker_flag("-Wl,--color-diagnostics" LINKER_SUPPORTS_COLOR_DIAGNOSTICS)
 696   append_if(LINKER_SUPPORTS_COLOR_DIAGNOSTICS "-Wl,--color-diagnostics"
 697     CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 698 endif()
 699
 700 # Add flags for add_dead_strip().
 701 # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
 702 # But MinSizeRel seems to add that automatically, so maybe disable these
 703 # flags instead if LLVM_NO_DEAD_STRIP is set.
 704 if(NOT CYGWIN AND NOT WIN32)
 705   if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin" AND
 706      NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 707     check_c_compiler_flag("-Werror -fno-function-sections" C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 708     if (C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 709       # Don't add -ffunction-section if it can be disabled with -fno-function-sections.
 710       # Doing so will break sanitizers.
 711       add_flag_if_supported("-ffunction-sections" FFUNCTION_SECTIONS)
 712     endif()
 713     add_flag_if_supported("-fdata-sections" FDATA_SECTIONS)
 714   endif()
 715 endif()
 716
 717 if(MSVC)
 718   # Remove flags here, for exceptions and RTTI.
 719   # Each target property or source property should be responsible to control
 720   # them.
 721   # CL.EXE complains to override flags like "/GR /GR-".
 722   string(REGEX REPLACE "(^| ) */EH[-cs]+ *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 723   string(REGEX REPLACE "(^| ) */GR-? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 724 endif()
 725
 726 # Provide public options to globally control RTTI and EH
 727 option(LLVM_ENABLE_EH "Enable Exception handling" OFF)
 728 option(LLVM_ENABLE_RTTI "Enable run time type information" OFF)
 729 if(LLVM_ENABLE_EH AND NOT LLVM_ENABLE_RTTI)
 730   message(FATAL_ERROR "Exception handling requires RTTI. You must set LLVM_ENABLE_RTTI to ON")
 731 endif()
 732
 733 option(LLVM_ENABLE_IR_PGO "Build LLVM and tools with IR PGO instrumentation (experimental)" Off)
 734 mark_as_advanced(LLVM_ENABLE_IR_PGO)
 735
 736 option(LLVM_BUILD_INSTRUMENTED "Build LLVM and tools with PGO instrumentation" Off)
 737 mark_as_advanced(LLVM_BUILD_INSTRUMENTED)
 738
 739 if (LLVM_BUILD_INSTRUMENTED)
 740   if (LLVM_ENABLE_IR_PGO)
 741     append("-fprofile-generate='${LLVM_PROFILE_DATA_DIR}'"
 742       CMAKE_CXX_FLAGS
 743       CMAKE_C_FLAGS
 744       CMAKE_EXE_LINKER_FLAGS
 745       CMAKE_SHARED_LINKER_FLAGS)
 746   else()
 747     append("-fprofile-instr-generate='${LLVM_PROFILE_FILE_PATTERN}'"
 748       CMAKE_CXX_FLAGS
 749       CMAKE_C_FLAGS
 750       CMAKE_EXE_LINKER_FLAGS
 751       CMAKE_SHARED_LINKER_FLAGS)
 752   endif()
 753 endif()
 754
 755 option(LLVM_BUILD_INSTRUMENTED_COVERAGE "Build LLVM and tools with Code Coverage instrumentation" Off)
 756 mark_as_advanced(LLVM_BUILD_INSTRUMENTED_COVERAGE)
 757 append_if(LLVM_BUILD_INSTRUMENTED_COVERAGE "-fprofile-instr-generate='${LLVM_PROFILE_FILE_PATTERN}' -fcoverage-mapping"
 758   CMAKE_CXX_FLAGS
 759   CMAKE_C_FLAGS
 760   CMAKE_EXE_LINKER_FLAGS
 761   CMAKE_SHARED_LINKER_FLAGS)
 762
 763 if(LLVM_ENABLE_LTO AND LLVM_ON_WIN32 AND NOT LINKER_IS_LLD_LINK)
 764   message(FATAL_ERROR "When compiling for Windows, LLVM_ENABLE_LTO requires using lld as the linker (point CMAKE_LINKER at lld-link.exe)")
 765 endif()
 766 if(uppercase_LLVM_ENABLE_LTO STREQUAL "THIN")
 767   append("-flto=thin" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 768   if(NOT LINKER_IS_LLD_LINK)
 769     append("-flto=thin" CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 770   endif()
 771   # If the linker supports it, enable the lto cache. This improves initial build
 772   # time a little since we re-link a lot of the same objects, and significantly
 773   # improves incremental build time.
 774   # FIXME: We should move all this logic into the clang driver.
 775   if(APPLE)
 776     append("-Wl,-cache_path_lto,${PROJECT_BINARY_DIR}/lto.cache"
 777            CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 778   elseif(UNIX AND LLVM_USE_LINKER STREQUAL "lld")
 779     append("-Wl,--thinlto-cache-dir=${PROJECT_BINARY_DIR}/lto.cache"
 780            CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 781   elseif(LLVM_USE_LINKER STREQUAL "gold")
 782     append("-Wl,--plugin-opt,cache-dir=${PROJECT_BINARY_DIR}/lto.cache"
 783            CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 784   endif()
 785 elseif(uppercase_LLVM_ENABLE_LTO STREQUAL "FULL")
 786   append("-flto=full" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 787   if(NOT LINKER_IS_LLD_LINK)
 788     append("-flto=full" CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 789   endif()
 790 elseif(LLVM_ENABLE_LTO)
 791   append("-flto" CMAKE_CXX_FLAGS CMAKE_C_FLAGS)
 792   if(NOT LINKER_IS_LLD_LINK)
 793     append("-flto" CMAKE_EXE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
 794   endif()
 795 endif()
 796
 797 # This option makes utils/extract_symbols.py be used to determine the list of
 798 # symbols to export from LLVM tools. This is necessary when using MSVC if you
 799 # want to allow plugins, though note that the plugin has to explicitly link
 800 # against (exactly one) tool so we can't unilaterally turn on
 801 # LLVM_ENABLE_PLUGINS when it's enabled.
 802 option(LLVM_EXPORT_SYMBOLS_FOR_PLUGINS "Export symbols from LLVM tools so that plugins can import them" OFF)
 803 if(BUILD_SHARED_LIBS AND LLVM_EXPORT_SYMBOLS_FOR_PLUGINS)
 804   message(FATAL_ERROR "BUILD_SHARED_LIBS not compatible with LLVM_EXPORT_SYMBOLS_FOR_PLUGINS")
 805 endif()
 806 if(LLVM_LINK_LLVM_DYLIB AND LLVM_EXPORT_SYMBOLS_FOR_PLUGINS)
 807   message(FATAL_ERROR "LLVM_LINK_LLVM_DYLIB not compatible with LLVM_EXPORT_SYMBOLS_FOR_PLUGINS")
 808 endif()
 809
 810 # Plugin support
 811 # FIXME: Make this configurable.
 812 if(WIN32 OR CYGWIN)
 813   if(BUILD_SHARED_LIBS OR LLVM_BUILD_LLVM_DYLIB)
 814     set(LLVM_ENABLE_PLUGINS ON)
 815   else()
 816     set(LLVM_ENABLE_PLUGINS OFF)
 817   endif()
 818 else()
 819   set(LLVM_ENABLE_PLUGINS ON)
 820 endif()
 821
 822 function(get_compile_definitions)
 823   get_directory_property(top_dir_definitions DIRECTORY ${CMAKE_SOURCE_DIR} COMPILE_DEFINITIONS)
 824   foreach(definition ${top_dir_definitions})
 825     if(DEFINED result)
 826       string(APPEND result " -D${definition}")
 827     else()
 828       set(result "-D${definition}")
 829     endif()
 830   endforeach()
 831   set(LLVM_DEFINITIONS "${result}" PARENT_SCOPE)
 832 endfunction()
 833 get_compile_definitions()