CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 3.4.3)
   4
   5 if(POLICY CMP0068)
   6   cmake_policy(SET CMP0068 NEW)
   7   set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR ON)
   8 endif()
   9
  10 if(POLICY CMP0075)
  11   cmake_policy(SET CMP0075 NEW)
  12 endif()
  13
  14 if(NOT DEFINED LLVM_VERSION_MAJOR)
  15   set(LLVM_VERSION_MAJOR 9)
  16 endif()
  17 if(NOT DEFINED LLVM_VERSION_MINOR)
  18   set(LLVM_VERSION_MINOR 0)
  19 endif()
  20 if(NOT DEFINED LLVM_VERSION_PATCH)
  21   set(LLVM_VERSION_PATCH 0)
  22 endif()
  23 if(NOT DEFINED LLVM_VERSION_SUFFIX)
  24   set(LLVM_VERSION_SUFFIX svn)
  25 endif()
  26
  27 if (NOT PACKAGE_VERSION)
  28   set(PACKAGE_VERSION
  29     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  30 endif()
  31
  32 if ((CMAKE_GENERATOR MATCHES "Visual Studio") AND (CMAKE_GENERATOR_TOOLSET STREQUAL ""))
  33   message(WARNING "Visual Studio generators use the x86 host compiler by "
  34                   "default, even for 64-bit targets. This can result in linker "
  35                   "instability and out of memory errors. To use the 64-bit "
  36                   "host compiler, pass -Thost=x64 on the CMake command line.")
  37 endif()
  38
  39 project(LLVM
  40   VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}
  41   LANGUAGES C CXX ASM)
  42
  43 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  44   message(STATUS "No build type selected, default to Debug")
  45   set(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (default Debug)" FORCE)
  46 endif()
  47
  48 # This should only apply if you are both on an Apple host, and targeting Apple.
  49 if(CMAKE_HOST_APPLE AND APPLE)
  50   # if CMAKE_LIBTOOL is not set, try and find it with xcrun or find_program
  51   if(NOT CMAKE_LIBTOOL)
  52     if(NOT CMAKE_XCRUN)
  53       find_program(CMAKE_XCRUN NAMES xcrun)
  54     endif()
  55     if(CMAKE_XCRUN)
  56       execute_process(COMMAND ${CMAKE_XCRUN} -find libtool
  57         OUTPUT_VARIABLE CMAKE_LIBTOOL
  58         OUTPUT_STRIP_TRAILING_WHITESPACE)
  59     endif()
  60
  61     if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
  62       find_program(CMAKE_LIBTOOL NAMES libtool)
  63     endif()
  64   endif()
  65
  66   get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
  67   if(CMAKE_LIBTOOL)
  68     set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
  69     message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
  70
  71     execute_process(COMMAND ${CMAKE_LIBTOOL} -V
  72       OUTPUT_VARIABLE LIBTOOL_V_OUTPUT
  73       OUTPUT_STRIP_TRAILING_WHITESPACE)
  74     if("${LIBTOOL_V_OUTPUT}" MATCHES ".*cctools-([0-9.]+).*")
  75       string(REGEX REPLACE ".*cctools-([0-9.]+).*" "\\1" LIBTOOL_VERSION
  76         ${LIBTOOL_V_OUTPUT})
  77       if(NOT LIBTOOL_VERSION VERSION_LESS "862")
  78         set(LIBTOOL_NO_WARNING_FLAG "-no_warning_for_no_symbols")
  79       endif()
  80     endif()
  81
  82     foreach(lang ${languages})
  83       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  84         "\"${CMAKE_LIBTOOL}\" -static ${LIBTOOL_NO_WARNING_FLAG} -o <TARGET> \
  85         <LINK_FLAGS> <OBJECTS> ")
  86     endforeach()
  87   endif()
  88
  89   # If DYLD_LIBRARY_PATH is set we need to set it on archiver commands
  90   if(DYLD_LIBRARY_PATH)
  91     set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
  92     foreach(lang ${languages})
  93       foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
  94         list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW
  95              "${dyld_envar} ${cmd}")
  96       endforeach()
  97       set(CMAKE_${lang}_CREATE_STATIC_LIBRARY
  98         ${CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW})
  99     endforeach()
 100   endif()
 101 endif()
 102
 103 # Side-by-side subprojects layout: automatically set the
 104 # LLVM_EXTERNAL_${project}_SOURCE_DIR using LLVM_ALL_PROJECTS
 105 # This allows an easy way of setting up a build directory for llvm and another
 106 # one for llvm+clang+... using the same sources.
 107 set(LLVM_ALL_PROJECTS "clang;clang-tools-extra;compiler-rt;debuginfo-tests;libclc;libcxx;libcxxabi;libunwind;lld;lldb;llgo;openmp;parallel-libs;polly;pstl")
 108 set(LLVM_ENABLE_PROJECTS "" CACHE STRING
 109         "Semicolon-separated list of projects to build (${LLVM_ALL_PROJECTS}), or \"all\".")
 110 if( LLVM_ENABLE_PROJECTS STREQUAL "all" )
 111   set( LLVM_ENABLE_PROJECTS ${LLVM_ALL_PROJECTS})
 112 endif()
 113
 114 # LLVM_ENABLE_PROJECTS_USED is `ON` if the user has ever used the
 115 # `LLVM_ENABLE_PROJECTS` CMake cache variable.  This exists for
 116 # several reasons:
 117 #
 118 # * As an indicator that the `LLVM_ENABLE_PROJECTS` list is now the single
 119 # source of truth for which projects to build. This means we will ignore user
 120 # supplied `LLVM_TOOL_<project>_BUILD` CMake cache variables and overwrite
 121 # them.
 122 #
 123 # * The case where the user previously had `LLVM_ENABLE_PROJECTS` set to a
 124 # non-empty list but now the user wishes to disable building all other projects
 125 # by setting `LLVM_ENABLE_PROJECTS` to an empty string. In that case we still
 126 # need to set the `LLVM_TOOL_${upper_proj}_BUILD` variables so that we disable
 127 # building all the projects that were previously enabled.
 128 set(LLVM_ENABLE_PROJECTS_USED OFF CACHE BOOL "")
 129 mark_as_advanced(LLVM_ENABLE_PROJECTS_USED)
 130
 131 if (LLVM_ENABLE_PROJECTS_USED OR NOT LLVM_ENABLE_PROJECTS STREQUAL "")
 132   set(LLVM_ENABLE_PROJECTS_USED ON CACHE BOOL "" FORCE)
 133   foreach(proj ${LLVM_ALL_PROJECTS} ${LLVM_EXTERNAL_PROJECTS})
 134     string(TOUPPER "${proj}" upper_proj)
 135     string(REGEX REPLACE "-" "_" upper_proj ${upper_proj})
 136     if ("${proj}" IN_LIST LLVM_ENABLE_PROJECTS)
 137       message(STATUS "${proj} project is enabled")
 138       set(SHOULD_ENABLE_PROJECT TRUE)
 139       set(PROJ_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
 140       if(NOT EXISTS "${PROJ_DIR}" OR NOT IS_DIRECTORY "${PROJ_DIR}")
 141         message(FATAL_ERROR "LLVM_ENABLE_PROJECTS requests ${proj} but directory not found: ${PROJ_DIR}")
 142       endif()
 143       set(LLVM_EXTERNAL_${upper_proj}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}" CACHE STRING "")
 144     else()
 145       message(STATUS "${proj} project is disabled")
 146       set(SHOULD_ENABLE_PROJECT FALSE)
 147     endif()
 148     # Force `LLVM_TOOL_${upper_proj}_BUILD` variables to have values that
 149     # corresponds with `LLVM_ENABLE_PROJECTS`. This prevents the user setting
 150     # `LLVM_TOOL_${upper_proj}_BUILD` variables externally. At some point
 151     # we should deprecate allowing users to set these variables by turning them
 152     # into normal CMake variables rather than cache variables.
 153     set(LLVM_TOOL_${upper_proj}_BUILD
 154       ${SHOULD_ENABLE_PROJECT}
 155       CACHE
 156       BOOL "Whether to build ${upper_proj} as part of LLVM" FORCE
 157     )
 158   endforeach()
 159 endif()
 160 unset(SHOULD_ENABLE_PROJECT)
 161
 162 # Build llvm with ccache if the package is present
 163 set(LLVM_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
 164 if(LLVM_CCACHE_BUILD)
 165   find_program(CCACHE_PROGRAM ccache)
 166   if(CCACHE_PROGRAM)
 167       set(LLVM_CCACHE_MAXSIZE "" CACHE STRING "Size of ccache")
 168       set(LLVM_CCACHE_DIR "" CACHE STRING "Directory to keep ccached data")
 169       set(LLVM_CCACHE_PARAMS "CCACHE_CPP2=yes CCACHE_HASHDIR=yes"
 170           CACHE STRING "Parameters to pass through to ccache")
 171
 172       set(CCACHE_PROGRAM "${LLVM_CCACHE_PARAMS} ${CCACHE_PROGRAM}")
 173       if (LLVM_CCACHE_MAXSIZE)
 174         set(CCACHE_PROGRAM "CCACHE_MAXSIZE=${LLVM_CCACHE_MAXSIZE} ${CCACHE_PROGRAM}")
 175       endif()
 176       if (LLVM_CCACHE_DIR)
 177         set(CCACHE_PROGRAM "CCACHE_DIR=${LLVM_CCACHE_DIR} ${CCACHE_PROGRAM}")
 178       endif()
 179       set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_PROGRAM})
 180   else()
 181     message(FATAL_ERROR "Unable to find the program ccache. Set LLVM_CCACHE_BUILD to OFF")
 182   endif()
 183 endif()
 184
 185 option(LLVM_DEPENDENCY_DEBUGGING "Dependency debugging mode to verify correctly expressed library dependencies (Darwin only)" OFF)
 186
 187 # Some features of the LLVM build may be disallowed when dependency debugging is
 188 # enabled. In particular you cannot use ccache because we want to force compile
 189 # operations to always happen.
 190 if(LLVM_DEPENDENCY_DEBUGGING)
 191   if(NOT CMAKE_HOST_APPLE)
 192     message(FATAL_ERROR "Dependency debugging is only currently supported on Darwin hosts.")
 193   endif()
 194   if(LLVM_CCACHE_BUILD)
 195     message(FATAL_ERROR "Cannot enable dependency debugging while using ccache.")
 196   endif()
 197 endif()
 198
 199 option(LLVM_ENABLE_DAGISEL_COV "Debug: Prints tablegen patterns that were used for selecting" OFF)
 200 option(LLVM_ENABLE_GISEL_COV "Enable collection of GlobalISel rule coverage" OFF)
 201 if(LLVM_ENABLE_GISEL_COV)
 202   set(LLVM_GISEL_COV_PREFIX "${CMAKE_BINARY_DIR}/gisel-coverage-" CACHE STRING "Provide a filename prefix to collect the GlobalISel rule coverage")
 203 endif()
 204
 205 # Add path for custom modules
 206 set(CMAKE_MODULE_PATH
 207   ${CMAKE_MODULE_PATH}
 208   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 209   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
 210   )
 211
 212 # Generate a CompilationDatabase (compile_commands.json file) for our build,
 213 # for use by clang_complete, YouCompleteMe, etc.
 214 set(CMAKE_EXPORT_COMPILE_COMMANDS 1)
 215
 216 option(LLVM_INSTALL_BINUTILS_SYMLINKS
 217   "Install symlinks from the binutils tool names to the corresponding LLVM tools." OFF)
 218
 219 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
 220
 221 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
 222
 223 # Unfortunatly Clang is too eager to search directories for module maps, which can cause the
 224 # installed version of the maps to be found when building LLVM from source. Therefore we turn off
 225 # the installation by default. See llvm.org/PR31905.
 226 option(LLVM_INSTALL_MODULEMAPS "Install the modulemap files in the 'install' target." OFF)
 227
 228 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
 229 if ( LLVM_USE_FOLDERS )
 230   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 231 endif()
 232
 233 include(VersionFromVCS)
 234
 235 option(LLVM_APPEND_VC_REV
 236   "Embed the version control system revision in LLVM" ON)
 237
 238 set(PACKAGE_NAME LLVM)
 239 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
 240 set(PACKAGE_BUGREPORT "https://bugs.llvm.org/")
 241
 242 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
 243   "Default URL where bug reports are to be submitted.")
 244
 245 # Configure CPack.
 246 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
 247 set(CPACK_PACKAGE_VENDOR "LLVM")
 248 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 249 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 250 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 251 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 252 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 253 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 254 if(WIN32 AND NOT UNIX)
 255   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 256   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 257   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 258   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 259   set(CPACK_NSIS_MODIFY_PATH "ON")
 260   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 261   if( CMAKE_CL_64 )
 262     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 263   endif()
 264 endif()
 265 include(CPack)
 266
 267 # Sanity check our source directory to make sure that we are not trying to
 268 # generate an in-source build (unless on MSVC_IDE, where it is ok), and to make
 269 # sure that we don't have any stray generated files lying around in the tree
 270 # (which would end up getting picked up by header search, instead of the correct
 271 # versions).
 272 if( CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR AND NOT MSVC_IDE )
 273   message(FATAL_ERROR "In-source builds are not allowed.
 274 Please create a directory and run cmake from there, passing the path
 275 to this source directory as the last argument.
 276 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 277 Please delete them.")
 278 endif()
 279
 280 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 281
 282 if (CMAKE_BUILD_TYPE AND
 283     NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 284   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 285 endif()
 286
 287 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 288
 289 set(LLVM_TOOLS_INSTALL_DIR "bin" CACHE STRING "Path for binary subdirectory (defaults to 'bin')")
 290 mark_as_advanced(LLVM_TOOLS_INSTALL_DIR)
 291
 292 set(LLVM_UTILS_INSTALL_DIR "${LLVM_TOOLS_INSTALL_DIR}" CACHE STRING
 293     "Path to install LLVM utilities (enabled by LLVM_INSTALL_UTILS=ON) (defaults to LLVM_TOOLS_INSTALL_DIR)")
 294 mark_as_advanced(LLVM_UTILS_INSTALL_DIR)
 295
 296 # They are used as destination of target generators.
 297 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 298 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 299 if(WIN32 OR CYGWIN)
 300   # DLL platform -- put DLLs into bin.
 301   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 302 else()
 303   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 304 endif()
 305
 306 # Each of them corresponds to llvm-config's.
 307 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 308 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 309 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 310 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 311 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 312
 313 # Note: LLVM_CMAKE_PATH does not include generated files
 314 set(LLVM_CMAKE_PATH ${LLVM_MAIN_SRC_DIR}/cmake/modules)
 315 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 316 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 317
 318 # List of all targets to be built by default:
 319 set(LLVM_ALL_TARGETS
 320   AArch64
 321   AMDGPU
 322   ARM
 323   BPF
 324   Hexagon
 325   Lanai
 326   Mips
 327   MSP430
 328   NVPTX
 329   PowerPC
 330   Sparc
 331   SystemZ
 332   WebAssembly
 333   X86
 334   XCore
 335   )
 336
 337 # List of targets with JIT support:
 338 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 339
 340 set(LLVM_TARGETS_TO_BUILD "all"
 341     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 342
 343 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 344   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 345
 346 option(BUILD_SHARED_LIBS
 347   "Build all libraries as shared libraries instead of static" OFF)
 348
 349 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 350 if(LLVM_ENABLE_BACKTRACES)
 351   set(ENABLE_BACKTRACES 1)
 352 endif()
 353
 354 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 355 if(LLVM_ENABLE_CRASH_OVERRIDES)
 356   set(ENABLE_CRASH_OVERRIDES 1)
 357 endif()
 358
 359 option(LLVM_ENABLE_CRASH_DUMPS "Turn on memory dumps on crashes. Currently only implemented on Windows." OFF)
 360
 361 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 362 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 363 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 364
 365 set(LLVM_TARGET_ARCH "host"
 366   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 367
 368 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 369
 370 set(LLVM_ENABLE_LIBXML2 "ON" CACHE STRING "Use libxml2 if available. Can be ON, OFF, or FORCE_ON")
 371
 372 option(LLVM_ENABLE_LIBEDIT "Use libedit if available." ON)
 373
 374 option(LLVM_ENABLE_LIBPFM "Use libpfm for performance counters if available." ON)
 375
 376 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 377
 378 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 379
 380 set(LLVM_Z3_INSTALL_DIR "" CACHE STRING "Install directory of the Z3 solver.")
 381
 382 find_package(Z3 4.7.1)
 383
 384 if (LLVM_Z3_INSTALL_DIR)
 385   if (NOT Z3_FOUND)
 386     message(FATAL_ERROR "Z3 >= 4.7.1 has not been found in LLVM_Z3_INSTALL_DIR: ${LLVM_Z3_INSTALL_DIR}.")
 387   endif()
 388 endif()
 389
 390 set(LLVM_ENABLE_Z3_SOLVER_DEFAULT "${Z3_FOUND}")
 391
 392 option(LLVM_ENABLE_Z3_SOLVER
 393   "Enable Support for the Z3 constraint solver in LLVM."
 394   ${LLVM_ENABLE_Z3_SOLVER_DEFAULT}
 395 )
 396
 397 if (LLVM_ENABLE_Z3_SOLVER)
 398   if (NOT Z3_FOUND)
 399     message(FATAL_ERROR "LLVM_ENABLE_Z3_SOLVER cannot be enabled when Z3 is not available.")
 400   endif()
 401
 402   set(LLVM_WITH_Z3 1)
 403 endif()
 404
 405 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 406   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 407 endif()
 408
 409 set(LLVM_TARGETS_TO_BUILD
 410    ${LLVM_TARGETS_TO_BUILD}
 411    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 412 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 413
 414 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 415 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 416 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 417 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 418   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." ON)
 419   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." OFF)
 420 else()
 421   option(LLVM_ENABLE_MODULE_DEBUGGING "Compile with -gmodules." OFF)
 422   option(LLVM_ENABLE_LOCAL_SUBMODULE_VISIBILITY "Compile with -fmodules-local-submodule-visibility." ON)
 423 endif()
 424 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 425 option(LLVM_ENABLE_LLD "Use lld as C and C++ linker." OFF)
 426 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 427 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 428
 429 set(LLVM_CXX_STD_default "c++11")
 430 # Preserve behaviour of legacy cache variables
 431 if (LLVM_ENABLE_CXX1Y)
 432   set(LLVM_CXX_STD_default "c++1y")
 433 elseif (LLVM_ENABLE_CXX1Z)
 434   set(LLVM_CXX_STD_default "c++1z")
 435 endif()
 436 set(LLVM_CXX_STD ${LLVM_CXX_STD_default}
 437     CACHE STRING "C++ standard to use for compilation.")
 438
 439 option(LLVM_ENABLE_DUMP "Enable dump functions even when assertions are disabled" OFF)
 440
 441 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 442   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 443 else()
 444   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 445 endif()
 446
 447 option(LLVM_ENABLE_EXPENSIVE_CHECKS "Enable expensive checks" OFF)
 448
 449 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 450   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 451
 452 option(LLVM_FORCE_USE_OLD_TOOLCHAIN
 453        "Set to ON to force using an old, unsupported host toolchain." OFF)
 454
 455 option(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN
 456        "Set to ON to only warn when using a toolchain which is about to be deprecated, instead of emitting an error." OFF)
 457
 458 option(LLVM_USE_INTEL_JITEVENTS
 459   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 460   OFF)
 461
 462 if( LLVM_USE_INTEL_JITEVENTS )
 463   # Verify we are on a supported platform
 464   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 465     message(FATAL_ERROR
 466       "Intel JIT API support is available on Linux and Windows only.")
 467   endif()
 468 endif( LLVM_USE_INTEL_JITEVENTS )
 469
 470 option(LLVM_USE_OPROFILE
 471   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 472
 473 option(LLVM_EXTERNALIZE_DEBUGINFO
 474   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 475
 476 set(LLVM_CODESIGNING_IDENTITY "" CACHE STRING
 477   "Sign executables and dylibs with the given identity or skip if empty (Darwin Only)")
 478
 479 # If enabled, verify we are on a platform that supports oprofile.
 480 if( LLVM_USE_OPROFILE )
 481   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 482     message(FATAL_ERROR "OProfile support is available on Linux only.")
 483   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 484 endif( LLVM_USE_OPROFILE )
 485
 486 option(LLVM_USE_PERF
 487   "Use perf JIT interface to inform perf about JIT code" OFF)
 488
 489 # If enabled, verify we are on a platform that supports perf.
 490 if( LLVM_USE_PERF )
 491   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 492     message(FATAL_ERROR "perf support is available on Linux only.")
 493   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 494 endif( LLVM_USE_PERF )
 495
 496 set(LLVM_USE_SANITIZER "" CACHE STRING
 497   "Define the sanitizer used to build binaries and tests.")
 498 option(LLVM_OPTIMIZE_SANITIZED_BUILDS "Pass -O1 on debug sanitizer builds" ON)
 499 set(LLVM_LIB_FUZZING_ENGINE "" CACHE PATH
 500   "Path to fuzzing library for linking with fuzz targets")
 501
 502 option(LLVM_USE_SPLIT_DWARF
 503   "Use -gsplit-dwarf when compiling llvm." OFF)
 504
 505 option(LLVM_POLLY_LINK_INTO_TOOLS "Statically link Polly into tools (if available)" ON)
 506 option(LLVM_POLLY_BUILD "Build LLVM with Polly" ON)
 507
 508 if (EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 509   set(POLLY_IN_TREE TRUE)
 510 elseif(LLVM_EXTERNAL_POLLY_SOURCE_DIR)
 511   set(POLLY_IN_TREE TRUE)
 512 else()
 513   set(POLLY_IN_TREE FALSE)
 514 endif()
 515
 516 if (LLVM_POLLY_BUILD AND POLLY_IN_TREE)
 517   set(WITH_POLLY ON)
 518 else()
 519   set(WITH_POLLY OFF)
 520 endif()
 521
 522 if (LLVM_POLLY_LINK_INTO_TOOLS AND WITH_POLLY)
 523   set(LINK_POLLY_INTO_TOOLS ON)
 524 else()
 525   set(LINK_POLLY_INTO_TOOLS OFF)
 526 endif()
 527
 528 # Define an option controlling whether we should build for 32-bit on 64-bit
 529 # platforms, where supported.
 530 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 531   # TODO: support other platforms and toolchains.
 532   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 533 endif()
 534
 535 # Define the default arguments to use with 'lit', and an option for the user to
 536 # override.
 537 set(LIT_ARGS_DEFAULT "-sv")
 538 if (MSVC_IDE OR XCODE)
 539   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 540 endif()
 541 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 542
 543 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 544 if( WIN32 AND NOT CYGWIN )
 545   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 546 endif()
 547
 548 # Define options to control the inclusion and default build behavior for
 549 # components which may not strictly be necessary (tools, examples, and tests).
 550 #
 551 # This is primarily to support building smaller or faster project files.
 552 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 553 option(LLVM_BUILD_TOOLS
 554   "Build the LLVM tools. If OFF, just generate build targets." ON)
 555
 556 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 557 option(LLVM_BUILD_UTILS
 558   "Build LLVM utility binaries. If OFF, just generate build targets." ON)
 559
 560 option(LLVM_INCLUDE_RUNTIMES "Generate build targets for the LLVM runtimes." ON)
 561 option(LLVM_BUILD_RUNTIMES
 562   "Build the LLVM runtimes. If OFF, just generate build targets." ON)
 563
 564 option(LLVM_BUILD_RUNTIME
 565   "Build the LLVM runtime libraries." ON)
 566 option(LLVM_BUILD_EXAMPLES
 567   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 568 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 569
 570 option(LLVM_BUILD_TESTS
 571   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 572 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 573 option(LLVM_INCLUDE_GO_TESTS "Include the Go bindings tests in test build targets." ON)
 574
 575 option(LLVM_BUILD_BENCHMARKS "Add LLVM benchmark targets to the list of default
 576 targets. If OFF, benchmarks still could be built using Benchmarks target." OFF)
 577 option(LLVM_INCLUDE_BENCHMARKS "Generate benchmark targets. If OFF, benchmarks can't be built." ON)
 578
 579 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 580 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 581 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 582 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 583 option (LLVM_ENABLE_OCAMLDOC "Build OCaml bindings documentation." ON)
 584 option (LLVM_ENABLE_BINDINGS "Build bindings." ON)
 585
 586 set(LLVM_INSTALL_DOXYGEN_HTML_DIR "share/doc/llvm/doxygen-html"
 587     CACHE STRING "Doxygen-generated HTML documentation install directory")
 588 set(LLVM_INSTALL_OCAMLDOC_HTML_DIR "share/doc/llvm/ocaml-html"
 589     CACHE STRING "OCamldoc-generated HTML documentation install directory")
 590
 591 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 592   "Build compiler-rt as an external project." OFF)
 593
 594 option (LLVM_VERSION_PRINTER_SHOW_HOST_TARGET_INFO
 595   "Show target and host info when tools are invoked with --version." ON)
 596
 597 # You can configure which libraries from LLVM you want to include in the
 598 # shared library by setting LLVM_DYLIB_COMPONENTS to a semi-colon delimited
 599 # list of LLVM components. All component names handled by llvm-config are valid.
 600 if(NOT DEFINED LLVM_DYLIB_COMPONENTS)
 601   set(LLVM_DYLIB_COMPONENTS "all" CACHE STRING
 602     "Semicolon-separated list of components to include in libLLVM, or \"all\".")
 603 endif()
 604 option(LLVM_LINK_LLVM_DYLIB "Link tools against the libllvm dynamic library" OFF)
 605 if(MSVC)
 606   option(LLVM_BUILD_LLVM_C_DYLIB "Build LLVM-C.dll (Windows only)" ON)
 607 else()
 608   option(LLVM_BUILD_LLVM_C_DYLIB "Build libllvm-c re-export library (Darwin only)" OFF)
 609 endif()
 610 set(LLVM_BUILD_LLVM_DYLIB_default OFF)
 611 if(LLVM_LINK_LLVM_DYLIB OR (LLVM_BUILD_LLVM_C_DYLIB AND NOT MSVC))
 612   set(LLVM_BUILD_LLVM_DYLIB_default ON)
 613 endif()
 614 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" ${LLVM_BUILD_LLVM_DYLIB_default})
 615
 616 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 617 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND (LLVM_ENABLE_ASSERTIONS OR CMAKE_CONFIGURATION_TYPES)))
 618   set(LLVM_USE_HOST_TOOLS ON)
 619 endif()
 620
 621 if (MSVC_IDE AND NOT (MSVC_VERSION LESS 1900))
 622   option(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION "Configure project to use Visual Studio native visualizers" TRUE)
 623 else()
 624   set(LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION FALSE CACHE INTERNAL "For Visual Studio 2013, manually copy natvis files to Documents\\Visual Studio 2013\\Visualizers" FORCE)
 625 endif()
 626
 627 if (LLVM_BUILD_INSTRUMENTED OR LLVM_BUILD_INSTRUMENTED_COVERAGE OR
 628     LLVM_ENABLE_IR_PGO)
 629   if(NOT LLVM_PROFILE_MERGE_POOL_SIZE)
 630     # A pool size of 1-2 is probably sufficient on a SSD. 3-4 should be fine
 631     # for spining disks. Anything higher may only help on slower mediums.
 632     set(LLVM_PROFILE_MERGE_POOL_SIZE "4")
 633   endif()
 634   if(NOT LLVM_PROFILE_FILE_PATTERN)
 635     if(NOT LLVM_PROFILE_DATA_DIR)
 636       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/profiles" LLVM_PROFILE_DATA_DIR)
 637     endif()
 638                 file(TO_NATIVE_PATH "${LLVM_PROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_PROFILE_FILE_PATTERN)
 639   endif()
 640   if(NOT LLVM_CSPROFILE_FILE_PATTERN)
 641     if(NOT LLVM_CSPROFILE_DATA_DIR)
 642       file(TO_NATIVE_PATH "${LLVM_BINARY_DIR}/csprofiles" LLVM_CSPROFILE_DATA_DIR)
 643     endif()
 644     file(TO_NATIVE_PATH "${LLVM_CSPROFILE_DATA_DIR}/%${LLVM_PROFILE_MERGE_POOL_SIZE}m.profraw" LLVM_CSPROFILE_FILE_PATTERN)
 645   endif()
 646 endif()
 647
 648 if (LLVM_BUILD_STATIC)
 649   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 650 endif()
 651
 652 # Override the default target with an environment variable named by LLVM_TARGET_TRIPLE_ENV.
 653 set(LLVM_TARGET_TRIPLE_ENV CACHE STRING "The name of environment variable to override default target. Disabled by blank.")
 654 mark_as_advanced(LLVM_TARGET_TRIPLE_ENV)
 655
 656 set(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR OFF CACHE BOOL
 657   "Enable per-target runtimes directory")
 658
 659 # All options referred to from HandleLLVMOptions have to be specified
 660 # BEFORE this include, otherwise options will not be correctly set on
 661 # first cmake run
 662 include(config-ix)
 663
 664 string(REPLACE "Native" ${LLVM_NATIVE_ARCH}
 665   LLVM_TARGETS_TO_BUILD "${LLVM_TARGETS_TO_BUILD}")
 666 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 667
 668 # By default, we target the host, but this can be overridden at CMake
 669 # invocation time.
 670 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 671   "Default target for which LLVM will generate code." )
 672 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 673 message(STATUS "LLVM host triple: ${LLVM_HOST_TRIPLE}")
 674 message(STATUS "LLVM default target triple: ${LLVM_DEFAULT_TARGET_TRIPLE}")
 675
 676 include(HandleLLVMOptions)
 677
 678 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 679 # FIXME: We should support systems with only Python 3, but that requires work
 680 # on LLDB.
 681 set(Python_ADDITIONAL_VERSIONS 2.7)
 682 include(FindPythonInterp)
 683 if( NOT PYTHONINTERP_FOUND )
 684   message(FATAL_ERROR
 685 "Unable to find Python interpreter, required for builds and testing.
 686
 687 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 688 endif()
 689
 690 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 691   message(FATAL_ERROR "Python 2.7 or newer is required")
 692 endif()
 693
 694 ######
 695 # LLVMBuild Integration
 696 #
 697 # We use llvm-build to generate all the data required by the CMake based
 698 # build system in one swoop:
 699 #
 700 #  - We generate a file (a CMake fragment) in the object root which contains
 701 #    all the definitions that are required by CMake.
 702 #
 703 #  - We generate the library table used by llvm-config.
 704 #
 705 #  - We generate the dependencies for the CMake fragment, so that we will
 706 #    automatically reconfigure ourselves.
 707
 708 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 709 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 710   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 711 set(LLVMBUILDCMAKEFRAG
 712   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 713
 714 # Create the list of optional components that are enabled
 715 if (LLVM_USE_INTEL_JITEVENTS)
 716   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 717 endif (LLVM_USE_INTEL_JITEVENTS)
 718 if (LLVM_USE_OPROFILE)
 719   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 720 endif (LLVM_USE_OPROFILE)
 721 if (LLVM_USE_PERF)
 722   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} PerfJITEvents)
 723 endif (LLVM_USE_PERF)
 724
 725 message(STATUS "Constructing LLVMBuild project information")
 726 execute_process(
 727   COMMAND ${PYTHON_EXECUTABLE} -B ${LLVMBUILDTOOL}
 728             --native-target "${LLVM_NATIVE_ARCH}"
 729             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 730             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 731             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 732             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 733             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 734             ERROR_VARIABLE LLVMBUILDERRORS
 735             OUTPUT_STRIP_TRAILING_WHITESPACE
 736             ERROR_STRIP_TRAILING_WHITESPACE
 737   RESULT_VARIABLE LLVMBUILDRESULT)
 738
 739 # On Win32, CMake doesn't properly handle piping the default output/error
 740 # streams into the GUI console. So, we explicitly catch and report them.
 741 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 742   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 743 endif()
 744 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 745   message(FATAL_ERROR
 746     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 747 endif()
 748
 749 # Include the generated CMake fragment. This will define properties from the
 750 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 751 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 752 # files change.
 753 include(${LLVMBUILDCMAKEFRAG})
 754
 755 ######
 756
 757 # Configure all of the various header file fragments LLVM uses which depend on
 758 # configuration variables.
 759 set(LLVM_ENUM_TARGETS "")
 760 set(LLVM_ENUM_ASM_PRINTERS "")
 761 set(LLVM_ENUM_ASM_PARSERS "")
 762 set(LLVM_ENUM_DISASSEMBLERS "")
 763 foreach(t ${LLVM_TARGETS_TO_BUILD})
 764   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 765
 766   list(FIND LLVM_ALL_TARGETS ${t} idx)
 767   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 768   # At this point, LLVMBUILDTOOL already checked all the targets passed in
 769   # LLVM_TARGETS_TO_BUILD and LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, so
 770   # this test just makes sure that any experimental targets were passed via
 771   # LLVM_EXPERIMENTAL_TARGETS_TO_BUILD, not LLVM_TARGETS_TO_BUILD.
 772   if( idx LESS 0 AND idy LESS 0 )
 773     message(FATAL_ERROR "The target `${t}' is experimental and must be passed "
 774       "via LLVM_EXPERIMENTAL_TARGETS_TO_BUILD.")
 775   else()
 776     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 777   endif()
 778
 779   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 780   if( asmp_file )
 781     set(LLVM_ENUM_ASM_PRINTERS
 782       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 783   endif()
 784   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 785     set(LLVM_ENUM_ASM_PARSERS
 786       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 787   endif()
 788   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 789     set(LLVM_ENUM_DISASSEMBLERS
 790       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 791   endif()
 792 endforeach(t)
 793
 794 # Produce the target definition files, which provide a way for clients to easily
 795 # include various classes of targets.
 796 configure_file(
 797   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 798   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 799   )
 800 configure_file(
 801   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 802   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 803   )
 804 configure_file(
 805   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 806   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 807   )
 808 configure_file(
 809   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 810   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 811   )
 812
 813 # Configure the three LLVM configuration header files.
 814 configure_file(
 815   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 816   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 817 configure_file(
 818   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 819   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 820 configure_file(
 821   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/abi-breaking.h.cmake
 822   ${LLVM_INCLUDE_DIR}/llvm/Config/abi-breaking.h)
 823
 824 # Add target for generating source rpm package.
 825 set(LLVM_SRPM_USER_BINARY_SPECFILE ${CMAKE_CURRENT_SOURCE_DIR}/llvm.spec.in
 826     CACHE FILEPATH ".spec file to use for srpm generation")
 827 set(LLVM_SRPM_BINARY_SPECFILE ${CMAKE_CURRENT_BINARY_DIR}/llvm.spec)
 828 set(LLVM_SRPM_DIR "${CMAKE_CURRENT_BINARY_DIR}/srpm")
 829
 830 get_source_info(${CMAKE_CURRENT_SOURCE_DIR} revision repository)
 831 string(LENGTH "${revision}" revision_length)
 832 if(revision MATCHES "^[0-9]+$" AND revision_length LESS 40)
 833   set(LLVM_RPM_SPEC_REVISION "r${revision}")
 834 else()
 835   set(LLVM_RPM_SPEC_REVISION "${revision}")
 836 endif()
 837
 838 configure_file(
 839   ${LLVM_SRPM_USER_BINARY_SPECFILE}
 840   ${LLVM_SRPM_BINARY_SPECFILE} @ONLY)
 841
 842 add_custom_target(srpm
 843   COMMAND cpack -G TGZ --config CPackSourceConfig.cmake -B ${LLVM_SRPM_DIR}/SOURCES
 844   COMMAND rpmbuild -bs --define '_topdir ${LLVM_SRPM_DIR}' ${LLVM_SRPM_BINARY_SPECFILE})
 845 set_target_properties(srpm PROPERTIES FOLDER "Misc")
 846
 847
 848 # They are not referenced. See set_output_directory().
 849 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 850 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 851 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 852
 853 if(APPLE AND DARWIN_LTO_LIBRARY)
 854   set(CMAKE_EXE_LINKER_FLAGS
 855     "${CMAKE_EXE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 856   set(CMAKE_SHARED_LINKER_FLAGS
 857     "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 858   set(CMAKE_MODULE_LINKER_FLAGS
 859     "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-lto_library -Wl,${DARWIN_LTO_LIBRARY}")
 860 endif()
 861
 862 # Work around a broken bfd ld behavior. When linking a binary with a
 863 # foo.so library, it will try to find any library that foo.so uses and
 864 # check its symbols. This is wasteful (the check was done when foo.so
 865 # was created) and can fail since it is not the dynamic linker and
 866 # doesn't know how to handle search paths correctly.
 867 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS|AIX")
 868   set(CMAKE_EXE_LINKER_FLAGS
 869       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 870 endif()
 871
 872 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 873
 874 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 875
 876 # when crosscompiling import the executable targets from a file
 877 if(LLVM_USE_HOST_TOOLS)
 878   include(CrossCompile)
 879 endif(LLVM_USE_HOST_TOOLS)
 880 if(LLVM_TARGET_IS_CROSSCOMPILE_HOST)
 881 # Dummy use to avoid CMake Warning: Manually-specified variables were not used
 882 # (this is a variable that CrossCompile sets on recursive invocations)
 883 endif()
 884
 885 if(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 886   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 887   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 888   include_directories(SYSTEM "/usr/local/include")
 889   link_directories("/usr/local/lib")
 890 endif(${CMAKE_SYSTEM_NAME} MATCHES "(FreeBSD|DragonFly)")
 891
 892 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 893    # special hack for Solaris to handle crazy system sys/regset.h
 894    include_directories("${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/Solaris")
 895 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 896
 897 # Make sure we don't get -rdynamic in every binary. For those that need it,
 898 # use export_executable_symbols(target).
 899 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 900
 901 set(LLVM_PROFDATA_FILE "" CACHE FILEPATH
 902   "Profiling data file to use when compiling in order to improve runtime performance.")
 903
 904 if(LLVM_PROFDATA_FILE AND EXISTS ${LLVM_PROFDATA_FILE})
 905   if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 906     add_definitions("-fprofile-instr-use=${LLVM_PROFDATA_FILE}")
 907   else()
 908     message(FATAL_ERROR "LLVM_PROFDATA_FILE can only be specified when compiling with clang")
 909   endif()
 910 endif()
 911
 912 include(AddLLVM)
 913 include(TableGen)
 914
 915 if( MINGW AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
 916   # People report that -O3 is unreliable on MinGW. The traditional
 917   # build also uses -O2 for that reason:
 918   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 919 endif()
 920
 921 # Put this before tblgen. Else we have a circular dependence.
 922 add_subdirectory(lib/Demangle)
 923 add_subdirectory(lib/Support)
 924 add_subdirectory(lib/TableGen)
 925
 926 add_subdirectory(utils/TableGen)
 927
 928 add_subdirectory(include/llvm)
 929
 930 add_subdirectory(lib)
 931
 932 if( LLVM_INCLUDE_UTILS )
 933   add_subdirectory(utils/FileCheck)
 934   add_subdirectory(utils/PerfectShuffle)
 935   add_subdirectory(utils/count)
 936   add_subdirectory(utils/not)
 937   add_subdirectory(utils/yaml-bench)
 938 else()
 939   if ( LLVM_INCLUDE_TESTS )
 940     message(FATAL_ERROR "Including tests when not building utils will not work.
 941     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLUDE_TESTS to Off.")
 942   endif()
 943 endif()
 944
 945 # Use LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION instead of LLVM_INCLUDE_UTILS because it is not really a util
 946 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 947   add_subdirectory(utils/LLVMVisualizers)
 948 endif()
 949
 950 foreach( binding ${LLVM_BINDINGS_LIST} )
 951   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 952     add_subdirectory(bindings/${binding})
 953   endif()
 954 endforeach()
 955
 956 add_subdirectory(projects)
 957
 958 if( LLVM_INCLUDE_TOOLS )
 959   add_subdirectory(tools)
 960 endif()
 961
 962 if( LLVM_INCLUDE_RUNTIMES )
 963   add_subdirectory(runtimes)
 964 endif()
 965
 966 if( LLVM_INCLUDE_EXAMPLES )
 967   add_subdirectory(examples)
 968 endif()
 969
 970 if( LLVM_INCLUDE_TESTS )
 971   if(EXISTS ${LLVM_MAIN_SRC_DIR}/projects/test-suite AND TARGET clang)
 972     include(LLVMExternalProjectUtils)
 973     llvm_ExternalProject_Add(test-suite ${LLVM_MAIN_SRC_DIR}/projects/test-suite
 974       USE_TOOLCHAIN
 975       EXCLUDE_FROM_ALL
 976       NO_INSTALL
 977       ALWAYS_CLEAN)
 978   endif()
 979   add_subdirectory(utils/lit)
 980   add_subdirectory(test)
 981   add_subdirectory(unittests)
 982   if( LLVM_INCLUDE_UTILS )
 983     add_subdirectory(utils/unittest)
 984   endif()
 985
 986   if (WIN32)
 987     # This utility is used to prevent crashing tests from calling Dr. Watson on
 988     # Windows.
 989     add_subdirectory(utils/KillTheDoctor)
 990   endif()
 991
 992   # Add a global check rule now that all subdirectories have been traversed
 993   # and we know the total set of lit testsuites.
 994   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 995   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 996   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 997   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 998   get_property(LLVM_ADDITIONAL_TEST_TARGETS
 999                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
1000   get_property(LLVM_ADDITIONAL_TEST_DEPENDS
1001                GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS)
1002   add_lit_target(check-all
1003     "Running all regression tests"
1004     ${LLVM_LIT_TESTSUITES}
1005     PARAMS ${LLVM_LIT_PARAMS}
1006     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
1007     ARGS ${LLVM_LIT_EXTRA_ARGS}
1008     )
1009   if(TARGET check-runtimes)
1010     add_dependencies(check-all check-runtimes)
1011   endif()
1012   add_custom_target(test-depends
1013                     DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_DEPENDS})
1014   set_target_properties(test-depends PROPERTIES FOLDER "Tests")
1015 endif()
1016
1017 if (LLVM_INCLUDE_DOCS)
1018   add_subdirectory(docs)
1019 endif()
1020
1021 add_subdirectory(cmake/modules)
1022
1023 # Do this last so that all lit targets have already been created.
1024 if (LLVM_INCLUDE_UTILS)
1025   add_subdirectory(utils/llvm-lit)
1026 endif()
1027
1028 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1029   install(DIRECTORY include/llvm include/llvm-c
1030     DESTINATION include
1031     COMPONENT llvm-headers
1032     FILES_MATCHING
1033     PATTERN "*.def"
1034     PATTERN "*.h"
1035     PATTERN "*.td"
1036     PATTERN "*.inc"
1037     PATTERN "LICENSE.TXT"
1038     PATTERN ".svn" EXCLUDE
1039     )
1040
1041   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm ${LLVM_INCLUDE_DIR}/llvm-c
1042     DESTINATION include
1043     COMPONENT llvm-headers
1044     FILES_MATCHING
1045     PATTERN "*.def"
1046     PATTERN "*.h"
1047     PATTERN "*.gen"
1048     PATTERN "*.inc"
1049     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
1050     PATTERN "CMakeFiles" EXCLUDE
1051     PATTERN "config.h" EXCLUDE
1052     PATTERN ".svn" EXCLUDE
1053     )
1054
1055   if (LLVM_INSTALL_MODULEMAPS)
1056     install(DIRECTORY include/llvm include/llvm-c
1057             DESTINATION include
1058             COMPONENT llvm-headers
1059             FILES_MATCHING
1060             PATTERN "module.modulemap"
1061             )
1062     install(FILES include/llvm/module.install.modulemap
1063             DESTINATION include/llvm
1064             COMPONENT llvm-headers
1065             RENAME "module.extern.modulemap"
1066             )
1067   endif(LLVM_INSTALL_MODULEMAPS)
1068
1069   # Installing the headers needs to depend on generating any public
1070   # tablegen'd headers.
1071   add_custom_target(llvm-headers DEPENDS intrinsics_gen)
1072   set_target_properties(llvm-headers PROPERTIES FOLDER "Misc")
1073
1074   if (NOT LLVM_ENABLE_IDE)
1075     add_llvm_install_targets(install-llvm-headers
1076                              DEPENDS llvm-headers
1077                              COMPONENT llvm-headers)
1078   endif()
1079
1080   # Custom target to install all libraries.
1081   add_custom_target(llvm-libraries)
1082   set_target_properties(llvm-libraries PROPERTIES FOLDER "Misc")
1083
1084   if (NOT LLVM_ENABLE_IDE)
1085     add_llvm_install_targets(install-llvm-libraries
1086                              DEPENDS llvm-libraries
1087                              COMPONENT llvm-libraries)
1088   endif()
1089
1090   get_property(LLVM_LIBS GLOBAL PROPERTY LLVM_LIBS)
1091   if(LLVM_LIBS)
1092     list(REMOVE_DUPLICATES LLVM_LIBS)
1093     foreach(lib ${LLVM_LIBS})
1094       add_dependencies(llvm-libraries ${lib})
1095       if (NOT LLVM_ENABLE_IDE)
1096         add_dependencies(install-llvm-libraries install-${lib})
1097       endif()
1098     endforeach()
1099   endif()
1100 endif()
1101
1102 # This must be at the end of the LLVM root CMakeLists file because it must run
1103 # after all targets are created.
1104 if(LLVM_DISTRIBUTION_COMPONENTS)
1105   if(LLVM_ENABLE_IDE)
1106     message(FATAL_ERROR "LLVM_DISTRIBUTION_COMPONENTS cannot be specified with multi-configuration generators (i.e. Xcode or Visual Studio)")
1107   endif()
1108
1109   add_custom_target(distribution)
1110   add_custom_target(install-distribution)
1111   add_custom_target(install-distribution-stripped)
1112   foreach(target ${LLVM_DISTRIBUTION_COMPONENTS} ${LLVM_RUNTIME_DISTRIBUTION_COMPONENTS})
1113     if(TARGET ${target})
1114       add_dependencies(distribution ${target})
1115     else()
1116       message(SEND_ERROR "Specified distribution component '${target}' doesn't have a target")
1117     endif()
1118
1119     if(TARGET install-${target})
1120       add_dependencies(install-distribution install-${target})
1121     else()
1122       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install target")
1123     endif()
1124
1125     if(TARGET install-${target}-stripped)
1126       add_dependencies(install-distribution-stripped install-${target}-stripped)
1127     else()
1128       message(SEND_ERROR "Specified distribution component '${target}' doesn't have an install-stripped target."
1129                          " Its installation target creation should be changed to use add_llvm_install_targets,"
1130                          " or you should manually create the 'install-${target}-stripped' target.")
1131     endif()
1132   endforeach()
1133 endif()
1134
1135 # This allows us to deploy the Universal CRT DLLs by passing -DCMAKE_INSTALL_UCRT_LIBRARIES=ON to CMake
1136 if (MSVC AND CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" AND CMAKE_INSTALL_UCRT_LIBRARIES)
1137   include(InstallRequiredSystemLibraries)
1138 endif()
1139
1140 if (LLVM_INCLUDE_BENCHMARKS)
1141   # Override benchmark defaults so that when the library itself is updated these
1142   # modifications are not lost.
1143   set(BENCHMARK_ENABLE_TESTING OFF CACHE BOOL "Disable benchmark testing" FORCE)
1144   set(BENCHMARK_ENABLE_EXCEPTIONS OFF CACHE BOOL "Disable benchmark exceptions" FORCE)
1145   set(BENCHMARK_ENABLE_INSTALL OFF CACHE BOOL "Don't install benchmark" FORCE)
1146   set(BENCHMARK_DOWNLOAD_DEPENDENCIES OFF CACHE BOOL "Don't download dependencies" FORCE)
1147   set(BENCHMARK_ENABLE_GTEST_TESTS OFF CACHE BOOL "Disable Google Test in benchmark" FORCE)
1148   # Since LLVM requires C++11 it is safe to assume that std::regex is available.
1149   set(HAVE_STD_REGEX ON CACHE BOOL "OK" FORCE)
1150
1151   add_subdirectory(utils/benchmark)
1152   add_subdirectory(benchmarks)
1153 endif()