test/Analysis/DependenceAnalysis/NonCanonicalizedSubscript.ll

   1 ; RUN: opt < %s -disable-output "-passes=print<da>" -aa-pipeline=basic-aa 2>&1 \
   2 ; RUN: | FileCheck %s -check-prefix=DELIN
   3 ; RUN: opt < %s -analyze -basicaa -da | FileCheck %s -check-prefix=DELIN
   4
   5 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64-S128"
   6 target triple = "x86_64-apple-macosx10.6.0"
   7
   8 ; for (int i = 0; i < 100; ++i) {
   9 ;   int t0 = a[i][i];
  10 ;   int t1 = t0 + 1;
  11 ;   a[i][5] = t1;
  12 ; }
  13 ; The subscript 5 in a[i][5] is deliberately an i32, mismatching the types of
  14 ; other subscript. DependenceAnalysis before the fix crashed due to this
  15 ; mismatch.
  16 define void @i32_subscript([100 x [100 x i32]]* %a, i32* %b) {
  17 ; DELIN-LABEL: 'Dependence Analysis' for function 'i32_subscript'
  18 entry:
  19   br label %for.body
  20
  21 for.body:
  22 ; DELIN: da analyze - none!
  23 ; DELIN: da analyze - anti [=|<]!
  24 ; DELIN: da analyze - none!
  25   %i = phi i64 [ 0, %entry ], [ %i.inc, %for.body ]
  26   %a.addr = getelementptr [100 x [100 x i32]], [100 x [100 x i32]]* %a, i64 0, i64 %i, i64 %i
  27   %a.addr.2 = getelementptr [100 x [100 x i32]], [100 x [100 x i32]]* %a, i64 0, i64 %i, i32 5
  28   %0 = load i32, i32* %a.addr, align 4
  29   %1 = add i32 %0, 1
  30   store i32 %1, i32* %a.addr.2, align 4
  31   %i.inc = add nsw i64 %i, 1
  32   %exitcond = icmp ne i64 %i.inc, 100
  33   br i1 %exitcond, label %for.body, label %for.end
  34
  35 for.end:
  36   ret void
  37 }
  38
  39 target datalayout = "e-m:e-i64:64-f80:128-n8:16:32:64-S128"
  40 target triple = "x86_64-unknown-linux-gnu"
  41
  42 ;  unsigned i, j;
  43 ;  for (i = 1; i < SIZE; i++) {
  44 ;    for (j = i; j < SIZE; j++) {
  45 ;      a[i][j] = a[i+1][j-1] + 2;
  46 ;    }
  47 ;  }
  48 ;  Extends the previous example to coupled MIV subscripts.
  49
  50
  51 @a = global [10004 x [10004 x i32]] zeroinitializer, align 16
  52
  53 ; Function Attrs: nounwind uwtable
  54 define void @coupled_miv_type_mismatch(i32 %n) #0 {
  55 ; DELIN-LABEL: 'Dependence Analysis' for function 'coupled_miv_type_mismatch'
  56 entry:
  57   br label %for.cond
  58
  59 ; DELIN: da analyze - input [* *]!
  60 ; DELIN: da analyze - anti [* *|<]!
  61 ; DELIN: da analyze - none!
  62 for.cond:                                         ; preds = %for.inc11, %entry
  63   %indvars.iv11 = phi i64 [ %indvars.iv.next12, %for.inc11 ], [ 1, %entry ]
  64   %exitcond14 = icmp ne i64 %indvars.iv11, 10000
  65   br i1 %exitcond14, label %for.cond1.preheader, label %for.end13
  66
  67 for.cond1.preheader:                              ; preds = %for.cond
  68   %0 = trunc i64 %indvars.iv11 to i32
  69   br label %for.cond1
  70
  71 for.cond1:                                        ; preds = %for.cond1.preheader, %for.body3
  72   %indvars.iv8 = phi i64 [ %indvars.iv11, %for.cond1.preheader ], [ %indvars.iv.next9, %for.body3 ]
  73   %j.0 = phi i32 [ %inc, %for.body3 ], [ %0, %for.cond1.preheader ]
  74   %lftr.wideiv = trunc i64 %indvars.iv8 to i32
  75   %exitcond = icmp ne i32 %lftr.wideiv, 10000
  76   br i1 %exitcond, label %for.body3, label %for.inc11
  77
  78 for.body3:                                        ; preds = %for.cond1
  79   %sub = add nsw i32 %j.0, -1
  80   %idxprom = zext i32 %sub to i64
  81   %1 = add nuw nsw i64 %indvars.iv11, 1
  82   %arrayidx5 = getelementptr inbounds [10004 x [10004 x i32]], [10004 x [10004 x i32]]* @a, i64 0, i64 %1, i64 %idxprom
  83   %2 = load i32, i32* %arrayidx5, align 4
  84   %add6 = add nsw i32 %2, 2
  85   %arrayidx10 = getelementptr inbounds [10004 x [10004 x i32]], [10004 x [10004 x i32]]* @a, i64 0, i64 %indvars.iv11, i64 %indvars.iv8
  86   store i32 %add6, i32* %arrayidx10, align 4
  87   %indvars.iv.next9 = add nuw nsw i64 %indvars.iv8, 1
  88   %inc = add nuw nsw i32 %j.0, 1
  89   br label %for.cond1
  90
  91 for.inc11:                                        ; preds = %for.cond1
  92   %indvars.iv.next12 = add nuw nsw i64 %indvars.iv11, 1
  93   br label %for.cond
  94
  95 for.end13:                                        ; preds = %for.cond
  96   ret void
  97 }
  98
  99 attributes #0 = { nounwind uwtable "less-precise-fpmad"="false" "no-frame-pointer-elim"="true" "no-frame-pointer-elim-non-leaf" "no-infs-fp-math"="false" "no-nans-fp-math"="false" "stack-protector-buffer-size"="8" "target-cpu"="x86-64" "target-features"="+sse,+sse2" "unsafe-fp-math"="false" "use-soft-float"="false" }
 100
 101 !llvm.ident = !{!0}
 102
 103 !0 = !{!"clang version 3.7.0"}